IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use open qw{:utf8 :std};
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  29         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  30         hook(type => "rcs", id => "rcs_preprevert", call => \&rcs_preprevert);
  31         hook(type => "rcs", id => "rcs_revert", call => \&rcs_revert);
  32         hook(type => "rcs", id => "rcs_find_changes", call => \&rcs_find_changes);
  33         hook(type => "rcs", id => "rcs_get_current_rev", call => \&rcs_get_current_rev);
  34 }
  35
  36 sub checkconfig () {
  37         if (! defined $config{gitorigin_branch}) {
  38                 $config{gitorigin_branch}="origin";
  39         }
  40         if (! defined $config{gitmaster_branch}) {
  41                 $config{gitmaster_branch}="master";
  42         }
  43         if (defined $config{git_wrapper} &&
  44             length $config{git_wrapper}) {
  45                 push @{$config{wrappers}}, {
  46                         wrapper => $config{git_wrapper},
  47                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  48                         wrapper_background_command => $config{git_wrapper_background_command},
  49                 };
  50         }
  51
  52         if (defined $config{git_test_receive_wrapper} &&
  53             length $config{git_test_receive_wrapper} &&
  54             defined $config{untrusted_committers} &&
  55             @{$config{untrusted_committers}}) {
  56                 push @{$config{wrappers}}, {
  57                         test_receive => 1,
  58                         wrapper => $config{git_test_receive_wrapper},
  59                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  60                 };
  61         }
  62
  63         # Avoid notes, parser does not handle and they only slow things down.
  64         $ENV{GIT_NOTES_REF}="";
  65
  66         # Run receive test only if being called by the wrapper, and not
  67         # when generating same.
  68         if ($config{test_receive} && ! exists $config{wrapper}) {
  69                 require IkiWiki::Receive;
  70                 IkiWiki::Receive::test();
  71         }
  72 }
  73
  74 sub getsetup () {
  75         return
  76                 plugin => {
  77                         safe => 0, # rcs plugin
  78                         rebuild => undef,
  79                         section => "rcs",
  80                 },
  81                 git_wrapper => {
  82                         type => "string",
  83                         example => "/git/wiki.git/hooks/post-update",
  84                         description => "git hook to generate",
  85                         safe => 0, # file
  86                         rebuild => 0,
  87                 },
  88                 git_wrapper_background_command => {
  89                         type => "string",
  90                         example => "git push github",
  91                         description => "shell command for git_wrapper to run, in the background",
  92                         safe => 0, # command
  93                         rebuild => 0,
  94                 },
  95                 git_wrappermode => {
  96                         type => "string",
  97                         example => '06755',
  98                         description => "mode for git_wrapper (can safely be made suid)",
  99                         safe => 0,
 100                         rebuild => 0,
 101                 },
 102                 git_test_receive_wrapper => {
 103                         type => "string",
 104                         example => "/git/wiki.git/hooks/pre-receive",
 105                         description => "git pre-receive hook to generate",
 106                         safe => 0, # file
 107                         rebuild => 0,
 108                 },
 109                 untrusted_committers => {
 110                         type => "string",
 111                         example => [],
 112                         description => "unix users whose commits should be checked by the pre-receive hook",
 113                         safe => 0,
 114                         rebuild => 0,
 115                 },
 116                 historyurl => {
 117                         type => "string",
 118                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]];hb=HEAD",
 119                         description => "gitweb url to show file history ([[file]] substituted)",
 120                         safe => 1,
 121                         rebuild => 1,
 122                 },
 123                 diffurl => {
 124                         type => "string",
 125                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 126                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 127                         safe => 1,
 128                         rebuild => 1,
 129                 },
 130                 gitorigin_branch => {
 131                         type => "string",
 132                         example => "origin",
 133                         description => "where to pull and push changes (set to empty string to disable)",
 134                         safe => 0, # paranoia
 135                         rebuild => 0,
 136                 },
 137                 gitmaster_branch => {
 138                         type => "string",
 139                         example => "master",
 140                         description => "branch that the wiki is stored in",
 141                         safe => 0, # paranoia
 142                         rebuild => 0,
 143                 },
 144 }
 145
 146 sub genwrapper {
 147         if ($config{test_receive}) {
 148                 require IkiWiki::Receive;
 149                 return IkiWiki::Receive::genwrapper();
 150         }
 151         else {
 152                 return "";
 153         }
 154 }
 155
 156 my $git_dir=undef;
 157 my $prefix=undef;
 158
 159 sub in_git_dir ($$) {
 160         $git_dir=shift;
 161         my @ret=shift->();
 162         $git_dir=undef;
 163         $prefix=undef;
 164         return @ret;
 165 }
 166
 167 sub safe_git (&@) {
 168         # Start a child process safely without resorting to /bin/sh.
 169         # Returns command output (in list content) or success state
 170         # (in scalar context), or runs the specified data handler.
 171
 172         my ($error_handler, $data_handler, @cmdline) = @_;
 173
 174         my $pid = open my $OUT, "-|";
 175
 176         error("Cannot fork: $!") if !defined $pid;
 177
 178         if (!$pid) {
 179                 # In child.
 180                 # Git commands want to be in wc.
 181                 if (! defined $git_dir) {
 182                         chdir $config{srcdir}
 183                             or error("cannot chdir to $config{srcdir}: $!");
 184                 }
 185                 else {
 186                         chdir $git_dir
 187                             or error("cannot chdir to $git_dir: $!");
 188                 }
 189                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 190         }
 191         # In parent.
 192
 193         # git output is probably utf-8 encoded, but may contain
 194         # other encodings or invalidly encoded stuff. So do not rely
 195         # on the normal utf-8 IO layer, decode it by hand.
 196         binmode($OUT);
 197
 198         my @lines;
 199         while (<$OUT>) {
 200                 $_=decode_utf8($_, 0);
 201
 202                 chomp;
 203
 204                 if (! defined $data_handler) {
 205                         push @lines, $_;
 206                 }
 207                 else {
 208                         last unless $data_handler->($_);
 209                 }
 210         }
 211
 212         close $OUT;
 213
 214         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 215
 216         return wantarray ? @lines : ($? == 0);
 217 }
 218 # Convenient wrappers.
 219 sub run_or_die ($@) { safe_git(\&error, undef, @_) }
 220 sub run_or_cry ($@) { safe_git(sub { warn @_ }, undef, @_) }
 221 sub run_or_non ($@) { safe_git(undef, undef, @_) }
 222
 223
 224 sub merge_past ($$$) {
 225         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 226         # Git merge commands work with the committed changes, except in the
 227         # implicit case of '-m' of git checkout(1).  So we should invent a
 228         # kludge here.  In principle, we need to create a throw-away branch
 229         # in preparing for the merge itself.  Since branches are cheap (and
 230         # branching is fast), this shouldn't cost high.
 231         #
 232         # The main problem is the presence of _uncommitted_ local changes.  One
 233         # possible approach to get rid of this situation could be that we first
 234         # make a temporary commit in the master branch and later restore the
 235         # initial state (this is possible since Git has the ability to undo a
 236         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 237         # as follows:
 238         #
 239         #       - create a diff of HEAD:current-sha1
 240         #       - dummy commit
 241         #       - create a dummy branch and switch to it
 242         #       - rewind to past (reset --hard to the current-sha1)
 243         #       - apply the diff and commit
 244         #       - switch to master and do the merge with the dummy branch
 245         #       - make a soft reset (undo the last commit of master)
 246         #
 247         # The above method has some drawbacks: (1) it needs a redundant commit
 248         # just to get rid of local changes, (2) somewhat slow because of the
 249         # required system forks.  Until someone points a more straight method
 250         # (which I would be grateful) I have implemented an alternative method.
 251         # In this approach, we hide all the modified files from Git by renaming
 252         # them (using the 'rename' builtin) and later restore those files in
 253         # the throw-away branch (that is, we put the files themselves instead
 254         # of applying a patch).
 255
 256         my ($sha1, $file, $message) = @_;
 257
 258         my @undo;      # undo stack for cleanup in case of an error
 259         my $conflict;  # file content with conflict markers
 260
 261         eval {
 262                 # Hide local changes from Git by renaming the modified file.
 263                 # Relative paths must be converted to absolute for renaming.
 264                 my ($target, $hidden) = (
 265                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 266                 );
 267                 rename($target, $hidden)
 268                     or error("rename '$target' to '$hidden' failed: $!");
 269                 # Ensure to restore the renamed file on error.
 270                 push @undo, sub {
 271                         return if ! -e "$hidden"; # already renamed
 272                         rename($hidden, $target)
 273                             or warn "rename '$hidden' to '$target' failed: $!";
 274                 };
 275
 276                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 277
 278                 # Create a throw-away branch and rewind backward.
 279                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 280                 run_or_die('git', 'branch', $branch, $sha1);
 281
 282                 # Switch to throw-away branch for the merge operation.
 283                 push @undo, sub {
 284                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 285                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 286                         }
 287                 };
 288                 run_or_die('git', 'checkout', $branch);
 289
 290                 # Put the modified file in _this_ branch.
 291                 rename($hidden, $target)
 292                     or error("rename '$hidden' to '$target' failed: $!");
 293
 294                 # _Silently_ commit all modifications in the current branch.
 295                 run_or_non('git', 'commit', '-m', $message, '-a');
 296                 # ... and re-switch to master.
 297                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 298
 299                 # Attempt to merge without complaining.
 300                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 301                         $conflict = readfile($target);
 302                         run_or_die('git', 'reset', '--hard');
 303                 }
 304         };
 305         my $failure = $@;
 306
 307         # Process undo stack (in reverse order).  By policy cleanup
 308         # actions should normally print a warning on failure.
 309         while (my $handle = pop @undo) {
 310                 $handle->();
 311         }
 312
 313         error("Git merge failed!\n$failure\n") if $failure;
 314
 315         return $conflict;
 316 }
 317
 318 sub decode_git_file ($) {
 319         my $file=shift;
 320
 321         # git does not output utf-8 filenames, but instead
 322         # double-quotes them with the utf-8 characters
 323         # escaped as \nnn\nnn.
 324         if ($file =~ m/^"(.*)"$/) {
 325                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 326         }
 327
 328         # strip prefix if in a subdir
 329         if (! defined $prefix) {
 330                 ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 331                 if (! defined $prefix) {
 332                         $prefix="";
 333                 }
 334         }
 335         $file =~ s/^\Q$prefix\E//;
 336
 337         return decode("utf8", $file);
 338 }
 339
 340 sub parse_diff_tree ($) {
 341         # Parse the raw diff tree chunk and return the info hash.
 342         # See git-diff-tree(1) for the syntax.
 343         my $dt_ref = shift;
 344
 345         # End of stream?
 346         return if ! @{ $dt_ref } ||
 347                   !defined $dt_ref->[0] || !length $dt_ref->[0];
 348
 349         my %ci;
 350         # Header line.
 351         while (my $line = shift @{ $dt_ref }) {
 352                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 353
 354                 my $sha1 = $2;
 355                 $ci{'sha1'} = $sha1;
 356                 last;
 357         }
 358
 359         # Identification lines for the commit.
 360         while (my $line = shift @{ $dt_ref }) {
 361                 # Regexps are semi-stolen from gitweb.cgi.
 362                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 363                         $ci{'tree'} = $1;
 364                 }
 365                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 366                         # XXX: collecting in reverse order
 367                         push @{ $ci{'parents'} }, $1;
 368                 }
 369                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 370                         my ($who, $name, $epoch, $tz) =
 371                            ($1,   $2,    $3,     $4 );
 372
 373                         $ci{  $who          } = $name;
 374                         $ci{ "${who}_epoch" } = $epoch;
 375                         $ci{ "${who}_tz"    } = $tz;
 376
 377                         if ($name =~ m/^([^<]+)\s+<([^@>]+)/) {
 378                                 $ci{"${who}_name"} = $1;
 379                                 $ci{"${who}_username"} = $2;
 380                         }
 381                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 382                                 $ci{"${who}_username"} = $1;
 383                         }
 384                         else {
 385                                 $ci{"${who}_username"} = $name;
 386                         }
 387                 }
 388                 elsif ($line =~ m/^$/) {
 389                         # Trailing empty line signals next section.
 390                         last;
 391                 }
 392         }
 393
 394         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 395
 396         if (defined $ci{'parents'}) {
 397                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 398         }
 399         else {
 400                 $ci{'parent'} = 0 x 40;
 401         }
 402
 403         # Commit message (optional).
 404         while ($dt_ref->[0] =~ /^    /) {
 405                 my $line = shift @{ $dt_ref };
 406                 $line =~ s/^    //;
 407                 push @{ $ci{'comment'} }, $line;
 408         }
 409         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 410
 411         # Modified files.
 412         while (my $line = shift @{ $dt_ref }) {
 413                 if ($line =~ m{^
 414                         (:+)       # number of parents
 415                         ([^\t]+)\t # modes, sha1, status
 416                         (.*)       # file names
 417                 $}xo) {
 418                         my $num_parents = length $1;
 419                         my @tmp = split(" ", $2);
 420                         my ($file, $file_to) = split("\t", $3);
 421                         my @mode_from = splice(@tmp, 0, $num_parents);
 422                         my $mode_to = shift(@tmp);
 423                         my @sha1_from = splice(@tmp, 0, $num_parents);
 424                         my $sha1_to = shift(@tmp);
 425                         my $status = shift(@tmp);
 426
 427                         if (length $file) {
 428                                 push @{ $ci{'details'} }, {
 429                                         'file'      => decode_git_file($file),
 430                                         'sha1_from' => $sha1_from[0],
 431                                         'sha1_to'   => $sha1_to,
 432                                         'mode_from' => $mode_from[0],
 433                                         'mode_to'   => $mode_to,
 434                                         'status'    => $status,
 435                                 };
 436                         }
 437                         next;
 438                 };
 439                 last;
 440         }
 441
 442         return \%ci;
 443 }
 444
 445 sub git_commit_info ($;$) {
 446         # Return an array of commit info hashes of num commits
 447         # starting from the given sha1sum.
 448         my ($sha1, $num) = @_;
 449
 450         my @opts;
 451         push @opts, "--max-count=$num" if defined $num;
 452
 453         my @raw_lines = run_or_die('git', 'log', @opts,
 454                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 455                 '-r', $sha1, '--', '.');
 456
 457         my @ci;
 458         while (my $parsed = parse_diff_tree(\@raw_lines)) {
 459                 push @ci, $parsed;
 460         }
 461
 462         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 463
 464         return wantarray ? @ci : $ci[0];
 465 }
 466
 467 sub rcs_find_changes ($) {
 468         my $oldrev=shift;
 469
 470         # Note that git log will sometimes show files being added that
 471         # don't exist. Particularly, git merge -s ours can result in a
 472         # merge commit where some files were not really added.
 473         # This is why the code below verifies that the files really
 474         # exist.
 475         my @raw_lines = run_or_die('git', 'log',
 476                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 477                 '--no-renames', , '--reverse',
 478                 '-r', "$oldrev..HEAD", '--', '.');
 479
 480         # Due to --reverse, we see changes in chronological order.
 481         my %changed;
 482         my %deleted;
 483         my $nullsha = 0 x 40;
 484         my $newrev=$oldrev;
 485         while (my $ci = parse_diff_tree(\@raw_lines)) {
 486                 $newrev=$ci->{sha1};
 487                 foreach my $i (@{$ci->{details}}) {
 488                         my $file=$i->{file};
 489                         if ($i->{sha1_to} eq $nullsha) {
 490                                 if (! -e "$config{srcdir}/$file") {
 491                                         delete $changed{$file};
 492                                         $deleted{$file}=1;
 493                                 }
 494                         }
 495                         else {
 496                                 if (-e "$config{srcdir}/$file") {
 497                                         delete $deleted{$file};
 498                                         $changed{$file}=1;
 499                                 }
 500                         }
 501                 }
 502         }
 503
 504         return (\%changed, \%deleted, $newrev);
 505 }
 506
 507 sub git_sha1_file ($) {
 508         my $file=shift;
 509         git_sha1("--", $file);
 510 }
 511
 512 sub git_sha1 (@) {
 513         # Ignore error since a non-existing file might be given.
 514         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 515                 '--', @_);
 516         if (defined $sha1) {
 517                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 518         }
 519         return defined $sha1 ? $sha1 : '';
 520 }
 521
 522 sub rcs_get_current_rev () {
 523         git_sha1();
 524 }
 525
 526 sub rcs_update () {
 527         # Update working directory.
 528
 529         if (length $config{gitorigin_branch}) {
 530                 run_or_cry('git', 'pull', '--prune', $config{gitorigin_branch});
 531         }
 532 }
 533
 534 sub rcs_prepedit ($) {
 535         # Return the commit sha1sum of the file when editing begins.
 536         # This will be later used in rcs_commit if a merge is required.
 537         my ($file) = @_;
 538
 539         return git_sha1_file($file);
 540 }
 541
 542 sub rcs_commit (@) {
 543         # Try to commit the page; returns undef on _success_ and
 544         # a version of the page with the rcs's conflict markers on
 545         # failure.
 546         my %params=@_;
 547
 548         # Check to see if the page has been changed by someone else since
 549         # rcs_prepedit was called.
 550         my $cur    = git_sha1_file($params{file});
 551         my ($prev) = $params{token} =~ /^($sha1_pattern)$/; # untaint
 552
 553         if (defined $cur && defined $prev && $cur ne $prev) {
 554                 my $conflict = merge_past($prev, $params{file}, $dummy_commit_msg);
 555                 return $conflict if defined $conflict;
 556         }
 557
 558         return rcs_commit_helper(@_);
 559 }
 560
 561 sub rcs_commit_staged (@) {
 562         # Commits all staged changes. Changes can be staged using rcs_add,
 563         # rcs_remove, and rcs_rename.
 564         return rcs_commit_helper(@_);
 565 }
 566
 567 sub rcs_commit_helper (@) {
 568         my %params=@_;
 569
 570         my %env=%ENV;
 571
 572         if (defined $params{session}) {
 573                 # Set the commit author and email based on web session info.
 574                 my $u;
 575                 if (defined $params{session}->param("name")) {
 576                         $u=$params{session}->param("name");
 577                 }
 578                 elsif (defined $params{session}->remote_addr()) {
 579                         $u=$params{session}->remote_addr();
 580                 }
 581                 if (defined $u) {
 582                         $u=encode_utf8($u);
 583                         $ENV{GIT_AUTHOR_NAME}=$u;
 584                 }
 585                 if (defined $params{session}->param("nickname")) {
 586                         $u=encode_utf8($params{session}->param("nickname"));
 587                         $u=~s/\s+/_/g;
 588                         $u=~s/[^-_0-9[:alnum:]]+//g;
 589                 }
 590                 if (defined $u) {
 591                         $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 592                 }
 593         }
 594
 595         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 596         my @opts;
 597         if ($params{message} !~ /\S/) {
 598                 # Force git to allow empty commit messages.
 599                 # (If this version of git supports it.)
 600                 my ($version)=`git --version` =~ /git version (.*)/;
 601                 if ($version ge "1.7.8") {
 602                         push @opts, "--allow-empty-message", "--no-edit";
 603                 }
 604                 if ($version ge "1.7.2") {
 605                         push @opts, "--allow-empty-message";
 606                 }
 607                 elsif ($version ge "1.5.4") {
 608                         push @opts, '--cleanup=verbatim';
 609                 }
 610                 else {
 611                         $params{message}.=".";
 612                 }
 613         }
 614         if (exists $params{file}) {
 615                 push @opts, '--', $params{file};
 616         }
 617         # git commit returns non-zero if nothing really changed.
 618         # So we should ignore its exit status (hence run_or_non).
 619         if (run_or_non('git', 'commit', '-m', $params{message}, '-q', @opts)) {
 620                 if (length $config{gitorigin_branch}) {
 621                         run_or_cry('git', 'push', $config{gitorigin_branch}, $config{gitmaster_branch});
 622                 }
 623         }
 624
 625         %ENV=%env;
 626         return undef; # success
 627 }
 628
 629 sub rcs_add ($) {
 630         # Add file to archive.
 631
 632         my ($file) = @_;
 633
 634         run_or_cry('git', 'add', $file);
 635 }
 636
 637 sub rcs_remove ($) {
 638         # Remove file from archive.
 639
 640         my ($file) = @_;
 641
 642         run_or_cry('git', 'rm', '-f', $file);
 643 }
 644
 645 sub rcs_rename ($$) {
 646         my ($src, $dest) = @_;
 647
 648         run_or_cry('git', 'mv', '-f', $src, $dest);
 649 }
 650
 651 sub rcs_recentchanges ($) {
 652         # List of recent changes.
 653
 654         my ($num) = @_;
 655
 656         eval q{use Date::Parse};
 657         error($@) if $@;
 658
 659         my @rets;
 660         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 661                 # Skip redundant commits.
 662                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 663
 664                 my ($sha1, $when) = (
 665                         $ci->{'sha1'},
 666                         $ci->{'author_epoch'}
 667                 );
 668
 669                 my @pages;
 670                 foreach my $detail (@{ $ci->{'details'} }) {
 671                         my $file = $detail->{'file'};
 672                         my $efile = join('/',
 673                                 map { uri_escape_utf8($_) } split('/', $file)
 674                         );
 675
 676                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 677                         $diffurl =~ s/\[\[file\]\]/$efile/go;
 678                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 679                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 680                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 681                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 682
 683                         push @pages, {
 684                                 page => pagename($file),
 685                                 diffurl => $diffurl,
 686                         };
 687                 }
 688
 689                 my @messages;
 690                 my $pastblank=0;
 691                 foreach my $line (@{$ci->{'comment'}}) {
 692                         $pastblank=1 if $line eq '';
 693                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 694                         push @messages, { line => $line };
 695                 }
 696
 697                 my $user=$ci->{'author_username'};
 698                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 699                 my $nickname;
 700
 701                 # Set nickname only if a non-url author_username is available,
 702                 # and author_name is an url.
 703                 if ($user !~ /:\/\// && defined $ci->{'author_name'} &&
 704                     $ci->{'author_name'} =~ /:\/\//) {
 705                         $nickname=$user;
 706                         $user=$ci->{'author_name'};
 707                 }
 708
 709                 # compatability code for old web commit messages
 710                 if (! $web_commit &&
 711                       defined $messages[0] &&
 712                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 713                         $user = defined $2 ? "$2" : "$3";
 714                         $messages[0]->{line} = $4;
 715                         $web_commit=1;
 716                 }
 717
 718                 push @rets, {
 719                         rev        => $sha1,
 720                         user       => $user,
 721                         nickname   => $nickname,
 722                         committype => $web_commit ? "web" : "git",
 723                         when       => $when,
 724                         message    => [@messages],
 725                         pages      => [@pages],
 726                 } if @pages;
 727
 728                 last if @rets >= $num;
 729         }
 730
 731         return @rets;
 732 }
 733
 734 sub rcs_diff ($;$) {
 735         my $rev=shift;
 736         my $maxlines=shift;
 737         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 738         my @lines;
 739         my $addlines=sub {
 740                 my $line=shift;
 741                 return if defined $maxlines && @lines == $maxlines;
 742                 push @lines, $line."\n"
 743                         if (@lines || $line=~/^diff --git/);
 744                 return 1;
 745         };
 746         safe_git(undef, $addlines, "git", "show", $sha1);
 747         if (wantarray) {
 748                 return @lines;
 749         }
 750         else {
 751                 return join("", @lines);
 752         }
 753 }
 754
 755 {
 756 my %time_cache;
 757
 758 sub findtimes ($$) {
 759         my $file=shift;
 760         my $id=shift; # 0 = mtime ; 1 = ctime
 761
 762         if (! keys %time_cache) {
 763                 my $date;
 764                 foreach my $line (run_or_die('git', 'log',
 765                                 '--pretty=format:%at',
 766                                 '--name-only', '--relative')) {
 767                         if (! defined $date && $line =~ /^(\d+)$/) {
 768                                 $date=$line;
 769                         }
 770                         elsif (! length $line) {
 771                                 $date=undef;
 772                         }
 773                         else {
 774                                 my $f=decode_git_file($line);
 775
 776                                 if (! $time_cache{$f}) {
 777                                         $time_cache{$f}[0]=$date; # mtime
 778                                 }
 779                                 $time_cache{$f}[1]=$date; # ctime
 780                         }
 781                 }
 782         }
 783
 784         return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
 785 }
 786
 787 }
 788
 789 sub rcs_getctime ($) {
 790         my $file=shift;
 791
 792         return findtimes($file, 1);
 793 }
 794
 795 sub rcs_getmtime ($) {
 796         my $file=shift;
 797
 798         return findtimes($file, 0);
 799 }
 800
 801 {
 802 my $ret;
 803 sub git_find_root {
 804         # The wiki may not be the only thing in the git repo.
 805         # Determine if it is in a subdirectory by examining the srcdir,
 806         # and its parents, looking for the .git directory.
 807
 808         return @$ret if defined $ret;
 809
 810         my $subdir="";
 811         my $dir=$config{srcdir};
 812         while (! -d "$dir/.git") {
 813                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 814                 $dir=IkiWiki::dirname($dir);
 815                 if (! length $dir) {
 816                         error("cannot determine root of git repo");
 817                 }
 818         }
 819
 820         $ret=[$subdir, $dir];
 821         return @$ret;
 822 }
 823
 824 }
 825
 826 sub git_parse_changes {
 827         my $reverted = shift;
 828         my @changes = @_;
 829
 830         my ($subdir, $rootdir) = git_find_root();
 831         my @rets;
 832         foreach my $ci (@changes) {
 833                 foreach my $detail (@{ $ci->{'details'} }) {
 834                         my $file = $detail->{'file'};
 835
 836                         # check that all changed files are in the subdir
 837                         if (length $subdir &&
 838                             ! ($file =~ s/^\Q$subdir\E//)) {
 839                                 error sprintf(gettext("you are not allowed to change %s"), $file);
 840                         }
 841
 842                         my ($action, $mode, $path);
 843                         if ($detail->{'status'} =~ /^[M]+\d*$/) {
 844                                 $action="change";
 845                                 $mode=$detail->{'mode_to'};
 846                         }
 847                         elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 848                                 $action= $reverted ? "remove" : "add";
 849                                 $mode=$detail->{'mode_to'};
 850                         }
 851                         elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 852                                 $action= $reverted ? "add" : "remove";
 853                                 $mode=$detail->{'mode_from'};
 854                         }
 855                         else {
 856                                 error "unknown status ".$detail->{'status'};
 857                         }
 858
 859                         # test that the file mode is ok
 860                         if ($mode !~ /^100[64][64][64]$/) {
 861                                 error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 862                         }
 863                         if ($action eq "change") {
 864                                 if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 865                                         error gettext("you are not allowed to change file modes");
 866                                 }
 867                         }
 868
 869                         # extract attachment to temp file
 870                         if (($action eq 'add' || $action eq 'change') &&
 871                             ! pagetype($file)) {
 872                                 eval q{use File::Temp};
 873                                 die $@ if $@;
 874                                 my $fh;
 875                                 ($fh, $path)=File::Temp::tempfile(undef, UNLINK => 1);
 876                                 my $cmd = "cd $git_dir && ".
 877                                           "git show $detail->{sha1_to} > '$path'";
 878                                 if (system($cmd) != 0) {
 879                                         error("failed writing temp file '$path'.");
 880                                 }
 881                         }
 882
 883                         push @rets, {
 884                                 file => $file,
 885                                 action => $action,
 886                                 path => $path,
 887                         };
 888                 }
 889         }
 890
 891         return @rets;
 892 }
 893
 894 sub rcs_receive () {
 895         my @rets;
 896         while (<>) {
 897                 chomp;
 898                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 899
 900                 # only allow changes to gitmaster_branch
 901                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 902                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 903                 }
 904
 905                 # Avoid chdir when running git here, because the changes
 906                 # are in the master git repo, not the srcdir repo.
 907                 # (Also, if a subdir is involved, we don't want to chdir to
 908                 # it and only see changes in it.)
 909                 # The pre-receive hook already puts us in the right place.
 910                 in_git_dir(".", sub {
 911                         push @rets, git_parse_changes(0, git_commit_info($oldrev."..".$newrev));
 912                 });
 913         }
 914
 915         return reverse @rets;
 916 }
 917
 918 sub rcs_preprevert ($) {
 919         my $rev=shift;
 920         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 921
 922         # Examine changes from root of git repo, not from any subdir,
 923         # in order to see all changes.
 924         my ($subdir, $rootdir) = git_find_root();
 925         in_git_dir($rootdir, sub {
 926                 my @commits=git_commit_info($sha1, 1);
 927
 928                 if (! @commits) {
 929                         error "unknown commit"; # just in case
 930                 }
 931
 932                 # git revert will fail on merge commits. Add a nice message.
 933                 if (exists $commits[0]->{parents} &&
 934                     @{$commits[0]->{parents}} > 1) {
 935                         error gettext("you are not allowed to revert a merge");
 936                 }
 937
 938                 git_parse_changes(1, @commits);
 939         });
 940 }
 941
 942 sub rcs_revert ($) {
 943         # Try to revert the given rev; returns undef on _success_.
 944         my $rev = shift;
 945         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 946
 947         if (run_or_non('git', 'revert', '--no-commit', $sha1)) {
 948                 return undef;
 949         }
 950         else {
 951                 run_or_die('git', 'reset', '--hard');
 952                 return sprintf(gettext("Failed to revert commit %s"), $sha1);
 953         }
 954 }
 955
 956 1