IkiWiki/Plugin/shortcut.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::shortcut;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "shortcut", call => \&getsetup);
  10         hook(type => "checkconfig", id => "shortcut", call => \&checkconfig);
  11         hook(type => "preprocess", id => "shortcut", call => \&preprocess_shortcut);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                 },
  20 }
  21
  22 sub checkconfig () {
  23         if (defined $config{srcdir}) {
  24                 # Preprocess the shortcuts page to get all the available shortcuts
  25                 # defined before other pages are rendered.
  26                 my $srcfile=srcfile("shortcuts.mdwn", 1);
  27                 if (! defined $srcfile) {
  28                         error(gettext("shortcut plugin will not work without a shortcuts.mdwn"));
  29                 }
  30                 IkiWiki::preprocess("shortcuts", "shortcuts", readfile($srcfile));
  31         }
  32 }
  33
  34 sub preprocess_shortcut (@) {
  35         my %params=@_;
  36
  37         if (! defined $params{name} || ! defined $params{url}) {
  38                 error gettext("missing name or url parameter");
  39         }
  40
  41         hook(type => "preprocess", no_override => 1, id => $params{name},
  42                 shortcut => 1,
  43                 call => sub { shortcut_expand($params{url}, $params{desc}, @_) });
  44
  45         #translators: This is used to display what shortcuts are defined.
  46         #translators: First parameter is the name of the shortcut, the second
  47         #translators: is an URL.
  48         return sprintf(gettext("shortcut %s points to <i>%s</i>"), $params{name}, $params{url});
  49 }
  50
  51 sub shortcut_expand ($$@) {
  52         my $url=shift;
  53         my $desc=shift;
  54         my %params=@_;
  55
  56         # Get params in original order.
  57         my @params;
  58         while (@_) {
  59                 my $key=shift;
  60                 my $value=shift;
  61                 push @params, $key if ! length $value;
  62         }
  63
  64         # If the shortcuts page changes, all pages that use shortcuts will
  65         # need to be updated.
  66         add_depends($params{destpage}, "shortcuts");
  67
  68         my $text=join(" ", @params);
  69         my $encoded_text=$text;
  70         $encoded_text=~s/([^A-Za-z0-9])/sprintf("%%%02X", ord($1))/seg;
  71
  72         $url=~s{\%([sS])}{
  73                 $1 eq 's' ? $encoded_text : $text
  74         }eg;
  75
  76         $text=~s/_/ /g;
  77         if (defined $params{desc}) {
  78                 $desc=$params{desc};
  79         }
  80         if (defined $desc) {
  81                 $desc=~s/\%s/$text/g;
  82         }
  83         else {
  84                 $desc=$text;
  85         }
  86
  87         return "<a href=\"$url\">$desc</a>";
  88 }
  89
  90 1