IkiWiki/Plugin/pagestats.pm

   1 #!/usr/bin/perl
   2 #
   3 # Produce page statistics in various forms.
   4 #
   5 # Currently supported:
   6 #   cloud: produces statistics in the form of a del.icio.us-style tag cloud
   7 #          (default)
   8 #   table: produces a table with the number of backlinks for each page
   9 #
  10 # by Enrico Zini
  11 package IkiWiki::Plugin::pagestats;
  12
  13 use warnings;
  14 use strict;
  15 use IkiWiki;
  16
  17 # Names of the HTML classes to use for the tag cloud
  18 our @classes = ('smallestPC', 'smallPC', 'normalPC', 'bigPC', 'biggestPC' );
  19
  20 sub import { #{{{
  21         hook(type => "preprocess", id => "pagestats", call => \&preprocess);
  22 } # }}}
  23
  24 sub preprocess (@) { #{{{
  25         my %params=@_;
  26         $params{pages}="*" unless defined $params{pages};
  27         my $style = ($params{style} or 'cloud');
  28
  29         # Needs to update whenever a page is added or removed, so
  30         # register a dependency.
  31         add_depends($params{page}, $params{pages});
  32
  33         my %counts;
  34         my $max = 0;
  35         foreach my $page (keys %links) {
  36                 if (pagespec_match($page, $params{pages})) {
  37                         my @bl = IkiWiki::backlinks($page);
  38                         $counts{$page} = scalar(@bl);
  39                         $max = $counts{$page} if $counts{$page} > $max;
  40                 }
  41         }
  42
  43         if ($style eq 'table') {
  44                 return "<table class='pageStats'>\n".
  45                         join("\n", map {
  46                                 "<tr><td>".
  47                                 htmllink($params{page}, $params{destpage}, $_, 1).
  48                                 "</td><td>".$counts{$_}."</td></tr>"
  49                         }
  50                         sort { $counts{$b} <=> $counts{$a} } keys %counts).
  51                         "\n</table>\n" ;
  52         } else {
  53                 # In case of misspelling, default to a page cloud
  54
  55                 my $res = "<div class='pagecloud'>\n";
  56                 foreach my $page (sort keys %counts) {
  57                         my $class = $classes[$counts{$page} * scalar(@classes) / ($max + 1)];
  58                         $res .= "<span class=\"$class\">".
  59                                 htmllink($params{page}, $params{destpage}, $page).
  60                                 "</span>\n";
  61                 }
  62                 $res .= "</div>\n";
  63
  64                 return $res;
  65         }
  66 } # }}}
  67
  68 1