IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use HTML::Entities;
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX ();
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15             %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16             %pagesources %destsources %depends %depends_simple %hooks
  17             %forcerebuild %loaded_plugins %typedlinks %oldtypedlinks};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error template htmlpage deptype
  21                  add_depends pagespec_match pagespec_match_list bestlink
  22                  htmllink readfile writefile pagetype srcfile pagename
  23                  displaytime will_render gettext ngettext urlto targetpage
  24                  add_underlay pagetitle titlepage linkpage newpagefile
  25                  inject add_link
  26                  %config %links %pagestate %wikistate %renderedfiles
  27                  %pagesources %destsources %typedlinks);
  28 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  29 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  30 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  31
  32 # Page dependency types.
  33 our $DEPEND_CONTENT=1;
  34 our $DEPEND_PRESENCE=2;
  35 our $DEPEND_LINKS=4;
  36
  37 # Optimisation.
  38 use Memoize;
  39 memoize("abs2rel");
  40 memoize("sortspec_translate");
  41 memoize("pagespec_translate");
  42 memoize("template_file");
  43
  44 sub getsetup () {
  45         wikiname => {
  46                 type => "string",
  47                 default => "wiki",
  48                 description => "name of the wiki",
  49                 safe => 1,
  50                 rebuild => 1,
  51         },
  52         adminemail => {
  53                 type => "string",
  54                 default => undef,
  55                 example => 'me@example.com',
  56                 description => "contact email for wiki",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         adminuser => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are wiki admins",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         banned_users => {
  68                 type => "string",
  69                 default => [],
  70                 description => "users who are banned from the wiki",
  71                 safe => 1,
  72                 rebuild => 0,
  73         },
  74         srcdir => {
  75                 type => "string",
  76                 default => undef,
  77                 example => "$ENV{HOME}/wiki",
  78                 description => "where the source of the wiki is located",
  79                 safe => 0, # path
  80                 rebuild => 1,
  81         },
  82         destdir => {
  83                 type => "string",
  84                 default => undef,
  85                 example => "/var/www/wiki",
  86                 description => "where to build the wiki",
  87                 safe => 0, # path
  88                 rebuild => 1,
  89         },
  90         url => {
  91                 type => "string",
  92                 default => '',
  93                 example => "http://example.com/wiki",
  94                 description => "base url to the wiki",
  95                 safe => 1,
  96                 rebuild => 1,
  97         },
  98         cgiurl => {
  99                 type => "string",
 100                 default => '',
 101                 example => "http://example.com/wiki/ikiwiki.cgi",
 102                 description => "url to the ikiwiki.cgi",
 103                 safe => 1,
 104                 rebuild => 1,
 105         },
 106         cgi_wrapper => {
 107                 type => "string",
 108                 default => '',
 109                 example => "/var/www/wiki/ikiwiki.cgi",
 110                 description => "filename of cgi wrapper to generate",
 111                 safe => 0, # file
 112                 rebuild => 0,
 113         },
 114         cgi_wrappermode => {
 115                 type => "string",
 116                 default => '06755',
 117                 description => "mode for cgi_wrapper (can safely be made suid)",
 118                 safe => 0,
 119                 rebuild => 0,
 120         },
 121         rcs => {
 122                 type => "string",
 123                 default => '',
 124                 description => "rcs backend to use",
 125                 safe => 0, # don't allow overriding
 126                 rebuild => 0,
 127         },
 128         default_plugins => {
 129                 type => "internal",
 130                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 131                                 openid signinedit lockedit conditional
 132                                 recentchanges parentlinks editpage}],
 133                 description => "plugins to enable by default",
 134                 safe => 0,
 135                 rebuild => 1,
 136         },
 137         add_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to add to the default configuration",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         disable_plugins => {
 145                 type => "string",
 146                 default => [],
 147                 description => "plugins to disable",
 148                 safe => 1,
 149                 rebuild => 1,
 150         },
 151         templatedir => {
 152                 type => "string",
 153                 default => "$installdir/share/ikiwiki/templates",
 154                 description => "location of template files",
 155                 advanced => 1,
 156                 safe => 0, # path
 157                 rebuild => 1,
 158         },
 159         templatedirs => {
 160                 type => "internal",
 161                 default => [],
 162                 description => "additional directories containing template files",
 163                 safe => 0,
 164                 rebuild => 0,
 165         },
 166         underlaydir => {
 167                 type => "string",
 168                 default => "$installdir/share/ikiwiki/basewiki",
 169                 description => "base wiki source location",
 170                 advanced => 1,
 171                 safe => 0, # path
 172                 rebuild => 0,
 173         },
 174         underlaydirbase => {
 175                 type => "internal",
 176                 default => "$installdir/share/ikiwiki",
 177                 description => "parent directory containing additional underlays",
 178                 safe => 0,
 179                 rebuild => 0,
 180         },
 181         wrappers => {
 182                 type => "internal",
 183                 default => [],
 184                 description => "wrappers to generate",
 185                 safe => 0,
 186                 rebuild => 0,
 187         },
 188         underlaydirs => {
 189                 type => "internal",
 190                 default => [],
 191                 description => "additional underlays to use",
 192                 safe => 0,
 193                 rebuild => 0,
 194         },
 195         verbose => {
 196                 type => "boolean",
 197                 example => 1,
 198                 description => "display verbose messages?",
 199                 safe => 1,
 200                 rebuild => 0,
 201         },
 202         syslog => {
 203                 type => "boolean",
 204                 example => 1,
 205                 description => "log to syslog?",
 206                 safe => 1,
 207                 rebuild => 0,
 208         },
 209         usedirs => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "create output files named page/index.html?",
 213                 safe => 0, # changing requires manual transition
 214                 rebuild => 1,
 215         },
 216         prefix_directives => {
 217                 type => "boolean",
 218                 default => 1,
 219                 description => "use '!'-prefixed preprocessor directives?",
 220                 safe => 0, # changing requires manual transition
 221                 rebuild => 1,
 222         },
 223         indexpages => {
 224                 type => "boolean",
 225                 default => 0,
 226                 description => "use page/index.mdwn source files",
 227                 safe => 1,
 228                 rebuild => 1,
 229         },
 230         discussion => {
 231                 type => "boolean",
 232                 default => 1,
 233                 description => "enable Discussion pages?",
 234                 safe => 1,
 235                 rebuild => 1,
 236         },
 237         discussionpage => {
 238                 type => "string",
 239                 default => gettext("Discussion"),
 240                 description => "name of Discussion pages",
 241                 safe => 1,
 242                 rebuild => 1,
 243         },
 244         sslcookie => {
 245                 type => "boolean",
 246                 default => 0,
 247                 description => "only send cookies over SSL connections?",
 248                 advanced => 1,
 249                 safe => 1,
 250                 rebuild => 0,
 251         },
 252         default_pageext => {
 253                 type => "string",
 254                 default => "mdwn",
 255                 description => "extension to use for new pages",
 256                 safe => 0, # not sanitized
 257                 rebuild => 0,
 258         },
 259         htmlext => {
 260                 type => "string",
 261                 default => "html",
 262                 description => "extension to use for html files",
 263                 safe => 0, # not sanitized
 264                 rebuild => 1,
 265         },
 266         timeformat => {
 267                 type => "string",
 268                 default => '%c',
 269                 description => "strftime format string to display date",
 270                 advanced => 1,
 271                 safe => 1,
 272                 rebuild => 1,
 273         },
 274         locale => {
 275                 type => "string",
 276                 default => undef,
 277                 example => "en_US.UTF-8",
 278                 description => "UTF-8 locale to use",
 279                 advanced => 1,
 280                 safe => 0,
 281                 rebuild => 1,
 282         },
 283         userdir => {
 284                 type => "string",
 285                 default => "",
 286                 example => "users",
 287                 description => "put user pages below specified page",
 288                 safe => 1,
 289                 rebuild => 1,
 290         },
 291         numbacklinks => {
 292                 type => "integer",
 293                 default => 10,
 294                 description => "how many backlinks to show before hiding excess (0 to show all)",
 295                 safe => 1,
 296                 rebuild => 1,
 297         },
 298         hardlink => {
 299                 type => "boolean",
 300                 default => 0,
 301                 description => "attempt to hardlink source files? (optimisation for large files)",
 302                 advanced => 1,
 303                 safe => 0, # paranoia
 304                 rebuild => 0,
 305         },
 306         umask => {
 307                 type => "integer",
 308                 example => "022",
 309                 description => "force ikiwiki to use a particular umask",
 310                 advanced => 1,
 311                 safe => 0, # paranoia
 312                 rebuild => 0,
 313         },
 314         wrappergroup => {
 315                 type => "string",
 316                 example => "ikiwiki",
 317                 description => "group for wrappers to run in",
 318                 advanced => 1,
 319                 safe => 0, # paranoia
 320                 rebuild => 0,
 321         },
 322         libdir => {
 323                 type => "string",
 324                 default => "",
 325                 example => "$ENV{HOME}/.ikiwiki/",
 326                 description => "extra library and plugin directory",
 327                 advanced => 1,
 328                 safe => 0, # directory
 329                 rebuild => 0,
 330         },
 331         ENV => {
 332                 type => "string",
 333                 default => {},
 334                 description => "environment variables",
 335                 safe => 0, # paranoia
 336                 rebuild => 0,
 337         },
 338         include => {
 339                 type => "string",
 340                 default => undef,
 341                 example => '^\.htaccess$',
 342                 description => "regexp of normally excluded files to include",
 343                 advanced => 1,
 344                 safe => 0, # regexp
 345                 rebuild => 1,
 346         },
 347         exclude => {
 348                 type => "string",
 349                 default => undef,
 350                 example => '^(*\.private|Makefile)$',
 351                 description => "regexp of files that should be skipped",
 352                 advanced => 1,
 353                 safe => 0, # regexp
 354                 rebuild => 1,
 355         },
 356         wiki_file_prune_regexps => {
 357                 type => "internal",
 358                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 359                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 360                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 361                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 362                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 363                 description => "regexps of source files to ignore",
 364                 safe => 0,
 365                 rebuild => 1,
 366         },
 367         wiki_file_chars => {
 368                 type => "string",
 369                 description => "specifies the characters that are allowed in source filenames",
 370                 default => "-[:alnum:]+/.:_",
 371                 safe => 0,
 372                 rebuild => 1,
 373         },
 374         wiki_file_regexp => {
 375                 type => "internal",
 376                 description => "regexp of legal source files",
 377                 safe => 0,
 378                 rebuild => 1,
 379         },
 380         web_commit_regexp => {
 381                 type => "internal",
 382                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 383                 description => "regexp to parse web commits from logs",
 384                 safe => 0,
 385                 rebuild => 0,
 386         },
 387         cgi => {
 388                 type => "internal",
 389                 default => 0,
 390                 description => "run as a cgi",
 391                 safe => 0,
 392                 rebuild => 0,
 393         },
 394         cgi_disable_uploads => {
 395                 type => "internal",
 396                 default => 1,
 397                 description => "whether CGI should accept file uploads",
 398                 safe => 0,
 399                 rebuild => 0,
 400         },
 401         post_commit => {
 402                 type => "internal",
 403                 default => 0,
 404                 description => "run as a post-commit hook",
 405                 safe => 0,
 406                 rebuild => 0,
 407         },
 408         rebuild => {
 409                 type => "internal",
 410                 default => 0,
 411                 description => "running in rebuild mode",
 412                 safe => 0,
 413                 rebuild => 0,
 414         },
 415         setup => {
 416                 type => "internal",
 417                 default => undef,
 418                 description => "running in setup mode",
 419                 safe => 0,
 420                 rebuild => 0,
 421         },
 422         clean => {
 423                 type => "internal",
 424                 default => 0,
 425                 description => "running in clean mode",
 426                 safe => 0,
 427                 rebuild => 0,
 428         },
 429         refresh => {
 430                 type => "internal",
 431                 default => 0,
 432                 description => "running in refresh mode",
 433                 safe => 0,
 434                 rebuild => 0,
 435         },
 436         test_receive => {
 437                 type => "internal",
 438                 default => 0,
 439                 description => "running in receive test mode",
 440                 safe => 0,
 441                 rebuild => 0,
 442         },
 443         gettime => {
 444                 type => "internal",
 445                 description => "running in gettime mode",
 446                 safe => 0,
 447                 rebuild => 0,
 448         },
 449         w3mmode => {
 450                 type => "internal",
 451                 default => 0,
 452                 description => "running in w3mmode",
 453                 safe => 0,
 454                 rebuild => 0,
 455         },
 456         wikistatedir => {
 457                 type => "internal",
 458                 default => undef,
 459                 description => "path to the .ikiwiki directory holding ikiwiki state",
 460                 safe => 0,
 461                 rebuild => 0,
 462         },
 463         setupfile => {
 464                 type => "internal",
 465                 default => undef,
 466                 description => "path to setup file",
 467                 safe => 0,
 468                 rebuild => 0,
 469         },
 470         setuptype => {
 471                 type => "internal",
 472                 default => "Standard",
 473                 description => "perl class to use to dump setup file",
 474                 safe => 0,
 475                 rebuild => 0,
 476         },
 477         allow_symlinks_before_srcdir => {
 478                 type => "boolean",
 479                 default => 0,
 480                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 481                 safe => 0,
 482                 rebuild => 0,
 483         },
 484 }
 485
 486 sub defaultconfig () {
 487         my %s=getsetup();
 488         my @ret;
 489         foreach my $key (keys %s) {
 490                 push @ret, $key, $s{$key}->{default};
 491         }
 492         use Data::Dumper;
 493         return @ret;
 494 }
 495
 496 sub checkconfig () {
 497         # locale stuff; avoid LC_ALL since it overrides everything
 498         if (defined $ENV{LC_ALL}) {
 499                 $ENV{LANG} = $ENV{LC_ALL};
 500                 delete $ENV{LC_ALL};
 501         }
 502         if (defined $config{locale}) {
 503                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 504                         $ENV{LANG}=$config{locale};
 505                         define_gettext();
 506                 }
 507         }
 508
 509         if (! defined $config{wiki_file_regexp}) {
 510                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 511         }
 512
 513         if (ref $config{ENV} eq 'HASH') {
 514                 foreach my $val (keys %{$config{ENV}}) {
 515                         $ENV{$val}=$config{ENV}{$val};
 516                 }
 517         }
 518
 519         if ($config{w3mmode}) {
 520                 eval q{use Cwd q{abs_path}};
 521                 error($@) if $@;
 522                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 523                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 524                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 525                         unless $config{cgiurl} =~ m!file:///!;
 526                 $config{url}="file://".$config{destdir};
 527         }
 528
 529         if ($config{cgi} && ! length $config{url}) {
 530                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 531         }
 532
 533         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 534                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 535
 536         if (defined $config{umask}) {
 537                 umask(possibly_foolish_untaint($config{umask}));
 538         }
 539
 540         run_hooks(checkconfig => sub { shift->() });
 541
 542         return 1;
 543 }
 544
 545 sub listplugins () {
 546         my %ret;
 547
 548         foreach my $dir (@INC, $config{libdir}) {
 549                 next unless defined $dir && length $dir;
 550                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 551                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 552                         $ret{$plugin}=1;
 553                 }
 554         }
 555         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 556                 next unless defined $dir && length $dir;
 557                 foreach my $file (glob("$dir/plugins/*")) {
 558                         $ret{basename($file)}=1 if -x $file;
 559                 }
 560         }
 561
 562         return keys %ret;
 563 }
 564
 565 sub loadplugins () {
 566         if (defined $config{libdir} && length $config{libdir}) {
 567                 unshift @INC, possibly_foolish_untaint($config{libdir});
 568         }
 569
 570         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 571                 loadplugin($plugin);
 572         }
 573
 574         if ($config{rcs}) {
 575                 if (exists $hooks{rcs}) {
 576                         error(gettext("cannot use multiple rcs plugins"));
 577                 }
 578                 loadplugin($config{rcs});
 579         }
 580         if (! exists $hooks{rcs}) {
 581                 loadplugin("norcs");
 582         }
 583
 584         run_hooks(getopt => sub { shift->() });
 585         if (grep /^-/, @ARGV) {
 586                 print STDERR "Unknown option (or missing parameter): $_\n"
 587                         foreach grep /^-/, @ARGV;
 588                 usage();
 589         }
 590
 591         return 1;
 592 }
 593
 594 sub loadplugin ($) {
 595         my $plugin=shift;
 596
 597         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 598
 599         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 600                          "$installdir/lib/ikiwiki") {
 601                 if (defined $dir && -x "$dir/plugins/$plugin") {
 602                         eval { require IkiWiki::Plugin::external };
 603                         if ($@) {
 604                                 my $reason=$@;
 605                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 606                         }
 607                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 608                         $loaded_plugins{$plugin}=1;
 609                         return 1;
 610                 }
 611         }
 612
 613         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 614         eval qq{use $mod};
 615         if ($@) {
 616                 error("Failed to load plugin $mod: $@");
 617         }
 618         $loaded_plugins{$plugin}=1;
 619         return 1;
 620 }
 621
 622 sub error ($;$) {
 623         my $message=shift;
 624         my $cleaner=shift;
 625         log_message('err' => $message) if $config{syslog};
 626         if (defined $cleaner) {
 627                 $cleaner->();
 628         }
 629         die $message."\n";
 630 }
 631
 632 sub debug ($) {
 633         return unless $config{verbose};
 634         return log_message(debug => @_);
 635 }
 636
 637 my $log_open=0;
 638 sub log_message ($$) {
 639         my $type=shift;
 640
 641         if ($config{syslog}) {
 642                 require Sys::Syslog;
 643                 if (! $log_open) {
 644                         Sys::Syslog::setlogsock('unix');
 645                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 646                         $log_open=1;
 647                 }
 648                 return eval {
 649                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 650                 };
 651         }
 652         elsif (! $config{cgi}) {
 653                 return print "@_\n";
 654         }
 655         else {
 656                 return print STDERR "@_\n";
 657         }
 658 }
 659
 660 sub possibly_foolish_untaint ($) {
 661         my $tainted=shift;
 662         my ($untainted)=$tainted=~/(.*)/s;
 663         return $untainted;
 664 }
 665
 666 sub basename ($) {
 667         my $file=shift;
 668
 669         $file=~s!.*/+!!;
 670         return $file;
 671 }
 672
 673 sub dirname ($) {
 674         my $file=shift;
 675
 676         $file=~s!/*[^/]+$!!;
 677         return $file;
 678 }
 679
 680 sub isinternal ($) {
 681         my $page=shift;
 682         return exists $pagesources{$page} &&
 683                 $pagesources{$page} =~ /\._([^.]+)$/;
 684 }
 685
 686 sub pagetype ($) {
 687         my $file=shift;
 688
 689         if ($file =~ /\.([^.]+)$/) {
 690                 return $1 if exists $hooks{htmlize}{$1};
 691         }
 692         my $base=basename($file);
 693         if (exists $hooks{htmlize}{$base} &&
 694             $hooks{htmlize}{$base}{noextension}) {
 695                 return $base;
 696         }
 697         return;
 698 }
 699
 700 my %pagename_cache;
 701
 702 sub pagename ($) {
 703         my $file=shift;
 704
 705         if (exists $pagename_cache{$file}) {
 706                 return $pagename_cache{$file};
 707         }
 708
 709         my $type=pagetype($file);
 710         my $page=$file;
 711         $page=~s/\Q.$type\E*$//
 712                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 713                         && !$hooks{htmlize}{$type}{noextension};
 714         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 715                 $page=$1;
 716         }
 717
 718         $pagename_cache{$file} = $page;
 719         return $page;
 720 }
 721
 722 sub newpagefile ($$) {
 723         my $page=shift;
 724         my $type=shift;
 725
 726         if (! $config{indexpages} || $page eq 'index') {
 727                 return $page.".".$type;
 728         }
 729         else {
 730                 return $page."/index.".$type;
 731         }
 732 }
 733
 734 sub targetpage ($$;$) {
 735         my $page=shift;
 736         my $ext=shift;
 737         my $filename=shift;
 738
 739         if (defined $filename) {
 740                 return $page."/".$filename.".".$ext;
 741         }
 742         elsif (! $config{usedirs} || $page eq 'index') {
 743                 return $page.".".$ext;
 744         }
 745         else {
 746                 return $page."/index.".$ext;
 747         }
 748 }
 749
 750 sub htmlpage ($) {
 751         my $page=shift;
 752
 753         return targetpage($page, $config{htmlext});
 754 }
 755
 756 sub srcfile_stat {
 757         my $file=shift;
 758         my $nothrow=shift;
 759
 760         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 761         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 762                 return "$dir/$file", stat(_) if -e "$dir/$file";
 763         }
 764         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 765         return;
 766 }
 767
 768 sub srcfile ($;$) {
 769         return (srcfile_stat(@_))[0];
 770 }
 771
 772 sub add_underlay ($) {
 773         my $dir=shift;
 774
 775         if ($dir !~ /^\//) {
 776                 $dir="$config{underlaydirbase}/$dir";
 777         }
 778
 779         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 780                 unshift @{$config{underlaydirs}}, $dir;
 781         }
 782
 783         return 1;
 784 }
 785
 786 sub readfile ($;$$) {
 787         my $file=shift;
 788         my $binary=shift;
 789         my $wantfd=shift;
 790
 791         if (-l $file) {
 792                 error("cannot read a symlink ($file)");
 793         }
 794
 795         local $/=undef;
 796         open (my $in, "<", $file) || error("failed to read $file: $!");
 797         binmode($in) if ($binary);
 798         return \*$in if $wantfd;
 799         my $ret=<$in>;
 800         # check for invalid utf-8, and toss it back to avoid crashes
 801         if (! utf8::valid($ret)) {
 802                 $ret=encode_utf8($ret);
 803         }
 804         close $in || error("failed to read $file: $!");
 805         return $ret;
 806 }
 807
 808 sub prep_writefile ($$) {
 809         my $file=shift;
 810         my $destdir=shift;
 811
 812         my $test=$file;
 813         while (length $test) {
 814                 if (-l "$destdir/$test") {
 815                         error("cannot write to a symlink ($test)");
 816                 }
 817                 $test=dirname($test);
 818         }
 819
 820         my $dir=dirname("$destdir/$file");
 821         if (! -d $dir) {
 822                 my $d="";
 823                 foreach my $s (split(m!/+!, $dir)) {
 824                         $d.="$s/";
 825                         if (! -d $d) {
 826                                 mkdir($d) || error("failed to create directory $d: $!");
 827                         }
 828                 }
 829         }
 830
 831         return 1;
 832 }
 833
 834 sub writefile ($$$;$$) {
 835         my $file=shift; # can include subdirs
 836         my $destdir=shift; # directory to put file in
 837         my $content=shift;
 838         my $binary=shift;
 839         my $writer=shift;
 840
 841         prep_writefile($file, $destdir);
 842
 843         my $newfile="$destdir/$file.ikiwiki-new";
 844         if (-l $newfile) {
 845                 error("cannot write to a symlink ($newfile)");
 846         }
 847
 848         my $cleanup = sub { unlink($newfile) };
 849         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 850         binmode($out) if ($binary);
 851         if ($writer) {
 852                 $writer->(\*$out, $cleanup);
 853         }
 854         else {
 855                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 856         }
 857         close $out || error("failed saving $newfile: $!", $cleanup);
 858         rename($newfile, "$destdir/$file") ||
 859                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 860
 861         return 1;
 862 }
 863
 864 my %cleared;
 865 sub will_render ($$;$) {
 866         my $page=shift;
 867         my $dest=shift;
 868         my $clear=shift;
 869
 870         # Important security check.
 871         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 872             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 873                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 874         }
 875
 876         if (! $clear || $cleared{$page}) {
 877                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 878         }
 879         else {
 880                 foreach my $old (@{$renderedfiles{$page}}) {
 881                         delete $destsources{$old};
 882                 }
 883                 $renderedfiles{$page}=[$dest];
 884                 $cleared{$page}=1;
 885         }
 886         $destsources{$dest}=$page;
 887
 888         return 1;
 889 }
 890
 891 sub bestlink ($$) {
 892         my $page=shift;
 893         my $link=shift;
 894
 895         my $cwd=$page;
 896         if ($link=~s/^\/+//) {
 897                 # absolute links
 898                 $cwd="";
 899         }
 900         $link=~s/\/$//;
 901
 902         do {
 903                 my $l=$cwd;
 904                 $l.="/" if length $l;
 905                 $l.=$link;
 906
 907                 if (exists $pagesources{$l}) {
 908                         return $l;
 909                 }
 910                 elsif (exists $pagecase{lc $l}) {
 911                         return $pagecase{lc $l};
 912                 }
 913         } while $cwd=~s{/?[^/]+$}{};
 914
 915         if (length $config{userdir}) {
 916                 my $l = "$config{userdir}/".lc($link);
 917                 if (exists $pagesources{$l}) {
 918                         return $l;
 919                 }
 920                 elsif (exists $pagecase{lc $l}) {
 921                         return $pagecase{lc $l};
 922                 }
 923         }
 924
 925         #print STDERR "warning: page $page, broken link: $link\n";
 926         return "";
 927 }
 928
 929 sub isinlinableimage ($) {
 930         my $file=shift;
 931
 932         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 933 }
 934
 935 sub pagetitle ($;$) {
 936         my $page=shift;
 937         my $unescaped=shift;
 938
 939         if ($unescaped) {
 940                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 941         }
 942         else {
 943                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 944         }
 945
 946         return $page;
 947 }
 948
 949 sub titlepage ($) {
 950         my $title=shift;
 951         # support use w/o %config set
 952         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 953         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 954         return $title;
 955 }
 956
 957 sub linkpage ($) {
 958         my $link=shift;
 959         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 960         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 961         return $link;
 962 }
 963
 964 sub cgiurl (@) {
 965         my %params=@_;
 966
 967         my $cgiurl=$config{cgiurl};
 968         if (exists $params{cgiurl}) {
 969                 $cgiurl=$params{cgiurl};
 970                 delete $params{cgiurl};
 971         }
 972         return $cgiurl."?".
 973                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 974 }
 975
 976 sub baseurl (;$) {
 977         my $page=shift;
 978
 979         return "$config{url}/" if ! defined $page;
 980
 981         $page=htmlpage($page);
 982         $page=~s/[^\/]+$//;
 983         $page=~s/[^\/]+\//..\//g;
 984         return $page;
 985 }
 986
 987 sub abs2rel ($$) {
 988         # Work around very innefficient behavior in File::Spec if abs2rel
 989         # is passed two relative paths. It's much faster if paths are
 990         # absolute! (Debian bug #376658; fixed in debian unstable now)
 991         my $path="/".shift;
 992         my $base="/".shift;
 993
 994         require File::Spec;
 995         my $ret=File::Spec->abs2rel($path, $base);
 996         $ret=~s/^// if defined $ret;
 997         return $ret;
 998 }
 999
1000 sub displaytime ($;$) {
1001         # Plugins can override this function to mark up the time to
1002         # display.
1003         return '<span class="date">'.formattime(@_).'</span>';
1004 }
1005
1006 sub formattime ($;$) {
1007         # Plugins can override this function to format the time.
1008         my $time=shift;
1009         my $format=shift;
1010         if (! defined $format) {
1011                 $format=$config{timeformat};
1012         }
1013
1014         # strftime doesn't know about encodings, so make sure
1015         # its output is properly treated as utf8
1016         return decode_utf8(POSIX::strftime($format, localtime($time)));
1017 }
1018
1019 sub beautify_urlpath ($) {
1020         my $url=shift;
1021
1022         # Ensure url is not an empty link, and if necessary,
1023         # add ./ to avoid colon confusion.
1024         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1025                 $url="./$url";
1026         }
1027
1028         if ($config{usedirs}) {
1029                 $url =~ s!/index.$config{htmlext}$!/!;
1030         }
1031
1032         return $url;
1033 }
1034
1035 sub urlto ($$;$) {
1036         my $to=shift;
1037         my $from=shift;
1038         my $absolute=shift;
1039
1040         if (! length $to) {
1041                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
1042         }
1043
1044         if (! $destsources{$to}) {
1045                 $to=htmlpage($to);
1046         }
1047
1048         if ($absolute) {
1049                 return $config{url}.beautify_urlpath("/".$to);
1050         }
1051
1052         my $link = abs2rel($to, dirname(htmlpage($from)));
1053
1054         return beautify_urlpath($link);
1055 }
1056
1057 sub htmllink ($$$;@) {
1058         my $lpage=shift; # the page doing the linking
1059         my $page=shift; # the page that will contain the link (different for inline)
1060         my $link=shift;
1061         my %opts=@_;
1062
1063         $link=~s/\/$//;
1064
1065         my $bestlink;
1066         if (! $opts{forcesubpage}) {
1067                 $bestlink=bestlink($lpage, $link);
1068         }
1069         else {
1070                 $bestlink="$lpage/".lc($link);
1071         }
1072
1073         my $linktext;
1074         if (defined $opts{linktext}) {
1075                 $linktext=$opts{linktext};
1076         }
1077         else {
1078                 $linktext=pagetitle(basename($link));
1079         }
1080
1081         return "<span class=\"selflink\">$linktext</span>"
1082                 if length $bestlink && $page eq $bestlink &&
1083                    ! defined $opts{anchor};
1084
1085         if (! $destsources{$bestlink}) {
1086                 $bestlink=htmlpage($bestlink);
1087
1088                 if (! $destsources{$bestlink}) {
1089                         return $linktext unless length $config{cgiurl};
1090                         return "<span class=\"createlink\"><a href=\"".
1091                                 cgiurl(
1092                                         do => "create",
1093                                         page => lc($link),
1094                                         from => $lpage
1095                                 ).
1096                                 "\" rel=\"nofollow\">?</a>$linktext</span>"
1097                 }
1098         }
1099
1100         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1101         $bestlink=beautify_urlpath($bestlink);
1102
1103         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1104                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1105         }
1106
1107         if (defined $opts{anchor}) {
1108                 $bestlink.="#".$opts{anchor};
1109         }
1110
1111         my @attrs;
1112         foreach my $attr (qw{rel class title}) {
1113                 if (defined $opts{$attr}) {
1114                         push @attrs, " $attr=\"$opts{$attr}\"";
1115                 }
1116         }
1117
1118         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1119 }
1120
1121 sub userpage ($) {
1122         my $user=shift;
1123         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1124 }
1125
1126 sub openiduser ($) {
1127         my $user=shift;
1128
1129         if ($user =~ m!^https?://! &&
1130             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1131                 my $display;
1132
1133                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1134                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1135                 }
1136                 else {
1137                         # backcompat with old version
1138                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1139                         $display=$oid->display;
1140                 }
1141
1142                 # Convert "user.somehost.com" to "user [somehost.com]"
1143                 # (also "user.somehost.co.uk")
1144                 if ($display !~ /\[/) {
1145                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1146                 }
1147                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1148                 # (also "https://somehost.com/user/")
1149                 if ($display !~ /\[/) {
1150                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1151                 }
1152                 $display=~s!^https?://!!; # make sure this is removed
1153                 eval q{use CGI 'escapeHTML'};
1154                 error($@) if $@;
1155                 return escapeHTML($display);
1156         }
1157         return;
1158 }
1159
1160 sub htmlize ($$$$) {
1161         my $page=shift;
1162         my $destpage=shift;
1163         my $type=shift;
1164         my $content=shift;
1165
1166         my $oneline = $content !~ /\n/;
1167
1168         if (exists $hooks{htmlize}{$type}) {
1169                 $content=$hooks{htmlize}{$type}{call}->(
1170                         page => $page,
1171                         content => $content,
1172                 );
1173         }
1174         else {
1175                 error("htmlization of $type not supported");
1176         }
1177
1178         run_hooks(sanitize => sub {
1179                 $content=shift->(
1180                         page => $page,
1181                         destpage => $destpage,
1182                         content => $content,
1183                 );
1184         });
1185
1186         if ($oneline) {
1187                 # hack to get rid of enclosing junk added by markdown
1188                 # and other htmlizers/sanitizers
1189                 $content=~s/^<p>//i;
1190                 $content=~s/<\/p>\n*$//i;
1191         }
1192
1193         return $content;
1194 }
1195
1196 sub linkify ($$$) {
1197         my $page=shift;
1198         my $destpage=shift;
1199         my $content=shift;
1200
1201         run_hooks(linkify => sub {
1202                 $content=shift->(
1203                         page => $page,
1204                         destpage => $destpage,
1205                         content => $content,
1206                 );
1207         });
1208
1209         return $content;
1210 }
1211
1212 our %preprocessing;
1213 our $preprocess_preview=0;
1214 sub preprocess ($$$;$$) {
1215         my $page=shift; # the page the data comes from
1216         my $destpage=shift; # the page the data will appear in (different for inline)
1217         my $content=shift;
1218         my $scan=shift;
1219         my $preview=shift;
1220
1221         # Using local because it needs to be set within any nested calls
1222         # of this function.
1223         local $preprocess_preview=$preview if defined $preview;
1224
1225         my $handle=sub {
1226                 my $escape=shift;
1227                 my $prefix=shift;
1228                 my $command=shift;
1229                 my $params=shift;
1230                 $params="" if ! defined $params;
1231
1232                 if (length $escape) {
1233                         return "[[$prefix$command $params]]";
1234                 }
1235                 elsif (exists $hooks{preprocess}{$command}) {
1236                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1237                         # Note: preserve order of params, some plugins may
1238                         # consider it significant.
1239                         my @params;
1240                         while ($params =~ m{
1241                                 (?:([-\w]+)=)?          # 1: named parameter key?
1242                                 (?:
1243                                         """(.*?)"""     # 2: triple-quoted value
1244                                 |
1245                                         "([^"]*?)"      # 3: single-quoted value
1246                                 |
1247                                         (\S+)           # 4: unquoted value
1248                                 )
1249                                 (?:\s+|$)               # delimiter to next param
1250                         }sgx) {
1251                                 my $key=$1;
1252                                 my $val;
1253                                 if (defined $2) {
1254                                         $val=$2;
1255                                         $val=~s/\r\n/\n/mg;
1256                                         $val=~s/^\n+//g;
1257                                         $val=~s/\n+$//g;
1258                                 }
1259                                 elsif (defined $3) {
1260                                         $val=$3;
1261                                 }
1262                                 elsif (defined $4) {
1263                                         $val=$4;
1264                                 }
1265
1266                                 if (defined $key) {
1267                                         push @params, $key, $val;
1268                                 }
1269                                 else {
1270                                         push @params, $val, '';
1271                                 }
1272                         }
1273                         if ($preprocessing{$page}++ > 3) {
1274                                 # Avoid loops of preprocessed pages preprocessing
1275                                 # other pages that preprocess them, etc.
1276                                 return "[[!$command <span class=\"error\">".
1277                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1278                                                 $page, $preprocessing{$page}).
1279                                         "</span>]]";
1280                         }
1281                         my $ret;
1282                         if (! $scan) {
1283                                 $ret=eval {
1284                                         $hooks{preprocess}{$command}{call}->(
1285                                                 @params,
1286                                                 page => $page,
1287                                                 destpage => $destpage,
1288                                                 preview => $preprocess_preview,
1289                                         );
1290                                 };
1291                                 if ($@) {
1292                                         my $error=$@;
1293                                         chomp $error;
1294                                         $ret="[[!$command <span class=\"error\">".
1295                                                 gettext("Error").": $error"."</span>]]";
1296                                 }
1297                         }
1298                         else {
1299                                 # use void context during scan pass
1300                                 eval {
1301                                         $hooks{preprocess}{$command}{call}->(
1302                                                 @params,
1303                                                 page => $page,
1304                                                 destpage => $destpage,
1305                                                 preview => $preprocess_preview,
1306                                         );
1307                                 };
1308                                 $ret="";
1309                         }
1310                         $preprocessing{$page}--;
1311                         return $ret;
1312                 }
1313                 else {
1314                         return "[[$prefix$command $params]]";
1315                 }
1316         };
1317
1318         my $regex;
1319         if ($config{prefix_directives}) {
1320                 $regex = qr{
1321                         (\\?)           # 1: escape?
1322                         \[\[(!)         # directive open; 2: prefix
1323                         ([-\w]+)        # 3: command
1324                         (               # 4: the parameters..
1325                                 \s+     # Must have space if parameters present
1326                                 (?:
1327                                         (?:[-\w]+=)?            # named parameter key?
1328                                         (?:
1329                                                 """.*?"""       # triple-quoted value
1330                                                 |
1331                                                 "[^"]*?"        # single-quoted value
1332                                                 |
1333                                                 [^"\s\]]+       # unquoted value
1334                                         )
1335                                         \s*                     # whitespace or end
1336                                                                 # of directive
1337                                 )
1338                         *)?             # 0 or more parameters
1339                         \]\]            # directive closed
1340                 }sx;
1341         }
1342         else {
1343                 $regex = qr{
1344                         (\\?)           # 1: escape?
1345                         \[\[(!?)        # directive open; 2: optional prefix
1346                         ([-\w]+)        # 3: command
1347                         \s+
1348                         (               # 4: the parameters..
1349                                 (?:
1350                                         (?:[-\w]+=)?            # named parameter key?
1351                                         (?:
1352                                                 """.*?"""       # triple-quoted value
1353                                                 |
1354                                                 "[^"]*?"        # single-quoted value
1355                                                 |
1356                                                 [^"\s\]]+       # unquoted value
1357                                         )
1358                                         \s*                     # whitespace or end
1359                                                                 # of directive
1360                                 )
1361                         *)              # 0 or more parameters
1362                         \]\]            # directive closed
1363                 }sx;
1364         }
1365
1366         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1367         return $content;
1368 }
1369
1370 sub filter ($$$) {
1371         my $page=shift;
1372         my $destpage=shift;
1373         my $content=shift;
1374
1375         run_hooks(filter => sub {
1376                 $content=shift->(page => $page, destpage => $destpage,
1377                         content => $content);
1378         });
1379
1380         return $content;
1381 }
1382
1383 sub indexlink () {
1384         return "<a href=\"$config{url}\">$config{wikiname}</a>";
1385 }
1386
1387 sub check_canedit ($$$;$) {
1388         my $page=shift;
1389         my $q=shift;
1390         my $session=shift;
1391         my $nonfatal=shift;
1392
1393         my $canedit;
1394         run_hooks(canedit => sub {
1395                 return if defined $canedit;
1396                 my $ret=shift->($page, $q, $session);
1397                 if (defined $ret) {
1398                         if ($ret eq "") {
1399                                 $canedit=1;
1400                         }
1401                         elsif (ref $ret eq 'CODE') {
1402                                 $ret->() unless $nonfatal;
1403                                 $canedit=0;
1404                         }
1405                         elsif (defined $ret) {
1406                                 error($ret) unless $nonfatal;
1407                                 $canedit=0;
1408                         }
1409                 }
1410         });
1411         return defined $canedit ? $canedit : 1;
1412 }
1413
1414 sub check_content (@) {
1415         my %params=@_;
1416
1417         return 1 if ! exists $hooks{checkcontent}; # optimisation
1418
1419         if (exists $pagesources{$params{page}}) {
1420                 my @diff;
1421                 my %old=map { $_ => 1 }
1422                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1423                 foreach my $line (split("\n", $params{content})) {
1424                         push @diff, $line if ! exists $old{$line};
1425                 }
1426                 $params{diff}=join("\n", @diff);
1427         }
1428
1429         my $ok;
1430         run_hooks(checkcontent => sub {
1431                 return if defined $ok;
1432                 my $ret=shift->(%params);
1433                 if (defined $ret) {
1434                         if ($ret eq "") {
1435                                 $ok=1;
1436                         }
1437                         elsif (ref $ret eq 'CODE') {
1438                                 $ret->() unless $params{nonfatal};
1439                                 $ok=0;
1440                         }
1441                         elsif (defined $ret) {
1442                                 error($ret) unless $params{nonfatal};
1443                                 $ok=0;
1444                         }
1445                 }
1446
1447         });
1448         return defined $ok ? $ok : 1;
1449 }
1450
1451 my $wikilock;
1452
1453 sub lockwiki () {
1454         # Take an exclusive lock on the wiki to prevent multiple concurrent
1455         # run issues. The lock will be dropped on program exit.
1456         if (! -d $config{wikistatedir}) {
1457                 mkdir($config{wikistatedir});
1458         }
1459         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1460                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1461         if (! flock($wikilock, 2)) { # LOCK_EX
1462                 error("failed to get lock");
1463         }
1464         return 1;
1465 }
1466
1467 sub unlockwiki () {
1468         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1469         return close($wikilock) if $wikilock;
1470         return;
1471 }
1472
1473 my $commitlock;
1474
1475 sub commit_hook_enabled () {
1476         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1477                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1478         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1479                 close($commitlock) || error("failed closing commitlock: $!");
1480                 return 0;
1481         }
1482         close($commitlock) || error("failed closing commitlock: $!");
1483         return 1;
1484 }
1485
1486 sub disable_commit_hook () {
1487         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1488                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1489         if (! flock($commitlock, 2)) { # LOCK_EX
1490                 error("failed to get commit lock");
1491         }
1492         return 1;
1493 }
1494
1495 sub enable_commit_hook () {
1496         return close($commitlock) if $commitlock;
1497         return;
1498 }
1499
1500 sub loadindex () {
1501         %oldrenderedfiles=%pagectime=();
1502         if (! $config{rebuild}) {
1503                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1504                 %destsources=%renderedfiles=%pagecase=%pagestate=
1505                 %depends_simple=%typedlinks=%oldtypedlinks=();
1506         }
1507         my $in;
1508         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1509                 if (-e "$config{wikistatedir}/index") {
1510                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1511                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1512                 }
1513                 else {
1514                         $config{gettime}=1; # first build
1515                         return;
1516                 }
1517         }
1518
1519         my $index=Storable::fd_retrieve($in);
1520         if (! defined $index) {
1521                 return 0;
1522         }
1523
1524         my $pages;
1525         if (exists $index->{version} && ! ref $index->{version}) {
1526                 $pages=$index->{page};
1527                 %wikistate=%{$index->{state}};
1528         }
1529         else {
1530                 $pages=$index;
1531                 %wikistate=();
1532         }
1533
1534         foreach my $src (keys %$pages) {
1535                 my $d=$pages->{$src};
1536                 my $page=pagename($src);
1537                 $pagectime{$page}=$d->{ctime};
1538                 if (! $config{rebuild}) {
1539                         $pagesources{$page}=$src;
1540                         $pagemtime{$page}=$d->{mtime};
1541                         $renderedfiles{$page}=$d->{dest};
1542                         if (exists $d->{links} && ref $d->{links}) {
1543                                 $links{$page}=$d->{links};
1544                                 $oldlinks{$page}=[@{$d->{links}}];
1545                         }
1546                         if (ref $d->{depends_simple} eq 'ARRAY') {
1547                                 # old format
1548                                 $depends_simple{$page}={
1549                                         map { $_ => 1 } @{$d->{depends_simple}}
1550                                 };
1551                         }
1552                         elsif (exists $d->{depends_simple}) {
1553                                 $depends_simple{$page}=$d->{depends_simple};
1554                         }
1555                         if (exists $d->{dependslist}) {
1556                                 # old format
1557                                 $depends{$page}={
1558                                         map { $_ => $DEPEND_CONTENT }
1559                                                 @{$d->{dependslist}}
1560                                 };
1561                         }
1562                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1563                                 # old format
1564                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1565                         }
1566                         elsif (exists $d->{depends}) {
1567                                 $depends{$page}=$d->{depends};
1568                         }
1569                         if (exists $d->{state}) {
1570                                 $pagestate{$page}=$d->{state};
1571                         }
1572                         if (exists $d->{typedlinks}) {
1573                                 $typedlinks{$page}=$d->{typedlinks};
1574
1575                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
1576                                         next unless %$links;
1577                                         $oldtypedlinks{$page}{$type} = {%$links};
1578                                 }
1579                         }
1580                 }
1581                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1582         }
1583         foreach my $page (keys %pagesources) {
1584                 $pagecase{lc $page}=$page;
1585         }
1586         foreach my $page (keys %renderedfiles) {
1587                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1588         }
1589         return close($in);
1590 }
1591
1592 sub saveindex () {
1593         run_hooks(savestate => sub { shift->() });
1594
1595         my %hookids;
1596         foreach my $type (keys %hooks) {
1597                 $hookids{$_}=1 foreach keys %{$hooks{$type}};
1598         }
1599         my @hookids=keys %hookids;
1600
1601         if (! -d $config{wikistatedir}) {
1602                 mkdir($config{wikistatedir});
1603         }
1604         my $newfile="$config{wikistatedir}/indexdb.new";
1605         my $cleanup = sub { unlink($newfile) };
1606         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1607
1608         my %index;
1609         foreach my $page (keys %pagemtime) {
1610                 next unless $pagemtime{$page};
1611                 my $src=$pagesources{$page};
1612
1613                 $index{page}{$src}={
1614                         ctime => $pagectime{$page},
1615                         mtime => $pagemtime{$page},
1616                         dest => $renderedfiles{$page},
1617                         links => $links{$page},
1618                 };
1619
1620                 if (exists $depends{$page}) {
1621                         $index{page}{$src}{depends} = $depends{$page};
1622                 }
1623
1624                 if (exists $depends_simple{$page}) {
1625                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1626                 }
1627
1628                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
1629                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
1630                 }
1631
1632                 if (exists $pagestate{$page}) {
1633                         foreach my $id (@hookids) {
1634                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1635                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1636                                 }
1637                         }
1638                 }
1639         }
1640
1641         $index{state}={};
1642         foreach my $id (@hookids) {
1643                 foreach my $key (keys %{$wikistate{$id}}) {
1644                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1645                 }
1646         }
1647
1648         $index{version}="3";
1649         my $ret=Storable::nstore_fd(\%index, $out);
1650         return if ! defined $ret || ! $ret;
1651         close $out || error("failed saving to $newfile: $!", $cleanup);
1652         rename($newfile, "$config{wikistatedir}/indexdb") ||
1653                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1654
1655         return 1;
1656 }
1657
1658 sub template_file ($) {
1659         my $template=shift;
1660
1661         foreach my $dir ($config{templatedir}, @{$config{templatedirs}},
1662                          "$installdir/share/ikiwiki/templates") {
1663                 return "$dir/$template" if -e "$dir/$template";
1664         }
1665         return;
1666 }
1667
1668 sub template_params (@) {
1669         my $filename=template_file(shift);
1670
1671         if (! defined $filename) {
1672                 return if wantarray;
1673                 return "";
1674         }
1675
1676         my @ret=(
1677                 filter => sub {
1678                         my $text_ref = shift;
1679                         ${$text_ref} = decode_utf8(${$text_ref});
1680                 },
1681                 filename => $filename,
1682                 loop_context_vars => 1,
1683                 die_on_bad_params => 0,
1684                 @_
1685         );
1686         return wantarray ? @ret : {@ret};
1687 }
1688
1689 sub template ($;@) {
1690         require HTML::Template;
1691         return HTML::Template->new(template_params(@_));
1692 }
1693
1694 sub misctemplate ($$;@) {
1695         my $title=shift;
1696         my $pagebody=shift;
1697
1698         my $template=template("misc.tmpl");
1699         $template->param(
1700                 title => $title,
1701                 indexlink => indexlink(),
1702                 wikiname => $config{wikiname},
1703                 pagebody => $pagebody,
1704                 baseurl => baseurl(),
1705                 @_,
1706         );
1707         run_hooks(pagetemplate => sub {
1708                 shift->(page => "", destpage => "", template => $template);
1709         });
1710         return $template->output;
1711 }
1712
1713 sub hook (@) {
1714         my %param=@_;
1715
1716         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1717                 error 'hook requires type, call, and id parameters';
1718         }
1719
1720         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1721
1722         $hooks{$param{type}}{$param{id}}=\%param;
1723         return 1;
1724 }
1725
1726 sub run_hooks ($$) {
1727         # Calls the given sub for each hook of the given type,
1728         # passing it the hook function to call.
1729         my $type=shift;
1730         my $sub=shift;
1731
1732         if (exists $hooks{$type}) {
1733                 my (@first, @middle, @last);
1734                 foreach my $id (keys %{$hooks{$type}}) {
1735                         if ($hooks{$type}{$id}{first}) {
1736                                 push @first, $id;
1737                         }
1738                         elsif ($hooks{$type}{$id}{last}) {
1739                                 push @last, $id;
1740                         }
1741                         else {
1742                                 push @middle, $id;
1743                         }
1744                 }
1745                 foreach my $id (@first, @middle, @last) {
1746                         $sub->($hooks{$type}{$id}{call});
1747                 }
1748         }
1749
1750         return 1;
1751 }
1752
1753 sub rcs_update () {
1754         $hooks{rcs}{rcs_update}{call}->(@_);
1755 }
1756
1757 sub rcs_prepedit ($) {
1758         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1759 }
1760
1761 sub rcs_commit ($$$;$$) {
1762         $hooks{rcs}{rcs_commit}{call}->(@_);
1763 }
1764
1765 sub rcs_commit_staged ($$$) {
1766         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1767 }
1768
1769 sub rcs_add ($) {
1770         $hooks{rcs}{rcs_add}{call}->(@_);
1771 }
1772
1773 sub rcs_remove ($) {
1774         $hooks{rcs}{rcs_remove}{call}->(@_);
1775 }
1776
1777 sub rcs_rename ($$) {
1778         $hooks{rcs}{rcs_rename}{call}->(@_);
1779 }
1780
1781 sub rcs_recentchanges ($) {
1782         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1783 }
1784
1785 sub rcs_diff ($) {
1786         $hooks{rcs}{rcs_diff}{call}->(@_);
1787 }
1788
1789 sub rcs_getctime ($) {
1790         $hooks{rcs}{rcs_getctime}{call}->(@_);
1791 }
1792
1793 sub rcs_getmtime ($) {
1794         $hooks{rcs}{rcs_getmtime}{call}->(@_);
1795 }
1796
1797 sub rcs_receive () {
1798         $hooks{rcs}{rcs_receive}{call}->();
1799 }
1800
1801 sub add_depends ($$;$) {
1802         my $page=shift;
1803         my $pagespec=shift;
1804         my $deptype=shift || $DEPEND_CONTENT;
1805
1806         # Is the pagespec a simple page name?
1807         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
1808             $pagespec !~ /[\s*?()!]/) {
1809                 $depends_simple{$page}{lc $pagespec} |= $deptype;
1810                 return 1;
1811         }
1812
1813         # Add explicit dependencies for influences.
1814         my $sub=pagespec_translate($pagespec);
1815         return unless defined $sub;
1816         foreach my $p (keys %pagesources) {
1817                 my $r=$sub->($p, location => $page);
1818                 my $i=$r->influences;
1819                 foreach my $k (keys %$i) {
1820                         $depends_simple{$page}{lc $k} |= $i->{$k};
1821                 }
1822                 last if $r->influences_static;
1823         }
1824
1825         $depends{$page}{$pagespec} |= $deptype;
1826         return 1;
1827 }
1828
1829 sub deptype (@) {
1830         my $deptype=0;
1831         foreach my $type (@_) {
1832                 if ($type eq 'presence') {
1833                         $deptype |= $DEPEND_PRESENCE;
1834                 }
1835                 elsif ($type eq 'links') {
1836                         $deptype |= $DEPEND_LINKS;
1837                 }
1838                 elsif ($type eq 'content') {
1839                         $deptype |= $DEPEND_CONTENT;
1840                 }
1841         }
1842         return $deptype;
1843 }
1844
1845 my $file_prune_regexp;
1846 sub file_pruned ($) {
1847         my $file=shift;
1848
1849         if (defined $config{include} && length $config{include}) {
1850                 return 0 if $file =~ m/$config{include}/;
1851         }
1852
1853         if (! defined $file_prune_regexp) {
1854                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1855                 $file_prune_regexp=qr/$file_prune_regexp/;
1856         }
1857         return $file =~ m/$file_prune_regexp/;
1858 }
1859
1860 sub define_gettext () {
1861         # If translation is needed, redefine the gettext function to do it.
1862         # Otherwise, it becomes a quick no-op.
1863         my $gettext_obj;
1864         my $getobj;
1865         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1866             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1867             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1868                 $getobj=sub {
1869                         $gettext_obj=eval q{
1870                                 use Locale::gettext q{textdomain};
1871                                 Locale::gettext->domain('ikiwiki')
1872                         };
1873                 };
1874         }
1875
1876         no warnings 'redefine';
1877         *gettext=sub {
1878                 $getobj->() if $getobj;
1879                 if ($gettext_obj) {
1880                         $gettext_obj->get(shift);
1881                 }
1882                 else {
1883                         return shift;
1884                 }
1885         };
1886         *ngettext=sub {
1887                 $getobj->() if $getobj;
1888                 if ($gettext_obj) {
1889                         $gettext_obj->nget(@_);
1890                 }
1891                 else {
1892                         return ($_[2] == 1 ? $_[0] : $_[1])
1893                 }
1894         };
1895 }
1896
1897 sub gettext {
1898         define_gettext();
1899         gettext(@_);
1900 }
1901
1902 sub ngettext {
1903         define_gettext();
1904         ngettext(@_);
1905 }
1906
1907 sub yesno ($) {
1908         my $val=shift;
1909
1910         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
1911 }
1912
1913 sub inject {
1914         # Injects a new function into the symbol table to replace an
1915         # exported function.
1916         my %params=@_;
1917
1918         # This is deep ugly perl foo, beware.
1919         no strict;
1920         no warnings;
1921         if (! defined $params{parent}) {
1922                 $params{parent}='::';
1923                 $params{old}=\&{$params{name}};
1924                 $params{name}=~s/.*:://;
1925         }
1926         my $parent=$params{parent};
1927         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
1928                 $ns = $params{parent} . $ns;
1929                 inject(%params, parent => $ns) unless $ns eq '::main::';
1930                 *{$ns . $params{name}} = $params{call}
1931                         if exists ${$ns}{$params{name}} &&
1932                            \&{${$ns}{$params{name}}} == $params{old};
1933         }
1934         use strict;
1935         use warnings;
1936 }
1937
1938 sub add_link ($$;$) {
1939         my $page=shift;
1940         my $link=shift;
1941         my $type=shift;
1942
1943         push @{$links{$page}}, $link
1944                 unless grep { $_ eq $link } @{$links{$page}};
1945
1946         if (defined $type) {
1947                 $typedlinks{$page}{$type}{$link} = 1;
1948         }
1949 }
1950
1951 sub sortspec_translate ($$) {
1952         my $spec = shift;
1953         my $reverse = shift;
1954
1955         my $code = "";
1956         my @data;
1957         while ($spec =~ m{
1958                 \s*
1959                 (-?)            # group 1: perhaps negated
1960                 \s*
1961                 (               # group 2: a word
1962                         \w+\([^\)]*\)   # command(params)
1963                         |
1964                         [^\s]+          # or anything else
1965                 )
1966                 \s*
1967         }gx) {
1968                 my $negated = $1;
1969                 my $word = $2;
1970                 my $params = undef;
1971
1972                 if ($word =~ m/^(\w+)\((.*)\)$/) {
1973                         # command with parameters
1974                         $params = $2;
1975                         $word = $1;
1976                 }
1977                 elsif ($word !~ m/^\w+$/) {
1978                         error(sprintf(gettext("invalid sort type %s"), $word));
1979                 }
1980
1981                 if (length $code) {
1982                         $code .= " || ";
1983                 }
1984
1985                 if ($negated) {
1986                         $code .= "-";
1987                 }
1988
1989                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
1990                         if (defined $params) {
1991                                 push @data, $params;
1992                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
1993                         }
1994                         else {
1995                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
1996                         }
1997                 }
1998                 else {
1999                         error(sprintf(gettext("unknown sort type %s"), $word));
2000                 }
2001         }
2002
2003         if (! length $code) {
2004                 # undefined sorting method... sort arbitrarily
2005                 return sub { 0 };
2006         }
2007
2008         if ($reverse) {
2009                 $code="-($code)";
2010         }
2011
2012         no warnings;
2013         return eval 'sub { '.$code.' }';
2014 }
2015
2016 sub pagespec_translate ($) {
2017         my $spec=shift;
2018
2019         # Convert spec to perl code.
2020         my $code="";
2021         my @data;
2022         while ($spec=~m{
2023                 \s*             # ignore whitespace
2024                 (               # 1: match a single word
2025                         \!              # !
2026                 |
2027                         \(              # (
2028                 |
2029                         \)              # )
2030                 |
2031                         \w+\([^\)]*\)   # command(params)
2032                 |
2033                         [^\s()]+        # any other text
2034                 )
2035                 \s*             # ignore whitespace
2036         }gx) {
2037                 my $word=$1;
2038                 if (lc $word eq 'and') {
2039                         $code.=' &';
2040                 }
2041                 elsif (lc $word eq 'or') {
2042                         $code.=' |';
2043                 }
2044                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2045                         $code.=' '.$word;
2046                 }
2047                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2048                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2049                                 push @data, $2;
2050                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2051                         }
2052                         else {
2053                                 push @data, qq{unknown function in pagespec "$word"};
2054                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2055                         }
2056                 }
2057                 else {
2058                         push @data, $word;
2059                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2060                 }
2061         }
2062
2063         if (! length $code) {
2064                 $code="IkiWiki::FailReason->new('empty pagespec')";
2065         }
2066
2067         no warnings;
2068         return eval 'sub { my $page=shift; '.$code.' }';
2069 }
2070
2071 sub pagespec_match ($$;@) {
2072         my $page=shift;
2073         my $spec=shift;
2074         my @params=@_;
2075
2076         # Backwards compatability with old calling convention.
2077         if (@params == 1) {
2078                 unshift @params, 'location';
2079         }
2080
2081         my $sub=pagespec_translate($spec);
2082         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2083                 if ! defined $sub;
2084         return $sub->($page, @params);
2085 }
2086
2087 sub pagespec_match_list ($$;@) {
2088         my $page=shift;
2089         my $pagespec=shift;
2090         my %params=@_;
2091
2092         # Backwards compatability with old calling convention.
2093         if (ref $page) {
2094                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2095                 $params{list}=$page;
2096                 $page=$params{location}; # ugh!
2097         }
2098
2099         my $sub=pagespec_translate($pagespec);
2100         error "syntax error in pagespec \"$pagespec\""
2101                 if ! defined $sub;
2102         my $sort=sortspec_translate($params{sort}, $params{reverse})
2103                 if defined $params{sort};
2104
2105         my @candidates;
2106         if (exists $params{list}) {
2107                 @candidates=exists $params{filter}
2108                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2109                         : @{$params{list}};
2110         }
2111         else {
2112                 @candidates=exists $params{filter}
2113                         ? grep { ! $params{filter}->($_) } keys %pagesources
2114                         : keys %pagesources;
2115         }
2116
2117         # clear params, remainder is passed to pagespec
2118         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2119         my $num=$params{num};
2120         delete @params{qw{num deptype reverse sort filter list}};
2121
2122         # when only the top matches will be returned, it's efficient to
2123         # sort before matching to pagespec,
2124         if (defined $num && defined $sort) {
2125                 @candidates=IkiWiki::SortSpec::sort_pages(
2126                         $sort, @candidates);
2127         }
2128
2129         my @matches;
2130         my $firstfail;
2131         my $count=0;
2132         my $accum=IkiWiki::SuccessReason->new();
2133         foreach my $p (@candidates) {
2134                 my $r=$sub->($p, %params, location => $page);
2135                 error(sprintf(gettext("cannot match pages: %s"), $r))
2136                         if $r->isa("IkiWiki::ErrorReason");
2137                 $accum |= $r;
2138                 if ($r) {
2139                         push @matches, $p;
2140                         last if defined $num && ++$count == $num;
2141                 }
2142         }
2143
2144         # Add simple dependencies for accumulated influences.
2145         my $i=$accum->influences;
2146         foreach my $k (keys %$i) {
2147                 $depends_simple{$page}{lc $k} |= $i->{$k};
2148         }
2149
2150         # when all matches will be returned, it's efficient to
2151         # sort after matching
2152         if (! defined $num && defined $sort) {
2153                 return IkiWiki::SortSpec::sort_pages(
2154                         $sort, @matches);
2155         }
2156         else {
2157                 return @matches;
2158         }
2159 }
2160
2161 sub pagespec_valid ($) {
2162         my $spec=shift;
2163
2164         return defined pagespec_translate($spec);
2165 }
2166
2167 sub glob2re ($) {
2168         my $re=quotemeta(shift);
2169         $re=~s/\\\*/.*/g;
2170         $re=~s/\\\?/./g;
2171         return $re;
2172 }
2173
2174 package IkiWiki::FailReason;
2175
2176 use overload (
2177         '""'    => sub { $_[0][0] },
2178         '0+'    => sub { 0 },
2179         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2180         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2181         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2182         fallback => 1,
2183 );
2184
2185 our @ISA = 'IkiWiki::SuccessReason';
2186
2187 package IkiWiki::SuccessReason;
2188
2189 use overload (
2190         '""'    => sub { $_[0][0] },
2191         '0+'    => sub { 1 },
2192         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2193         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2194         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2195         fallback => 1,
2196 );
2197
2198 sub new {
2199         my $class = shift;
2200         my $value = shift;
2201         return bless [$value, {@_}], $class;
2202 }
2203
2204 sub influences {
2205         my $this=shift;
2206         $this->[1]={@_} if @_;
2207         my %i=%{$this->[1]};
2208         delete $i{""};
2209         return \%i;
2210 }
2211
2212 sub influences_static {
2213         return ! $_[0][1]->{""};
2214 }
2215
2216 sub merge_influences {
2217         my $this=shift;
2218         my $other=shift;
2219         my $anded=shift;
2220
2221         if (! $anded || (($this || %{$this->[1]}) &&
2222                         ($other || %{$other->[1]}))) {
2223                 foreach my $influence (keys %{$other->[1]}) {
2224                         $this->[1]{$influence} |= $other->[1]{$influence};
2225                 }
2226         }
2227         else {
2228                 # influence blocker
2229                 $this->[1]={};
2230         }
2231 }
2232
2233 package IkiWiki::ErrorReason;
2234
2235 our @ISA = 'IkiWiki::FailReason';
2236
2237 package IkiWiki::PageSpec;
2238
2239 sub derel ($$) {
2240         my $path=shift;
2241         my $from=shift;
2242
2243         if ($path =~ m!^\./!) {
2244                 $from=~s#/?[^/]+$## if defined $from;
2245                 $path=~s#^\./##;
2246                 $path="$from/$path" if length $from;
2247         }
2248
2249         return $path;
2250 }
2251
2252 sub match_glob ($$;@) {
2253         my $page=shift;
2254         my $glob=shift;
2255         my %params=@_;
2256
2257         $glob=derel($glob, $params{location});
2258
2259         my $regexp=IkiWiki::glob2re($glob);
2260         if ($page=~/^$regexp$/i) {
2261                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2262                         return IkiWiki::SuccessReason->new("$glob matches $page");
2263                 }
2264                 else {
2265                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2266                 }
2267         }
2268         else {
2269                 return IkiWiki::FailReason->new("$glob does not match $page");
2270         }
2271 }
2272
2273 sub match_internal ($$;@) {
2274         return match_glob($_[0], $_[1], @_, internal => 1)
2275 }
2276
2277 sub match_link ($$;@) {
2278         my $page=shift;
2279         my $link=lc(shift);
2280         my %params=@_;
2281
2282         $link=derel($link, $params{location});
2283         my $from=exists $params{location} ? $params{location} : '';
2284         my $linktype=$params{linktype};
2285         my $qualifier='';
2286         if (defined $linktype) {
2287                 $qualifier=" with type $linktype";
2288         }
2289
2290         my $links = $IkiWiki::links{$page};
2291         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2292                 unless $links && @{$links};
2293         my $bestlink = IkiWiki::bestlink($from, $link);
2294         foreach my $p (@{$links}) {
2295                 if (length $bestlink) {
2296                         if ((!defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p}) && $bestlink eq IkiWiki::bestlink($page, $p)) {
2297                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2298                         }
2299                 }
2300                 else {
2301                         if ((!defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p}) && match_glob($p, $link, %params)) {
2302                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2303                         }
2304                         my ($p_rel)=$p=~/^\/?(.*)/;
2305                         $link=~s/^\///;
2306                         if ((!defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p_rel}) && match_glob($p_rel, $link, %params)) {
2307                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2308                         }
2309                 }
2310         }
2311         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2312 }
2313
2314 sub match_backlink ($$;@) {
2315         my $ret=match_link($_[1], $_[0], @_);
2316         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2317         return $ret;
2318 }
2319
2320 sub match_created_before ($$;@) {
2321         my $page=shift;
2322         my $testpage=shift;
2323         my %params=@_;
2324
2325         $testpage=derel($testpage, $params{location});
2326
2327         if (exists $IkiWiki::pagectime{$testpage}) {
2328                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2329                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2330                 }
2331                 else {
2332                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2333                 }
2334         }
2335         else {
2336                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2337         }
2338 }
2339
2340 sub match_created_after ($$;@) {
2341         my $page=shift;
2342         my $testpage=shift;
2343         my %params=@_;
2344
2345         $testpage=derel($testpage, $params{location});
2346
2347         if (exists $IkiWiki::pagectime{$testpage}) {
2348                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2349                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2350                 }
2351                 else {
2352                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2353                 }
2354         }
2355         else {
2356                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2357         }
2358 }
2359
2360 sub match_creation_day ($$;@) {
2361         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
2362                 return IkiWiki::SuccessReason->new('creation_day matched');
2363         }
2364         else {
2365                 return IkiWiki::FailReason->new('creation_day did not match');
2366         }
2367 }
2368
2369 sub match_creation_month ($$;@) {
2370         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
2371                 return IkiWiki::SuccessReason->new('creation_month matched');
2372         }
2373         else {
2374                 return IkiWiki::FailReason->new('creation_month did not match');
2375         }
2376 }
2377
2378 sub match_creation_year ($$;@) {
2379         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
2380                 return IkiWiki::SuccessReason->new('creation_year matched');
2381         }
2382         else {
2383                 return IkiWiki::FailReason->new('creation_year did not match');
2384         }
2385 }
2386
2387 sub match_user ($$;@) {
2388         shift;
2389         my $user=shift;
2390         my %params=@_;
2391
2392         my $regexp=IkiWiki::glob2re($user);
2393
2394         if (! exists $params{user}) {
2395                 return IkiWiki::ErrorReason->new("no user specified");
2396         }
2397
2398         if (defined $params{user} && $params{user}=~/^$regexp$/i) {
2399                 return IkiWiki::SuccessReason->new("user is $user");
2400         }
2401         elsif (! defined $params{user}) {
2402                 return IkiWiki::FailReason->new("not logged in");
2403         }
2404         else {
2405                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2406         }
2407 }
2408
2409 sub match_admin ($$;@) {
2410         shift;
2411         shift;
2412         my %params=@_;
2413
2414         if (! exists $params{user}) {
2415                 return IkiWiki::ErrorReason->new("no user specified");
2416         }
2417
2418         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2419                 return IkiWiki::SuccessReason->new("user is an admin");
2420         }
2421         elsif (! defined $params{user}) {
2422                 return IkiWiki::FailReason->new("not logged in");
2423         }
2424         else {
2425                 return IkiWiki::FailReason->new("user is not an admin");
2426         }
2427 }
2428
2429 sub match_ip ($$;@) {
2430         shift;
2431         my $ip=shift;
2432         my %params=@_;
2433
2434         if (! exists $params{ip}) {
2435                 return IkiWiki::ErrorReason->new("no IP specified");
2436         }
2437
2438         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2439                 return IkiWiki::SuccessReason->new("IP is $ip");
2440         }
2441         else {
2442                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2443         }
2444 }
2445
2446 package IkiWiki::SortSpec;
2447
2448 # This is in the SortSpec namespace so that the $a and $b that sort() uses
2449 # are easily available in this namespace, for cmp functions to use them.
2450 sub sort_pages {
2451         my $f=shift;
2452         sort $f @_
2453 }
2454
2455 sub cmp_title {
2456         IkiWiki::pagetitle(IkiWiki::basename($a))
2457         cmp
2458         IkiWiki::pagetitle(IkiWiki::basename($b))
2459 }
2460
2461 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
2462 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
2463
2464 1