IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31
  32 memoize("istranslatable");
  33 memoize("_istranslation");
  34 memoize("percenttranslated");
  35
  36 sub import {
  37         hook(type => "getsetup", id => "po", call => \&getsetup);
  38         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  39         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  40         hook(type => "scan", id => "po", call => \&scan, last => 1);
  41         hook(type => "filter", id => "po", call => \&filter);
  42         hook(type => "htmlize", id => "po", call => \&htmlize);
  43         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  44         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  45         hook(type => "delete", id => "po", call => \&mydelete);
  46         hook(type => "change", id => "po", call => \&change);
  47         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  48         hook(type => "canremove", id => "po", call => \&canremove);
  49         hook(type => "canrename", id => "po", call => \&canrename);
  50         hook(type => "editcontent", id => "po", call => \&editcontent);
  51         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  52         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  53
  54         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  55         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  56         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  57         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  58         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  59         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  60         $origsubs{'urlto'}=\&IkiWiki::urlto;
  61         inject(name => "IkiWiki::urlto", call => \&myurlto);
  62         $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  63         inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  64         $origsubs{'rootpage'}=\&IkiWiki::rootpage;
  65         inject(name => "IkiWiki::rootpage", call => \&myrootpage);
  66 }
  67
  68
  69 # ,----
  70 # | Table of contents
  71 # `----
  72
  73 # 1. Hooks
  74 # 2. Injected functions
  75 # 3. Blackboxes for private data
  76 # 4. Helper functions
  77 # 5. PageSpecs
  78
  79
  80 # ,----
  81 # | Hooks
  82 # `----
  83
  84 sub getsetup () {
  85         return
  86                 plugin => {
  87                         safe => 0,
  88                         rebuild => 1,
  89                 },
  90                 po_master_language => {
  91                         type => "string",
  92                         example => {
  93                                 'code' => 'en',
  94                                 'name' => 'English'
  95                         },
  96                         description => "master language (non-PO files)",
  97                         safe => 1,
  98                         rebuild => 1,
  99                 },
 100                 po_slave_languages => {
 101                         type => "string",
 102                         example => {
 103                                 'fr' => 'Français',
 104                                 'es' => 'Español',
 105                                 'de' => 'Deutsch'
 106                         },
 107                         description => "slave languages (PO files)",
 108                         safe => 1,
 109                         rebuild => 1,
 110                 },
 111                 po_translatable_pages => {
 112                         type => "pagespec",
 113                         example => "* and !*/Discussion",
 114                         description => "PageSpec controlling which pages are translatable",
 115                         link => "ikiwiki/PageSpec",
 116                         safe => 1,
 117                         rebuild => 1,
 118                 },
 119                 po_link_to => {
 120                         type => "string",
 121                         example => "current",
 122                         description => "internal linking behavior (default/current/negotiated)",
 123                         safe => 1,
 124                         rebuild => 1,
 125                 },
 126 }
 127
 128 sub checkconfig () {
 129         foreach my $field (qw{po_master_language}) {
 130                 if (! exists $config{$field} || ! defined $config{$field}) {
 131                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 132                                       $field, 'po'));
 133                 }
 134         }
 135
 136         map {
 137                 islanguagecode($_)
 138                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 139         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 140
 141         if (! exists $config{po_translatable_pages} ||
 142             ! defined $config{po_translatable_pages}) {
 143                 $config{po_translatable_pages}="";
 144         }
 145         if (! exists $config{po_link_to} ||
 146             ! defined $config{po_link_to}) {
 147                 $config{po_link_to}='default';
 148         }
 149         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 150                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 151                              $config{po_link_to}));
 152                 $config{po_link_to}='default';
 153         }
 154         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 155                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 156                 $config{po_link_to}='default';
 157         }
 158
 159         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 160
 161         # Translated versions of the underlays are added if available.
 162         foreach my $underlay ("basewiki",
 163                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 164                                   reverse @{$config{underlaydirs}}) {
 165                 next if $underlay=~/^locale\//;
 166
 167                 # Underlays containing the po files for slave languages.
 168                 foreach my $ll (keys %{$config{po_slave_languages}}) {
 169                         add_underlay("po/$ll/$underlay")
 170                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 171                 }
 172
 173                 if ($config{po_master_language}{code} ne 'en') {
 174                         # Add underlay containing translated source files
 175                         # for the master language.
 176                         add_underlay("locale/$config{po_master_language}{code}/$underlay");
 177                 }
 178         }
 179 }
 180
 181 sub needsbuild () {
 182         my $needsbuild=shift;
 183
 184         # backup @needsbuild content so that change() can know whether
 185         # a given master page was rendered because its source file was changed
 186         @origneedsbuild=(@$needsbuild);
 187
 188         flushmemoizecache();
 189         buildtranslationscache();
 190
 191         # make existing translations depend on the corresponding master page
 192         foreach my $master (keys %translations) {
 193                 map add_depends($_, $master), values %{otherlanguages($master)};
 194         }
 195 }
 196
 197 # Massage the recorded state of internal links so that:
 198 # - it matches the actually generated links, rather than the links as written
 199 #   in the pages' source
 200 # - backlinks are consistent in all cases
 201 sub scan (@) {
 202         my %params=@_;
 203         my $page=$params{page};
 204         my $content=$params{content};
 205
 206         if (istranslation($page)) {
 207                 foreach my $destpage (@{$links{$page}}) {
 208                         if (istranslatable($destpage)) {
 209                                 # replace the occurence of $destpage in $links{$page}
 210                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 211                                         if (@{$links{$page}}[$i] eq $destpage) {
 212                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 213                                                 last;
 214                                         }
 215                                 }
 216                         }
 217                 }
 218         }
 219         elsif (! istranslatable($page) && ! istranslation($page)) {
 220                 foreach my $destpage (@{$links{$page}}) {
 221                         if (istranslatable($destpage)) {
 222                                 # make sure any destpage's translations has
 223                                 # $page in its backlinks
 224                                 push @{$links{$page}},
 225                                         values %{otherlanguages($destpage)};
 226                         }
 227                 }
 228         }
 229 }
 230
 231 # We use filter to convert PO to the master page's format,
 232 # since the rest of ikiwiki should not work on PO files.
 233 sub filter (@) {
 234         my %params = @_;
 235
 236         my $page = $params{page};
 237         my $destpage = $params{destpage};
 238         my $content = $params{content};
 239         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 240                 $content = po_to_markup($page, $content);
 241                 setalreadyfiltered($page, $destpage);
 242         }
 243         return $content;
 244 }
 245
 246 sub htmlize (@) {
 247         my %params=@_;
 248
 249         my $page = $params{page};
 250         my $content = $params{content};
 251
 252         # ignore PO files this plugin did not create
 253         return $content unless istranslation($page);
 254
 255         # force content to be htmlize'd as if it was the same type as the master page
 256         return IkiWiki::htmlize($page, $page,
 257                 pagetype(srcfile($pagesources{masterpage($page)})),
 258                 $content);
 259 }
 260
 261 sub pagetemplate (@) {
 262         my %params=@_;
 263         my $page=$params{page};
 264         my $destpage=$params{destpage};
 265         my $template=$params{template};
 266
 267         my ($masterpage, $lang) = istranslation($page);
 268
 269         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 270                 $template->param(percenttranslated => percenttranslated($page));
 271         }
 272         if ($template->query(name => "istranslation")) {
 273                 $template->param(istranslation => scalar istranslation($page));
 274         }
 275         if ($template->query(name => "istranslatable")) {
 276                 $template->param(istranslatable => istranslatable($page));
 277         }
 278         if ($template->query(name => "HOMEPAGEURL")) {
 279                 $template->param(homepageurl => homepageurl($page));
 280         }
 281         if ($template->query(name => "otherlanguages")) {
 282                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 283                 map add_depends($page, $_), (values %{otherlanguages($page)});
 284         }
 285         if ($config{discussion} && istranslation($page)) {
 286                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 287                    (length $config{cgiurl} ||
 288                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 289                         $template->param('discussionlink' => htmllink(
 290                                 $page,
 291                                 $destpage,
 292                                 $masterpage . '/' . $config{discussionpage},
 293                                 noimageinline => 1,
 294                                 forcesubpage => 0,
 295                                 linktext => $config{discussionpage},
 296                 ));
 297                 }
 298         }
 299         # Remove broken parentlink to ./index.html on home page's translations.
 300         # It works because this hook has the "last" parameter set, to ensure it
 301         # runs after parentlinks' own pagetemplate hook.
 302         if ($template->param('parentlinks')
 303             && istranslation($page)
 304             && $masterpage eq "index") {
 305                 $template->param('parentlinks' => []);
 306         }
 307         if (ishomepage($page) && $template->query(name => "title")) {
 308                 $template->param(title => $config{wikiname});
 309         }
 310 } # }}}
 311
 312 # Add the renamed page translations to the list of to-be-renamed pages.
 313 sub renamepages (@) {
 314         my %params = @_;
 315
 316         my %torename = %{$params{torename}};
 317         my $session = $params{session};
 318
 319         # Save the page(s) the user asked to rename, so that our
 320         # canrename hook can tell the difference between:
 321         #  - a translation being renamed as a consequence of its master page
 322         #    being renamed
 323         #  - a user trying to directly rename a translation
 324         # This is why this hook has to be run first, before the list of pages
 325         # to rename is modified by other plugins.
 326         my @orig_torename;
 327         @orig_torename=@{$session->param("po_orig_torename")}
 328                 if defined $session->param("po_orig_torename");
 329         push @orig_torename, $torename{src};
 330         $session->param(po_orig_torename => \@orig_torename);
 331         IkiWiki::cgi_savesession($session);
 332
 333         return () unless istranslatable($torename{src});
 334
 335         my @ret;
 336         my %otherpages=%{otherlanguages($torename{src})};
 337         while (my ($lang, $otherpage) = each %otherpages) {
 338                 push @ret, {
 339                         src => $otherpage,
 340                         srcfile => $pagesources{$otherpage},
 341                         dest => otherlanguage($torename{dest}, $lang),
 342                         destfile => $torename{dest}.".".$lang.".po",
 343                         required => 0,
 344                 };
 345         }
 346         return @ret;
 347 }
 348
 349 sub mydelete (@) {
 350         my @deleted=@_;
 351
 352         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 353 }
 354
 355 sub change (@) {
 356         my @rendered=@_;
 357
 358         # All meta titles are first extracted at scan time, i.e. before we turn
 359         # PO files back into translated markdown; escaping of double-quotes in
 360         # PO files breaks the meta plugin's parsing enough to save ugly titles
 361         # to %pagestate at this time.
 362         #
 363         # Then, at render time, every page passes in turn through the Great
 364         # Rendering Chain (filter->preprocess->linkify->htmlize), and the meta
 365         # plugin's preprocess hook is this time in a position to correctly
 366         # extract the titles from slave pages.
 367         #
 368         # This is, unfortunately, too late: if the page A, linking to the page
 369         # B, is rendered before B, it will display the wrongly-extracted meta
 370         # title as the link text to B.
 371         #
 372         # On the one hand, such a corner case only happens on rebuild: on
 373         # refresh, every rendered page is fixed to contain correct meta titles.
 374         # On the other hand, it can take some time to get every page fixed.
 375         # We therefore re-render every rendered page after a rebuild to fix them
 376         # at once. As this more or less doubles the time needed to rebuild the
 377         # wiki, we do so only when really needed.
 378
 379         if (@rendered
 380             && exists $config{rebuild} && defined $config{rebuild} && $config{rebuild}
 381             && UNIVERSAL::can("IkiWiki::Plugin::meta", "getsetup")
 382             && exists $config{meta_overrides_page_title}
 383             && defined $config{meta_overrides_page_title}
 384             && $config{meta_overrides_page_title}) {
 385                 debug(sprintf(gettext("rebuilding all pages to fix meta titles")));
 386                 resetalreadyfiltered();
 387                 require IkiWiki::Render;
 388                 foreach my $file (@rendered) {
 389                         debug(sprintf(gettext("building %s"), $file));
 390                         IkiWiki::render($file);
 391                 }
 392         }
 393
 394         my $updated_po_files=0;
 395
 396         # Refresh/create POT and PO files as needed.
 397         # (But avoid doing so if they are in an underlay directory.)
 398         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 399                 my $masterfile=srcfile($file);
 400                 my $page=pagename($file);
 401                 my $updated_pot_file=0;
 402                 # Only refresh POT file if it does not exist, or if
 403                 # $pagesources{$page} was changed: don't if only the HTML was
 404                 # refreshed, e.g. because of a dependency.
 405                 if ($masterfile eq "$config{srcdir}/$file" &&
 406                    ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 407                     || ! -e potfile($masterfile))) {
 408                         refreshpot($masterfile);
 409                         $updated_pot_file=1;
 410                 }
 411                 my @pofiles;
 412                 foreach my $po (pofiles($masterfile)) {
 413                         next if ! $updated_pot_file && ! -e $po;
 414                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 415                         push @pofiles, $po;
 416                 }
 417                 if (@pofiles) {
 418                         refreshpofiles($masterfile, @pofiles);
 419                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 420                         $updated_po_files=1;
 421                 }
 422         }
 423
 424         if ($updated_po_files) {
 425                 commit_and_refresh(
 426                         gettext("updated PO files"),
 427                         "IkiWiki::Plugin::po::change");
 428         }
 429 }
 430
 431 sub checkcontent (@) {
 432         my %params=@_;
 433
 434         if (istranslation($params{page})) {
 435                 my $res = isvalidpo($params{content});
 436                 if ($res) {
 437                         return undef;
 438                 }
 439                 else {
 440                         return "$res";
 441                 }
 442         }
 443         return undef;
 444 }
 445
 446 sub canremove (@) {
 447         my %params = @_;
 448
 449         if (istranslation($params{page})) {
 450                 return gettext("Can not remove a translation. If the master page is removed, ".
 451                                "however, its translations will be removed as well.");
 452         }
 453         return undef;
 454 }
 455
 456 sub canrename (@) {
 457         my %params = @_;
 458         my $session = $params{session};
 459
 460         if (istranslation($params{src})) {
 461                 my $masterpage = masterpage($params{src});
 462                 # Tell the difference between:
 463                 #  - a translation being renamed as a consequence of its master page
 464                 #    being renamed, which is allowed
 465                 #  - a user trying to directly rename a translation, which is forbidden
 466                 # by looking for the master page in the list of to-be-renamed pages we
 467                 # saved early in the renaming process.
 468                 my $orig_torename = $session->param("po_orig_torename");
 469                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 470                         return gettext("Can not rename a translation. If the master page is renamed, ".
 471                                        "however, its translations will be renamed as well.");
 472                 }
 473         }
 474         return undef;
 475 }
 476
 477 # As we're previewing or saving a page, the content may have
 478 # changed, so tell the next filter() invocation it must not be lazy.
 479 sub editcontent () {
 480         my %params=@_;
 481
 482         unsetalreadyfiltered($params{page}, $params{page});
 483         return $params{content};
 484 }
 485
 486 sub formbuilder_setup (@) {
 487         my %params=@_;
 488         my $form=$params{form};
 489         my $q=$params{cgi};
 490
 491         return unless defined $form->field("do");
 492
 493         if ($form->field("do") eq "create") {
 494                 # Warn the user: new pages must be written in master language.
 495                 my $template=template("pocreatepage.tmpl");
 496                 $template->param(LANG => $config{po_master_language}{name});
 497                 $form->tmpl_param(message => $template->output);
 498         }
 499         elsif ($form->field("do") eq "edit") {
 500                 # Remove the rename/remove buttons on slave pages.
 501                 # This has to be done after the rename/remove plugins have added
 502                 # their buttons, which is why this hook must be run last.
 503                 # The canrename/canremove hooks already ensure this is forbidden
 504                 # at the backend level, so this is only UI sugar.
 505                 if (istranslation($form->field("page"))) {
 506                         map {
 507                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 508                                         if (@{$params{buttons}}[$i] eq $_) {
 509                                                 delete  @{$params{buttons}}[$i];
 510                                                 last;
 511                                         }
 512                                 }
 513                         } qw(Rename Remove);
 514                 }
 515         }
 516 }
 517
 518 sub formbuilder (@) {
 519         my %params=@_;
 520         my $form=$params{form};
 521         my $q=$params{cgi};
 522
 523         return unless defined $form->field("do");
 524
 525         # Do not allow to create pages of type po: they are automatically created.
 526         # The main reason to do so is to bypass the "favor the type of linking page
 527         # on page creation" logic, which is unsuitable when a broken link is clicked
 528         # on a slave (PO) page.
 529         # This cannot be done in the formbuilder_setup hook as the list of types is
 530         # computed later.
 531         if ($form->field("do") eq "create") {
 532                 foreach my $field ($form->field) {
 533                         next unless "$field" eq "type";
 534                         next unless $field->type eq 'select';
 535                         my $orig_value = $field->value;
 536                         # remove po from the list of types
 537                         my @types = grep { $_->[0] ne 'po' } $field->options;
 538                         $field->options(\@types) if @types;
 539                         # favor the type of linking page's masterpage
 540                         if ($orig_value eq 'po') {
 541                                 my ($from, $type);
 542                                 if (defined $form->field('from')) {
 543                                         ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 544                                         $from = masterpage($from);
 545                                 }
 546                                 if (defined $from && exists $pagesources{$from}) {
 547                                         $type=pagetype($pagesources{$from});
 548                                 }
 549                                 $type=$config{default_pageext} unless defined $type;
 550                                 $field->value($type) ;
 551                         }
 552                 }
 553         }
 554 }
 555
 556 # ,----
 557 # | Injected functions
 558 # `----
 559
 560 # Implement po_link_to 'current' and 'negotiated' settings.
 561 sub mybestlink ($$) {
 562         my $page=shift;
 563         my $link=shift;
 564
 565         return $origsubs{'bestlink'}->($page, $link)
 566                 if $config{po_link_to} eq "default";
 567
 568         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 569         my @caller = caller(1);
 570         if (length $res
 571             && istranslatable($res)
 572             && istranslation($page)
 573             &&  !(exists $caller[3] && defined $caller[3]
 574                   && ($caller[3] eq "IkiWiki::PageSpec::match_link"))) {
 575                 return $res . "." . lang($page);
 576         }
 577         return $res;
 578 }
 579
 580 sub mybeautify_urlpath ($) {
 581         my $url=shift;
 582
 583         my $res=$origsubs{'beautify_urlpath'}->($url);
 584         if ($config{po_link_to} eq "negotiated") {
 585                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 586                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 587                 map {
 588                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 589                 } (keys %{$config{po_slave_languages}});
 590         }
 591         return $res;
 592 }
 593
 594 sub mytargetpage ($$) {
 595         my $page=shift;
 596         my $ext=shift;
 597
 598         if (istranslation($page) || istranslatable($page)) {
 599                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 600                 if (! $config{usedirs} || $masterpage eq 'index') {
 601                         return $masterpage . "." . $lang . "." . $ext;
 602                 }
 603                 else {
 604                         return $masterpage . "/index." . $lang . "." . $ext;
 605                 }
 606         }
 607         return $origsubs{'targetpage'}->($page, $ext);
 608 }
 609
 610 sub myurlto ($$;$) {
 611         my $to=shift;
 612         my $from=shift;
 613         my $absolute=shift;
 614
 615         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 616         if (! length $to
 617             && $config{po_link_to} eq "current"
 618             && istranslatable('index')) {
 619                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 620         }
 621         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 622         # so that one is redirected to the just-edited page rather than to the
 623         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 624         # we only do so when our beautify_urlpath would actually do what we want to
 625         # avoid, i.e. when po_link_to = negotiated.
 626         # also avoid doing so when run by cgi_goto, so that the links on recentchanges
 627         # page actually lead to the exact page they pretend to.
 628         if ($config{po_link_to} eq "negotiated") {
 629                 my @caller = caller(1);
 630                 my $use_orig = 0;
 631                 $use_orig = 1 if (exists $caller[3] && defined $caller[3]
 632                                  && ($caller[3] eq "IkiWiki::cgi_editpage" ||
 633                                      $caller[3] eq "IkiWiki::Plugin::goto::cgi_goto")
 634                                  );
 635                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 636                         if $use_orig;
 637                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 638                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 639                         if $use_orig;
 640                 return $res;
 641         }
 642         else {
 643                 return $origsubs{'urlto'}->($to,$from,$absolute)
 644         }
 645 }
 646
 647 sub mycgiurl (@) {
 648         my %params=@_;
 649
 650         # slave pages have no subpages
 651         if (istranslation($params{'from'})) {
 652                 $params{'from'} = masterpage($params{'from'});
 653         }
 654         return $origsubs{'cgiurl'}->(%params);
 655 }
 656
 657 sub myrootpage (@) {
 658         my %params=@_;
 659
 660         my $rootpage;
 661         if (exists $params{rootpage}) {
 662                 $rootpage=$origsubs{'bestlink'}->($params{page}, $params{rootpage});
 663                 if (!length $rootpage) {
 664                         $rootpage=$params{rootpage};
 665                 }
 666         }
 667         else {
 668                 $rootpage=masterpage($params{page});
 669         }
 670         return $rootpage;
 671 }
 672
 673 # ,----
 674 # | Blackboxes for private data
 675 # `----
 676
 677 {
 678         my %filtered;
 679
 680         sub alreadyfiltered($$) {
 681                 my $page=shift;
 682                 my $destpage=shift;
 683
 684                 return exists $filtered{$page}{$destpage}
 685                          && $filtered{$page}{$destpage} eq 1;
 686         }
 687
 688         sub setalreadyfiltered($$) {
 689                 my $page=shift;
 690                 my $destpage=shift;
 691
 692                 $filtered{$page}{$destpage}=1;
 693         }
 694
 695         sub unsetalreadyfiltered($$) {
 696                 my $page=shift;
 697                 my $destpage=shift;
 698
 699                 if (exists $filtered{$page}{$destpage}) {
 700                         delete $filtered{$page}{$destpage};
 701                 }
 702         }
 703
 704         sub resetalreadyfiltered() {
 705                 undef %filtered;
 706         }
 707 }
 708
 709 # ,----
 710 # | Helper functions
 711 # `----
 712
 713 sub maybe_add_leading_slash ($;$) {
 714         my $str=shift;
 715         my $add=shift;
 716         $add=1 unless defined $add;
 717         return '/' . $str if $add;
 718         return $str;
 719 }
 720
 721 sub istranslatablefile ($) {
 722         my $file=shift;
 723
 724         return 0 unless defined $file;
 725         my $type=pagetype($file);
 726         return 0 if ! defined $type || $type eq 'po';
 727         return 0 if $file =~ /\.pot$/;
 728         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 729         return;
 730 }
 731
 732 sub istranslatable ($) {
 733         my $page=shift;
 734
 735         $page=~s#^/##;
 736         return 1 if istranslatablefile($pagesources{$page});
 737         return;
 738 }
 739
 740 sub _istranslation ($) {
 741         my $page=shift;
 742
 743         $page='' unless defined $page && length $page;
 744         my $hasleadingslash = ($page=~s#^/##);
 745         my $file=$pagesources{$page};
 746         return 0 unless defined $file
 747                          && defined pagetype($file)
 748                          && pagetype($file) eq 'po';
 749         return 0 if $file =~ /\.pot$/;
 750
 751         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 752         return 0 unless defined $masterpage && defined $lang
 753                          && length $masterpage && length $lang
 754                          && defined $pagesources{$masterpage}
 755                          && defined $config{po_slave_languages}{$lang};
 756
 757         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 758                 if istranslatable($masterpage);
 759 }
 760
 761 sub istranslation ($) {
 762         my $page=shift;
 763
 764         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 765                 my $hasleadingslash = ($masterpage=~s#^/##);
 766                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 767                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 768         }
 769         return "";
 770 }
 771
 772 sub masterpage ($) {
 773         my $page=shift;
 774
 775         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 776                 return $masterpage;
 777         }
 778         return $page;
 779 }
 780
 781 sub lang ($) {
 782         my $page=shift;
 783
 784         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 785                 return $lang;
 786         }
 787         return $config{po_master_language}{code};
 788 }
 789
 790 sub islanguagecode ($) {
 791         my $code=shift;
 792
 793         return $code =~ /^[a-z]{2}$/;
 794 }
 795
 796 sub otherlanguage ($$) {
 797         my $page=shift;
 798         my $code=shift;
 799
 800         return masterpage($page) if $code eq $config{po_master_language}{code};
 801         return masterpage($page) . '.' . $code;
 802 }
 803
 804 sub otherlanguages ($) {
 805         my $page=shift;
 806
 807         my %ret;
 808         return \%ret unless istranslation($page) || istranslatable($page);
 809         my $curlang=lang($page);
 810         foreach my $lang
 811                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 812                 next if $lang eq $curlang;
 813                 $ret{$lang}=otherlanguage($page, $lang);
 814         }
 815         return \%ret;
 816 }
 817
 818 sub potfile ($) {
 819         my $masterfile=shift;
 820
 821         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 822         $dir='' if $dir eq './';
 823         return File::Spec->catpath('', $dir, $name . ".pot");
 824 }
 825
 826 sub pofile ($$) {
 827         my $masterfile=shift;
 828         my $lang=shift;
 829
 830         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 831         $dir='' if $dir eq './';
 832         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 833 }
 834
 835 sub pofiles ($) {
 836         my $masterfile=shift;
 837
 838         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 839 }
 840
 841 sub refreshpot ($) {
 842         my $masterfile=shift;
 843
 844         my $potfile=potfile($masterfile);
 845         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 846         my $doc=Locale::Po4a::Chooser::new('text',%options);
 847         $doc->{TT}{utf_mode} = 1;
 848         $doc->{TT}{file_in_charset} = 'utf-8';
 849         $doc->{TT}{file_out_charset} = 'utf-8';
 850         $doc->read($masterfile);
 851         # let's cheat a bit to force porefs option to be passed to
 852         # Locale::Po4a::Po; this is undocument use of internal
 853         # Locale::Po4a::TransTractor's data, compulsory since this module
 854         # prevents us from using the porefs option.
 855         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 856         $doc->{TT}{po_out}->set_charset('utf-8');
 857         # do the actual work
 858         $doc->parse;
 859         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 860         $doc->writepo($potfile);
 861 }
 862
 863 sub refreshpofiles ($@) {
 864         my $masterfile=shift;
 865         my @pofiles=@_;
 866
 867         my $potfile=potfile($masterfile);
 868         if (! -e $potfile) {
 869                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 870         }
 871
 872         foreach my $pofile (@pofiles) {
 873                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 874
 875                 if (! -e $pofile) {
 876                         # If the po file exists in an underlay, copy it
 877                         # from there.
 878                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 879                         foreach my $dir (@{$config{underlaydirs}}) {
 880                                 if (-e "$dir/$pobase") {
 881                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 882                                                 or error("po(refreshpofiles) ".
 883                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 884                                                                  $pofile));
 885                                 }
 886                         }
 887                 }
 888
 889                 if (-e $pofile) {
 890                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 891                                 or error("po(refreshpofiles) ".
 892                                          sprintf(gettext("failed to update %s"),
 893                                                  $pofile));
 894                 }
 895                 else {
 896                         File::Copy::syscopy($potfile,$pofile)
 897                                 or error("po(refreshpofiles) ".
 898                                          sprintf(gettext("failed to copy the POT file to %s"),
 899                                                  $pofile));
 900                 }
 901         }
 902 }
 903
 904 sub buildtranslationscache() {
 905         # use istranslation's side-effect
 906         map istranslation($_), (keys %pagesources);
 907 }
 908
 909 sub resettranslationscache() {
 910         undef %translations;
 911 }
 912
 913 sub flushmemoizecache() {
 914         Memoize::flush_cache("istranslatable");
 915         Memoize::flush_cache("_istranslation");
 916         Memoize::flush_cache("percenttranslated");
 917 }
 918
 919 sub urlto_with_orig_beautiful_urlpath($$) {
 920         my $to=shift;
 921         my $from=shift;
 922
 923         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 924         my $res=urlto($to, $from);
 925         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 926
 927         return $res;
 928 }
 929
 930 sub percenttranslated ($) {
 931         my $page=shift;
 932
 933         $page=~s/^\///;
 934         return gettext("N/A") unless istranslation($page);
 935         my $file=srcfile($pagesources{$page});
 936         my $masterfile = srcfile($pagesources{masterpage($page)});
 937         my %options = (
 938                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 939         );
 940         my $doc=Locale::Po4a::Chooser::new('text',%options);
 941         $doc->process(
 942                 'po_in_name'    => [ $file ],
 943                 'file_in_name'  => [ $masterfile ],
 944                 'file_in_charset'  => 'utf-8',
 945                 'file_out_charset' => 'utf-8',
 946         ) or error("po(percenttranslated) ".
 947                    sprintf(gettext("failed to translate %s"), $page));
 948         my ($percent,$hit,$queries) = $doc->stats();
 949         $percent =~ s/\.[0-9]+$//;
 950         return $percent;
 951 }
 952
 953 sub languagename ($) {
 954         my $code=shift;
 955
 956         return $config{po_master_language}{name}
 957                 if $code eq $config{po_master_language}{code};
 958         return $config{po_slave_languages}{$code}
 959                 if defined $config{po_slave_languages}{$code};
 960         return;
 961 }
 962
 963 sub otherlanguagesloop ($) {
 964         my $page=shift;
 965
 966         my @ret;
 967         my %otherpages=%{otherlanguages($page)};
 968         while (my ($lang, $otherpage) = each %otherpages) {
 969                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 970                         push @ret, {
 971                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 972                                 code => $lang,
 973                                 language => languagename($lang),
 974                                 master => 1,
 975                         };
 976                 }
 977                 elsif (istranslation($otherpage)) {
 978                         push @ret, {
 979                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 980                                 code => $lang,
 981                                 language => languagename($lang),
 982                                 percent => percenttranslated($otherpage),
 983                         }
 984                 }
 985         }
 986         return sort {
 987                 return -1 if $a->{code} eq $config{po_master_language}{code};
 988                 return 1 if $b->{code} eq $config{po_master_language}{code};
 989                 return $a->{language} cmp $b->{language};
 990         } @ret;
 991 }
 992
 993 sub homepageurl (;$) {
 994         my $page=shift;
 995
 996         return urlto('', $page);
 997 }
 998
 999 sub ishomepage ($) {
1000         my $page = shift;
1001
1002         return 1 if $page eq 'index';
1003         map { return 1 if $page eq 'index.'.$_ } keys %{$config{po_slave_languages}};
1004         return undef;
1005 }
1006
1007 sub deletetranslations ($) {
1008         my $deletedmasterfile=shift;
1009
1010         my $deletedmasterpage=pagename($deletedmasterfile);
1011         my @todelete;
1012         map {
1013                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
1014                 my $absfile = "$config{srcdir}/$file";
1015                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
1016                         push @todelete, $file;
1017                 }
1018         } keys %{$config{po_slave_languages}};
1019
1020         map {
1021                 if ($config{rcs}) {
1022                         IkiWiki::rcs_remove($_);
1023                 }
1024                 else {
1025                         IkiWiki::prune("$config{srcdir}/$_");
1026                 }
1027         } @todelete;
1028
1029         if (@todelete) {
1030                 commit_and_refresh(
1031                         gettext("removed obsolete PO files"),
1032                         "IkiWiki::Plugin::po::deletetranslations");
1033         }
1034 }
1035
1036 sub commit_and_refresh ($$) {
1037         my ($msg, $author) = (shift, shift);
1038
1039         if ($config{rcs}) {
1040                 IkiWiki::disable_commit_hook();
1041                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
1042                 IkiWiki::enable_commit_hook();
1043                 IkiWiki::rcs_update();
1044         }
1045         # Reinitialize module's private variables.
1046         resetalreadyfiltered();
1047         resettranslationscache();
1048         flushmemoizecache();
1049         # Trigger a wiki refresh.
1050         require IkiWiki::Render;
1051         # without preliminary saveindex/loadindex, refresh()
1052         # complains about a lot of uninitialized variables
1053         IkiWiki::saveindex();
1054         IkiWiki::loadindex();
1055         IkiWiki::refresh();
1056         IkiWiki::saveindex();
1057 }
1058
1059 # on success, returns the filtered content.
1060 # on error, if $nonfatal, warn and return undef; else, error out.
1061 sub po_to_markup ($$;$) {
1062         my ($page, $content) = (shift, shift);
1063         my $nonfatal = shift;
1064
1065         $content = '' unless defined $content;
1066         $content = decode_utf8(encode_utf8($content));
1067         # CRLF line terminators make poor Locale::Po4a feel bad
1068         $content=~s/\r\n/\n/g;
1069
1070         # There are incompatibilities between some File::Temp versions
1071         # (including 0.18, bundled with Lenny's perl-modules package)
1072         # and others (e.g. 0.20, previously present in the archive as
1073         # a standalone package): under certain circumstances, some
1074         # return a relative filename, whereas others return an absolute one;
1075         # we here use this module in a way that is at least compatible
1076         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1077         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1078                                     DIR => File::Spec->tmpdir,
1079                                     UNLINK => 1)->filename;
1080         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1081                                      DIR => File::Spec->tmpdir,
1082                                      UNLINK => 1)->filename;
1083
1084         my $fail = sub ($) {
1085                 my $msg = "po(po_to_markup) - $page : " . shift;
1086                 if ($nonfatal) {
1087                         warn $msg;
1088                         return undef;
1089                 }
1090                 error($msg, sub { unlink $infile, $outfile});
1091         };
1092
1093         writefile(basename($infile), File::Spec->tmpdir, $content)
1094                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1095
1096         my $masterfile = srcfile($pagesources{masterpage($page)});
1097         my %options = (
1098                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
1099         );
1100         my $doc=Locale::Po4a::Chooser::new('text',%options);
1101         $doc->process(
1102                 'po_in_name'    => [ $infile ],
1103                 'file_in_name'  => [ $masterfile ],
1104                 'file_in_charset'  => 'utf-8',
1105                 'file_out_charset' => 'utf-8',
1106         ) or return $fail->(gettext("failed to translate"));
1107         $doc->write($outfile)
1108                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1109
1110         $content = readfile($outfile)
1111                 or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
1112
1113         # Unlinking should happen automatically, thanks to File::Temp,
1114         # but it does not work here, probably because of the way writefile()
1115         # and Locale::Po4a::write() work.
1116         unlink $infile, $outfile;
1117
1118         return $content;
1119 }
1120
1121 # returns a SuccessReason or FailReason object
1122 sub isvalidpo ($) {
1123         my $content = shift;
1124
1125         # NB: we don't use po_to_markup here, since Po4a parser does
1126         # not mind invalid PO content
1127         $content = '' unless defined $content;
1128         $content = decode_utf8(encode_utf8($content));
1129
1130         # There are incompatibilities between some File::Temp versions
1131         # (including 0.18, bundled with Lenny's perl-modules package)
1132         # and others (e.g. 0.20, previously present in the archive as
1133         # a standalone package): under certain circumstances, some
1134         # return a relative filename, whereas others return an absolute one;
1135         # we here use this module in a way that is at least compatible
1136         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1137         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1138                                     DIR => File::Spec->tmpdir,
1139                                     UNLINK => 1)->filename;
1140
1141         my $fail = sub ($) {
1142                 my $msg = '[po/isvalidpo] ' . shift;
1143                 unlink $infile;
1144                 return IkiWiki::FailReason->new("$msg");
1145         };
1146
1147         writefile(basename($infile), File::Spec->tmpdir, $content)
1148                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1149
1150         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1151
1152         # Unlinking should happen automatically, thanks to File::Temp,
1153         # but it does not work here, probably because of the way writefile()
1154         # and Locale::Po4a::write() work.
1155         unlink $infile;
1156
1157         if ($res) {
1158             return IkiWiki::SuccessReason->new("valid gettext data");
1159         }
1160         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1161                                         "to previous page to continue edit"));
1162 }
1163
1164 # ,----
1165 # | PageSpecs
1166 # `----
1167
1168 package IkiWiki::PageSpec;
1169
1170 sub match_istranslation ($;@) {
1171         my $page=shift;
1172
1173         if (IkiWiki::Plugin::po::istranslation($page)) {
1174                 return IkiWiki::SuccessReason->new("is a translation page");
1175         }
1176         else {
1177                 return IkiWiki::FailReason->new("is not a translation page");
1178         }
1179 }
1180
1181 sub match_istranslatable ($;@) {
1182         my $page=shift;
1183
1184         if (IkiWiki::Plugin::po::istranslatable($page)) {
1185                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1186         }
1187         else {
1188                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1189         }
1190 }
1191
1192 sub match_lang ($$;@) {
1193         my $page=shift;
1194         my $wanted=shift;
1195
1196         my $regexp=IkiWiki::glob2re($wanted);
1197         my $lang=IkiWiki::Plugin::po::lang($page);
1198         if ($lang !~ /^$regexp$/i) {
1199                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1200         }
1201         else {
1202                 return IkiWiki::SuccessReason->new("file language is $wanted");
1203         }
1204 }
1205
1206 sub match_currentlang ($$;@) {
1207         my $page=shift;
1208         shift;
1209         my %params=@_;
1210
1211         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1212
1213         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1214         my $lang=IkiWiki::Plugin::po::lang($page);
1215
1216         if ($lang eq $currentlang) {
1217                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1218         }
1219         else {
1220                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1221         }
1222 }
1223
1224 1