IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31 my @slavelanguages; # language codes ordered as in config po_slave_languages
  32
  33 memoize("istranslatable");
  34 memoize("_istranslation");
  35 memoize("percenttranslated");
  36
  37 sub import {
  38         hook(type => "getsetup", id => "po", call => \&getsetup);
  39         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  40         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  41         hook(type => "scan", id => "po", call => \&scan, last => 1);
  42         hook(type => "filter", id => "po", call => \&filter);
  43         hook(type => "htmlize", id => "po", call => \&htmlize);
  44         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  45         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  46         hook(type => "delete", id => "po", call => \&mydelete);
  47         hook(type => "change", id => "po", call => \&change);
  48         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  49         hook(type => "canremove", id => "po", call => \&canremove);
  50         hook(type => "canrename", id => "po", call => \&canrename);
  51         hook(type => "editcontent", id => "po", call => \&editcontent);
  52         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  53         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  54
  55         if (! %origsubs) {
  56                 $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  57                 inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  58                 $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  59                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  60                 $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  61                 inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  62                 $origsubs{'urlto'}=\&IkiWiki::urlto;
  63                 inject(name => "IkiWiki::urlto", call => \&myurlto);
  64                 $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  65                 inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  66                 $origsubs{'rootpage'}=\&IkiWiki::rootpage;
  67                 inject(name => "IkiWiki::rootpage", call => \&myrootpage);
  68                 $origsubs{'isselflink'}=\&IkiWiki::isselflink;
  69                 inject(name => "IkiWiki::isselflink", call => \&myisselflink);
  70         }
  71 }
  72
  73
  74 # ,----
  75 # | Table of contents
  76 # `----
  77
  78 # 1. Hooks
  79 # 2. Injected functions
  80 # 3. Blackboxes for private data
  81 # 4. Helper functions
  82 # 5. PageSpecs
  83
  84
  85 # ,----
  86 # | Hooks
  87 # `----
  88
  89 sub getsetup () {
  90         return
  91                 plugin => {
  92                         safe => 0,
  93                         rebuild => 1, # format plugin
  94                         section => "format",
  95                 },
  96                 po_master_language => {
  97                         type => "string",
  98                         example => {
  99                                 'code' => 'en',
 100                                 'name' => 'English'
 101                         },
 102                         description => "master language (non-PO files)",
 103                         safe => 1,
 104                         rebuild => 1,
 105                 },
 106                 po_slave_languages => {
 107                         type => "string",
 108                         example => [
 109                                 'fr|Français',
 110                                 'es|Español',
 111                                 'de|Deutsch'
 112                         ],
 113                         description => "slave languages (PO files)",
 114                         safe => 1,
 115                         rebuild => 1,
 116                 },
 117                 po_translatable_pages => {
 118                         type => "pagespec",
 119                         example => "* and !*/Discussion",
 120                         description => "PageSpec controlling which pages are translatable",
 121                         link => "ikiwiki/PageSpec",
 122                         safe => 1,
 123                         rebuild => 1,
 124                 },
 125                 po_link_to => {
 126                         type => "string",
 127                         example => "current",
 128                         description => "internal linking behavior (default/current/negotiated)",
 129                         safe => 1,
 130                         rebuild => 1,
 131                 },
 132 }
 133
 134 sub checkconfig () {
 135         foreach my $field (qw{po_master_language}) {
 136                 if (! exists $config{$field} || ! defined $config{$field}) {
 137                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 138                                       $field, 'po'));
 139                 }
 140         }
 141
 142         if (ref $config{po_slave_languages} eq 'ARRAY') {
 143                 my %slaves;
 144                 foreach my $pair (@{$config{po_slave_languages}}) {
 145                         my ($code, $name) = ( $pair =~ /^([a-z]{2})\|(.+)$/ );
 146                         if (!defined $code || !defined $name) {
 147                                 error(sprintf(gettext("%s has invalid syntax: must use CODE|NAME"),
 148                                               $pair));
 149                         }
 150                         $slaves{$code} = $name;
 151                         push @slavelanguages, $code;
 152
 153                 }
 154                 $config{po_slave_languages} = \%slaves;
 155         }
 156         elsif (ref $config{po_slave_languages} eq 'HASH') {
 157                 @slavelanguages = sort {
 158                         $config{po_slave_languages}->{$a} cmp $config{po_slave_languages}->{$b};
 159                 } keys %{$config{po_slave_languages}};
 160         }
 161
 162         delete $config{po_slave_languages}{$config{po_master_language}{code}};;
 163
 164         map {
 165                 islanguagecode($_)
 166                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 167         } ($config{po_master_language}{code}, @slavelanguages);
 168
 169         if (! exists $config{po_translatable_pages} ||
 170             ! defined $config{po_translatable_pages}) {
 171                 $config{po_translatable_pages}="";
 172         }
 173         if (! exists $config{po_link_to} ||
 174             ! defined $config{po_link_to}) {
 175                 $config{po_link_to}='default';
 176         }
 177         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 178                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 179                              $config{po_link_to}));
 180                 $config{po_link_to}='default';
 181         }
 182         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 183                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 184                 $config{po_link_to}='default';
 185         }
 186
 187         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 188
 189         # Translated versions of the underlays are added if available.
 190         foreach my $underlay ("basewiki",
 191                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 192                                   reverse @{$config{underlaydirs}}) {
 193                 next if $underlay=~/^locale\//;
 194
 195                 # Underlays containing the po files for slave languages.
 196                 foreach my $ll (@slavelanguages) {
 197                         add_underlay("po/$ll/$underlay")
 198                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 199                 }
 200
 201                 if ($config{po_master_language}{code} ne 'en') {
 202                         # Add underlay containing translated source files
 203                         # for the master language.
 204                         add_underlay("locale/$config{po_master_language}{code}/$underlay")
 205                                 if -d "$config{underlaydirbase}/locale/$config{po_master_language}{code}/$underlay";
 206                 }
 207         }
 208 }
 209
 210 sub needsbuild () {
 211         my $needsbuild=shift;
 212
 213         # backup @needsbuild content so that change() can know whether
 214         # a given master page was rendered because its source file was changed
 215         @origneedsbuild=(@$needsbuild);
 216
 217         flushmemoizecache();
 218         buildtranslationscache();
 219
 220         # make existing translations depend on the corresponding master page
 221         foreach my $master (keys %translations) {
 222                 map add_depends($_, $master), values %{otherlanguages_pages($master)};
 223         }
 224 }
 225
 226 sub scan (@) {
 227         my %params=@_;
 228         my $page=$params{page};
 229         my $content=$params{content};
 230         my $run_by_po=$params{run_by_po};
 231
 232         # Massage the recorded state of internal links so that:
 233         # - it matches the actually generated links, rather than the links as
 234         #   written in the pages' source
 235         # - backlinks are consistent in all cases
 236
 237         # A second scan pass is made over translation pages, so as an
 238         # optimization, we only do so on the second pass in this case,
 239         # i.e. when this hook is called by itself.
 240         if ($run_by_po && istranslation($page)) {
 241                 # replace the occurence of $destpage in $links{$page}
 242                 my @orig_links = @{$links{$page}};
 243                 $links{$page} = [];
 244                 foreach my $destpage (@orig_links) {
 245                         if (istranslatedto($destpage, lang($page))) {
 246                                 add_link($page, $destpage . '.' . lang($page));
 247                         }
 248                         else {
 249                                 add_link($page, $destpage);
 250                         }
 251                 }
 252         }
 253         # No second scan pass is done for a non-translation page, so
 254         # links massaging must happen on first pass in this case.
 255         elsif (! $run_by_po && ! istranslatable($page) && ! istranslation($page)) {
 256                 foreach my $destpage (@{$links{$page}}) {
 257                         if (istranslatable($destpage)) {
 258                                 # make sure any destpage's translations has
 259                                 # $page in its backlinks
 260                                 foreach my $link (values %{otherlanguages_pages($destpage)}) {
 261                                         add_link($page, $link);
 262                                 }
 263                         }
 264                 }
 265         }
 266
 267         # Re-run the preprocess hooks in scan mode, then the scan hooks,
 268         # over the po-to-markup converted content
 269         return if $run_by_po; # avoid looping endlessly
 270         return unless istranslation($page);
 271         $content = po_to_markup($page, $content);
 272         require IkiWiki;
 273         IkiWiki::preprocess($page, $page, $content, 1);
 274         IkiWiki::run_hooks(scan => sub {
 275                 shift->(
 276                         page => $page,
 277                         content => $content,
 278                         run_by_po => 1,
 279                 );
 280         });
 281 }
 282
 283 # We use filter to convert PO to the master page's format,
 284 # since the rest of ikiwiki should not work on PO files.
 285 sub filter (@) {
 286         my %params = @_;
 287
 288         my $page = $params{page};
 289         my $destpage = $params{destpage};
 290         my $content = $params{content};
 291         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 292                 $content = po_to_markup($page, $content);
 293                 setalreadyfiltered($page, $destpage);
 294         }
 295         return $content;
 296 }
 297
 298 sub htmlize (@) {
 299         my %params=@_;
 300
 301         my $page = $params{page};
 302         my $content = $params{content};
 303
 304         # ignore PO files this plugin did not create
 305         return $content unless istranslation($page);
 306
 307         # force content to be htmlize'd as if it was the same type as the master page
 308         return IkiWiki::htmlize($page, $page,
 309                 pagetype(srcfile($pagesources{masterpage($page)})),
 310                 $content);
 311 }
 312
 313 sub pagetemplate (@) {
 314         my %params=@_;
 315         my $page=$params{page};
 316         my $destpage=$params{destpage};
 317         my $template=$params{template};
 318
 319         my ($masterpage, $lang) = istranslation($page);
 320
 321         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 322                 $template->param(percenttranslated => percenttranslated($page));
 323         }
 324         if ($template->query(name => "istranslation")) {
 325                 $template->param(istranslation => scalar istranslation($page));
 326         }
 327         if ($template->query(name => "istranslatable")) {
 328                 $template->param(istranslatable => istranslatable($page));
 329         }
 330         if ($template->query(name => "HOMEPAGEURL")) {
 331                 $template->param(homepageurl => homepageurl($page));
 332         }
 333         if ($template->query(name => "otherlanguages")) {
 334                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 335                 map add_depends($page, $_), (values %{otherlanguages_pages($page)});
 336         }
 337         if ($config{discussion} && istranslation($page)) {
 338                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 339                    (length $config{cgiurl} ||
 340                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 341                         $template->param('discussionlink' => htmllink(
 342                                 $page,
 343                                 $destpage,
 344                                 $masterpage . '/' . $config{discussionpage},
 345                                 noimageinline => 1,
 346                                 forcesubpage => 0,
 347                                 linktext => $config{discussionpage},
 348                 ));
 349                 }
 350         }
 351         # Remove broken parentlink to ./index.html on home page's translations.
 352         # It works because this hook has the "last" parameter set, to ensure it
 353         # runs after parentlinks' own pagetemplate hook.
 354         if ($template->param('parentlinks')
 355             && istranslation($page)
 356             && $masterpage eq "index") {
 357                 $template->param('parentlinks' => []);
 358         }
 359         if (ishomepage($page) && $template->query(name => "title")) {
 360                 $template->param(title => $config{wikiname});
 361         }
 362 }
 363
 364 # Add the renamed page translations to the list of to-be-renamed pages.
 365 sub renamepages (@) {
 366         my %params = @_;
 367
 368         my %torename = %{$params{torename}};
 369         my $session = $params{session};
 370
 371         # Save the page(s) the user asked to rename, so that our
 372         # canrename hook can tell the difference between:
 373         #  - a translation being renamed as a consequence of its master page
 374         #    being renamed
 375         #  - a user trying to directly rename a translation
 376         # This is why this hook has to be run first, before the list of pages
 377         # to rename is modified by other plugins.
 378         my @orig_torename;
 379         @orig_torename=@{$session->param("po_orig_torename")}
 380                 if defined $session->param("po_orig_torename");
 381         push @orig_torename, $torename{src};
 382         $session->param(po_orig_torename => \@orig_torename);
 383         IkiWiki::cgi_savesession($session);
 384
 385         return () unless istranslatable($torename{src});
 386
 387         my @ret;
 388         my %otherpages=%{otherlanguages_pages($torename{src})};
 389         while (my ($lang, $otherpage) = each %otherpages) {
 390                 push @ret, {
 391                         src => $otherpage,
 392                         srcfile => $pagesources{$otherpage},
 393                         dest => otherlanguage_page($torename{dest}, $lang),
 394                         destfile => $torename{dest}.".".$lang.".po",
 395                         required => 0,
 396                 };
 397         }
 398         return @ret;
 399 }
 400
 401 sub mydelete (@) {
 402         my @deleted=@_;
 403
 404         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 405 }
 406
 407 sub change (@) {
 408         my @rendered=@_;
 409
 410         my $updated_po_files=0;
 411
 412         # Refresh/create POT and PO files as needed.
 413         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 414                 my $masterfile=srcfile($file);
 415                 my $page=pagename($file);
 416                 my $updated_pot_file=0;
 417
 418                 # Avoid touching underlay files.
 419                 next if $masterfile ne "$config{srcdir}/$file";
 420
 421                 # Only refresh POT file if it does not exist, or if
 422                 # the source was changed: don't if only the HTML was
 423                 # refreshed, e.g. because of a dependency.
 424                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild) ||
 425                     ! -e potfile($masterfile)) {
 426                         refreshpot($masterfile);
 427                         $updated_pot_file=1;
 428                 }
 429                 my @pofiles;
 430                 foreach my $po (pofiles($masterfile)) {
 431                         next if ! $updated_pot_file && -e $po;
 432                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 433                         push @pofiles, $po;
 434                 }
 435                 if (@pofiles) {
 436                         refreshpofiles($masterfile, @pofiles);
 437                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 438                         $updated_po_files=1;
 439                 }
 440         }
 441
 442         if ($updated_po_files) {
 443                 commit_and_refresh(
 444                         gettext("updated PO files"));
 445         }
 446 }
 447
 448 sub checkcontent (@) {
 449         my %params=@_;
 450
 451         if (istranslation($params{page})) {
 452                 my $res = isvalidpo($params{content});
 453                 if ($res) {
 454                         return undef;
 455                 }
 456                 else {
 457                         return "$res";
 458                 }
 459         }
 460         return undef;
 461 }
 462
 463 sub canremove (@) {
 464         my %params = @_;
 465
 466         if (istranslation($params{page})) {
 467                 return gettext("Can not remove a translation. If the master page is removed, ".
 468                                "however, its translations will be removed as well.");
 469         }
 470         return undef;
 471 }
 472
 473 sub canrename (@) {
 474         my %params = @_;
 475         my $session = $params{session};
 476
 477         if (istranslation($params{src})) {
 478                 my $masterpage = masterpage($params{src});
 479                 # Tell the difference between:
 480                 #  - a translation being renamed as a consequence of its master page
 481                 #    being renamed, which is allowed
 482                 #  - a user trying to directly rename a translation, which is forbidden
 483                 # by looking for the master page in the list of to-be-renamed pages we
 484                 # saved early in the renaming process.
 485                 my $orig_torename = $session->param("po_orig_torename");
 486                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 487                         return gettext("Can not rename a translation. If the master page is renamed, ".
 488                                        "however, its translations will be renamed as well.");
 489                 }
 490         }
 491         return undef;
 492 }
 493
 494 # As we're previewing or saving a page, the content may have
 495 # changed, so tell the next filter() invocation it must not be lazy.
 496 sub editcontent () {
 497         my %params=@_;
 498
 499         unsetalreadyfiltered($params{page}, $params{page});
 500         return $params{content};
 501 }
 502
 503 sub formbuilder_setup (@) {
 504         my %params=@_;
 505         my $form=$params{form};
 506         my $q=$params{cgi};
 507
 508         return unless defined $form->field("do");
 509
 510         if ($form->field("do") eq "create") {
 511                 # Warn the user: new pages must be written in master language.
 512                 my $template=template("pocreatepage.tmpl");
 513                 $template->param(LANG => $config{po_master_language}{name});
 514                 $form->tmpl_param(message => $template->output);
 515         }
 516         elsif ($form->field("do") eq "edit") {
 517                 # Remove the rename/remove buttons on slave pages.
 518                 # This has to be done after the rename/remove plugins have added
 519                 # their buttons, which is why this hook must be run last.
 520                 # The canrename/canremove hooks already ensure this is forbidden
 521                 # at the backend level, so this is only UI sugar.
 522                 if (istranslation($form->field("page"))) {
 523                         map {
 524                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 525                                         if (@{$params{buttons}}[$i] eq $_) {
 526                                                 delete  @{$params{buttons}}[$i];
 527                                                 last;
 528                                         }
 529                                 }
 530                         } qw(Rename Remove);
 531                 }
 532         }
 533 }
 534
 535 sub formbuilder (@) {
 536         my %params=@_;
 537         my $form=$params{form};
 538         my $q=$params{cgi};
 539
 540         return unless defined $form->field("do");
 541
 542         # Do not allow to create pages of type po: they are automatically created.
 543         # The main reason to do so is to bypass the "favor the type of linking page
 544         # on page creation" logic, which is unsuitable when a broken link is clicked
 545         # on a slave (PO) page.
 546         # This cannot be done in the formbuilder_setup hook as the list of types is
 547         # computed later.
 548         if ($form->field("do") eq "create") {
 549                 foreach my $field ($form->field) {
 550                         next unless "$field" eq "type";
 551                         next unless $field->type eq 'select';
 552                         my $orig_value = $field->value;
 553                         # remove po from the list of types
 554                         my @types = grep { $_->[0] ne 'po' } $field->options;
 555                         $field->options(\@types) if @types;
 556                         # favor the type of linking page's masterpage
 557                         if ($orig_value eq 'po') {
 558                                 my ($from, $type);
 559                                 if (defined $form->field('from')) {
 560                                         ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 561                                         $from = masterpage($from);
 562                                 }
 563                                 if (defined $from && exists $pagesources{$from}) {
 564                                         $type=pagetype($pagesources{$from});
 565                                 }
 566                                 $type=$config{default_pageext} unless defined $type;
 567                                 $field->value($type) ;
 568                         }
 569                 }
 570         }
 571 }
 572
 573 # ,----
 574 # | Injected functions
 575 # `----
 576
 577 # Implement po_link_to 'current' and 'negotiated' settings.
 578 sub mybestlink ($$) {
 579         my $page=shift;
 580         my $link=shift;
 581
 582         return $origsubs{'bestlink'}->($page, $link)
 583                 if defined $config{po_link_to} && $config{po_link_to} eq "default";
 584
 585         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 586         my @caller = caller(1);
 587         if (length $res
 588             && istranslatedto($res, lang($page))
 589             && istranslation($page)
 590             &&  !(exists $caller[3] && defined $caller[3]
 591                   && ($caller[3] eq "IkiWiki::PageSpec::match_link"))) {
 592                 return $res . "." . lang($page);
 593         }
 594         return $res;
 595 }
 596
 597 sub mybeautify_urlpath ($) {
 598         my $url=shift;
 599
 600         my $res=$origsubs{'beautify_urlpath'}->($url);
 601         if (defined $config{po_link_to} && $config{po_link_to} eq "negotiated") {
 602                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 603                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 604                 map {
 605                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 606                 } @slavelanguages;
 607         }
 608         return $res;
 609 }
 610
 611 sub mytargetpage ($$) {
 612         my $page=shift;
 613         my $ext=shift;
 614
 615         if (istranslation($page) || istranslatable($page)) {
 616                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 617                 if (! $config{usedirs} || $masterpage eq 'index') {
 618                         return $masterpage . "." . $lang . "." . $ext;
 619                 }
 620                 else {
 621                         return $masterpage . "/index." . $lang . "." . $ext;
 622                 }
 623         }
 624         return $origsubs{'targetpage'}->($page, $ext);
 625 }
 626
 627 sub myurlto ($$;$) {
 628         my $to=shift;
 629         my $from=shift;
 630         my $absolute=shift;
 631
 632         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 633         if (! length $to
 634             && $config{po_link_to} eq "current"
 635             && istranslatable('index')) {
 636                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 637         }
 638         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 639         # so that one is redirected to the just-edited page rather than to the
 640         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 641         # we only do so when our beautify_urlpath would actually do what we want to
 642         # avoid, i.e. when po_link_to = negotiated.
 643         # also avoid doing so when run by cgi_goto, so that the links on recentchanges
 644         # page actually lead to the exact page they pretend to.
 645         if ($config{po_link_to} eq "negotiated") {
 646                 my @caller = caller(1);
 647                 my $use_orig = 0;
 648                 $use_orig = 1 if (exists $caller[3] && defined $caller[3]
 649                                  && ($caller[3] eq "IkiWiki::cgi_editpage" ||
 650                                      $caller[3] eq "IkiWiki::Plugin::goto::cgi_goto")
 651                                  );
 652                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 653                         if $use_orig;
 654                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 655                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 656                         if $use_orig;
 657                 return $res;
 658         }
 659         else {
 660                 return $origsubs{'urlto'}->($to,$from,$absolute)
 661         }
 662 }
 663
 664 sub mycgiurl (@) {
 665         my %params=@_;
 666
 667         # slave pages have no subpages
 668         if (istranslation($params{'from'})) {
 669                 $params{'from'} = masterpage($params{'from'});
 670         }
 671         return $origsubs{'cgiurl'}->(%params);
 672 }
 673
 674 sub myrootpage (@) {
 675         my %params=@_;
 676
 677         my $rootpage;
 678         if (exists $params{rootpage}) {
 679                 $rootpage=$origsubs{'bestlink'}->($params{page}, $params{rootpage});
 680                 if (!length $rootpage) {
 681                         $rootpage=$params{rootpage};
 682                 }
 683         }
 684         else {
 685                 $rootpage=masterpage($params{page});
 686         }
 687         return $rootpage;
 688 }
 689
 690 sub myisselflink ($$) {
 691         my $page=shift;
 692         my $link=shift;
 693
 694         return 1 if $origsubs{'isselflink'}->($page, $link);
 695         if (istranslation($page)) {
 696                 return $origsubs{'isselflink'}->(masterpage($page), $link);
 697         }
 698         return;
 699 }
 700
 701 # ,----
 702 # | Blackboxes for private data
 703 # `----
 704
 705 {
 706         my %filtered;
 707
 708         sub alreadyfiltered($$) {
 709                 my $page=shift;
 710                 my $destpage=shift;
 711
 712                 return exists $filtered{$page}{$destpage}
 713                          && $filtered{$page}{$destpage} eq 1;
 714         }
 715
 716         sub setalreadyfiltered($$) {
 717                 my $page=shift;
 718                 my $destpage=shift;
 719
 720                 $filtered{$page}{$destpage}=1;
 721         }
 722
 723         sub unsetalreadyfiltered($$) {
 724                 my $page=shift;
 725                 my $destpage=shift;
 726
 727                 if (exists $filtered{$page}{$destpage}) {
 728                         delete $filtered{$page}{$destpage};
 729                 }
 730         }
 731
 732         sub resetalreadyfiltered() {
 733                 undef %filtered;
 734         }
 735 }
 736
 737 # ,----
 738 # | Helper functions
 739 # `----
 740
 741 sub maybe_add_leading_slash ($;$) {
 742         my $str=shift;
 743         my $add=shift;
 744         $add=1 unless defined $add;
 745         return '/' . $str if $add;
 746         return $str;
 747 }
 748
 749 sub istranslatablefile ($) {
 750         my $file=shift;
 751
 752         return 0 unless defined $file;
 753         my $type=pagetype($file);
 754         return 0 if ! defined $type || $type eq 'po';
 755         return 0 if $file =~ /\.pot$/;
 756         return 0 if ! defined $config{po_translatable_pages};
 757         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 758         return;
 759 }
 760
 761 sub istranslatable ($) {
 762         my $page=shift;
 763
 764         $page=~s#^/##;
 765         return 1 if istranslatablefile($pagesources{$page});
 766         return;
 767 }
 768
 769 sub istranslatedto ($$) {
 770         my $page=shift;
 771         my $destlang = shift;
 772
 773         $page=~s#^/##;
 774         return 0 unless istranslatable($page);
 775         exists $pagesources{otherlanguage_page($page, $destlang)};
 776 }
 777
 778 sub _istranslation ($) {
 779         my $page=shift;
 780
 781         $page='' unless defined $page && length $page;
 782         my $hasleadingslash = ($page=~s#^/##);
 783         my $file=$pagesources{$page};
 784         return 0 unless defined $file
 785                          && defined pagetype($file)
 786                          && pagetype($file) eq 'po';
 787         return 0 if $file =~ /\.pot$/;
 788
 789         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 790         return 0 unless defined $masterpage && defined $lang
 791                          && length $masterpage && length $lang
 792                          && defined $pagesources{$masterpage}
 793                          && defined $config{po_slave_languages}{$lang};
 794
 795         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 796                 if istranslatable($masterpage);
 797 }
 798
 799 sub istranslation ($) {
 800         my $page=shift;
 801
 802         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 803                 my $hasleadingslash = ($masterpage=~s#^/##);
 804                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 805                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 806         }
 807         return "";
 808 }
 809
 810 sub masterpage ($) {
 811         my $page=shift;
 812
 813         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 814                 return $masterpage;
 815         }
 816         return $page;
 817 }
 818
 819 sub lang ($) {
 820         my $page=shift;
 821
 822         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 823                 return $lang;
 824         }
 825         return $config{po_master_language}{code};
 826 }
 827
 828 sub islanguagecode ($) {
 829         my $code=shift;
 830
 831         return $code =~ /^[a-z]{2}$/;
 832 }
 833
 834 sub otherlanguage_page ($$) {
 835         my $page=shift;
 836         my $code=shift;
 837
 838         return masterpage($page) if $code eq $config{po_master_language}{code};
 839         return masterpage($page) . '.' . $code;
 840 }
 841
 842 # Returns the list of other languages codes: the master language comes first,
 843 # then the codes are ordered the same way as in po_slave_languages, if it is
 844 # an array, or in the language name lexical order, if it is a hash.
 845 sub otherlanguages_codes ($) {
 846         my $page=shift;
 847
 848         my @ret;
 849         return \@ret unless istranslation($page) || istranslatable($page);
 850         my $curlang=lang($page);
 851         foreach my $lang
 852                 ($config{po_master_language}{code}, @slavelanguages) {
 853                 next if $lang eq $curlang;
 854                 if ($lang eq $config{po_master_language}{code} ||
 855                     istranslatedto(masterpage($page), $lang)) {
 856                         push @ret, $lang;
 857                 }
 858         }
 859         return \@ret;
 860 }
 861
 862 sub otherlanguages_pages ($) {
 863         my $page=shift;
 864
 865         my %ret;
 866         map {
 867                 $ret{$_} = otherlanguage_page($page, $_)
 868         } @{otherlanguages_codes($page)};
 869
 870         return \%ret;
 871 }
 872
 873 sub potfile ($) {
 874         my $masterfile=shift;
 875
 876         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 877         $dir='' if $dir eq './';
 878         return File::Spec->catpath('', $dir, $name . ".pot");
 879 }
 880
 881 sub pofile ($$) {
 882         my $masterfile=shift;
 883         my $lang=shift;
 884
 885         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 886         $dir='' if $dir eq './';
 887         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 888 }
 889
 890 sub pofiles ($) {
 891         my $masterfile=shift;
 892
 893         return map pofile($masterfile, $_), @slavelanguages;
 894 }
 895
 896 sub refreshpot ($) {
 897         my $masterfile=shift;
 898
 899         my $potfile=potfile($masterfile);
 900         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
 901                                            po4a_options($masterfile));
 902         $doc->{TT}{utf_mode} = 1;
 903         $doc->{TT}{file_in_charset} = 'UTF-8';
 904         $doc->{TT}{file_out_charset} = 'UTF-8';
 905         $doc->read($masterfile);
 906         # let's cheat a bit to force porefs option to be passed to
 907         # Locale::Po4a::Po; this is undocument use of internal
 908         # Locale::Po4a::TransTractor's data, compulsory since this module
 909         # prevents us from using the porefs option.
 910         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 911         $doc->{TT}{po_out}->set_charset('UTF-8');
 912         # do the actual work
 913         $doc->parse;
 914         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 915         $doc->writepo($potfile);
 916 }
 917
 918 sub refreshpofiles ($@) {
 919         my $masterfile=shift;
 920         my @pofiles=@_;
 921
 922         my $potfile=potfile($masterfile);
 923         if (! -e $potfile) {
 924                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 925         }
 926
 927         foreach my $pofile (@pofiles) {
 928                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 929
 930                 if (! -e $pofile) {
 931                         # If the po file exists in an underlay, copy it
 932                         # from there.
 933                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 934                         foreach my $dir (@{$config{underlaydirs}}) {
 935                                 if (-e "$dir/$pobase") {
 936                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 937                                                 or error("po(refreshpofiles) ".
 938                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 939                                                                  $pofile));
 940                                 }
 941                         }
 942                 }
 943
 944                 if (-e $pofile) {
 945                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 946                                 or error("po(refreshpofiles) ".
 947                                          sprintf(gettext("failed to update %s"),
 948                                                  $pofile));
 949                 }
 950                 else {
 951                         File::Copy::syscopy($potfile,$pofile)
 952                                 or error("po(refreshpofiles) ".
 953                                          sprintf(gettext("failed to copy the POT file to %s"),
 954                                                  $pofile));
 955                 }
 956         }
 957 }
 958
 959 sub buildtranslationscache() {
 960         # use istranslation's side-effect
 961         map istranslation($_), (keys %pagesources);
 962 }
 963
 964 sub resettranslationscache() {
 965         undef %translations;
 966 }
 967
 968 sub flushmemoizecache() {
 969         Memoize::flush_cache("istranslatable");
 970         Memoize::flush_cache("_istranslation");
 971         Memoize::flush_cache("percenttranslated");
 972 }
 973
 974 sub urlto_with_orig_beautiful_urlpath($$) {
 975         my $to=shift;
 976         my $from=shift;
 977
 978         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 979         my $res=urlto($to, $from);
 980         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 981
 982         return $res;
 983 }
 984
 985 sub percenttranslated ($) {
 986         my $page=shift;
 987
 988         $page=~s/^\///;
 989         return gettext("N/A") unless istranslation($page);
 990         my $file=srcfile($pagesources{$page});
 991         my $masterfile = srcfile($pagesources{masterpage($page)});
 992         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
 993                                            po4a_options($masterfile));
 994         $doc->process(
 995                 'po_in_name'    => [ $file ],
 996                 'file_in_name'  => [ $masterfile ],
 997                 'file_in_charset'  => 'UTF-8',
 998                 'file_out_charset' => 'UTF-8',
 999         ) or error("po(percenttranslated) ".
1000                    sprintf(gettext("failed to translate %s"), $page));
1001         my ($percent,$hit,$queries) = $doc->stats();
1002         $percent =~ s/\.[0-9]+$//;
1003         return $percent;
1004 }
1005
1006 sub languagename ($) {
1007         my $code=shift;
1008
1009         return $config{po_master_language}{name}
1010                 if $code eq $config{po_master_language}{code};
1011         return $config{po_slave_languages}{$code}
1012                 if defined $config{po_slave_languages}{$code};
1013         return;
1014 }
1015
1016 sub otherlanguagesloop ($) {
1017         my $page=shift;
1018
1019         my @ret;
1020         if (istranslation($page)) {
1021                 push @ret, {
1022                         url => urlto_with_orig_beautiful_urlpath(masterpage($page), $page),
1023                         code => $config{po_master_language}{code},
1024                         language => $config{po_master_language}{name},
1025                         master => 1,
1026                 };
1027         }
1028         foreach my $lang (@{otherlanguages_codes($page)}) {
1029                 next if $lang eq $config{po_master_language}{code};
1030                 my $otherpage = otherlanguage_page($page, $lang);
1031                 push @ret, {
1032                         url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
1033                         code => $lang,
1034                         language => languagename($lang),
1035                         percent => percenttranslated($otherpage),
1036                 }
1037         }
1038         return @ret;
1039 }
1040
1041 sub homepageurl (;$) {
1042         my $page=shift;
1043
1044         return urlto('', $page);
1045 }
1046
1047 sub ishomepage ($) {
1048         my $page = shift;
1049
1050         return 1 if $page eq 'index';
1051         map { return 1 if $page eq 'index.'.$_ } @slavelanguages;
1052         return undef;
1053 }
1054
1055 sub deletetranslations ($) {
1056         my $deletedmasterfile=shift;
1057
1058         my $deletedmasterpage=pagename($deletedmasterfile);
1059         my @todelete;
1060         map {
1061                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
1062                 my $absfile = "$config{srcdir}/$file";
1063                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
1064                         push @todelete, $file;
1065                 }
1066         } @slavelanguages;
1067
1068         map {
1069                 if ($config{rcs}) {
1070                         IkiWiki::rcs_remove($_);
1071                 }
1072                 else {
1073                         IkiWiki::prune("$config{srcdir}/$_");
1074                 }
1075         } @todelete;
1076
1077         if (@todelete) {
1078                 commit_and_refresh(
1079                         gettext("removed obsolete PO files"));
1080         }
1081 }
1082
1083 sub commit_and_refresh ($) {
1084         my $msg = shift;
1085
1086         if ($config{rcs}) {
1087                 IkiWiki::disable_commit_hook();
1088                 IkiWiki::rcs_commit_staged(
1089                         message => $msg,
1090                 );
1091                 IkiWiki::enable_commit_hook();
1092                 IkiWiki::rcs_update();
1093         }
1094         # Reinitialize module's private variables.
1095         resetalreadyfiltered();
1096         resettranslationscache();
1097         flushmemoizecache();
1098         # Trigger a wiki refresh.
1099         require IkiWiki::Render;
1100         # without preliminary saveindex/loadindex, refresh()
1101         # complains about a lot of uninitialized variables
1102         IkiWiki::saveindex();
1103         IkiWiki::loadindex();
1104         IkiWiki::refresh();
1105         IkiWiki::saveindex();
1106 }
1107
1108 sub po_to_markup ($$) {
1109         my ($page, $content) = (shift, shift);
1110
1111         $content = '' unless defined $content;
1112         $content = decode_utf8(encode_utf8($content));
1113         # CRLF line terminators make poor Locale::Po4a feel bad
1114         $content=~s/\r\n/\n/g;
1115
1116         # There are incompatibilities between some File::Temp versions
1117         # (including 0.18, bundled with Lenny's perl-modules package)
1118         # and others (e.g. 0.20, previously present in the archive as
1119         # a standalone package): under certain circumstances, some
1120         # return a relative filename, whereas others return an absolute one;
1121         # we here use this module in a way that is at least compatible
1122         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1123         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1124                                     DIR => File::Spec->tmpdir,
1125                                     UNLINK => 1)->filename;
1126         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1127                                      DIR => File::Spec->tmpdir,
1128                                      UNLINK => 1)->filename;
1129
1130         my $fail = sub ($) {
1131                 my $msg = "po(po_to_markup) - $page : " . shift;
1132                 error($msg, sub { unlink $infile, $outfile});
1133         };
1134
1135         writefile(basename($infile), File::Spec->tmpdir, $content)
1136                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1137
1138         my $masterfile = srcfile($pagesources{masterpage($page)});
1139         my $doc=Locale::Po4a::Chooser::new(po4a_type($masterfile),
1140                                            po4a_options($masterfile));
1141         $doc->process(
1142                 'po_in_name'    => [ $infile ],
1143                 'file_in_name'  => [ $masterfile ],
1144                 'file_in_charset'  => 'UTF-8',
1145                 'file_out_charset' => 'UTF-8',
1146         ) or return $fail->(gettext("failed to translate"));
1147         $doc->write($outfile)
1148                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1149
1150         $content = readfile($outfile);
1151
1152         # Unlinking should happen automatically, thanks to File::Temp,
1153         # but it does not work here, probably because of the way writefile()
1154         # and Locale::Po4a::write() work.
1155         unlink $infile, $outfile;
1156
1157         return $content;
1158 }
1159
1160 # returns a SuccessReason or FailReason object
1161 sub isvalidpo ($) {
1162         my $content = shift;
1163
1164         # NB: we don't use po_to_markup here, since Po4a parser does
1165         # not mind invalid PO content
1166         $content = '' unless defined $content;
1167         $content = decode_utf8(encode_utf8($content));
1168
1169         # There are incompatibilities between some File::Temp versions
1170         # (including 0.18, bundled with Lenny's perl-modules package)
1171         # and others (e.g. 0.20, previously present in the archive as
1172         # a standalone package): under certain circumstances, some
1173         # return a relative filename, whereas others return an absolute one;
1174         # we here use this module in a way that is at least compatible
1175         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1176         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1177                                     DIR => File::Spec->tmpdir,
1178                                     UNLINK => 1)->filename;
1179
1180         my $fail = sub ($) {
1181                 my $msg = '[po/isvalidpo] ' . shift;
1182                 unlink $infile;
1183                 return IkiWiki::FailReason->new("$msg");
1184         };
1185
1186         writefile(basename($infile), File::Spec->tmpdir, $content)
1187                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1188
1189         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1190
1191         # Unlinking should happen automatically, thanks to File::Temp,
1192         # but it does not work here, probably because of the way writefile()
1193         # and Locale::Po4a::write() work.
1194         unlink $infile;
1195
1196         if ($res) {
1197                 return IkiWiki::SuccessReason->new("valid gettext data");
1198         }
1199         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1200                                         "to previous page to continue edit"));
1201 }
1202
1203 sub po4a_type ($) {
1204         my $file = shift;
1205
1206         my $pagetype = pagetype($file);
1207         if ($pagetype eq 'html') {
1208                 return 'xhtml';
1209         }
1210         return 'text';
1211 }
1212
1213 sub po4a_options($) {
1214         my $file = shift;
1215
1216         my %options;
1217         my $pagetype = pagetype($file);
1218
1219         if ($pagetype eq 'html') {
1220                 # how to disable options is not consistent across po4a modules
1221                 $options{includessi} = '';
1222                 $options{includeexternal} = 0;
1223         }
1224         elsif ($pagetype eq 'mdwn') {
1225                 $options{markdown} = 1;
1226         }
1227         else {
1228                 $options{markdown} = 0;
1229         }
1230
1231         return %options;
1232 }
1233
1234 # ,----
1235 # | PageSpecs
1236 # `----
1237
1238 package IkiWiki::PageSpec;
1239
1240 sub match_istranslation ($;@) {
1241         my $page=shift;
1242
1243         if (IkiWiki::Plugin::po::istranslation($page)) {
1244                 return IkiWiki::SuccessReason->new("is a translation page");
1245         }
1246         else {
1247                 return IkiWiki::FailReason->new("is not a translation page");
1248         }
1249 }
1250
1251 sub match_istranslatable ($;@) {
1252         my $page=shift;
1253
1254         if (IkiWiki::Plugin::po::istranslatable($page)) {
1255                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1256         }
1257         else {
1258                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1259         }
1260 }
1261
1262 sub match_lang ($$;@) {
1263         my $page=shift;
1264         my $wanted=shift;
1265
1266         my $regexp=IkiWiki::glob2re($wanted);
1267         my $lang=IkiWiki::Plugin::po::lang($page);
1268         if ($lang !~ /^$regexp$/i) {
1269                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1270         }
1271         else {
1272                 return IkiWiki::SuccessReason->new("file language is $wanted");
1273         }
1274 }
1275
1276 sub match_currentlang ($$;@) {
1277         my $page=shift;
1278         shift;
1279         my %params=@_;
1280
1281         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1282
1283         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1284         my $lang=IkiWiki::Plugin::po::lang($page);
1285
1286         if ($lang eq $currentlang) {
1287                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1288         }
1289         else {
1290                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1291         }
1292 }
1293
1294 sub match_needstranslation ($$;@) {
1295         my $page=shift;
1296         my $wanted=shift;
1297
1298         if (defined $wanted && $wanted ne "") {
1299                 if ($wanted !~ /^\d+$/) {
1300                         return IkiWiki::FailReason->new("parameter is not an integer");
1301                 }
1302                 elsif ($wanted > 100) {
1303                         return IkiWiki::FailReason->new("parameter is greater than 100");
1304                 }
1305         }
1306         else {
1307                 $wanted=100;
1308         }
1309
1310         my $percenttranslated=IkiWiki::Plugin::po::percenttranslated($page);
1311         if ($percenttranslated eq 'N/A') {
1312                 return IkiWiki::FailReason->new("file is not a translatable page");
1313         }
1314         elsif ($percenttranslated < $wanted) {
1315                 return IkiWiki::SuccessReason->new("file has $percenttranslated translated");
1316         }
1317         else {
1318                 return IkiWiki::FailReason->new("file is translated enough");
1319         }
1320 }
1321
1322 1