IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub redirect ($$) { #{{{
  25         my $q=shift;
  26         my $url=shift;
  27         if (! $config{w3mmode}) {
  28                 print $q->redirect($url);
  29         }
  30         else {
  31                 print "Content-type: text/plain\n";
  32                 print "W3m-control: GOTO $url\n\n";
  33         }
  34 } #}}}
  35
  36 sub page_locked ($$;$) { #{{{
  37         my $page=shift;
  38         my $session=shift;
  39         my $nonfatal=shift;
  40
  41         my $user=$session->param("name");
  42         return if defined $user && is_admin($user);
  43
  44         foreach my $admin (@{$config{adminuser}}) {
  45                 my $locked_pages=userinfo_get($admin, "locked_pages");
  46                 if (pagespec_match($page, userinfo_get($admin, "locked_pages"))) {
  47                         return 1 if $nonfatal;
  48                         error(htmllink("", "", $page, 1)." is locked by ".
  49                               htmllink("", "", $admin, 1)." and cannot be edited.");
  50                 }
  51         }
  52
  53         return 0;
  54 } #}}}
  55
  56 sub decode_form_utf8 ($) { #{{{
  57         my $form = shift;
  58         foreach my $f ($form->field) {
  59                 next if Encode::is_utf8(scalar $form->field($f));
  60                 $form->field(name  => $f,
  61                              value => decode_utf8($form->field($f)),
  62                              force => 1,
  63                             );
  64         }
  65 } #}}}
  66
  67 sub cgi_recentchanges ($) { #{{{
  68         my $q=shift;
  69
  70         unlockwiki();
  71
  72         # Optimisation: building recentchanges means calculating lots of
  73         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  74         # during page builds as the return values may change, but they
  75         # won't here.)
  76         eval q{use Memoize};
  77         error($@) if $@;
  78         memoize("htmllink");
  79
  80         eval q{use Time::Duration};
  81         error($@) if $@;
  82         eval q{use CGI 'escapeHTML'};
  83         error($@) if $@;
  84
  85         my $changelog=[rcs_recentchanges(100)];
  86         foreach my $change (@$changelog) {
  87                 $change->{when} = concise(ago($change->{when}));
  88                 $change->{user} = htmllink("", "", escapeHTML($change->{user}), 1);
  89
  90                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
  91                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
  92                 $change->{pages} = [
  93                         map {
  94                                 $_->{link} = htmllink("", "", $_->{page}, 1);
  95                                 $_;
  96                         } @{$change->{pages}}
  97                 ];
  98                 push @{$change->{pages}}, { link => '...' } if $is_excess;
  99         }
 100
 101         my $template=template("recentchanges.tmpl");
 102         $template->param(
 103                 title => "RecentChanges",
 104                 indexlink => indexlink(),
 105                 wikiname => $config{wikiname},
 106                 changelog => $changelog,
 107                 baseurl => baseurl(),
 108         );
 109         run_hooks(pagetemplate => sub {
 110                 shift->(page => "", destpage => "", template => $template);
 111         });
 112         print $q->header(-charset => 'utf-8'), $template->output;
 113 } #}}}
 114
 115 sub cgi_signin ($$) { #{{{
 116         my $q=shift;
 117         my $session=shift;
 118
 119         eval q{use CGI::FormBuilder};
 120         error($@) if $@;
 121         my $form = CGI::FormBuilder->new(
 122                 title => "signin",
 123                 fields => [qw(do title page subpage from name password)],
 124                 header => 1,
 125                 charset => "utf-8",
 126                 method => 'POST',
 127                 validate => {
 128                         confirm_password => {
 129                                 perl => q{eq $form->field("password")},
 130                         },
 131                         email => 'EMAIL',
 132                 },
 133                 required => 'NONE',
 134                 javascript => 0,
 135                 params => $q,
 136                 action => $config{cgiurl},
 137                 header => 0,
 138                 template => (-e "$config{templatedir}/signin.tmpl" ?
 139                              {template_params("signin.tmpl")} : ""),
 140                 stylesheet => baseurl()."style.css",
 141         );
 142
 143         decode_form_utf8($form);
 144
 145         $form->field(name => "name", required => 0);
 146         $form->field(name => "do", type => "hidden");
 147         $form->field(name => "page", type => "hidden");
 148         $form->field(name => "title", type => "hidden");
 149         $form->field(name => "from", type => "hidden");
 150         $form->field(name => "subpage", type => "hidden");
 151         $form->field(name => "password", type => "password", required => 0);
 152         if ($form->submitted eq "Register" || $form->submitted eq "Create Account") {
 153                 $form->title("register");
 154                 $form->text("");
 155                 $form->fields(qw(do title page subpage from name password confirm_password email));
 156                 $form->field(name => "confirm_password", type => "password");
 157                 $form->field(name => "email", type => "text");
 158         }
 159         if ($q->param("do") ne "signin" && !$form->submitted) {
 160                 $form->text("You need to log in first.");
 161         }
 162
 163         if ($form->submitted) {
 164                 # Set required fields based on how form was submitted.
 165                 my %required=(
 166                         "Login" => [qw(name password)],
 167                         "Register" => [],
 168                         "Create Account" => [qw(name password confirm_password email)],
 169                         "Mail Password" => [qw(name)],
 170                 );
 171                 foreach my $opt (@{$required{$form->submitted}}) {
 172                         $form->field(name => $opt, required => 1);
 173                 }
 174
 175                 # Validate password differently depending on how
 176                 # form was submitted.
 177                 if ($form->submitted eq 'Login') {
 178                         $form->field(
 179                                 name => "password",
 180                                 validate => sub {
 181                                         length $form->field("name") &&
 182                                         shift eq userinfo_get($form->field("name"), 'password');
 183                                 },
 184                         );
 185                         $form->field(name => "name", validate => '/^\w+$/');
 186                 }
 187                 else {
 188                         $form->field(name => "password", validate => 'VALUE');
 189                 }
 190                 # And make sure the entered name exists when logging
 191                 # in or sending email, and does not when registering.
 192                 if ($form->submitted eq 'Create Account' ||
 193                     $form->submitted eq 'Register') {
 194                         $form->field(
 195                                 name => "name",
 196                                 validate => sub {
 197                                         my $name=shift;
 198                                         length $name &&
 199                                         $name=~/$config{wiki_file_regexp}/ &&
 200                                         ! userinfo_get($name, "regdate");
 201                                 },
 202                         );
 203                 }
 204                 else {
 205                         $form->field(
 206                                 name => "name",
 207                                 validate => sub {
 208                                         my $name=shift;
 209                                         length $name &&
 210                                         userinfo_get($name, "regdate");
 211                                 },
 212                         );
 213                 }
 214         }
 215         else {
 216                 # First time settings.
 217                 $form->field(name => "name", comment => "use FirstnameLastName");
 218                 if ($session->param("name")) {
 219                         $form->field(name => "name", value => $session->param("name"));
 220                 }
 221         }
 222
 223         if ($form->submitted && $form->validate) {
 224                 if ($form->submitted eq 'Login') {
 225                         $session->param("name", $form->field("name"));
 226                         if (defined $form->field("do") &&
 227                             $form->field("do") ne 'signin') {
 228                                 redirect($q, cgiurl(
 229                                         do => $form->field("do"),
 230                                         page => $form->field("page"),
 231                                         title => $form->field("title"),
 232                                         subpage => $form->field("subpage"),
 233                                         from => $form->field("from"),
 234                                 ));
 235                         }
 236                         else {
 237                                 redirect($q, $config{url});
 238                         }
 239                 }
 240                 elsif ($form->submitted eq 'Create Account') {
 241                         my $user_name=$form->field('name');
 242                         if (userinfo_setall($user_name, {
 243                                            'email' => $form->field('email'),
 244                                            'password' => $form->field('password'),
 245                                            'regdate' => time
 246                                          })) {
 247                                 $form->field(name => "confirm_password", type => "hidden");
 248                                 $form->field(name => "email", type => "hidden");
 249                                 $form->text("Account creation successful. Now you can Login.");
 250                                 printheader($session);
 251                                 print misctemplate($form->title, $form->render(submit => ["Login"]));
 252                         }
 253                         else {
 254                                 error("Error creating account.");
 255                         }
 256                 }
 257                 elsif ($form->submitted eq 'Mail Password') {
 258                         my $user_name=$form->field("name");
 259                         my $template=template("passwordmail.tmpl");
 260                         $template->param(
 261                                 user_name => $user_name,
 262                                 user_password => userinfo_get($user_name, "password"),
 263                                 wikiurl => $config{url},
 264                                 wikiname => $config{wikiname},
 265                                 REMOTE_ADDR => $ENV{REMOTE_ADDR},
 266                         );
 267
 268                         eval q{use Mail::Sendmail};
 269                         error($@) if $@;
 270                         sendmail(
 271                                 To => userinfo_get($user_name, "email"),
 272                                 From => "$config{wikiname} admin <$config{adminemail}>",
 273                                 Subject => "$config{wikiname} information",
 274                                 Message => $template->output,
 275                         ) or error("Failed to send mail");
 276
 277                         $form->text("Your password has been emailed to you.");
 278                         $form->field(name => "name", required => 0);
 279                         printheader($session);
 280                         print misctemplate($form->title, $form->render(submit => ["Login", "Mail Password"]));
 281                 }
 282                 elsif ($form->submitted eq "Register") {
 283                         printheader($session);
 284                         print misctemplate($form->title, $form->render(submit => ["Create Account"]));
 285                 }
 286         }
 287         elsif ($form->submitted eq "Create Account") {
 288                 printheader($session);
 289                 print misctemplate($form->title, $form->render(submit => ["Create Account"]));
 290         }
 291         else {
 292                 printheader($session);
 293                 print misctemplate($form->title, $form->render(submit => ["Login", "Register", "Mail Password"]));
 294         }
 295 } #}}}
 296
 297 sub cgi_prefs ($$) { #{{{
 298         my $q=shift;
 299         my $session=shift;
 300
 301         # The session id is stored on the form and checked to
 302         # guard against CSRF.
 303         my $sid=$q->param('sid');
 304         if (! defined $sid) {
 305                 $q->delete_all;
 306         }
 307         elsif ($sid ne $session->id) {
 308                 error(gettext("Your login session has expired."));
 309         }
 310
 311         eval q{use CGI::FormBuilder};
 312         error($@) if $@;
 313         my $form = CGI::FormBuilder->new(
 314                 title => "preferences",
 315                 fields => [qw(do name password confirm_password email
 316                               subscriptions locked_pages)],
 317                 header => 0,
 318                 charset => "utf-8",
 319                 method => 'POST',
 320                 validate => {
 321                         confirm_password => {
 322                                 perl => q{eq $form->field("password")},
 323                         },
 324                         email => 'EMAIL',
 325                 },
 326                 required => 'NONE',
 327                 javascript => 0,
 328                 params => $q,
 329                 action => $config{cgiurl},
 330                 template => (-e "$config{templatedir}/prefs.tmpl" ?
 331                              {template_params("prefs.tmpl")} : ""),
 332                 stylesheet => baseurl()."style.css",
 333         );
 334         my @buttons=("Save Preferences", "Logout", "Cancel");
 335
 336         my $user_name=$session->param("name");
 337         $form->field(name => "do", type => "hidden", value => "prefs",
 338                 force => 1);
 339         $form->field(name => "sid", type => "hidden", value => $session->id,
 340                 force => 1);
 341         $form->field(name => "name", disabled => 1,
 342                 value => $user_name, force => 1);
 343         $form->field(name => "password", type => "password");
 344         $form->field(name => "confirm_password", type => "password");
 345         $form->field(name => "subscriptions", size => 50,
 346                 comment => "(".htmllink("", "", "PageSpec", 1).")");
 347         $form->field(name => "locked_pages", size => 50,
 348                 comment => "(".htmllink("", "", "PageSpec", 1).")");
 349         $form->field(name => "banned_users", size => 50);
 350
 351         if (! is_admin($user_name)) {
 352                 $form->field(name => "locked_pages", type => "hidden");
 353                 $form->field(name => "banned_users", type => "hidden");
 354         }
 355
 356         if ($config{httpauth}) {
 357                 $form->field(name => "password", type => "hidden");
 358                 $form->field(name => "confirm_password", type => "hidden");
 359         }
 360
 361         if (! $form->submitted) {
 362                 $form->field(name => "email", force => 1,
 363                         value => userinfo_get($user_name, "email"));
 364                 $form->field(name => "subscriptions", force => 1,
 365                         value => userinfo_get($user_name, "subscriptions"));
 366                 $form->field(name => "locked_pages", force => 1,
 367                         value => userinfo_get($user_name, "locked_pages"));
 368                 if (is_admin($user_name)) {
 369                         $form->field(name => "banned_users", force => 1,
 370                                 value => join(" ", get_banned_users()));
 371                 }
 372         }
 373
 374         decode_form_utf8($form);
 375
 376         if ($form->submitted eq 'Logout') {
 377                 $session->delete();
 378                 redirect($q, $config{url});
 379                 return;
 380         }
 381         elsif ($form->submitted eq 'Cancel') {
 382                 redirect($q, $config{url});
 383                 return;
 384         }
 385         elsif ($form->submitted eq "Save Preferences" && $form->validate) {
 386                 foreach my $field (qw(password email subscriptions locked_pages)) {
 387                         if (length $form->field($field)) {
 388                                 userinfo_set($user_name, $field, $form->field($field)) || error("failed to set $field");
 389                         }
 390                 }
 391                 if (is_admin($user_name)) {
 392                         set_banned_users(grep { ! is_admin($_) }
 393                                         split(' ', $form->field("banned_users")));
 394                 }
 395                 $form->text("Preferences saved.");
 396         }
 397
 398         printheader($session);
 399         print misctemplate($form->title, $form->render(submit => \@buttons));
 400 } #}}}
 401
 402 sub cgi_editpage ($$) { #{{{
 403         my $q=shift;
 404         my $session=shift;
 405
 406         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 407         my @buttons=("Save Page", "Preview", "Cancel");
 408
 409         eval q{use CGI::FormBuilder; use CGI::FormBuilder::Template::HTML};
 410         error($@) if $@;
 411         my $renderer=CGI::FormBuilder::Template::HTML->new(
 412                 fields => \@fields,
 413                 template_params("editpage.tmpl"),
 414         );
 415         run_hooks(pagetemplate => sub {
 416                 shift->(page => "", destpage => "", template => $renderer->engine);
 417         });
 418         my $form = CGI::FormBuilder->new(
 419                 fields => \@fields,
 420                 header => 1,
 421                 charset => "utf-8",
 422                 method => 'POST',
 423                 validate => {
 424                         editcontent => '/.+/',
 425                 },
 426                 required => [qw{editcontent}],
 427                 javascript => 0,
 428                 params => $q,
 429                 action => $config{cgiurl},
 430                 table => 0,
 431                 template => $renderer,
 432         );
 433
 434         decode_form_utf8($form);
 435
 436         # This untaint is safe because titlepage removes any problematic
 437         # characters.
 438         my ($page)=$form->field('page');
 439         $page=titlepage(possibly_foolish_untaint($page));
 440         if (! defined $page || ! length $page ||
 441             $page=~/$config{wiki_file_prune_regexp}/ || $page=~/^\//) {
 442                 error("bad page name");
 443         }
 444
 445         my $from;
 446         if (defined $form->field('from')) {
 447                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 448         }
 449
 450         my $file;
 451         my $type;
 452         if (exists $pagesources{$page}) {
 453                 $file=$pagesources{$page};
 454                 $type=pagetype($file);
 455                 if (! defined $type) {
 456                         error("$page is not an editable page");
 457                 }
 458         }
 459         else {
 460                 $type=$form->param('type');
 461                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 462                         $type=possibly_foolish_untaint($type);
 463                 }
 464                 elsif (defined $from) {
 465                         # favor the type of linking page
 466                         $type=pagetype($pagesources{$from});
 467                 }
 468                 $type=$config{default_pageext} unless defined $type;
 469                 $file=$page.".".$type;
 470         }
 471
 472         my $newfile=0;
 473         if (! -e "$config{srcdir}/$file") {
 474                 $newfile=1;
 475         }
 476
 477         $form->field(name => "do", type => 'hidden');
 478         $form->field(name => "sid", type => "hidden", value => $session->id,
 479                 force => 1);
 480         $form->field(name => "from", type => 'hidden');
 481         $form->field(name => "rcsinfo", type => 'hidden');
 482         $form->field(name => "subpage", type => 'hidden');
 483         $form->field(name => "page", value => $page, force => 1);
 484         $form->field(name => "type", value => $type, force => 1);
 485         $form->field(name => "comments", type => "text", size => 80);
 486         $form->field(name => "editcontent", type => "textarea", rows => 20,
 487                 cols => 80);
 488         $form->tmpl_param("can_commit", $config{rcs});
 489         $form->tmpl_param("indexlink", indexlink());
 490         $form->tmpl_param("helponformattinglink",
 491                 htmllink("", "", "HelpOnFormatting", 1));
 492         $form->tmpl_param("baseurl", baseurl());
 493         if (! $form->submitted) {
 494                 $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 495                         force => 1);
 496         }
 497
 498         if ($form->submitted eq "Cancel") {
 499                 if ($newfile && defined $from) {
 500                         redirect($q, "$config{url}/".htmlpage($from));
 501                 }
 502                 elsif ($newfile) {
 503                         redirect($q, $config{url});
 504                 }
 505                 else {
 506                         redirect($q, "$config{url}/".htmlpage($page));
 507                 }
 508                 return;
 509         }
 510         elsif ($form->submitted eq "Preview") {
 511                 my $content=$form->field('editcontent');
 512                 my $comments=$form->field('comments');
 513                 $form->field(name => "editcontent",
 514                                 value => $content, force => 1);
 515                 $form->field(name => "comments",
 516                                 value => $comments, force => 1);
 517                 $config{rss}=$config{atom}=0; # avoid preview writing a feed!
 518                 $form->tmpl_param("page_preview",
 519                         htmlize($page, $type,
 520                         linkify($page, "",
 521                         preprocess($page, $page,
 522                         filter($page, $content)))));
 523         }
 524         else {
 525                 $form->tmpl_param("page_preview", "");
 526         }
 527         $form->tmpl_param("page_conflict", "");
 528
 529         if (! $form->submitted || $form->submitted eq "Preview" ||
 530             ! $form->validate) {
 531                 if ($form->field("do") eq "create") {
 532                         my @page_locs;
 533                         my $best_loc;
 534                         if (! defined $from || ! length $from ||
 535                             $from ne $form->field('from') ||
 536                             $from=~/$config{wiki_file_prune_regexp}/ ||
 537                             $from=~/^\// ||
 538                             $form->submitted eq "Preview") {
 539                                 @page_locs=$best_loc=$page;
 540                         }
 541                         else {
 542                                 my $dir=$from."/";
 543                                 $dir=~s![^/]+/+$!!;
 544
 545                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 546                                     $page eq 'discussion') {
 547                                         $best_loc="$from/$page";
 548                                 }
 549                                 else {
 550                                         $best_loc=$dir.$page;
 551                                 }
 552
 553                                 push @page_locs, $dir.$page;
 554                                 push @page_locs, "$from/$page";
 555                                 while (length $dir) {
 556                                         $dir=~s![^/]+/+$!!;
 557                                         push @page_locs, $dir.$page;
 558                                 }
 559                         }
 560
 561                         @page_locs = grep {
 562                                 ! exists $pagecase{lc $_} &&
 563                                 ! page_locked($_, $session, 1)
 564                         } @page_locs;
 565
 566                         if (! @page_locs) {
 567                                 # hmm, someone else made the page in the
 568                                 # meantime?
 569                                 redirect($q, "$config{url}/".htmlpage($page));
 570                                 return;
 571                         }
 572
 573                         my @page_types;
 574                         if (exists $hooks{htmlize}) {
 575                                 @page_types=keys %{$hooks{htmlize}};
 576                         }
 577
 578                         $form->tmpl_param("page_select", 1);
 579                         $form->field(name => "page", type => 'select',
 580                                 options => \@page_locs, value => $best_loc);
 581                         $form->field(name => "type", type => 'select',
 582                                 options => \@page_types);
 583                         $form->title("creating ".pagetitle($page));
 584                 }
 585                 elsif ($form->field("do") eq "edit") {
 586                         page_locked($page, $session);
 587                         if (! defined $form->field('editcontent') ||
 588                             ! length $form->field('editcontent')) {
 589                                 my $content="";
 590                                 if (exists $pagesources{$page}) {
 591                                         $content=readfile(srcfile($pagesources{$page}));
 592                                         $content=~s/\n/\r\n/g;
 593                                 }
 594                                 $form->field(name => "editcontent", value => $content,
 595                                         force => 1);
 596                         }
 597                         $form->tmpl_param("page_select", 0);
 598                         $form->field(name => "page", type => 'hidden');
 599                         $form->field(name => "type", type => 'hidden');
 600                         $form->title("editing ".pagetitle($page));
 601                 }
 602
 603                 print $form->render(submit => \@buttons);
 604         }
 605         else {
 606                 # save page
 607                 page_locked($page, $session);
 608
 609                 # The session id is stored on the form and checked to
 610                 # guard against CSRF. But only if the user is logged in,
 611                 # as anonok can allow anonymous edits.
 612                 if (defined $session->param("name")) {
 613                         my $sid=$q->param('sid');
 614                         if (! defined $sid || $sid ne $session->id) {
 615                                 error(gettext("Your login session has expired."));
 616                         }
 617                 }
 618
 619                 my $content=$form->field('editcontent');
 620
 621                 $content=~s/\r\n/\n/g;
 622                 $content=~s/\r/\n/g;
 623                 writefile($file, $config{srcdir}, $content);
 624
 625                 my $message="web commit ";
 626                 if (defined $session->param("name") &&
 627                     length $session->param("name")) {
 628                         $message.="by ".$session->param("name");
 629                 }
 630                 else {
 631                         $message.="from $ENV{REMOTE_ADDR}";
 632                 }
 633                 if (defined $form->field('comments') &&
 634                     length $form->field('comments')) {
 635                         $message.=": ".$form->field('comments');
 636                 }
 637
 638                 if ($config{rcs}) {
 639                         if ($newfile) {
 640                                 rcs_add($file);
 641                         }
 642                         # prevent deadlock with post-commit hook
 643                         unlockwiki();
 644                         # presumably the commit will trigger an update
 645                         # of the wiki
 646                         my $conflict=rcs_commit($file, $message,
 647                                 $form->field("rcsinfo"));
 648
 649                         if (defined $conflict) {
 650                                 $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 651                                         force => 1);
 652                                 $form->tmpl_param("page_conflict", 1);
 653                                 $form->field("editcontent", value => $conflict, force => 1);
 654                                 $form->field(name => "comments", value => $form->field('comments'), force => 1);
 655                                 $form->field("do", "edit)");
 656                                 $form->tmpl_param("page_select", 0);
 657                                 $form->field(name => "page", type => 'hidden');
 658                                 $form->field(name => "type", type => 'hidden');
 659                                 $form->title("editing $page");
 660                                 print $form->render(submit => \@buttons);
 661                                 return;
 662                         }
 663                 }
 664                 else {
 665                         require IkiWiki::Render;
 666                         refresh();
 667                         saveindex();
 668                 }
 669
 670                 # The trailing question mark tries to avoid broken
 671                 # caches and get the most recent version of the page.
 672                 redirect($q, "$config{url}/".htmlpage($page)."?updated");
 673         }
 674 } #}}}
 675
 676 sub cgi () { #{{{
 677         eval q{use CGI; use CGI::Session};
 678         error($@) if $@;
 679
 680         my $q=CGI->new;
 681
 682         run_hooks(cgi => sub { shift->($q) });
 683
 684         my $do=$q->param('do');
 685         if (! defined $do || ! length $do) {
 686                 my $error = $q->cgi_error;
 687                 if ($error) {
 688                         error("Request not processed: $error");
 689                 }
 690                 else {
 691                         error("\"do\" parameter missing");
 692                 }
 693         }
 694
 695         # Things that do not need a session.
 696         if ($do eq 'recentchanges') {
 697                 cgi_recentchanges($q);
 698                 return;
 699         }
 700         elsif ($do eq 'hyperestraier') {
 701                 cgi_hyperestraier();
 702         }
 703
 704         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 705
 706         my $oldmask=umask(077);
 707         my $session = CGI::Session->new("driver:DB_File", $q,
 708                 { FileName => "$config{wikistatedir}/sessions.db" });
 709         umask($oldmask);
 710
 711         # Everything below this point needs the user to be signed in.
 712         if (((! $config{anonok} || $do eq 'prefs') &&
 713              (! $config{httpauth}) &&
 714              (! defined $session->param("name") ||
 715              ! userinfo_get($session->param("name"), "regdate"))) || $do eq 'signin') {
 716                 cgi_signin($q, $session);
 717
 718                 # Force session flush with safe umask.
 719                 my $oldmask=umask(077);
 720                 $session->flush;
 721                 umask($oldmask);
 722
 723                 return;
 724         }
 725
 726         if ($config{httpauth} && (! defined $session->param("name"))) {
 727                 if (! defined $q->remote_user()) {
 728                         error("Could not determine authenticated username.");
 729                 }
 730                 else {
 731                         $session->param("name", $q->remote_user());
 732                         if (! userinfo_get($session->param("name"), "regdate")) {
 733                                 userinfo_setall($session->param("name"), {
 734                                         email => "",
 735                                         password => "",
 736                                         regdate=>time,
 737                                 });
 738                         }
 739                 }
 740         }
 741
 742         if (defined $session->param("name") && userinfo_get($session->param("name"), "banned")) {
 743                 print $q->header(-status => "403 Forbidden");
 744                 $session->delete();
 745                 print "You are banned.";
 746                 exit;
 747         }
 748
 749         if ($do eq 'create' || $do eq 'edit') {
 750                 cgi_editpage($q, $session);
 751         }
 752         elsif ($do eq 'prefs') {
 753                 cgi_prefs($q, $session);
 754         }
 755         elsif ($do eq 'blog') {
 756                 my $page=titlepage(decode_utf8($q->param('title')));
 757                 # if the page already exists, munge it to be unique
 758                 my $from=$q->param('from');
 759                 my $add="";
 760                 while (exists $pagecase{lc "$from/$page$add"}) {
 761                         $add=1 unless length $add;
 762                         $add++;
 763                 }
 764                 $q->param('page', $page.$add);
 765                 # now run same as create
 766                 $q->param('do', 'create');
 767                 cgi_editpage($q, $session);
 768         }
 769         else {
 770                 error("unknown do parameter");
 771         }
 772 } #}}}
 773
 774 1