IkiWiki/Plugin/conditional.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::conditional;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use UNIVERSAL;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "conditional", call => \&getsetup);
  11         hook(type => "preprocess", id => "if", call => \&preprocess_if);
  12 }
  13
  14 sub getsetup {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                 },
  20 }
  21
  22 sub preprocess_if (@) {
  23         my %params=@_;
  24
  25         foreach my $param (qw{test then}) {
  26                 if (! exists $params{$param}) {
  27                         error sprintf(gettext('%s parameter is required'), $param);
  28                 }
  29         }
  30
  31         my $result=0;
  32         if (! IkiWiki::yesno($params{all}) ||
  33             # An optimisation to avoid needless looping over every page
  34             # for simple uses of some of the tests.
  35             $params{test} =~ /^([\s\!()]*((enabled|sourcepage|destpage|included)\([^)]*\)|(and|or))[\s\!()]*)+$/) {
  36                 add_depends($params{page}, "($params{test}) and $params{page}");
  37                 $result=pagespec_match($params{page}, $params{test},
  38                                 location => $params{page},
  39                                 sourcepage => $params{page},
  40                                 destpage => $params{destpage});
  41         }
  42         else {
  43                 $result=pagespec_match_list($params{page}, $params{test},
  44                         # stop after first match
  45                         num => 1,
  46                         sourcepage => $params{page},
  47                         destpage => $params{destpage},
  48                 );
  49         }
  50
  51         my $ret;
  52         if ($result) {
  53                 $ret=$params{then};
  54         }
  55         elsif (exists $params{else}) {
  56                 $ret=$params{else};
  57         }
  58         else {
  59                 $ret="";
  60         }
  61         return IkiWiki::preprocess($params{page}, $params{destpage},
  62                 IkiWiki::filter($params{page}, $params{destpage}, $ret));
  63 }
  64
  65 package IkiWiki::PageSpec;
  66
  67 sub match_enabled ($$;@) {
  68         shift;
  69         my $plugin=shift;
  70
  71         # test if the plugin is enabled
  72         if (UNIVERSAL::can("IkiWiki::Plugin::".$plugin, "import")) {
  73                 return IkiWiki::SuccessReason->new("$plugin is enabled");
  74         }
  75         else {
  76                 return IkiWiki::FailReason->new("$plugin is not enabled");
  77         }
  78 }
  79
  80 sub match_sourcepage ($$;@) {
  81         shift;
  82         my $glob=shift;
  83         my %params=@_;
  84
  85         $glob=derel($glob, $params{location});
  86
  87         return IkiWiki::FailReason->new("cannot match sourcepage") unless exists $params{sourcepage};
  88         if (match_glob($params{sourcepage}, $glob, @_)) {
  89                 return IkiWiki::SuccessReason->new("sourcepage matches $glob");
  90         }
  91         else {
  92                 return IkiWiki::FailReason->new("sourcepage does not match $glob");
  93         }
  94 }
  95
  96 sub match_destpage ($$;@) {
  97         shift;
  98         my $glob=shift;
  99         my %params=@_;
 100
 101         $glob=derel($glob, $params{location});
 102
 103         return IkiWiki::FailReason->new("cannot match destpage") unless exists $params{destpage};
 104         if (match_glob($params{destpage}, $glob, @_)) {
 105                 return IkiWiki::SuccessReason->new("destpage matches $glob");
 106         }
 107         else {
 108                 return IkiWiki::FailReason->new("destpage does not match $glob");
 109         }
 110 }
 111
 112 sub match_included ($$;@) {
 113         shift;
 114         shift;
 115         my %params=@_;
 116
 117         return IkiWiki::FailReason->new("cannot match included") unless exists $params{sourcepage} && exists $params{destpage};
 118         if ($params{sourcepage} ne $params{destpage}) {
 119                 return IkiWiki::SuccessReason->new("page $params{sourcepage} is included");
 120         }
 121         else {
 122                 return IkiWiki::FailReason->new("page $params{sourcepage} is not included");
 123         }
 124 }
 125
 126 1