IkiWiki/Rcs/git.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use Encode;
   7 use open qw{:utf8 :std};
   8
   9 package IkiWiki;
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub _safe_git (&@) { #{{{
  15         # Start a child process safely without resorting /bin/sh.
  16         # Return command output or success state (in scalar context).
  17
  18         my ($error_handler, @cmdline) = @_;
  19
  20         my $pid = open my $OUT, "-|";
  21
  22         error("Cannot fork: $!") if !defined $pid;
  23
  24         if (!$pid) {
  25                 # In child.
  26                 # Git commands want to be in wc.
  27                 chdir $config{srcdir}
  28                     or error("Cannot chdir to $config{srcdir}: $!");
  29                 exec @cmdline or error("Cannot exec '@cmdline': $!");
  30         }
  31         # In parent.
  32
  33         my @lines;
  34         while (<$OUT>) {
  35                 chomp;
  36                 push @lines, $_;
  37         }
  38
  39         close $OUT;
  40
  41         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
  42
  43         return wantarray ? @lines : ($? == 0);
  44 }
  45 # Convenient wrappers.
  46 sub run_or_die ($@) { _safe_git(\&error, @_) }
  47 sub run_or_cry ($@) { _safe_git(sub { warn @_ },  @_) }
  48 sub run_or_non ($@) { _safe_git(undef,            @_) }
  49 #}}}
  50
  51 sub _merge_past ($$$) { #{{{
  52         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
  53         # Git merge commands work with the committed changes, except in the
  54         # implicit case of '-m' of git-checkout(1).  So we should invent a
  55         # kludge here.  In principle, we need to create a throw-away branch
  56         # in preparing for the merge itself.  Since branches are cheap (and
  57         # branching is fast), this shouldn't cost high.
  58         #
  59         # The main problem is the presence of _uncommitted_ local changes.  One
  60         # possible approach to get rid of this situation could be that we first
  61         # make a temporary commit in the master branch and later restore the
  62         # initial state (this is possible since Git has the ability to undo a
  63         # commit, i.e. 'git-reset --soft HEAD^').  The method can be summarized
  64         # as follows:
  65         #
  66         #       - create a diff of HEAD:current-sha1
  67         #       - dummy commit
  68         #       - create a dummy branch and switch to it
  69         #       - rewind to past (reset --hard to the current-sha1)
  70         #       - apply the diff and commit
  71         #       - switch to master and do the merge with the dummy branch
  72         #       - make a soft reset (undo the last commit of master)
  73         #
  74         # The above method has some drawbacks: (1) it needs a redundant commit
  75         # just to get rid of local changes, (2) somewhat slow because of the
  76         # required system forks.  Until someone points a more straight method
  77         # (which I would be grateful) I have implemented an alternative method.
  78         # In this approach, we hide all the modified files from Git by renaming
  79         # them (using the 'rename' builtin) and later restore those files in
  80         # the throw-away branch (that is, we put the files themselves instead
  81         # of applying a patch).
  82
  83         my ($sha1, $file, $message) = @_;
  84
  85         my @undo;      # undo stack for cleanup in case of an error
  86         my $conflict;  # file content with conflict markers
  87
  88         eval {
  89                 # Hide local changes from Git by renaming the modified file.
  90                 # Relative paths must be converted to absolute for renaming.
  91                 my ($target, $hidden) = (
  92                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
  93                 );
  94                 rename($target, $hidden)
  95                     or error("rename '$target' to '$hidden' failed: $!");
  96                 # Ensure to restore the renamed file on error.
  97                 push @undo, sub {
  98                         return if ! -e "$hidden"; # already renamed
  99                         rename($hidden, $target)
 100                             or warn "rename '$hidden' to '$target' failed: $!";
 101                 };
 102
 103                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 104
 105                 # Create a throw-away branch and rewind backward.
 106                 push @undo, sub { run_or_cry('git-branch', '-D', $branch) };
 107                 run_or_die('git-branch', $branch, $sha1);
 108
 109                 # Switch to throw-away branch for the merge operation.
 110                 push @undo, sub {
 111                         if (!run_or_cry('git-checkout', $config{gitmaster_branch})) {
 112                                 run_or_cry('git-checkout','-f',$config{gitmaster_branch});
 113                         }
 114                 };
 115                 run_or_die('git-checkout', $branch);
 116
 117                 # Put the modified file in _this_ branch.
 118                 rename($hidden, $target)
 119                     or error("rename '$hidden' to '$target' failed: $!");
 120
 121                 # _Silently_ commit all modifications in the current branch.
 122                 run_or_non('git-commit', '-m', $message, '-a');
 123                 # ... and re-switch to master.
 124                 run_or_die('git-checkout', $config{gitmaster_branch});
 125
 126                 # Attempt to merge without complaining.
 127                 if (!run_or_non('git-pull', '--no-commit', '.', $branch)) {
 128                         $conflict = readfile($target);
 129                         run_or_die('git-reset', '--hard');
 130                 }
 131         };
 132         my $failure = $@;
 133
 134         # Process undo stack (in reverse order).  By policy cleanup
 135         # actions should normally print a warning on failure.
 136         while (my $handle = pop @undo) {
 137                 $handle->();
 138         }
 139
 140         error("Git merge failed!\n$failure\n") if $failure;
 141
 142         return $conflict;
 143 } #}}}
 144
 145 sub _parse_diff_tree ($@) { #{{{
 146         # Parse the raw diff tree chunk and return the info hash.
 147         # See git-diff-tree(1) for the syntax.
 148
 149         my ($prefix, $dt_ref) = @_;
 150
 151         # End of stream?
 152         return if !defined @{ $dt_ref } ||
 153                   !defined @{ $dt_ref }[0] || !length @{ $dt_ref }[0];
 154
 155         my %ci;
 156         # Header line.
 157         while (my $line = shift @{ $dt_ref }) {
 158                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 159
 160                 my $sha1 = $2;
 161                 $ci{'sha1'} = $sha1;
 162                 last;
 163         }
 164
 165         # Identification lines for the commit.
 166         while (my $line = shift @{ $dt_ref }) {
 167                 # Regexps are semi-stolen from gitweb.cgi.
 168                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 169                         $ci{'tree'} = $1;
 170                 }
 171                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 172                         # XXX: collecting in reverse order
 173                         push @{ $ci{'parents'} }, $1;
 174                 }
 175                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 176                         my ($who, $name, $epoch, $tz) =
 177                            ($1,   $2,    $3,     $4 );
 178
 179                         $ci{  $who          } = $name;
 180                         $ci{ "${who}_epoch" } = $epoch;
 181                         $ci{ "${who}_tz"    } = $tz;
 182
 183                         if ($name =~ m/^([^<]+) <([^@>]+)/) {
 184                                 my ($fullname, $username) = ($1, $2);
 185                                 $ci{"${who}_fullname"}    = $fullname;
 186                                 $ci{"${who}_username"}    = $username;
 187                         }
 188                         else {
 189                                 $ci{"${who}_fullname"} =
 190                                         $ci{"${who}_username"} = $name;
 191                         }
 192                 }
 193                 elsif ($line =~ m/^$/) {
 194                         # Trailing empty line signals next section.
 195                         last;
 196                 }
 197         }
 198
 199         debug("No 'tree' or 'parents' seen in diff-tree output")
 200             if !defined $ci{'tree'} || !defined $ci{'parents'};
 201
 202         $ci{'parent'} = @{ $ci{'parents'} }[0] if defined $ci{'parents'};
 203
 204         # Commit message.
 205         while (my $line = shift @{ $dt_ref }) {
 206                 if ($line =~ m/^$/) {
 207                         # Trailing empty line signals next section.
 208                         last;
 209                 };
 210                 $line =~ s/^    //;
 211                 push @{ $ci{'comment'} }, $line;
 212         }
 213
 214         # Modified files.
 215         while (my $line = shift @{ $dt_ref }) {
 216                 if ($line =~ m{^:
 217                         ([0-7]{6})[ ]      # from mode
 218                         ([0-7]{6})[ ]      # to mode
 219                         ($sha1_pattern)[ ] # from sha1
 220                         ($sha1_pattern)[ ] # to sha1
 221                         (.)                # status
 222                         ([0-9]{0,3})\t     # similarity
 223                         (.*)               # file
 224                 $}xo) {
 225                         my ($sha1_from, $sha1_to, $file) =
 226                            ($3,         $4,       $7   );
 227
 228                         if ($file =~ m/^"(.*)"$/) {
 229                                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 230                         }
 231                         $file =~ s/^\Q$prefix\E//;
 232                         if (length $file) {
 233                                 push @{ $ci{'details'} }, {
 234                                         'file'      => decode_utf8($file),
 235                                         'sha1_from' => $sha1_from,
 236                                         'sha1_to'   => $sha1_to,
 237                                 };
 238                         }
 239                         next;
 240                 };
 241                 last;
 242         }
 243
 244         debug("No detail in diff-tree output") if !defined $ci{'details'};
 245
 246         return \%ci;
 247 } #}}}
 248
 249 sub git_commit_info ($;$) { #{{{
 250         # Return an array of commit info hashes of num commits (default: 1)
 251         # starting from the given sha1sum.
 252
 253         my ($sha1, $num) = @_;
 254
 255         $num ||= 1;
 256
 257         my @raw_lines = run_or_die('git-log', "--max-count=$num",
 258                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-m',
 259                 '-r', $sha1, '--', '.');
 260         my ($prefix) = run_or_die('git-rev-parse', '--show-prefix');
 261
 262         my @ci;
 263         while (my $parsed = _parse_diff_tree(($prefix or ""), \@raw_lines)) {
 264                 push @ci, $parsed;
 265         }
 266
 267         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 268
 269         return wantarray ? @ci : $ci[0];
 270 } #}}}
 271
 272 sub git_sha1 (;$) { #{{{
 273         # Return head sha1sum (of given file).
 274
 275         my $file = shift || q{--};
 276
 277         # Ignore error since a non-existing file might be given.
 278         my ($sha1) = run_or_non('git-rev-list', '--max-count=1', 'HEAD', $file);
 279         if ($sha1) {
 280                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 281         } else { debug("Empty sha1sum for '$file'.") }
 282         return defined $sha1 ? $sha1 : q{};
 283 } #}}}
 284
 285 sub rcs_update () { #{{{
 286         # Update working directory.
 287
 288         if (length $config{gitorigin_branch}) {
 289                 run_or_cry('git-pull', $config{gitorigin_branch});
 290         }
 291 } #}}}
 292
 293 sub rcs_prepedit ($) { #{{{
 294         # Return the commit sha1sum of the file when editing begins.
 295         # This will be later used in rcs_commit if a merge is required.
 296
 297         my ($file) = @_;
 298
 299         return git_sha1($file);
 300 } #}}}
 301
 302 sub rcs_commit ($$$;$$) { #{{{
 303         # Try to commit the page; returns undef on _success_ and
 304         # a version of the page with the rcs's conflict markers on
 305         # failure.
 306
 307         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
 308
 309         if (defined $user) {
 310                 $message = "web commit by $user" .
 311                     (length $message ? ": $message" : "");
 312         }
 313         elsif (defined $ipaddr) {
 314                 $message = "web commit from $ipaddr" .
 315                     (length $message ? ": $message" : "");
 316         }
 317
 318         # XXX: Wiki directory is in the unlocked state when starting this
 319         # action.  But it takes time for a Git process to finish its job
 320         # (especially if a merge required), so we must re-lock to prevent
 321         # race conditions.  Only when the time of the real commit action
 322         # (i.e. git-push(1)) comes, we'll unlock the directory.
 323         lockwiki();
 324
 325         # Check to see if the page has been changed by someone else since
 326         # rcs_prepedit was called.
 327         my $cur    = git_sha1($file);
 328         my ($prev) = $rcstoken =~ /^($sha1_pattern)$/; # untaint
 329
 330         if (defined $cur && defined $prev && $cur ne $prev) {
 331                 my $conflict = _merge_past($prev, $file, $dummy_commit_msg);
 332                 return $conflict if defined $conflict;
 333         }
 334
 335         # git-commit(1) returns non-zero if file has not been really changed.
 336         # so we should ignore its exit status (hence run_or_non).
 337         $message = possibly_foolish_untaint($message);
 338         if (run_or_non('git-commit', '-q', '-m', $message, '-i', $file)) {
 339                 unlockwiki();
 340                 if (length $config{gitorigin_branch}) {
 341                         run_or_cry('git-push', $config{gitorigin_branch});
 342                 }
 343         }
 344
 345         return undef; # success
 346 } #}}}
 347
 348 sub rcs_add ($) { # {{{
 349         # Add file to archive.
 350
 351         my ($file) = @_;
 352
 353         run_or_cry('git-add', $file);
 354 } #}}}
 355
 356 sub rcs_recentchanges ($) { #{{{
 357         # List of recent changes.
 358
 359         my ($num) = @_;
 360
 361         eval q{use Date::Parse};
 362         error($@) if $@;
 363
 364         my @rets;
 365         foreach my $ci (git_commit_info('HEAD', $num)) {
 366                 my $title = @{ $ci->{'comment'} }[0];
 367
 368                 # Skip redundant commits.
 369                 next if ($title eq $dummy_commit_msg);
 370
 371                 my ($sha1, $when) = (
 372                         $ci->{'sha1'},
 373                         time - $ci->{'author_epoch'}
 374                 );
 375
 376                 my (@pages, @messages);
 377                 foreach my $detail (@{ $ci->{'details'} }) {
 378                         my $file = $detail->{'file'};
 379
 380                         my $diffurl = $config{'diffurl'};
 381                         $diffurl =~ s/\[\[file\]\]/$file/go;
 382                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 383                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 384                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 385
 386                         push @pages, {
 387                                 page => pagename($file),
 388                                 diffurl => $diffurl,
 389                         };
 390                 }
 391                 push @messages, { line => $title };
 392
 393                 my ($user, $type) = (q{}, "web");
 394
 395                 if (defined $messages[0] &&
 396                     $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 397                         $user = defined $2 ? "$2" : "$3";
 398                         $messages[0]->{line} = $4;
 399                 }
 400                 else {
 401                         $type ="git";
 402                         $user = $ci->{'author_username'};
 403                 }
 404
 405                 push @rets, {
 406                         rev        => $sha1,
 407                         user       => $user,
 408                         committype => $type,
 409                         when       => $when,
 410                         message    => [@messages],
 411                         pages      => [@pages],
 412                 };
 413
 414                 last if @rets >= $num;
 415         }
 416
 417         return @rets;
 418 } #}}}
 419
 420 sub rcs_notify () { #{{{
 421         # Send notification mail to subscribed users.
 422         #
 423         # In usual Git usage, hooks/update script is presumed to send
 424         # notification mails (see git-receive-pack(1)).  But we prefer
 425         # hooks/post-update to support IkiWiki commits coming from a
 426         # cloned repository (through command line) because post-update
 427         # is called _after_ each ref in repository is updated (update
 428         # hook is called _before_ the repository is updated).  Since
 429         # post-update hook does not accept command line arguments, we
 430         # don't have an $ENV variable in this function.
 431         #
 432         # Here, we rely on a simple fact: we can extract all parts of the
 433         # notification content by parsing the "HEAD" commit (which also
 434         # triggers a refresh of IkiWiki pages) and we can obtain the diff
 435         # by comparing HEAD and HEAD^ (the previous commit).
 436
 437         my $sha1 = 'HEAD'; # the commit which triggers this action
 438
 439         my $ci = git_commit_info($sha1);
 440         return if !defined $ci;
 441
 442         my @changed_pages = map { $_->{'file'} } @{ $ci->{'details'} };
 443
 444         my ($user, $message);
 445         if (@{ $ci->{'comment'} }[0] =~ m/$config{web_commit_regexp}/) {
 446                 $user    = defined $2 ? "$2" : "$3";
 447                 $message = $4;
 448         }
 449         else {
 450                 $user    = $ci->{'author_username'};
 451                 $message = join "\n", @{ $ci->{'comment'} };
 452         }
 453
 454         require IkiWiki::UserInfo;
 455         send_commit_mails(
 456                 sub {
 457                         $message;
 458                 },
 459                 sub {
 460                         join "\n", run_or_die('git-diff', "${sha1}^", $sha1);
 461                 }, $user, @changed_pages
 462         );
 463 } #}}}
 464
 465 sub rcs_getctime ($) { #{{{
 466         my $file=shift;
 467         # Remove srcdir prefix
 468         $file =~ s/^\Q$config{srcdir}\E\/?//;
 469
 470         my $sha1  = git_sha1($file);
 471         my $ci    = git_commit_info($sha1);
 472         my $ctime = $ci->{'author_epoch'};
 473         debug("ctime for '$file': ". localtime($ctime));
 474
 475         return $ctime;
 476 } #}}}
 477
 478 1