t/img.t

   1 #!/usr/bin/perl
   2 #
   3 # unit test that creates test images (png, svg, multi-page pdf), runs ikiwiki
   4 # on them, checks the resulting images for plausibility based on their image
   5 # sizes, and checks if they vanish when not required in the build process any
   6 # more
   7 #
   8 # if you have trouble here, be aware that there are three debian packages that
   9 # can provide Image::Magick: perlmagick, libimage-magick-perl and
  10 # graphicsmagick-libmagick-dev-compat
  11 #
  12 package IkiWiki;
  13
  14 use warnings;
  15 use strict;
  16 use Cwd qw(getcwd);
  17 use Test::More;
  18 plan(skip_all => "Image::Magick not available")
  19         unless eval q{use Image::Magick; 1};
  20
  21 use IkiWiki;
  22
  23 my $installed = $ENV{INSTALLED_TESTS};
  24
  25 my @command;
  26 if ($installed) {
  27         @command = qw(ikiwiki);
  28 }
  29 else {
  30         ok(! system("make -s ikiwiki.out"));
  31         @command = ("perl", "-I".getcwd, qw(./ikiwiki.out
  32                 --underlaydir=underlays/basewiki
  33                 --set underlaydirbase=underlays
  34                 --templatedir=templates));
  35 }
  36
  37 push @command, qw(--set usedirs=0 --plugin img t/tmp/in t/tmp/out --verbose);
  38
  39 my $magick = new Image::Magick;
  40
  41 $magick->Read("t/img/twopages.pdf");
  42 my $PDFS_WORK = defined $magick->Get("width");
  43
  44 ok(! system("rm -rf t/tmp; mkdir -p t/tmp/in"));
  45
  46 ok(! system("cp t/img/redsquare.png t/tmp/in/redsquare.png"));
  47 ok(! system("cp t/img/redsquare.jpg t/tmp/in/redsquare.jpg"));
  48 ok(! system("cp t/img/redsquare.jpg t/tmp/in/redsquare.jpeg"));
  49 ok(! system("cp t/img/redsquare.jpg t/tmp/in/SHOUTY.JPG"));
  50 # colons in filenames are a corner case for img
  51 ok(! system("cp t/img/redsquare.png t/tmp/in/hello:world.png"));
  52 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c.png"));
  53 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d.png"));
  54 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d:e:f:g:h:i:j.png"));
  55
  56 writefile("bluesquare.svg", "t/tmp/in",
  57         '<svg width="30" height="30"><rect x="0" y="0" width="30" height="30" fill="blue"/></svg>');
  58 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.png"));
  59 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.bmp"));
  60 ok(! system("cp t/tmp/in/bluesquare.svg t/tmp/in/really-svg.pdf"));
  61
  62 # using different image sizes for different pages, so the pagenumber selection can be tested easily
  63 ok(! system("cp t/img/twopages.pdf t/tmp/in/twopages.pdf"));
  64 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.JPEG"));
  65 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.jpg"));
  66 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.png"));
  67 ok(! system("cp t/img/twopages.pdf t/tmp/in/really-pdf.svg"));
  68
  69 my $maybe_pdf_img = "";
  70 if ($PDFS_WORK) {
  71         $maybe_pdf_img = <<EOF;
  72 [[!img twopages.pdf size=12x]]
  73 [[!img twopages.pdf size=16x pagenumber=1]]
  74 EOF
  75 }
  76
  77 writefile("imgconversions.mdwn", "t/tmp/in", <<EOF
  78 [[!img redsquare.png]]
  79 [[!img redsquare.jpg size=11x]]
  80 [[!img redsquare.jpeg size=12x]]
  81 [[!img SHOUTY.JPG size=13x]]
  82 [[!img redsquare.png size=10x]]
  83 [[!img redsquare.png size=30x50]] expecting 30x30
  84 [[!img hello:world.png size=x8]] expecting 8x8
  85 [[!img a:b:c.png size=x4]]
  86 [[!img a:b:c:d:e:f:g:h:i:j.png size=x6]]
  87 [[!img bluesquare.svg size=42x]] expecting 42x
  88 [[!img bluesquare.svg size=x43]] expecting x43
  89 [[!img bluesquare.svg size=42x43]] expecting 42x43 because aspect ratio not preserved
  90 $maybe_pdf_img
  91
  92 # bad ideas
  93 [[!img really-svg.png size=666x]]
  94 [[!img really-svg.bmp size=666x]]
  95 [[!img really-svg.pdf size=666x]]
  96 [[!img really-pdf.JPEG size=666x]]
  97 [[!img really-pdf.jpg size=666x]]
  98 [[!img really-pdf.png size=666x]]
  99 [[!img really-pdf.svg size=666x]]
 100 EOF
 101 );
 102 ok(utime(333333333, 333333333, "t/tmp/in/imgconversions.mdwn"));
 103
 104 ok(! system(@command, '--set-yaml', 'img_allowed_formats=[JPEG, PNG, svg, pdf]'));
 105
 106 sub size($) {
 107         my $filename = shift;
 108         my $im = Image::Magick->new();
 109         my $r = $im->Read(":$filename");
 110         return "no image" if $r;
 111         my $w = $im->Get("width");
 112         my $h = $im->Get("height");
 113         return "${w}x${h}";
 114 }
 115
 116 my $outpath = "t/tmp/out/imgconversions";
 117 my $outhtml = readfile("$outpath.html");
 118
 119 is(size("$outpath/10x-redsquare.png"), "10x10");
 120 ok(! -e "$outpath/30x-redsquare.png");
 121 ok($outhtml =~ /width="30" height="30".*expecting 30x30/);
 122 ok($outhtml =~ /width="42".*expecting 42x/);
 123 ok($outhtml =~ /height="43".*expecting x43/);
 124 ok($outhtml =~ /width="42" height="43".*expecting 42x43/);
 125
 126 SKIP: {
 127         skip "PDF support not installed (try ghostscript)", 2
 128                 unless $PDFS_WORK;
 129         is(size("$outpath/12x-twopages.png"), "12x12");
 130         is(size("$outpath/16x-p1-twopages.png"), "16x2");
 131 }
 132
 133 ok($outhtml =~ /width="8" height="8".*expecting 8x8/);
 134 is(size("$outpath/x8-hello:world.png"), "8x8");
 135 is(size("$outpath/x4-a:b:c.png"), "4x4");
 136 is(size("$outpath/x6-a:b:c:d:e:f:g:h:i:j.png"), "6x6");
 137
 138 is(size("$outpath/11x-redsquare.jpg"), "11x11");
 139 is(size("$outpath/12x-redsquare.jpeg"), "12x12");
 140 is(size("$outpath/13x-SHOUTY.JPG"), "13x13");
 141 like($outhtml, qr{src="(\./)?imgconversions/11x-redsquare\.jpg" width="11" height="11"});
 142 like($outhtml, qr{src="(\./)?imgconversions/12x-redsquare\.jpeg" width="12" height="12"});
 143 like($outhtml, qr{src="(\./)?imgconversions/13x-SHOUTY\.JPG" width="13" height="13"});
 144
 145 # We do not misinterpret images
 146 my $quot = qr/(?:"|&quot;)/;
 147 like($outhtml, qr/${quot}really-svg\.png${quot} does not seem to be a valid png file/);
 148 ok(! -e "$outpath/666x-really-svg.png");
 149 ok(! -e "$outpath/666x-really-svg.bmp");
 150 like($outhtml, qr/${quot}really-pdf\.JPEG${quot} does not seem to be a valid jpeg file/);
 151 ok(! -e "$outpath/666x-really-pdf.jpeg");
 152 ok(! -e "$outpath/666x-really-pdf.JPEG");
 153 like($outhtml, qr/${quot}really-pdf\.jpg${quot} does not seem to be a valid jpeg file/);
 154 ok(! -e "$outpath/666x-really-pdf.jpg");
 155 like($outhtml, qr/${quot}really-pdf\.png${quot} does not seem to be a valid png file/);
 156 ok(! -e "$outpath/666x-really-pdf.png");
 157
 158 # disable support for uncommon formats and try again
 159 ok(! system(@command, "--rebuild"));
 160 ok(! -e "$outpath/10x-bluesquare.png");
 161 ok(! -e "$outpath/12x-twopages.png");
 162 ok(! -e "$outpath/16x-p1-twopages.png");
 163
 164 # now let's remove them again
 165
 166 if (1) { # for easier testing
 167         writefile("imgconversions.mdwn", "t/tmp/in", "nothing to see here");
 168
 169         ok(! system(@command, "--refresh"));
 170
 171         ok(! -e "$outpath/10x-redsquare.png");
 172         ok(! -e "$outpath/10x-bluesquare.png");
 173         ok(! -e "$outpath/12x-twopages.png");
 174         ok(! -e "$outpath/13x-SHOUTY.JPG");
 175         ok(! -e "$outpath/16x-p1-twopages.png");
 176         ok(! -e "$outpath/x8-hello:world.png");
 177         ok(! -e "$outpath/x4-a:b:c.png");
 178         ok(! -e "$outpath/x6-a:b:c:d:e:f:g:h:i:j.png");
 179
 180         # cleanup
 181         ok(! system("rm -rf t/tmp"));
 182 }
 183 done_testing;
 184
 185 1;