IkiWiki/Plugin/getsource.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::getsource;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use open qw{:utf8 :std};
   8
   9 sub import {
  10         hook(type => "getsetup", id => "getsource", call => \&getsetup);
  11         hook(type => "pagetemplate", id => "getsource", call => \&pagetemplate);
  12         hook(type => "cgi", id => "getsource", call => \&cgi_getsource);
  13 }
  14
  15 sub getsetup () {
  16         return
  17                 plugin => {
  18                         safe => 1,
  19                         rebuild => 1,
  20                 },
  21                 getsource_mimetype => {
  22                         type => "string",
  23                         example => "text/plain; charset=utf-8",
  24                         description => "Mime type for returned source.",
  25                         safe => 1,
  26                         rebuild => 0,
  27                 },
  28 }
  29
  30 sub pagetemplate (@) {
  31         my %params=@_;
  32
  33         my $page=$params{page};
  34         my $template=$params{template};
  35
  36         if (length $config{cgiurl}) {
  37                 $template->param(getsourceurl => IkiWiki::cgiurl(do => "getsource", page => $page));
  38                 $template->param(have_actions => 1);
  39         }
  40 }
  41
  42 sub cgi_getsource ($) {
  43         my $cgi=shift;
  44
  45         # Note: we use sessioncgi rather than just cgi
  46         # because we need %pagesources to be
  47         # populated.
  48
  49         return unless (defined $cgi->param('do') &&
  50                                         $cgi->param("do") eq "getsource");
  51
  52         IkiWiki::decode_cgi_utf8($cgi);
  53
  54         my $page=$cgi->param('page');
  55
  56         IkiWiki::loadindex();
  57
  58         if (! exists $pagesources{$page}) {
  59                 IkiWiki::cgi_custom_failure(
  60                         $cgi->header(-status => "404 Not Found"),
  61                         IkiWiki::misctemplate(gettext("missing page"),
  62                                 "<p>".
  63                                 sprintf(gettext("The page %s does not exist."),
  64                                         htmllink("", "", $page)).
  65                                 "</p>"));
  66                 exit;
  67         }
  68
  69         if (! defined pagetype($pagesources{$page})) {
  70                 IkiWiki::cgi_custom_failure(
  71                         $cgi->header(-status => "403 Forbidden"),
  72                         IkiWiki::misctemplate(gettext("not a page"),
  73                                 "<p>".
  74                                 sprintf(gettext("%s is an attachment, not a page."),
  75                                         htmllink("", "", $page)).
  76                                 "</p>"));
  77                 exit;
  78         }
  79
  80         if (! $config{getsource_mimetype}) {
  81                 $config{getsource_mimetype} = "text/plain; charset=utf-8";
  82         }
  83
  84         print "Content-Type: $config{getsource_mimetype}\r\n";
  85         print ("\r\n");
  86         print readfile(srcfile($pagesources{$page}));
  87
  88         exit 0;
  89 }
  90
  91 1