IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("_istranslation");
  27 memoize("percenttranslated");
  28
  29 sub import { #{{{
  30         hook(type => "getsetup", id => "po", call => \&getsetup);
  31         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  32         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  33         hook(type => "scan", id => "po", call => \&scan, last =>1);
  34         hook(type => "filter", id => "po", call => \&filter);
  35         hook(type => "htmlize", id => "po", call => \&htmlize);
  36         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  37         hook(type => "change", id => "po", call => \&change);
  38         hook(type => "editcontent", id => "po", call => \&editcontent);
  39
  40         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  41         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  42         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  43         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  44         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  45         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  46         $origsubs{'urlto'}=\&IkiWiki::urlto;
  47         inject(name => "IkiWiki::urlto", call => \&myurlto);
  48 } #}}}
  49
  50
  51 # ,----
  52 # | Table of contents
  53 # `----
  54
  55 # 1. Hooks
  56 # 2. Injected functions
  57 # 3. Blackboxes for private data
  58 # 4. Helper functions
  59 # 5. PageSpec's
  60
  61
  62 # ,----
  63 # | Hooks
  64 # `----
  65
  66 sub getsetup () { #{{{
  67         return
  68                 plugin => {
  69                         safe => 0,
  70                         rebuild => 1,
  71                 },
  72                 po_master_language => {
  73                         type => "string",
  74                         example => {
  75                                 'code' => 'en',
  76                                 'name' => 'English'
  77                         },
  78                         description => "master language (non-PO files)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 po_slave_languages => {
  83                         type => "string",
  84                         example => {
  85                                 'fr' => 'Français',
  86                                 'es' => 'Castellano',
  87                                 'de' => 'Deutsch'
  88                         },
  89                         description => "slave languages (PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_translatable_pages => {
  94                         type => "pagespec",
  95                         example => "!*/Discussion",
  96                         description => "PageSpec controlling which pages are translatable",
  97                         link => "ikiwiki/PageSpec",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_link_to => {
 102                         type => "string",
 103                         example => "current",
 104                         description => "internal linking behavior (default/current/negotiated)",
 105                         safe => 1,
 106                         rebuild => 1,
 107                 },
 108 } #}}}
 109
 110 sub checkconfig () { #{{{
 111         foreach my $field (qw{po_master_language po_slave_languages}) {
 112                 if (! exists $config{$field} || ! defined $config{$field}) {
 113                         error(sprintf(gettext("Must specify %s"), $field));
 114                 }
 115         }
 116         if (! (keys %{$config{po_slave_languages}})) {
 117                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 118         }
 119         map {
 120                 islanguagecode($_)
 121                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 122         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 123         if (! exists $config{po_translatable_pages} ||
 124             ! defined $config{po_translatable_pages}) {
 125                 $config{po_translatable_pages}="";
 126         }
 127         if (! exists $config{po_link_to} ||
 128             ! defined $config{po_link_to}) {
 129                 $config{po_link_to}='default';
 130         }
 131         elsif (! grep {
 132                         $config{po_link_to} eq $_
 133                 } ('default', 'current', 'negotiated')) {
 134                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 135                                 $config{po_link_to}));
 136                 $config{po_link_to}='default';
 137         }
 138         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 139                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 140                 $config{po_link_to}='default';
 141         }
 142         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 143 } #}}}
 144
 145 sub needsbuild () { #{{{
 146         my $needsbuild=shift;
 147
 148         # backup @needsbuild content so that change() can know whether
 149         # a given master page was rendered because its source file was changed
 150         @origneedsbuild=(@$needsbuild);
 151
 152         buildtranslationscache();
 153
 154         # make existing translations depend on the corresponding master page
 155         foreach my $master (keys %translations) {
 156                 map add_depends($_, $master), values %{otherlanguages($master)};
 157         }
 158 } #}}}
 159
 160 # Massage the recorded state of internal links so that:
 161 # - it matches the actually generated links, rather than the links as written
 162 #   in the pages' source
 163 # - backlinks are consistent in all cases
 164 sub scan (@) { #{{{
 165         my %params=@_;
 166         my $page=$params{page};
 167         my $content=$params{content};
 168
 169         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 170
 171         if (istranslation($page)) {
 172                 foreach my $destpage (@{$links{$page}}) {
 173                         if (istranslatable($destpage)) {
 174                                 # replace one occurence of $destpage in $links{$page}
 175                                 # (we only want to replace the one that was added by
 176                                 # IkiWiki::Plugin::link::scan, other occurences may be
 177                                 # there for other reasons)
 178                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 179                                         if (@{$links{$page}}[$i] eq $destpage) {
 180                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 181                                                 last;
 182                                         }
 183                                 }
 184                         }
 185                 }
 186         }
 187         elsif (! istranslatable($page) && ! istranslation($page)) {
 188                 foreach my $destpage (@{$links{$page}}) {
 189                         if (istranslatable($destpage)) {
 190                                 # make sure any destpage's translations has
 191                                 # $page in its backlinks
 192                                 push @{$links{$page}},
 193                                         values %{otherlanguages($destpage)};
 194                         }
 195                 }
 196         }
 197 } #}}}
 198
 199 # We use filter to convert PO to the master page's format,
 200 # since the rest of ikiwiki should not work on PO files.
 201 sub filter (@) { #{{{
 202         my %params = @_;
 203
 204         my $page = $params{page};
 205         my $destpage = $params{destpage};
 206         my $content = decode_utf8(encode_utf8($params{content}));
 207
 208         return $content if ( ! istranslation($page)
 209                              || alreadyfiltered($page, $destpage) );
 210
 211         # CRLF line terminators make poor Locale::Po4a feel bad
 212         $content=~s/\r\n/\n/g;
 213
 214         # Implementation notes
 215         #
 216         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 217         #    to learn how to disguise a variable as a file.
 218         # 2. There are incompatibilities between some File::Temp versions
 219         #    (including 0.18, bundled with Lenny's perl-modules package)
 220         #    and others (e.g. 0.20, previously present in the archive as
 221         #    a standalone package): under certain circumstances, some
 222         #    return a relative filename, whereas others return an absolute one;
 223         #    we here use this module in a way that is at least compatible
 224         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 225         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 226                                     DIR => File::Spec->tmpdir,
 227                                     UNLINK => 1)->filename;
 228         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 229                                      DIR => File::Spec->tmpdir,
 230                                      UNLINK => 1)->filename;
 231
 232         writefile(basename($infile), File::Spec->tmpdir, $content);
 233
 234         my $masterfile = srcfile($pagesources{masterpage($page)});
 235         my (@pos,@masters);
 236         push @pos,$infile;
 237         push @masters,$masterfile;
 238         my %options = (
 239                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 240         );
 241         my $doc=Locale::Po4a::Chooser::new('text',%options);
 242         $doc->process(
 243                 'po_in_name'    => \@pos,
 244                 'file_in_name'  => \@masters,
 245                 'file_in_charset'  => 'utf-8',
 246                 'file_out_charset' => 'utf-8',
 247         ) or error("[po/filter:$page]: failed to translate");
 248         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 249         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 250
 251         # Unlinking should happen automatically, thanks to File::Temp,
 252         # but it does not work here, probably because of the way writefile()
 253         # and Locale::Po4a::write() work.
 254         unlink $infile, $outfile;
 255
 256         setalreadyfiltered($page, $destpage);
 257         return $content;
 258 } #}}}
 259
 260 sub htmlize (@) { #{{{
 261         my %params=@_;
 262
 263         my $page = $params{page};
 264         my $content = $params{content};
 265         my $masterfile = srcfile($pagesources{masterpage($page)});
 266
 267         # force content to be htmlize'd as if it was the same type as the master page
 268         return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
 269 } #}}}
 270
 271 sub pagetemplate (@) { #{{{
 272         my %params=@_;
 273         my $page=$params{page};
 274         my $destpage=$params{destpage};
 275         my $template=$params{template};
 276
 277         my ($masterpage, $lang) = istranslation($page);
 278
 279         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 280                 $template->param(percenttranslated => percenttranslated($page));
 281         }
 282         if ($template->query(name => "istranslation")) {
 283                 $template->param(istranslation => scalar istranslation($page));
 284         }
 285         if ($template->query(name => "istranslatable")) {
 286                 $template->param(istranslatable => istranslatable($page));
 287         }
 288         if ($template->query(name => "otherlanguages")) {
 289                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 290                 map add_depends($page, $_), (values %{otherlanguages($page)});
 291         }
 292         # Rely on IkiWiki::Render's genpage() to decide wether
 293         # a discussion link should appear on $page; this is not
 294         # totally accurate, though: some broken links may be generated
 295         # when cgiurl is disabled.
 296         # This compromise avoids some code duplication, and will probably
 297         # prevent future breakage when ikiwiki internals change.
 298         # Known limitations are preferred to future random bugs.
 299         if ($template->param('discussionlink') && istranslation($page)) {
 300                 $template->param('discussionlink' => htmllink(
 301                                                         $page,
 302                                                         $destpage,
 303                                                         $masterpage . '/' . gettext("Discussion"),
 304                                                         noimageinline => 1,
 305                                                         forcesubpage => 0,
 306                                                         linktext => gettext("Discussion"),
 307                                                         ));
 308         }
 309         # Remove broken parentlink to ./index.html on home page's translations.
 310         # It works because this hook has the "last" parameter set, to ensure it
 311         # runs after parentlinks' own pagetemplate hook.
 312         if ($template->param('parentlinks')
 313             && istranslation($page)
 314             && $masterpage eq "index") {
 315                 $template->param('parentlinks' => []);
 316         }
 317 } # }}}
 318
 319 sub change(@) { #{{{
 320         my @rendered=@_;
 321
 322         my $updated_po_files=0;
 323
 324         # Refresh/create POT and PO files as needed.
 325         foreach my $page (map pagename($_), @rendered) {
 326                 next unless istranslatable($page);
 327                 my $file=srcfile($pagesources{$page});
 328                 my $updated_pot_file=0;
 329                 # Only refresh Pot file if it does not exist, or if
 330                 # $pagesources{$page} was changed: don't if only the HTML was
 331                 # refreshed, e.g. because of a dependency.
 332                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 333                     || ! -e potfile($file)) {
 334                         refreshpot($file);
 335                         $updated_pot_file=1;
 336                 }
 337                 my @pofiles;
 338                 map {
 339                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 340                 } (pofiles($file));
 341                 if (@pofiles) {
 342                         refreshpofiles($file, @pofiles);
 343                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 344                         $updated_po_files=1;
 345                 }
 346         }
 347
 348         if ($updated_po_files) {
 349                 # Check staged changes in.
 350                 if ($config{rcs}) {
 351                         IkiWiki::disable_commit_hook();
 352                         IkiWiki::rcs_commit_staged(gettext("updated PO files"),
 353                                 "IkiWiki::Plugin::po::change", "127.0.0.1");
 354                         IkiWiki::enable_commit_hook();
 355                         IkiWiki::rcs_update();
 356                 }
 357                 # Reinitialize module's private variables.
 358                 resetalreadyfiltered();
 359                 resettranslationscache();
 360                 # Trigger a wiki refresh.
 361                 require IkiWiki::Render;
 362                 IkiWiki::refresh();
 363                 IkiWiki::saveindex();
 364         }
 365 } #}}}
 366
 367 # As we're previewing or saving a page, the content may have
 368 # changed, so tell the next filter() invocation it must not be lazy.
 369 sub editcontent () { #{{{
 370         my %params=@_;
 371
 372         unsetalreadyfiltered($params{page}, $params{page});
 373         return $params{content};
 374 } #}}}
 375
 376
 377 # ,----
 378 # | Injected functions
 379 # `----
 380
 381 # Implement po_link_to=current
 382 sub mybestlink ($$) { #{{{
 383         my $page=shift;
 384         my $link=shift;
 385
 386         my $res=$origsubs{'bestlink'}->($page, $link);
 387         if (length $res
 388             && $config{po_link_to} eq "current"
 389             && istranslatable($res)
 390             && istranslation($page)) {
 391                 return $res . "." . lang($page);
 392         }
 393         return $res;
 394 } #}}}
 395
 396 sub mybeautify_urlpath ($) { #{{{
 397         my $url=shift;
 398
 399         my $res=$origsubs{'beautify_urlpath'}->($url);
 400         if ($config{po_link_to} eq "negotiated") {
 401                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 402         }
 403         return $res;
 404 } #}}}
 405
 406 sub mytargetpage ($$) { #{{{
 407         my $page=shift;
 408         my $ext=shift;
 409
 410         if (istranslation($page) || istranslatable($page)) {
 411                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 412                 if (! $config{usedirs} || $masterpage eq 'index') {
 413                         return $masterpage . "." . $lang . "." . $ext;
 414                 }
 415                 else {
 416                         return $masterpage . "/index." . $lang . "." . $ext;
 417                 }
 418         }
 419         return $origsubs{'targetpage'}->($page, $ext);
 420 } #}}}
 421
 422 sub myurlto ($$;$) { #{{{
 423         my $to=shift;
 424         my $from=shift;
 425         my $absolute=shift;
 426
 427         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 428         if (! length $to
 429             && $config{po_link_to} eq "current"
 430             && istranslation($from)
 431             && istranslatable('index')) {
 432                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 433         }
 434         return $origsubs{'urlto'}->($to,$from,$absolute);
 435 } #}}}
 436
 437
 438 # ,----
 439 # | Blackboxes for private data
 440 # `----
 441
 442 {
 443         my %filtered;
 444
 445         sub alreadyfiltered($$) { #{{{
 446                 my $page=shift;
 447                 my $destpage=shift;
 448
 449                 return ( exists $filtered{$page}{$destpage}
 450                          && $filtered{$page}{$destpage} eq 1 );
 451         } #}}}
 452
 453         sub setalreadyfiltered($$) { #{{{
 454                 my $page=shift;
 455                 my $destpage=shift;
 456
 457                 $filtered{$page}{$destpage}=1;
 458         } #}}}
 459
 460         sub unsetalreadyfiltered($$) { #{{{
 461                 my $page=shift;
 462                 my $destpage=shift;
 463
 464                 if (exists $filtered{$page}{$destpage}) {
 465                         delete $filtered{$page}{$destpage};
 466                 }
 467         } #}}}
 468
 469         sub resetalreadyfiltered() { #{{{
 470                 undef %filtered;
 471         } #}}}
 472 }
 473
 474
 475 # ,----
 476 # | Helper functions
 477 # `----
 478
 479 sub istranslatable ($) { #{{{
 480         my $page=shift;
 481
 482         my $file=$pagesources{$page};
 483
 484         return 0 unless defined $file;
 485         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 486         return 0 if $file =~ /\.pot$/;
 487         return pagespec_match($page, $config{po_translatable_pages});
 488 } #}}}
 489
 490 sub _istranslation ($) { #{{{
 491         my $page=shift;
 492
 493         my $file=$pagesources{$page};
 494
 495         return 0 unless (defined $file
 496                          && defined pagetype($file)
 497                          && pagetype($file) eq 'po');
 498         return 0 if $file =~ /\.pot$/;
 499
 500         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 501         return 0 unless (defined $masterpage && defined $lang
 502                          && length $masterpage && length $lang
 503                          && defined $pagesources{$masterpage}
 504                          && defined $config{po_slave_languages}{$lang});
 505
 506         return ($masterpage, $lang) if istranslatable($masterpage);
 507 } #}}}
 508
 509 sub istranslation ($) { #{{{
 510         my $page=shift;
 511
 512         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 513                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 514                 return ($masterpage, $lang);
 515         }
 516         return;
 517 } #}}}
 518
 519 sub masterpage ($) { #{{{
 520         my $page=shift;
 521
 522         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 523                 return $masterpage;
 524         }
 525         return $page;
 526 } #}}}
 527
 528 sub lang ($) { #{{{
 529         my $page=shift;
 530
 531         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 532                 return $lang;
 533         }
 534         return $config{po_master_language}{code};
 535 } #}}}
 536
 537 sub islanguagecode ($) { #{{{
 538         my $code=shift;
 539
 540         return ($code =~ /^[a-z]{2}$/);
 541 } #}}}
 542
 543 sub otherlanguages($) { #{{{
 544         my $page=shift;
 545
 546         my %ret;
 547         if (istranslatable($page)) {
 548                 %ret = %{$translations{$page}};
 549         }
 550         elsif (istranslation($page)) {
 551                 my $masterpage = masterpage($page);
 552                 $ret{$config{po_master_language}{code}} = $masterpage;
 553                 foreach my $lang (sort keys %{$translations{$masterpage}}) {
 554                         next if $lang eq lang($page);
 555                         $ret{$lang} = $translations{$masterpage}{$lang};
 556                 }
 557         }
 558         return \%ret;
 559 } #}}}
 560
 561 sub potfile ($) { #{{{
 562         my $masterfile=shift;
 563
 564         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 565         $dir='' if $dir eq './';
 566         return File::Spec->catpath('', $dir, $name . ".pot");
 567 } #}}}
 568
 569 sub pofile ($$) { #{{{
 570         my $masterfile=shift;
 571         my $lang=shift;
 572
 573         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 574         $dir='' if $dir eq './';
 575         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 576 } #}}}
 577
 578 sub pofiles ($) { #{{{
 579         my $masterfile=shift;
 580
 581         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 582 } #}}}
 583
 584 sub refreshpot ($) { #{{{
 585         my $masterfile=shift;
 586
 587         my $potfile=potfile($masterfile);
 588         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 589         my $doc=Locale::Po4a::Chooser::new('text',%options);
 590         $doc->{TT}{utf_mode} = 1;
 591         $doc->{TT}{file_in_charset} = 'utf-8';
 592         $doc->{TT}{file_out_charset} = 'utf-8';
 593         $doc->read($masterfile);
 594         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 595         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 596         # compulsory since this module prevents us from using the porefs option.
 597         my %po_options = ('porefs' => 'none');
 598         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 599         $doc->{TT}{po_out}->set_charset('utf-8');
 600         # do the actual work
 601         $doc->parse;
 602         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 603         $doc->writepo($potfile);
 604 } #}}}
 605
 606 sub refreshpofiles ($@) { #{{{
 607         my $masterfile=shift;
 608         my @pofiles=@_;
 609
 610         my $potfile=potfile($masterfile);
 611         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 612
 613         foreach my $pofile (@pofiles) {
 614                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 615                 if (-e $pofile) {
 616                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 617                                 or error("[po/refreshpofiles:$pofile] failed to update");
 618                 }
 619                 else {
 620                         File::Copy::syscopy($potfile,$pofile)
 621                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 622                 }
 623         }
 624 } #}}}
 625
 626 sub buildtranslationscache() { #{{{
 627         # use istranslation's side-effect
 628         map istranslation($_), (keys %pagesources);
 629 } #}}}
 630
 631 sub resettranslationscache() { #{{{
 632         undef %translations;
 633 } #}}}
 634
 635 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 636         my $to=shift;
 637         my $from=shift;
 638
 639         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 640         my $res=urlto($to, $from);
 641         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 642
 643         return $res;
 644 } #}}}
 645
 646 sub percenttranslated ($) { #{{{
 647         my $page=shift;
 648
 649         return gettext("N/A") unless istranslation($page);
 650         my $file=srcfile($pagesources{$page});
 651         my $masterfile = srcfile($pagesources{masterpage($page)});
 652         my (@pos,@masters);
 653         push @pos,$file;
 654         push @masters,$masterfile;
 655         my %options = (
 656                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 657         );
 658         my $doc=Locale::Po4a::Chooser::new('text',%options);
 659         $doc->process(
 660                 'po_in_name'    => \@pos,
 661                 'file_in_name'  => \@masters,
 662                 'file_in_charset'  => 'utf-8',
 663                 'file_out_charset' => 'utf-8',
 664         ) or error("[po/percenttranslated:$page]: failed to translate");
 665         my ($percent,$hit,$queries) = $doc->stats();
 666         return $percent;
 667 } #}}}
 668
 669 sub languagename ($) { #{{{
 670         my $code=shift;
 671
 672         return $config{po_master_language}{name}
 673                 if $code eq $config{po_master_language}{code};
 674         return $config{po_slave_languages}{$code}
 675                 if defined $config{po_slave_languages}{$code};
 676         return;
 677 } #}}}
 678
 679 sub otherlanguagesloop ($) { #{{{
 680         my $page=shift;
 681
 682         my @ret;
 683         my %otherpages=%{otherlanguages($page)};
 684         while (my ($lang, $otherpage) = each %otherpages) {
 685                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 686                         push @ret, {
 687                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 688                                 code => $lang,
 689                                 language => languagename($lang),
 690                                 master => 1,
 691                         };
 692                 }
 693                 else {
 694                         push @ret, {
 695                                 url => urlto($otherpage, $page),
 696                                 code => $lang,
 697                                 language => languagename($lang),
 698                                 percent => percenttranslated($otherpage),
 699                         }
 700                 }
 701         }
 702         return sort {
 703                         return -1 if $a->{code} eq $config{po_master_language}{code};
 704                         return 1 if $b->{code} eq $config{po_master_language}{code};
 705                         return $a->{language} cmp $b->{language};
 706                 } @ret;
 707 } #}}}
 708
 709
 710 # ,----
 711 # | PageSpec's
 712 # `----
 713
 714 package IkiWiki::PageSpec;
 715 use warnings;
 716 use strict;
 717 use IkiWiki 2.00;
 718
 719 sub match_istranslation ($;@) { #{{{
 720         my $page=shift;
 721
 722         if (IkiWiki::Plugin::po::istranslation($page)) {
 723                 return IkiWiki::SuccessReason->new("is a translation page");
 724         }
 725         else {
 726                 return IkiWiki::FailReason->new("is not a translation page");
 727         }
 728 } #}}}
 729
 730 sub match_istranslatable ($;@) { #{{{
 731         my $page=shift;
 732
 733         if (IkiWiki::Plugin::po::istranslatable($page)) {
 734                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 735         }
 736         else {
 737                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 738         }
 739 } #}}}
 740
 741 sub match_lang ($$;@) { #{{{
 742         my $page=shift;
 743         my $wanted=shift;
 744
 745         my $regexp=IkiWiki::glob2re($wanted);
 746         my $lang=IkiWiki::Plugin::po::lang($page);
 747         if ($lang!~/^$regexp$/i) {
 748                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 749         }
 750         else {
 751                 return IkiWiki::SuccessReason->new("file language is $wanted");
 752         }
 753 } #}}}
 754
 755 sub match_currentlang ($$;@) { #{{{
 756         my $page=shift;
 757         shift;
 758         my %params=@_;
 759
 760         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 761
 762         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 763         my $lang=IkiWiki::Plugin::po::lang($page);
 764
 765         if ($lang eq $currentlang) {
 766                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 767         }
 768         else {
 769                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 770         }
 771 } #}}}
 772
 773 1