IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use Data::Dumper;
   9 use IkiWiki;
  10
  11 sub gen_wrapper () { #{{{
  12         $config{srcdir}=File::Spec->rel2abs($config{srcdir});
  13         $config{destdir}=File::Spec->rel2abs($config{destdir});
  14         my $this=File::Spec->rel2abs($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER HTTPS} if $config{cgi};
  32         my $envsave="";
  33         foreach my $var (@envsave) {
  34                 $envsave.=<<"EOF"
  35         if ((s=getenv("$var")))
  36                 addenv("$var", s);
  37 EOF
  38         }
  39
  40         $Data::Dumper::Indent=0; # no newlines
  41         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  42         $configstring=~s/\\/\\\\/g;
  43         $configstring=~s/"/\\"/g;
  44         $configstring=~s/\n/\\n/g;
  45
  46         #translators: The first parameter is a filename, and the second is
  47         #translators: a (probably not translated) error message.
  48         open(OUT, ">$wrapper.c") || error(sprintf(gettext("failed to write %s: %s"), "$wrapper.c", $!));;
  49         print OUT <<"EOF";
  50 /* A wrapper for ikiwiki, can be safely made suid. */
  51 #include <stdio.h>
  52 #include <sys/types.h>
  53 #include <unistd.h>
  54 #include <stdlib.h>
  55 #include <string.h>
  56
  57 extern char **environ;
  58 char *newenviron[$#envsave+6];
  59 int i=0;
  60
  61 addenv(char *var, char *val) {
  62         char *s=malloc(strlen(var)+1+strlen(val)+1);
  63         if (!s)
  64                 perror("malloc");
  65         sprintf(s, "%s=%s", var, val);
  66         newenviron[i++]=s;
  67 }
  68
  69 int main (int argc, char **argv) {
  70         /* Sanitize environment. */
  71         char *s;
  72 $envsave
  73         newenviron[i++]="HOME=$ENV{HOME}";
  74         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
  75         asprintf(&s, "CALLER_UID=%i", getuid());
  76         newenviron[i++]=s;
  77         newenviron[i]=NULL;
  78         environ=newenviron;
  79
  80         if (setregid(getegid(), -1) != 0 &&
  81             setregid(getegid(), -1) != 0) {
  82                 perror("failed to drop real gid");
  83                 exit(1);
  84         }
  85         if (setreuid(geteuid(), -1) != 0 &&
  86             setreuid(geteuid(), -1) != 0) {
  87                 perror("failed to drop real uid");
  88                 exit(1);
  89         }
  90
  91         execl("$this", "$this", NULL);
  92         perror("exec $this");
  93         exit(1);
  94 }
  95 EOF
  96         close OUT;
  97
  98         my $cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
  99         if (system($cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
 100                 #translators: The parameter is a C filename.
 101                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 102         }
 103         unlink("$wrapper.c");
 104         if (defined $config{wrappergroup}) {
 105                 my $gid=(getgrnam($config{wrappergroup}))[2];
 106                 if (! defined $gid) {
 107                         error(sprintf("bad wrappergroup"));
 108                 }
 109                 if (! chown(-1, $gid, "$wrapper.new")) {
 110                         error("chown $wrapper.new: $!");
 111                 }
 112         }
 113         if (defined $config{wrappermode} &&
 114             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 115                 error("chmod $wrapper.new: $!");
 116         }
 117         if (! rename("$wrapper.new", $wrapper)) {
 118                 error("rename $wrapper.new $wrapper: $!");
 119         }
 120         #translators: The parameter is a filename.
 121         printf(gettext("successfully generated %s"), $wrapper);
 122         print "\n";
 123 } #}}}
 124
 125 1