IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use HTML::Entities;
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX;
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15             %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16             %pagesources %destsources %depends %depends_simple %hooks
  17             %forcerebuild %loaded_plugins};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error template htmlpage deptype
  21                  add_depends pagespec_match pagespec_match_list bestlink
  22                  htmllink readfile writefile pagetype srcfile pagename
  23                  displaytime will_render gettext urlto targetpage
  24                  add_underlay pagetitle titlepage linkpage newpagefile
  25                  inject add_link
  26                  %config %links %pagestate %wikistate %renderedfiles
  27                  %pagesources %destsources);
  28 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  29 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  30 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  31
  32 # Page dependency types.
  33 our $DEPEND_CONTENT=1;
  34 our $DEPEND_PRESENCE=2;
  35 our $DEPEND_LINKS=4;
  36
  37 # Optimisation.
  38 use Memoize;
  39 memoize("abs2rel");
  40 memoize("pagespec_translate");
  41 memoize("template_file");
  42
  43 sub getsetup () {
  44         wikiname => {
  45                 type => "string",
  46                 default => "wiki",
  47                 description => "name of the wiki",
  48                 safe => 1,
  49                 rebuild => 1,
  50         },
  51         adminemail => {
  52                 type => "string",
  53                 default => undef,
  54                 example => 'me@example.com',
  55                 description => "contact email for wiki",
  56                 safe => 1,
  57                 rebuild => 0,
  58         },
  59         adminuser => {
  60                 type => "string",
  61                 default => [],
  62                 description => "users who are wiki admins",
  63                 safe => 1,
  64                 rebuild => 0,
  65         },
  66         banned_users => {
  67                 type => "string",
  68                 default => [],
  69                 description => "users who are banned from the wiki",
  70                 safe => 1,
  71                 rebuild => 0,
  72         },
  73         srcdir => {
  74                 type => "string",
  75                 default => undef,
  76                 example => "$ENV{HOME}/wiki",
  77                 description => "where the source of the wiki is located",
  78                 safe => 0, # path
  79                 rebuild => 1,
  80         },
  81         destdir => {
  82                 type => "string",
  83                 default => undef,
  84                 example => "/var/www/wiki",
  85                 description => "where to build the wiki",
  86                 safe => 0, # path
  87                 rebuild => 1,
  88         },
  89         url => {
  90                 type => "string",
  91                 default => '',
  92                 example => "http://example.com/wiki",
  93                 description => "base url to the wiki",
  94                 safe => 1,
  95                 rebuild => 1,
  96         },
  97         cgiurl => {
  98                 type => "string",
  99                 default => '',
 100                 example => "http://example.com/wiki/ikiwiki.cgi",
 101                 description => "url to the ikiwiki.cgi",
 102                 safe => 1,
 103                 rebuild => 1,
 104         },
 105         cgi_wrapper => {
 106                 type => "string",
 107                 default => '',
 108                 example => "/var/www/wiki/ikiwiki.cgi",
 109                 description => "filename of cgi wrapper to generate",
 110                 safe => 0, # file
 111                 rebuild => 0,
 112         },
 113         cgi_wrappermode => {
 114                 type => "string",
 115                 default => '06755',
 116                 description => "mode for cgi_wrapper (can safely be made suid)",
 117                 safe => 0,
 118                 rebuild => 0,
 119         },
 120         rcs => {
 121                 type => "string",
 122                 default => '',
 123                 description => "rcs backend to use",
 124                 safe => 0, # don't allow overriding
 125                 rebuild => 0,
 126         },
 127         default_plugins => {
 128                 type => "internal",
 129                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 130                                 openid signinedit lockedit conditional
 131                                 recentchanges parentlinks editpage}],
 132                 description => "plugins to enable by default",
 133                 safe => 0,
 134                 rebuild => 1,
 135         },
 136         add_plugins => {
 137                 type => "string",
 138                 default => [],
 139                 description => "plugins to add to the default configuration",
 140                 safe => 1,
 141                 rebuild => 1,
 142         },
 143         disable_plugins => {
 144                 type => "string",
 145                 default => [],
 146                 description => "plugins to disable",
 147                 safe => 1,
 148                 rebuild => 1,
 149         },
 150         templatedir => {
 151                 type => "string",
 152                 default => "$installdir/share/ikiwiki/templates",
 153                 description => "location of template files",
 154                 advanced => 1,
 155                 safe => 0, # path
 156                 rebuild => 1,
 157         },
 158         templatedirs => {
 159                 type => "internal",
 160                 default => [],
 161                 description => "additional directories containing template files",
 162                 safe => 0,
 163                 rebuild => 0,
 164         },
 165         underlaydir => {
 166                 type => "string",
 167                 default => "$installdir/share/ikiwiki/basewiki",
 168                 description => "base wiki source location",
 169                 advanced => 1,
 170                 safe => 0, # path
 171                 rebuild => 0,
 172         },
 173         underlaydirbase => {
 174                 type => "internal",
 175                 default => "$installdir/share/ikiwiki",
 176                 description => "parent directory containing additional underlays",
 177                 safe => 0,
 178                 rebuild => 0,
 179         },
 180         wrappers => {
 181                 type => "internal",
 182                 default => [],
 183                 description => "wrappers to generate",
 184                 safe => 0,
 185                 rebuild => 0,
 186         },
 187         underlaydirs => {
 188                 type => "internal",
 189                 default => [],
 190                 description => "additional underlays to use",
 191                 safe => 0,
 192                 rebuild => 0,
 193         },
 194         verbose => {
 195                 type => "boolean",
 196                 example => 1,
 197                 description => "display verbose messages?",
 198                 safe => 1,
 199                 rebuild => 0,
 200         },
 201         syslog => {
 202                 type => "boolean",
 203                 example => 1,
 204                 description => "log to syslog?",
 205                 safe => 1,
 206                 rebuild => 0,
 207         },
 208         usedirs => {
 209                 type => "boolean",
 210                 default => 1,
 211                 description => "create output files named page/index.html?",
 212                 safe => 0, # changing requires manual transition
 213                 rebuild => 1,
 214         },
 215         prefix_directives => {
 216                 type => "boolean",
 217                 default => 1,
 218                 description => "use '!'-prefixed preprocessor directives?",
 219                 safe => 0, # changing requires manual transition
 220                 rebuild => 1,
 221         },
 222         indexpages => {
 223                 type => "boolean",
 224                 default => 0,
 225                 description => "use page/index.mdwn source files",
 226                 safe => 1,
 227                 rebuild => 1,
 228         },
 229         discussion => {
 230                 type => "boolean",
 231                 default => 1,
 232                 description => "enable Discussion pages?",
 233                 safe => 1,
 234                 rebuild => 1,
 235         },
 236         discussionpage => {
 237                 type => "string",
 238                 default => gettext("Discussion"),
 239                 description => "name of Discussion pages",
 240                 safe => 1,
 241                 rebuild => 1,
 242         },
 243         sslcookie => {
 244                 type => "boolean",
 245                 default => 0,
 246                 description => "only send cookies over SSL connections?",
 247                 advanced => 1,
 248                 safe => 1,
 249                 rebuild => 0,
 250         },
 251         default_pageext => {
 252                 type => "string",
 253                 default => "mdwn",
 254                 description => "extension to use for new pages",
 255                 safe => 0, # not sanitized
 256                 rebuild => 0,
 257         },
 258         htmlext => {
 259                 type => "string",
 260                 default => "html",
 261                 description => "extension to use for html files",
 262                 safe => 0, # not sanitized
 263                 rebuild => 1,
 264         },
 265         timeformat => {
 266                 type => "string",
 267                 default => '%c',
 268                 description => "strftime format string to display date",
 269                 advanced => 1,
 270                 safe => 1,
 271                 rebuild => 1,
 272         },
 273         locale => {
 274                 type => "string",
 275                 default => undef,
 276                 example => "en_US.UTF-8",
 277                 description => "UTF-8 locale to use",
 278                 advanced => 1,
 279                 safe => 0,
 280                 rebuild => 1,
 281         },
 282         userdir => {
 283                 type => "string",
 284                 default => "",
 285                 example => "users",
 286                 description => "put user pages below specified page",
 287                 safe => 1,
 288                 rebuild => 1,
 289         },
 290         numbacklinks => {
 291                 type => "integer",
 292                 default => 10,
 293                 description => "how many backlinks to show before hiding excess (0 to show all)",
 294                 safe => 1,
 295                 rebuild => 1,
 296         },
 297         hardlink => {
 298                 type => "boolean",
 299                 default => 0,
 300                 description => "attempt to hardlink source files? (optimisation for large files)",
 301                 advanced => 1,
 302                 safe => 0, # paranoia
 303                 rebuild => 0,
 304         },
 305         umask => {
 306                 type => "integer",
 307                 example => "022",
 308                 description => "force ikiwiki to use a particular umask",
 309                 advanced => 1,
 310                 safe => 0, # paranoia
 311                 rebuild => 0,
 312         },
 313         wrappergroup => {
 314                 type => "string",
 315                 example => "ikiwiki",
 316                 description => "group for wrappers to run in",
 317                 advanced => 1,
 318                 safe => 0, # paranoia
 319                 rebuild => 0,
 320         },
 321         libdir => {
 322                 type => "string",
 323                 default => "",
 324                 example => "$ENV{HOME}/.ikiwiki/",
 325                 description => "extra library and plugin directory",
 326                 advanced => 1,
 327                 safe => 0, # directory
 328                 rebuild => 0,
 329         },
 330         ENV => {
 331                 type => "string",
 332                 default => {},
 333                 description => "environment variables",
 334                 safe => 0, # paranoia
 335                 rebuild => 0,
 336         },
 337         exclude => {
 338                 type => "string",
 339                 default => undef,
 340                 example => '\.wav$',
 341                 description => "regexp of source files to ignore",
 342                 advanced => 1,
 343                 safe => 0, # regexp
 344                 rebuild => 1,
 345         },
 346         wiki_file_prune_regexps => {
 347                 type => "internal",
 348                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
 349                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 350                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 351                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 352                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 353                 description => "regexps of source files to ignore",
 354                 safe => 0,
 355                 rebuild => 1,
 356         },
 357         wiki_file_chars => {
 358                 type => "string",
 359                 description => "specifies the characters that are allowed in source filenames",
 360                 default => "-[:alnum:]+/.:_",
 361                 safe => 0,
 362                 rebuild => 1,
 363         },
 364         wiki_file_regexp => {
 365                 type => "internal",
 366                 description => "regexp of legal source files",
 367                 safe => 0,
 368                 rebuild => 1,
 369         },
 370         web_commit_regexp => {
 371                 type => "internal",
 372                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 373                 description => "regexp to parse web commits from logs",
 374                 safe => 0,
 375                 rebuild => 0,
 376         },
 377         cgi => {
 378                 type => "internal",
 379                 default => 0,
 380                 description => "run as a cgi",
 381                 safe => 0,
 382                 rebuild => 0,
 383         },
 384         cgi_disable_uploads => {
 385                 type => "internal",
 386                 default => 1,
 387                 description => "whether CGI should accept file uploads",
 388                 safe => 0,
 389                 rebuild => 0,
 390         },
 391         post_commit => {
 392                 type => "internal",
 393                 default => 0,
 394                 description => "run as a post-commit hook",
 395                 safe => 0,
 396                 rebuild => 0,
 397         },
 398         rebuild => {
 399                 type => "internal",
 400                 default => 0,
 401                 description => "running in rebuild mode",
 402                 safe => 0,
 403                 rebuild => 0,
 404         },
 405         setup => {
 406                 type => "internal",
 407                 default => undef,
 408                 description => "running in setup mode",
 409                 safe => 0,
 410                 rebuild => 0,
 411         },
 412         refresh => {
 413                 type => "internal",
 414                 default => 0,
 415                 description => "running in refresh mode",
 416                 safe => 0,
 417                 rebuild => 0,
 418         },
 419         test_receive => {
 420                 type => "internal",
 421                 default => 0,
 422                 description => "running in receive test mode",
 423                 safe => 0,
 424                 rebuild => 0,
 425         },
 426         getctime => {
 427                 type => "internal",
 428                 default => 0,
 429                 description => "running in getctime mode",
 430                 safe => 0,
 431                 rebuild => 0,
 432         },
 433         w3mmode => {
 434                 type => "internal",
 435                 default => 0,
 436                 description => "running in w3mmode",
 437                 safe => 0,
 438                 rebuild => 0,
 439         },
 440         wikistatedir => {
 441                 type => "internal",
 442                 default => undef,
 443                 description => "path to the .ikiwiki directory holding ikiwiki state",
 444                 safe => 0,
 445                 rebuild => 0,
 446         },
 447         setupfile => {
 448                 type => "internal",
 449                 default => undef,
 450                 description => "path to setup file",
 451                 safe => 0,
 452                 rebuild => 0,
 453         },
 454         allow_symlinks_before_srcdir => {
 455                 type => "boolean",
 456                 default => 0,
 457                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 458                 safe => 0,
 459                 rebuild => 0,
 460         },
 461 }
 462
 463 sub defaultconfig () {
 464         my %s=getsetup();
 465         my @ret;
 466         foreach my $key (keys %s) {
 467                 push @ret, $key, $s{$key}->{default};
 468         }
 469         use Data::Dumper;
 470         return @ret;
 471 }
 472
 473 sub checkconfig () {
 474         # locale stuff; avoid LC_ALL since it overrides everything
 475         if (defined $ENV{LC_ALL}) {
 476                 $ENV{LANG} = $ENV{LC_ALL};
 477                 delete $ENV{LC_ALL};
 478         }
 479         if (defined $config{locale}) {
 480                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 481                         $ENV{LANG}=$config{locale};
 482                         define_gettext();
 483                 }
 484         }
 485
 486         if (! defined $config{wiki_file_regexp}) {
 487                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 488         }
 489
 490         if (ref $config{ENV} eq 'HASH') {
 491                 foreach my $val (keys %{$config{ENV}}) {
 492                         $ENV{$val}=$config{ENV}{$val};
 493                 }
 494         }
 495
 496         if ($config{w3mmode}) {
 497                 eval q{use Cwd q{abs_path}};
 498                 error($@) if $@;
 499                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 500                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 501                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 502                         unless $config{cgiurl} =~ m!file:///!;
 503                 $config{url}="file://".$config{destdir};
 504         }
 505
 506         if ($config{cgi} && ! length $config{url}) {
 507                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 508         }
 509
 510         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 511                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 512
 513         if (defined $config{umask}) {
 514                 umask(possibly_foolish_untaint($config{umask}));
 515         }
 516
 517         run_hooks(checkconfig => sub { shift->() });
 518
 519         return 1;
 520 }
 521
 522 sub listplugins () {
 523         my %ret;
 524
 525         foreach my $dir (@INC, $config{libdir}) {
 526                 next unless defined $dir && length $dir;
 527                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 528                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 529                         $ret{$plugin}=1;
 530                 }
 531         }
 532         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 533                 next unless defined $dir && length $dir;
 534                 foreach my $file (glob("$dir/plugins/*")) {
 535                         $ret{basename($file)}=1 if -x $file;
 536                 }
 537         }
 538
 539         return keys %ret;
 540 }
 541
 542 sub loadplugins () {
 543         if (defined $config{libdir} && length $config{libdir}) {
 544                 unshift @INC, possibly_foolish_untaint($config{libdir});
 545         }
 546
 547         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 548                 loadplugin($plugin);
 549         }
 550
 551         if ($config{rcs}) {
 552                 if (exists $hooks{rcs}) {
 553                         error(gettext("cannot use multiple rcs plugins"));
 554                 }
 555                 loadplugin($config{rcs});
 556         }
 557         if (! exists $hooks{rcs}) {
 558                 loadplugin("norcs");
 559         }
 560
 561         run_hooks(getopt => sub { shift->() });
 562         if (grep /^-/, @ARGV) {
 563                 print STDERR "Unknown option (or missing parameter): $_\n"
 564                         foreach grep /^-/, @ARGV;
 565                 usage();
 566         }
 567
 568         return 1;
 569 }
 570
 571 sub loadplugin ($) {
 572         my $plugin=shift;
 573
 574         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 575
 576         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 577                          "$installdir/lib/ikiwiki") {
 578                 if (defined $dir && -x "$dir/plugins/$plugin") {
 579                         eval { require IkiWiki::Plugin::external };
 580                         if ($@) {
 581                                 my $reason=$@;
 582                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 583                         }
 584                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 585                         $loaded_plugins{$plugin}=1;
 586                         return 1;
 587                 }
 588         }
 589
 590         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 591         eval qq{use $mod};
 592         if ($@) {
 593                 error("Failed to load plugin $mod: $@");
 594         }
 595         $loaded_plugins{$plugin}=1;
 596         return 1;
 597 }
 598
 599 sub error ($;$) {
 600         my $message=shift;
 601         my $cleaner=shift;
 602         log_message('err' => $message) if $config{syslog};
 603         if (defined $cleaner) {
 604                 $cleaner->();
 605         }
 606         die $message."\n";
 607 }
 608
 609 sub debug ($) {
 610         return unless $config{verbose};
 611         return log_message(debug => @_);
 612 }
 613
 614 my $log_open=0;
 615 sub log_message ($$) {
 616         my $type=shift;
 617
 618         if ($config{syslog}) {
 619                 require Sys::Syslog;
 620                 if (! $log_open) {
 621                         Sys::Syslog::setlogsock('unix');
 622                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 623                         $log_open=1;
 624                 }
 625                 return eval {
 626                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 627                 };
 628         }
 629         elsif (! $config{cgi}) {
 630                 return print "@_\n";
 631         }
 632         else {
 633                 return print STDERR "@_\n";
 634         }
 635 }
 636
 637 sub possibly_foolish_untaint ($) {
 638         my $tainted=shift;
 639         my ($untainted)=$tainted=~/(.*)/s;
 640         return $untainted;
 641 }
 642
 643 sub basename ($) {
 644         my $file=shift;
 645
 646         $file=~s!.*/+!!;
 647         return $file;
 648 }
 649
 650 sub dirname ($) {
 651         my $file=shift;
 652
 653         $file=~s!/*[^/]+$!!;
 654         return $file;
 655 }
 656
 657 sub isinternal ($) {
 658         my $page=shift;
 659         return exists $pagesources{$page} &&
 660                 $pagesources{$page} =~ /\._([^.]+)$/;
 661 }
 662
 663 sub pagetype ($) {
 664         my $file=shift;
 665
 666         if ($file =~ /\.([^.]+)$/) {
 667                 return $1 if exists $hooks{htmlize}{$1};
 668         }
 669         my $base=basename($file);
 670         if (exists $hooks{htmlize}{$base} &&
 671             $hooks{htmlize}{$base}{noextension}) {
 672                 return $base;
 673         }
 674         return;
 675 }
 676
 677 my %pagename_cache;
 678
 679 sub pagename ($) {
 680         my $file=shift;
 681
 682         if (exists $pagename_cache{$file}) {
 683                 return $pagename_cache{$file};
 684         }
 685
 686         my $type=pagetype($file);
 687         my $page=$file;
 688         $page=~s/\Q.$type\E*$//
 689                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 690                         && !$hooks{htmlize}{$type}{noextension};
 691         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 692                 $page=$1;
 693         }
 694
 695         $pagename_cache{$file} = $page;
 696         return $page;
 697 }
 698
 699 sub newpagefile ($$) {
 700         my $page=shift;
 701         my $type=shift;
 702
 703         if (! $config{indexpages} || $page eq 'index') {
 704                 return $page.".".$type;
 705         }
 706         else {
 707                 return $page."/index.".$type;
 708         }
 709 }
 710
 711 sub targetpage ($$;$) {
 712         my $page=shift;
 713         my $ext=shift;
 714         my $filename=shift;
 715
 716         if (defined $filename) {
 717                 return $page."/".$filename.".".$ext;
 718         }
 719         elsif (! $config{usedirs} || $page eq 'index') {
 720                 return $page.".".$ext;
 721         }
 722         else {
 723                 return $page."/index.".$ext;
 724         }
 725 }
 726
 727 sub htmlpage ($) {
 728         my $page=shift;
 729
 730         return targetpage($page, $config{htmlext});
 731 }
 732
 733 sub srcfile_stat {
 734         my $file=shift;
 735         my $nothrow=shift;
 736
 737         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 738         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 739                 return "$dir/$file", stat(_) if -e "$dir/$file";
 740         }
 741         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 742         return;
 743 }
 744
 745 sub srcfile ($;$) {
 746         return (srcfile_stat(@_))[0];
 747 }
 748
 749 sub add_underlay ($) {
 750         my $dir=shift;
 751
 752         if ($dir !~ /^\//) {
 753                 $dir="$config{underlaydirbase}/$dir";
 754         }
 755
 756         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 757                 unshift @{$config{underlaydirs}}, $dir;
 758         }
 759
 760         return 1;
 761 }
 762
 763 sub readfile ($;$$) {
 764         my $file=shift;
 765         my $binary=shift;
 766         my $wantfd=shift;
 767
 768         if (-l $file) {
 769                 error("cannot read a symlink ($file)");
 770         }
 771
 772         local $/=undef;
 773         open (my $in, "<", $file) || error("failed to read $file: $!");
 774         binmode($in) if ($binary);
 775         return \*$in if $wantfd;
 776         my $ret=<$in>;
 777         # check for invalid utf-8, and toss it back to avoid crashes
 778         if (! utf8::valid($ret)) {
 779                 $ret=encode_utf8($ret);
 780         }
 781         close $in || error("failed to read $file: $!");
 782         return $ret;
 783 }
 784
 785 sub prep_writefile ($$) {
 786         my $file=shift;
 787         my $destdir=shift;
 788
 789         my $test=$file;
 790         while (length $test) {
 791                 if (-l "$destdir/$test") {
 792                         error("cannot write to a symlink ($test)");
 793                 }
 794                 $test=dirname($test);
 795         }
 796
 797         my $dir=dirname("$destdir/$file");
 798         if (! -d $dir) {
 799                 my $d="";
 800                 foreach my $s (split(m!/+!, $dir)) {
 801                         $d.="$s/";
 802                         if (! -d $d) {
 803                                 mkdir($d) || error("failed to create directory $d: $!");
 804                         }
 805                 }
 806         }
 807
 808         return 1;
 809 }
 810
 811 sub writefile ($$$;$$) {
 812         my $file=shift; # can include subdirs
 813         my $destdir=shift; # directory to put file in
 814         my $content=shift;
 815         my $binary=shift;
 816         my $writer=shift;
 817
 818         prep_writefile($file, $destdir);
 819
 820         my $newfile="$destdir/$file.ikiwiki-new";
 821         if (-l $newfile) {
 822                 error("cannot write to a symlink ($newfile)");
 823         }
 824
 825         my $cleanup = sub { unlink($newfile) };
 826         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 827         binmode($out) if ($binary);
 828         if ($writer) {
 829                 $writer->(\*$out, $cleanup);
 830         }
 831         else {
 832                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 833         }
 834         close $out || error("failed saving $newfile: $!", $cleanup);
 835         rename($newfile, "$destdir/$file") ||
 836                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 837
 838         return 1;
 839 }
 840
 841 my %cleared;
 842 sub will_render ($$;$) {
 843         my $page=shift;
 844         my $dest=shift;
 845         my $clear=shift;
 846
 847         # Important security check.
 848         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 849             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 850                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 851         }
 852
 853         if (! $clear || $cleared{$page}) {
 854                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 855         }
 856         else {
 857                 foreach my $old (@{$renderedfiles{$page}}) {
 858                         delete $destsources{$old};
 859                 }
 860                 $renderedfiles{$page}=[$dest];
 861                 $cleared{$page}=1;
 862         }
 863         $destsources{$dest}=$page;
 864
 865         return 1;
 866 }
 867
 868 sub bestlink ($$) {
 869         my $page=shift;
 870         my $link=shift;
 871
 872         my $cwd=$page;
 873         if ($link=~s/^\/+//) {
 874                 # absolute links
 875                 $cwd="";
 876         }
 877         $link=~s/\/$//;
 878
 879         do {
 880                 my $l=$cwd;
 881                 $l.="/" if length $l;
 882                 $l.=$link;
 883
 884                 if (exists $pagesources{$l}) {
 885                         return $l;
 886                 }
 887                 elsif (exists $pagecase{lc $l}) {
 888                         return $pagecase{lc $l};
 889                 }
 890         } while $cwd=~s{/?[^/]+$}{};
 891
 892         if (length $config{userdir}) {
 893                 my $l = "$config{userdir}/".lc($link);
 894                 if (exists $pagesources{$l}) {
 895                         return $l;
 896                 }
 897                 elsif (exists $pagecase{lc $l}) {
 898                         return $pagecase{lc $l};
 899                 }
 900         }
 901
 902         #print STDERR "warning: page $page, broken link: $link\n";
 903         return "";
 904 }
 905
 906 sub isinlinableimage ($) {
 907         my $file=shift;
 908
 909         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 910 }
 911
 912 sub pagetitle ($;$) {
 913         my $page=shift;
 914         my $unescaped=shift;
 915
 916         if ($unescaped) {
 917                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 918         }
 919         else {
 920                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 921         }
 922
 923         return $page;
 924 }
 925
 926 sub titlepage ($) {
 927         my $title=shift;
 928         # support use w/o %config set
 929         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 930         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 931         return $title;
 932 }
 933
 934 sub linkpage ($) {
 935         my $link=shift;
 936         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 937         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 938         return $link;
 939 }
 940
 941 sub cgiurl (@) {
 942         my %params=@_;
 943
 944         return $config{cgiurl}."?".
 945                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 946 }
 947
 948 sub baseurl (;$) {
 949         my $page=shift;
 950
 951         return "$config{url}/" if ! defined $page;
 952
 953         $page=htmlpage($page);
 954         $page=~s/[^\/]+$//;
 955         $page=~s/[^\/]+\//..\//g;
 956         return $page;
 957 }
 958
 959 sub abs2rel ($$) {
 960         # Work around very innefficient behavior in File::Spec if abs2rel
 961         # is passed two relative paths. It's much faster if paths are
 962         # absolute! (Debian bug #376658; fixed in debian unstable now)
 963         my $path="/".shift;
 964         my $base="/".shift;
 965
 966         require File::Spec;
 967         my $ret=File::Spec->abs2rel($path, $base);
 968         $ret=~s/^// if defined $ret;
 969         return $ret;
 970 }
 971
 972 sub displaytime ($;$) {
 973         # Plugins can override this function to mark up the time to
 974         # display.
 975         return '<span class="date">'.formattime(@_).'</span>';
 976 }
 977
 978 sub formattime ($;$) {
 979         # Plugins can override this function to format the time.
 980         my $time=shift;
 981         my $format=shift;
 982         if (! defined $format) {
 983                 $format=$config{timeformat};
 984         }
 985
 986         # strftime doesn't know about encodings, so make sure
 987         # its output is properly treated as utf8
 988         return decode_utf8(POSIX::strftime($format, localtime($time)));
 989 }
 990
 991 sub beautify_urlpath ($) {
 992         my $url=shift;
 993
 994         # Ensure url is not an empty link, and if necessary,
 995         # add ./ to avoid colon confusion.
 996         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
 997                 $url="./$url";
 998         }
 999
1000         if ($config{usedirs}) {
1001                 $url =~ s!/index.$config{htmlext}$!/!;
1002         }
1003
1004         return $url;
1005 }
1006
1007 sub urlto ($$;$) {
1008         my $to=shift;
1009         my $from=shift;
1010         my $absolute=shift;
1011
1012         if (! length $to) {
1013                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
1014         }
1015
1016         if (! $destsources{$to}) {
1017                 $to=htmlpage($to);
1018         }
1019
1020         if ($absolute) {
1021                 return $config{url}.beautify_urlpath("/".$to);
1022         }
1023
1024         my $link = abs2rel($to, dirname(htmlpage($from)));
1025
1026         return beautify_urlpath($link);
1027 }
1028
1029 sub htmllink ($$$;@) {
1030         my $lpage=shift; # the page doing the linking
1031         my $page=shift; # the page that will contain the link (different for inline)
1032         my $link=shift;
1033         my %opts=@_;
1034
1035         $link=~s/\/$//;
1036
1037         my $bestlink;
1038         if (! $opts{forcesubpage}) {
1039                 $bestlink=bestlink($lpage, $link);
1040         }
1041         else {
1042                 $bestlink="$lpage/".lc($link);
1043         }
1044
1045         my $linktext;
1046         if (defined $opts{linktext}) {
1047                 $linktext=$opts{linktext};
1048         }
1049         else {
1050                 $linktext=pagetitle(basename($link));
1051         }
1052
1053         return "<span class=\"selflink\">$linktext</span>"
1054                 if length $bestlink && $page eq $bestlink &&
1055                    ! defined $opts{anchor};
1056
1057         if (! $destsources{$bestlink}) {
1058                 $bestlink=htmlpage($bestlink);
1059
1060                 if (! $destsources{$bestlink}) {
1061                         return $linktext unless length $config{cgiurl};
1062                         return "<span class=\"createlink\"><a href=\"".
1063                                 cgiurl(
1064                                         do => "create",
1065                                         page => lc($link),
1066                                         from => $lpage
1067                                 ).
1068                                 "\" rel=\"nofollow\">?</a>$linktext</span>"
1069                 }
1070         }
1071
1072         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1073         $bestlink=beautify_urlpath($bestlink);
1074
1075         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1076                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1077         }
1078
1079         if (defined $opts{anchor}) {
1080                 $bestlink.="#".$opts{anchor};
1081         }
1082
1083         my @attrs;
1084         foreach my $attr (qw{rel class title}) {
1085                 if (defined $opts{$attr}) {
1086                         push @attrs, " $attr=\"$opts{$attr}\"";
1087                 }
1088         }
1089
1090         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1091 }
1092
1093 sub openiduser ($) {
1094         my $user=shift;
1095
1096         if ($user =~ m!^https?://! &&
1097             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1098                 my $display;
1099
1100                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1101                         # this works in at least 2.x
1102                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1103                 }
1104                 else {
1105                         # this only works in 1.x
1106                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1107                         $display=$oid->display;
1108                 }
1109
1110                 # Convert "user.somehost.com" to "user [somehost.com]"
1111                 # (also "user.somehost.co.uk")
1112                 if ($display !~ /\[/) {
1113                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1114                 }
1115                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1116                 # (also "https://somehost.com/user/")
1117                 if ($display !~ /\[/) {
1118                         $display=~s/^https?:\/\/(.+)\/([^\/]+)\/?$/$2 [$1]/;
1119                 }
1120                 $display=~s!^https?://!!; # make sure this is removed
1121                 eval q{use CGI 'escapeHTML'};
1122                 error($@) if $@;
1123                 return escapeHTML($display);
1124         }
1125         return;
1126 }
1127
1128 sub userlink ($) {
1129         my $user=shift;
1130
1131         my $oiduser=eval { openiduser($user) };
1132         if (defined $oiduser) {
1133                 return "<a href=\"$user\">$oiduser</a>";
1134         }
1135         else {
1136                 eval q{use CGI 'escapeHTML'};
1137                 error($@) if $@;
1138
1139                 return htmllink("", "", escapeHTML(
1140                         length $config{userdir} ? $config{userdir}."/".$user : $user
1141                 ), noimageinline => 1);
1142         }
1143 }
1144
1145 sub htmlize ($$$$) {
1146         my $page=shift;
1147         my $destpage=shift;
1148         my $type=shift;
1149         my $content=shift;
1150
1151         my $oneline = $content !~ /\n/;
1152
1153         if (exists $hooks{htmlize}{$type}) {
1154                 $content=$hooks{htmlize}{$type}{call}->(
1155                         page => $page,
1156                         content => $content,
1157                 );
1158         }
1159         else {
1160                 error("htmlization of $type not supported");
1161         }
1162
1163         run_hooks(sanitize => sub {
1164                 $content=shift->(
1165                         page => $page,
1166                         destpage => $destpage,
1167                         content => $content,
1168                 );
1169         });
1170
1171         if ($oneline) {
1172                 # hack to get rid of enclosing junk added by markdown
1173                 # and other htmlizers
1174                 $content=~s/^<p>//i;
1175                 $content=~s/<\/p>$//i;
1176                 chomp $content;
1177         }
1178
1179         return $content;
1180 }
1181
1182 sub linkify ($$$) {
1183         my $page=shift;
1184         my $destpage=shift;
1185         my $content=shift;
1186
1187         run_hooks(linkify => sub {
1188                 $content=shift->(
1189                         page => $page,
1190                         destpage => $destpage,
1191                         content => $content,
1192                 );
1193         });
1194
1195         return $content;
1196 }
1197
1198 our %preprocessing;
1199 our $preprocess_preview=0;
1200 sub preprocess ($$$;$$) {
1201         my $page=shift; # the page the data comes from
1202         my $destpage=shift; # the page the data will appear in (different for inline)
1203         my $content=shift;
1204         my $scan=shift;
1205         my $preview=shift;
1206
1207         # Using local because it needs to be set within any nested calls
1208         # of this function.
1209         local $preprocess_preview=$preview if defined $preview;
1210
1211         my $handle=sub {
1212                 my $escape=shift;
1213                 my $prefix=shift;
1214                 my $command=shift;
1215                 my $params=shift;
1216                 $params="" if ! defined $params;
1217
1218                 if (length $escape) {
1219                         return "[[$prefix$command $params]]";
1220                 }
1221                 elsif (exists $hooks{preprocess}{$command}) {
1222                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1223                         # Note: preserve order of params, some plugins may
1224                         # consider it significant.
1225                         my @params;
1226                         while ($params =~ m{
1227                                 (?:([-\w]+)=)?          # 1: named parameter key?
1228                                 (?:
1229                                         """(.*?)"""     # 2: triple-quoted value
1230                                 |
1231                                         "([^"]+)"       # 3: single-quoted value
1232                                 |
1233                                         (\S+)           # 4: unquoted value
1234                                 )
1235                                 (?:\s+|$)               # delimiter to next param
1236                         }sgx) {
1237                                 my $key=$1;
1238                                 my $val;
1239                                 if (defined $2) {
1240                                         $val=$2;
1241                                         $val=~s/\r\n/\n/mg;
1242                                         $val=~s/^\n+//g;
1243                                         $val=~s/\n+$//g;
1244                                 }
1245                                 elsif (defined $3) {
1246                                         $val=$3;
1247                                 }
1248                                 elsif (defined $4) {
1249                                         $val=$4;
1250                                 }
1251
1252                                 if (defined $key) {
1253                                         push @params, $key, $val;
1254                                 }
1255                                 else {
1256                                         push @params, $val, '';
1257                                 }
1258                         }
1259                         if ($preprocessing{$page}++ > 3) {
1260                                 # Avoid loops of preprocessed pages preprocessing
1261                                 # other pages that preprocess them, etc.
1262                                 return "[[!$command <span class=\"error\">".
1263                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1264                                                 $page, $preprocessing{$page}).
1265                                         "</span>]]";
1266                         }
1267                         my $ret;
1268                         if (! $scan) {
1269                                 $ret=eval {
1270                                         $hooks{preprocess}{$command}{call}->(
1271                                                 @params,
1272                                                 page => $page,
1273                                                 destpage => $destpage,
1274                                                 preview => $preprocess_preview,
1275                                         );
1276                                 };
1277                                 if ($@) {
1278                                         my $error=$@;
1279                                         chomp $error;
1280                                         $ret="[[!$command <span class=\"error\">".
1281                                                 gettext("Error").": $error"."</span>]]";
1282                                 }
1283                         }
1284                         else {
1285                                 # use void context during scan pass
1286                                 eval {
1287                                         $hooks{preprocess}{$command}{call}->(
1288                                                 @params,
1289                                                 page => $page,
1290                                                 destpage => $destpage,
1291                                                 preview => $preprocess_preview,
1292                                         );
1293                                 };
1294                                 $ret="";
1295                         }
1296                         $preprocessing{$page}--;
1297                         return $ret;
1298                 }
1299                 else {
1300                         return "[[$prefix$command $params]]";
1301                 }
1302         };
1303
1304         my $regex;
1305         if ($config{prefix_directives}) {
1306                 $regex = qr{
1307                         (\\?)           # 1: escape?
1308                         \[\[(!)         # directive open; 2: prefix
1309                         ([-\w]+)        # 3: command
1310                         (               # 4: the parameters..
1311                                 \s+     # Must have space if parameters present
1312                                 (?:
1313                                         (?:[-\w]+=)?            # named parameter key?
1314                                         (?:
1315                                                 """.*?"""       # triple-quoted value
1316                                                 |
1317                                                 "[^"]+"         # single-quoted value
1318                                                 |
1319                                                 [^"\s\]]+       # unquoted value
1320                                         )
1321                                         \s*                     # whitespace or end
1322                                                                 # of directive
1323                                 )
1324                         *)?             # 0 or more parameters
1325                         \]\]            # directive closed
1326                 }sx;
1327         }
1328         else {
1329                 $regex = qr{
1330                         (\\?)           # 1: escape?
1331                         \[\[(!?)        # directive open; 2: optional prefix
1332                         ([-\w]+)        # 3: command
1333                         \s+
1334                         (               # 4: the parameters..
1335                                 (?:
1336                                         (?:[-\w]+=)?            # named parameter key?
1337                                         (?:
1338                                                 """.*?"""       # triple-quoted value
1339                                                 |
1340                                                 "[^"]+"         # single-quoted value
1341                                                 |
1342                                                 [^"\s\]]+       # unquoted value
1343                                         )
1344                                         \s*                     # whitespace or end
1345                                                                 # of directive
1346                                 )
1347                         *)              # 0 or more parameters
1348                         \]\]            # directive closed
1349                 }sx;
1350         }
1351
1352         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1353         return $content;
1354 }
1355
1356 sub filter ($$$) {
1357         my $page=shift;
1358         my $destpage=shift;
1359         my $content=shift;
1360
1361         run_hooks(filter => sub {
1362                 $content=shift->(page => $page, destpage => $destpage,
1363                         content => $content);
1364         });
1365
1366         return $content;
1367 }
1368
1369 sub indexlink () {
1370         return "<a href=\"$config{url}\">$config{wikiname}</a>";
1371 }
1372
1373 sub check_canedit ($$$;$) {
1374         my $page=shift;
1375         my $q=shift;
1376         my $session=shift;
1377         my $nonfatal=shift;
1378
1379         my $canedit;
1380         run_hooks(canedit => sub {
1381                 return if defined $canedit;
1382                 my $ret=shift->($page, $q, $session);
1383                 if (defined $ret) {
1384                         if ($ret eq "") {
1385                                 $canedit=1;
1386                         }
1387                         elsif (ref $ret eq 'CODE') {
1388                                 $ret->() unless $nonfatal;
1389                                 $canedit=0;
1390                         }
1391                         elsif (defined $ret) {
1392                                 error($ret) unless $nonfatal;
1393                                 $canedit=0;
1394                         }
1395                 }
1396         });
1397         return defined $canedit ? $canedit : 1;
1398 }
1399
1400 sub check_content (@) {
1401         my %params=@_;
1402
1403         return 1 if ! exists $hooks{checkcontent}; # optimisation
1404
1405         if (exists $pagesources{$params{page}}) {
1406                 my @diff;
1407                 my %old=map { $_ => 1 }
1408                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1409                 foreach my $line (split("\n", $params{content})) {
1410                         push @diff, $line if ! exists $old{$line};
1411                 }
1412                 $params{diff}=join("\n", @diff);
1413         }
1414
1415         my $ok;
1416         run_hooks(checkcontent => sub {
1417                 return if defined $ok;
1418                 my $ret=shift->(%params);
1419                 if (defined $ret) {
1420                         if ($ret eq "") {
1421                                 $ok=1;
1422                         }
1423                         elsif (ref $ret eq 'CODE') {
1424                                 $ret->() unless $params{nonfatal};
1425                                 $ok=0;
1426                         }
1427                         elsif (defined $ret) {
1428                                 error($ret) unless $params{nonfatal};
1429                                 $ok=0;
1430                         }
1431                 }
1432
1433         });
1434         return defined $ok ? $ok : 1;
1435 }
1436
1437 my $wikilock;
1438
1439 sub lockwiki () {
1440         # Take an exclusive lock on the wiki to prevent multiple concurrent
1441         # run issues. The lock will be dropped on program exit.
1442         if (! -d $config{wikistatedir}) {
1443                 mkdir($config{wikistatedir});
1444         }
1445         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1446                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1447         if (! flock($wikilock, 2)) { # LOCK_EX
1448                 error("failed to get lock");
1449         }
1450         return 1;
1451 }
1452
1453 sub unlockwiki () {
1454         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1455         return close($wikilock) if $wikilock;
1456         return;
1457 }
1458
1459 my $commitlock;
1460
1461 sub commit_hook_enabled () {
1462         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1463                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1464         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1465                 close($commitlock) || error("failed closing commitlock: $!");
1466                 return 0;
1467         }
1468         close($commitlock) || error("failed closing commitlock: $!");
1469         return 1;
1470 }
1471
1472 sub disable_commit_hook () {
1473         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1474                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1475         if (! flock($commitlock, 2)) { # LOCK_EX
1476                 error("failed to get commit lock");
1477         }
1478         return 1;
1479 }
1480
1481 sub enable_commit_hook () {
1482         return close($commitlock) if $commitlock;
1483         return;
1484 }
1485
1486 sub loadindex () {
1487         %oldrenderedfiles=%pagectime=();
1488         if (! $config{rebuild}) {
1489                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1490                 %destsources=%renderedfiles=%pagecase=%pagestate=
1491                 %depends_simple=();
1492         }
1493         my $in;
1494         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1495                 if (-e "$config{wikistatedir}/index") {
1496                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1497                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1498                 }
1499                 else {
1500                         return;
1501                 }
1502         }
1503
1504         my $index=Storable::fd_retrieve($in);
1505         if (! defined $index) {
1506                 return 0;
1507         }
1508
1509         my $pages;
1510         if (exists $index->{version} && ! ref $index->{version}) {
1511                 $pages=$index->{page};
1512                 %wikistate=%{$index->{state}};
1513         }
1514         else {
1515                 $pages=$index;
1516                 %wikistate=();
1517         }
1518
1519         foreach my $src (keys %$pages) {
1520                 my $d=$pages->{$src};
1521                 my $page=pagename($src);
1522                 $pagectime{$page}=$d->{ctime};
1523                 if (! $config{rebuild}) {
1524                         $pagesources{$page}=$src;
1525                         $pagemtime{$page}=$d->{mtime};
1526                         $renderedfiles{$page}=$d->{dest};
1527                         if (exists $d->{links} && ref $d->{links}) {
1528                                 $links{$page}=$d->{links};
1529                                 $oldlinks{$page}=[@{$d->{links}}];
1530                         }
1531                         if (ref $d->{depends_simple} eq 'ARRAY') {
1532                                 # old format
1533                                 $depends_simple{$page}={
1534                                         map { $_ => 1 } @{$d->{depends_simple}}
1535                                 };
1536                         }
1537                         elsif (exists $d->{depends_simple}) {
1538                                 $depends_simple{$page}=$d->{depends_simple};
1539                         }
1540                         if (exists $d->{dependslist}) {
1541                                 # old format
1542                                 $depends{$page}={
1543                                         map { $_ => $DEPEND_CONTENT }
1544                                                 @{$d->{dependslist}}
1545                                 };
1546                         }
1547                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1548                                 # old format
1549                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1550                         }
1551                         elsif (exists $d->{depends}) {
1552                                 $depends{$page}=$d->{depends};
1553                         }
1554                         if (exists $d->{state}) {
1555                                 $pagestate{$page}=$d->{state};
1556                         }
1557                 }
1558                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1559         }
1560         foreach my $page (keys %pagesources) {
1561                 $pagecase{lc $page}=$page;
1562         }
1563         foreach my $page (keys %renderedfiles) {
1564                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1565         }
1566         return close($in);
1567 }
1568
1569 sub saveindex () {
1570         run_hooks(savestate => sub { shift->() });
1571
1572         my %hookids;
1573         foreach my $type (keys %hooks) {
1574                 $hookids{$_}=1 foreach keys %{$hooks{$type}};
1575         }
1576         my @hookids=keys %hookids;
1577
1578         if (! -d $config{wikistatedir}) {
1579                 mkdir($config{wikistatedir});
1580         }
1581         my $newfile="$config{wikistatedir}/indexdb.new";
1582         my $cleanup = sub { unlink($newfile) };
1583         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1584
1585         my %index;
1586         foreach my $page (keys %pagemtime) {
1587                 next unless $pagemtime{$page};
1588                 my $src=$pagesources{$page};
1589
1590                 $index{page}{$src}={
1591                         ctime => $pagectime{$page},
1592                         mtime => $pagemtime{$page},
1593                         dest => $renderedfiles{$page},
1594                         links => $links{$page},
1595                 };
1596
1597                 if (exists $depends{$page}) {
1598                         $index{page}{$src}{depends} = $depends{$page};
1599                 }
1600
1601                 if (exists $depends_simple{$page}) {
1602                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1603                 }
1604
1605                 if (exists $pagestate{$page}) {
1606                         foreach my $id (@hookids) {
1607                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1608                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1609                                 }
1610                         }
1611                 }
1612         }
1613
1614         $index{state}={};
1615         foreach my $id (@hookids) {
1616                 foreach my $key (keys %{$wikistate{$id}}) {
1617                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1618                 }
1619         }
1620
1621         $index{version}="3";
1622         my $ret=Storable::nstore_fd(\%index, $out);
1623         return if ! defined $ret || ! $ret;
1624         close $out || error("failed saving to $newfile: $!", $cleanup);
1625         rename($newfile, "$config{wikistatedir}/indexdb") ||
1626                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1627
1628         return 1;
1629 }
1630
1631 sub template_file ($) {
1632         my $template=shift;
1633
1634         foreach my $dir ($config{templatedir}, @{$config{templatedirs}},
1635                          "$installdir/share/ikiwiki/templates") {
1636                 return "$dir/$template" if -e "$dir/$template";
1637         }
1638         return;
1639 }
1640
1641 sub template_params (@) {
1642         my $filename=template_file(shift);
1643
1644         if (! defined $filename) {
1645                 return if wantarray;
1646                 return "";
1647         }
1648
1649         my @ret=(
1650                 filter => sub {
1651                         my $text_ref = shift;
1652                         ${$text_ref} = decode_utf8(${$text_ref});
1653                 },
1654                 filename => $filename,
1655                 loop_context_vars => 1,
1656                 die_on_bad_params => 0,
1657                 @_
1658         );
1659         return wantarray ? @ret : {@ret};
1660 }
1661
1662 sub template ($;@) {
1663         require HTML::Template;
1664         return HTML::Template->new(template_params(@_));
1665 }
1666
1667 sub misctemplate ($$;@) {
1668         my $title=shift;
1669         my $pagebody=shift;
1670
1671         my $template=template("misc.tmpl");
1672         $template->param(
1673                 title => $title,
1674                 indexlink => indexlink(),
1675                 wikiname => $config{wikiname},
1676                 pagebody => $pagebody,
1677                 baseurl => baseurl(),
1678                 @_,
1679         );
1680         run_hooks(pagetemplate => sub {
1681                 shift->(page => "", destpage => "", template => $template);
1682         });
1683         return $template->output;
1684 }
1685
1686 sub hook (@) {
1687         my %param=@_;
1688
1689         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1690                 error 'hook requires type, call, and id parameters';
1691         }
1692
1693         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1694
1695         $hooks{$param{type}}{$param{id}}=\%param;
1696         return 1;
1697 }
1698
1699 sub run_hooks ($$) {
1700         # Calls the given sub for each hook of the given type,
1701         # passing it the hook function to call.
1702         my $type=shift;
1703         my $sub=shift;
1704
1705         if (exists $hooks{$type}) {
1706                 my (@first, @middle, @last);
1707                 foreach my $id (keys %{$hooks{$type}}) {
1708                         if ($hooks{$type}{$id}{first}) {
1709                                 push @first, $id;
1710                         }
1711                         elsif ($hooks{$type}{$id}{last}) {
1712                                 push @last, $id;
1713                         }
1714                         else {
1715                                 push @middle, $id;
1716                         }
1717                 }
1718                 foreach my $id (@first, @middle, @last) {
1719                         $sub->($hooks{$type}{$id}{call});
1720                 }
1721         }
1722
1723         return 1;
1724 }
1725
1726 sub rcs_update () {
1727         $hooks{rcs}{rcs_update}{call}->(@_);
1728 }
1729
1730 sub rcs_prepedit ($) {
1731         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1732 }
1733
1734 sub rcs_commit ($$$;$$) {
1735         $hooks{rcs}{rcs_commit}{call}->(@_);
1736 }
1737
1738 sub rcs_commit_staged ($$$) {
1739         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1740 }
1741
1742 sub rcs_add ($) {
1743         $hooks{rcs}{rcs_add}{call}->(@_);
1744 }
1745
1746 sub rcs_remove ($) {
1747         $hooks{rcs}{rcs_remove}{call}->(@_);
1748 }
1749
1750 sub rcs_rename ($$) {
1751         $hooks{rcs}{rcs_rename}{call}->(@_);
1752 }
1753
1754 sub rcs_recentchanges ($) {
1755         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1756 }
1757
1758 sub rcs_diff ($) {
1759         $hooks{rcs}{rcs_diff}{call}->(@_);
1760 }
1761
1762 sub rcs_getctime ($) {
1763         $hooks{rcs}{rcs_getctime}{call}->(@_);
1764 }
1765
1766 sub rcs_receive () {
1767         $hooks{rcs}{rcs_receive}{call}->();
1768 }
1769
1770 sub add_depends ($$;$) {
1771         my $page=shift;
1772         my $pagespec=shift;
1773         my $deptype=shift || $DEPEND_CONTENT;
1774
1775         # Is the pagespec a simple page name?
1776         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
1777             $pagespec !~ /[\s*?()!]/) {
1778                 $depends_simple{$page}{lc $pagespec} |= $deptype;
1779                 return 1;
1780         }
1781
1782         # Add explicit dependencies for influences.
1783         my $sub=pagespec_translate($pagespec);
1784         return if $@;
1785         foreach my $p (keys %pagesources) {
1786                 my $r=$sub->($p, location => $page);
1787                 my $i=$r->influences;
1788                 foreach my $k (keys %$i) {
1789                         $depends_simple{$page}{lc $k} |= $i->{$k};
1790                 }
1791                 last if $r->influences_static;
1792         }
1793
1794         $depends{$page}{$pagespec} |= $deptype;
1795         return 1;
1796 }
1797
1798 sub deptype (@) {
1799         my $deptype=0;
1800         foreach my $type (@_) {
1801                 if ($type eq 'presence') {
1802                         $deptype |= $DEPEND_PRESENCE;
1803                 }
1804                 elsif ($type eq 'links') {
1805                         $deptype |= $DEPEND_LINKS;
1806                 }
1807                 elsif ($type eq 'content') {
1808                         $deptype |= $DEPEND_CONTENT;
1809                 }
1810         }
1811         return $deptype;
1812 }
1813
1814 sub file_pruned ($;$) {
1815         my $file=shift;
1816         if (@_) {
1817                 require File::Spec;
1818                 $file=File::Spec->canonpath($file);
1819                 my $base=File::Spec->canonpath(shift);
1820                 return if $file eq $base;
1821                 $file =~ s#^\Q$base\E/+##;
1822         }
1823
1824         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1825         return $file =~ m/$regexp/;
1826 }
1827
1828 sub define_gettext () {
1829         # If translation is needed, redefine the gettext function to do it.
1830         # Otherwise, it becomes a quick no-op.
1831         no warnings 'redefine';
1832         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1833             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1834             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1835                 *gettext=sub {
1836                         my $gettext_obj=eval q{
1837                                 use Locale::gettext q{textdomain};
1838                                 Locale::gettext->domain('ikiwiki')
1839                         };
1840
1841                         if ($gettext_obj) {
1842                                 $gettext_obj->get(shift);
1843                         }
1844                         else {
1845                                 return shift;
1846                         }
1847                 };
1848         }
1849         else {
1850                 *gettext=sub { return shift };
1851         }
1852 }
1853
1854 sub gettext {
1855         define_gettext();
1856         gettext(@_);
1857 }
1858
1859 sub yesno ($) {
1860         my $val=shift;
1861
1862         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
1863 }
1864
1865 sub inject {
1866         # Injects a new function into the symbol table to replace an
1867         # exported function.
1868         my %params=@_;
1869
1870         # This is deep ugly perl foo, beware.
1871         no strict;
1872         no warnings;
1873         if (! defined $params{parent}) {
1874                 $params{parent}='::';
1875                 $params{old}=\&{$params{name}};
1876                 $params{name}=~s/.*:://;
1877         }
1878         my $parent=$params{parent};
1879         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
1880                 $ns = $params{parent} . $ns;
1881                 inject(%params, parent => $ns) unless $ns eq '::main::';
1882                 *{$ns . $params{name}} = $params{call}
1883                         if exists ${$ns}{$params{name}} &&
1884                            \&{${$ns}{$params{name}}} == $params{old};
1885         }
1886         use strict;
1887         use warnings;
1888 }
1889
1890 sub add_link ($$) {
1891         my $page=shift;
1892         my $link=shift;
1893
1894         push @{$links{$page}}, $link
1895                 unless grep { $_ eq $link } @{$links{$page}};
1896 }
1897
1898 sub pagespec_translate ($) {
1899         my $spec=shift;
1900
1901         # Convert spec to perl code.
1902         my $code="";
1903         my @data;
1904         while ($spec=~m{
1905                 \s*             # ignore whitespace
1906                 (               # 1: match a single word
1907                         \!              # !
1908                 |
1909                         \(              # (
1910                 |
1911                         \)              # )
1912                 |
1913                         \w+\([^\)]*\)   # command(params)
1914                 |
1915                         [^\s()]+        # any other text
1916                 )
1917                 \s*             # ignore whitespace
1918         }gx) {
1919                 my $word=$1;
1920                 if (lc $word eq 'and') {
1921                         $code.=' &';
1922                 }
1923                 elsif (lc $word eq 'or') {
1924                         $code.=' |';
1925                 }
1926                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1927                         $code.=' '.$word;
1928                 }
1929                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1930                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1931                                 push @data, $2;
1932                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
1933                         }
1934                         else {
1935                                 push @data, qq{unknown function in pagespec "$word"};
1936                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
1937                         }
1938                 }
1939                 else {
1940                         push @data, $word;
1941                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
1942                 }
1943         }
1944
1945         if (! length $code) {
1946                 $code="IkiWiki::FailReason->new('empty pagespec')";
1947         }
1948
1949         no warnings;
1950         return eval 'sub { my $page=shift; '.$code.' }';
1951 }
1952
1953 sub pagespec_match ($$;@) {
1954         my $page=shift;
1955         my $spec=shift;
1956         my @params=@_;
1957
1958         # Backwards compatability with old calling convention.
1959         if (@params == 1) {
1960                 unshift @params, 'location';
1961         }
1962
1963         my $sub=pagespec_translate($spec);
1964         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
1965                 if $@ || ! defined $sub;
1966         return $sub->($page, @params);
1967 }
1968
1969 sub pagespec_match_list ($$;@) {
1970         my $page=shift;
1971         my $pagespec=shift;
1972         my %params=@_;
1973
1974         # Backwards compatability with old calling convention.
1975         if (ref $page) {
1976                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
1977                 $params{list}=$page;
1978                 $page=$params{location}; # ugh!
1979         }
1980
1981         my $sub=pagespec_translate($pagespec);
1982         error "syntax error in pagespec \"$pagespec\""
1983                 if $@ || ! defined $sub;
1984
1985         my @candidates;
1986         if (exists $params{list}) {
1987                 @candidates=exists $params{filter}
1988                         ? grep { ! $params{filter}->($_) } @{$params{list}}
1989                         : @{$params{list}};
1990         }
1991         else {
1992                 @candidates=exists $params{filter}
1993                         ? grep { ! $params{filter}->($_) } keys %pagesources
1994                         : keys %pagesources;
1995         }
1996
1997         if (defined $params{sort}) {
1998                 my $f;
1999                 if ($params{sort} eq 'title') {
2000                         $f=sub { pagetitle(basename($a)) cmp pagetitle(basename($b)) };
2001                 }
2002                 elsif ($params{sort} eq 'title_natural') {
2003                         eval q{use Sort::Naturally};
2004                         if ($@) {
2005                                 error(gettext("Sort::Naturally needed for title_natural sort"));
2006                         }
2007                         $f=sub { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) };
2008                 }
2009                 elsif ($params{sort} eq 'mtime') {
2010                         $f=sub { $pagemtime{$b} <=> $pagemtime{$a} };
2011                 }
2012                 elsif ($params{sort} eq 'age') {
2013                         $f=sub { $pagectime{$b} <=> $pagectime{$a} };
2014                 }
2015                 else {
2016                         error sprintf(gettext("unknown sort type %s"), $params{sort});
2017                 }
2018                 @candidates = sort { &$f } @candidates;
2019         }
2020
2021         @candidates=reverse(@candidates) if $params{reverse};
2022
2023         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2024
2025         # clear params, remainder is passed to pagespec
2026         my $num=$params{num};
2027         delete @params{qw{num deptype reverse sort filter list}};
2028
2029         my @matches;
2030         my $firstfail;
2031         my $count=0;
2032         my $accum=IkiWiki::SuccessReason->new();
2033         foreach my $p (@candidates) {
2034                 my $r=$sub->($p, %params, location => $page);
2035                 error(sprintf(gettext("cannot match pages: %s"), $r))
2036                         if $r->isa("IkiWiki::ErrorReason");
2037                 $accum |= $r;
2038                 if ($r) {
2039                         push @matches, $p;
2040                         last if defined $num && ++$count == $num;
2041                 }
2042         }
2043
2044         # Add simple dependencies for accumulated influences.
2045         my $i=$accum->influences;
2046         foreach my $k (keys %$i) {
2047                 $depends_simple{$page}{lc $k} |= $i->{$k};
2048         }
2049
2050         return @matches;
2051 }
2052
2053 sub pagespec_valid ($) {
2054         my $spec=shift;
2055
2056         my $sub=pagespec_translate($spec);
2057         return ! $@;
2058 }
2059
2060 sub glob2re ($) {
2061         my $re=quotemeta(shift);
2062         $re=~s/\\\*/.*/g;
2063         $re=~s/\\\?/./g;
2064         return $re;
2065 }
2066
2067 package IkiWiki::FailReason;
2068
2069 use overload (
2070         '""'    => sub { $_[0][0] },
2071         '0+'    => sub { 0 },
2072         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2073         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2074         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2075         fallback => 1,
2076 );
2077
2078 our @ISA = 'IkiWiki::SuccessReason';
2079
2080 package IkiWiki::SuccessReason;
2081
2082 use overload (
2083         '""'    => sub { $_[0][0] },
2084         '0+'    => sub { 1 },
2085         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2086         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2087         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2088         fallback => 1,
2089 );
2090
2091 sub new {
2092         my $class = shift;
2093         my $value = shift;
2094         return bless [$value, {@_}], $class;
2095 }
2096
2097 sub influences {
2098         my $this=shift;
2099         $this->[1]={@_} if @_;
2100         my %i=%{$this->[1]};
2101         delete $i{""};
2102         return \%i;
2103 }
2104
2105 sub influences_static {
2106         return ! $_[0][1]->{""};
2107 }
2108
2109 sub merge_influences {
2110         my $this=shift;
2111         my $other=shift;
2112         my $anded=shift;
2113
2114         if (! $anded || (($this || %{$this->[1]}) &&
2115                         ($other || %{$other->[1]}))) {
2116                 foreach my $influence (keys %{$other->[1]}) {
2117                         $this->[1]{$influence} |= $other->[1]{$influence};
2118                 }
2119         }
2120         else {
2121                 # influence blocker
2122                 $this->[1]={};
2123         }
2124 }
2125
2126 package IkiWiki::ErrorReason;
2127
2128 our @ISA = 'IkiWiki::FailReason';
2129
2130 package IkiWiki::PageSpec;
2131
2132 sub derel ($$) {
2133         my $path=shift;
2134         my $from=shift;
2135
2136         if ($path =~ m!^\./!) {
2137                 $from=~s#/?[^/]+$## if defined $from;
2138                 $path=~s#^\./##;
2139                 $path="$from/$path" if length $from;
2140         }
2141
2142         return $path;
2143 }
2144
2145 sub match_glob ($$;@) {
2146         my $page=shift;
2147         my $glob=shift;
2148         my %params=@_;
2149
2150         $glob=derel($glob, $params{location});
2151
2152         my $regexp=IkiWiki::glob2re($glob);
2153         if ($page=~/^$regexp$/i) {
2154                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2155                         return IkiWiki::SuccessReason->new("$glob matches $page");
2156                 }
2157                 else {
2158                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2159                 }
2160         }
2161         else {
2162                 return IkiWiki::FailReason->new("$glob does not match $page");
2163         }
2164 }
2165
2166 sub match_internal ($$;@) {
2167         return match_glob($_[0], $_[1], @_, internal => 1)
2168 }
2169
2170 sub match_link ($$;@) {
2171         my $page=shift;
2172         my $link=lc(shift);
2173         my %params=@_;
2174
2175         $link=derel($link, $params{location});
2176         my $from=exists $params{location} ? $params{location} : '';
2177
2178         my $links = $IkiWiki::links{$page};
2179         return IkiWiki::FailReason->new("$page has no links", "" => 1)
2180                 unless $links && @{$links};
2181         my $bestlink = IkiWiki::bestlink($from, $link);
2182         foreach my $p (@{$links}) {
2183                 if (length $bestlink) {
2184                         return IkiWiki::SuccessReason->new("$page links to $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2185                                 if $bestlink eq IkiWiki::bestlink($page, $p);
2186                 }
2187                 else {
2188                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2189                                 if match_glob($p, $link, %params);
2190                         my ($p_rel)=$p=~/^\/?(.*)/;
2191                         $link=~s/^\///;
2192                         return IkiWiki::SuccessReason->new("$page links to page $p_rel matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2193                                 if match_glob($p_rel, $link, %params);
2194                 }
2195         }
2196         return IkiWiki::FailReason->new("$page does not link to $link", "" => 1);
2197 }
2198
2199 sub match_backlink ($$;@) {
2200         my $ret=match_link($_[1], $_[0], @_);
2201         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2202         return $ret;
2203 }
2204
2205 sub match_created_before ($$;@) {
2206         my $page=shift;
2207         my $testpage=shift;
2208         my %params=@_;
2209
2210         $testpage=derel($testpage, $params{location});
2211
2212         if (exists $IkiWiki::pagectime{$testpage}) {
2213                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2214                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2215                 }
2216                 else {
2217                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2218                 }
2219         }
2220         else {
2221                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2222         }
2223 }
2224
2225 sub match_created_after ($$;@) {
2226         my $page=shift;
2227         my $testpage=shift;
2228         my %params=@_;
2229
2230         $testpage=derel($testpage, $params{location});
2231
2232         if (exists $IkiWiki::pagectime{$testpage}) {
2233                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2234                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2235                 }
2236                 else {
2237                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2238                 }
2239         }
2240         else {
2241                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2242         }
2243 }
2244
2245 sub match_creation_day ($$;@) {
2246         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
2247                 return IkiWiki::SuccessReason->new('creation_day matched');
2248         }
2249         else {
2250                 return IkiWiki::FailReason->new('creation_day did not match');
2251         }
2252 }
2253
2254 sub match_creation_month ($$;@) {
2255         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
2256                 return IkiWiki::SuccessReason->new('creation_month matched');
2257         }
2258         else {
2259                 return IkiWiki::FailReason->new('creation_month did not match');
2260         }
2261 }
2262
2263 sub match_creation_year ($$;@) {
2264         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
2265                 return IkiWiki::SuccessReason->new('creation_year matched');
2266         }
2267         else {
2268                 return IkiWiki::FailReason->new('creation_year did not match');
2269         }
2270 }
2271
2272 sub match_user ($$;@) {
2273         shift;
2274         my $user=shift;
2275         my %params=@_;
2276
2277         if (! exists $params{user}) {
2278                 return IkiWiki::ErrorReason->new("no user specified");
2279         }
2280
2281         if (defined $params{user} && lc $params{user} eq lc $user) {
2282                 return IkiWiki::SuccessReason->new("user is $user");
2283         }
2284         elsif (! defined $params{user}) {
2285                 return IkiWiki::FailReason->new("not logged in");
2286         }
2287         else {
2288                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2289         }
2290 }
2291
2292 sub match_admin ($$;@) {
2293         shift;
2294         shift;
2295         my %params=@_;
2296
2297         if (! exists $params{user}) {
2298                 return IkiWiki::ErrorReason->new("no user specified");
2299         }
2300
2301         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2302                 return IkiWiki::SuccessReason->new("user is an admin");
2303         }
2304         elsif (! defined $params{user}) {
2305                 return IkiWiki::FailReason->new("not logged in");
2306         }
2307         else {
2308                 return IkiWiki::FailReason->new("user is not an admin");
2309         }
2310 }
2311
2312 sub match_ip ($$;@) {
2313         shift;
2314         my $ip=shift;
2315         my %params=@_;
2316
2317         if (! exists $params{ip}) {
2318                 return IkiWiki::ErrorReason->new("no IP specified");
2319         }
2320
2321         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2322                 return IkiWiki::SuccessReason->new("IP is $ip");
2323         }
2324         else {
2325                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2326         }
2327 }
2328
2329 1