IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render gettext
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version
  20
  21 # Optimisation.
  22 use Memoize;
  23 memoize("abs2rel");
  24 memoize("pagespec_translate");
  25 memoize("file_pruned");
  26
  27 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29
  30 sub defaultconfig () { #{{{
  31         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./, qr/\.x?html?$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => '',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         anonok => 0,
  48         rss => 0,
  49         atom => 0,
  50         discussion => 1,
  51         rebuild => 0,
  52         refresh => 0,
  53         getctime => 0,
  54         w3mmode => 0,
  55         wrapper => undef,
  56         wrappermode => undef,
  57         svnrepo => undef,
  58         svnpath => "trunk",
  59         srcdir => undef,
  60         destdir => undef,
  61         pingurl => [],
  62         templatedir => "$installdir/share/ikiwiki/templates",
  63         underlaydir => "$installdir/share/ikiwiki/basewiki",
  64         setup => undef,
  65         adminuser => undef,
  66         adminemail => undef,
  67         plugin => [qw{mdwn inline htmlscrubber passwordauth}],
  68         timeformat => '%c',
  69         locale => undef,
  70         sslcookie => 0,
  71         httpauth => 0,
  72         userdir => "",
  73 } #}}}
  74
  75 sub checkconfig () { #{{{
  76         # locale stuff; avoid LC_ALL since it overrides everything
  77         if (defined $ENV{LC_ALL}) {
  78                 $ENV{LANG} = $ENV{LC_ALL};
  79                 delete $ENV{LC_ALL};
  80         }
  81         if (defined $config{locale}) {
  82                 eval q{use POSIX};
  83                 error($@) if $@;
  84                 $ENV{LANG} = $config{locale}
  85                         if POSIX::setlocale(&POSIX::LC_ALL, $config{locale});
  86         }
  87
  88         if ($config{w3mmode}) {
  89                 eval q{use Cwd q{abs_path}};
  90                 error($@) if $@;
  91                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  92                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  93                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  94                         unless $config{cgiurl} =~ m!file:///!;
  95                 $config{url}="file://".$config{destdir};
  96         }
  97
  98         if ($config{cgi} && ! length $config{url}) {
  99                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{rcs}) {
 106                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 107                 if ($@) {
 108                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 109                 }
 110         }
 111         else {
 112                 require IkiWiki::Rcs::Stub;
 113         }
 114
 115         run_hooks(checkconfig => sub { shift->() });
 116 } #}}}
 117
 118 sub loadplugins () { #{{{
 119         loadplugin($_) foreach @{$config{plugin}};
 120
 121         run_hooks(getopt => sub { shift->() });
 122         if (grep /^-/, @ARGV) {
 123                 print STDERR "Unknown option: $_\n"
 124                         foreach grep /^-/, @ARGV;
 125                 usage();
 126         }
 127 } #}}}
 128
 129 sub loadplugin ($) { #{{{
 130         my $plugin=shift;
 131
 132         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 133
 134         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 135         eval qq{use $mod};
 136         if ($@) {
 137                 error("Failed to load plugin $mod: $@");
 138         }
 139 } #}}}
 140
 141 sub error ($) { #{{{
 142         if ($config{cgi}) {
 143                 print "Content-type: text/html\n\n";
 144                 print misctemplate(gettext("Error"),
 145                         "<p>".gettext("Error").": @_</p>");
 146         }
 147         log_message(error => @_);
 148         exit(1);
 149 } #}}}
 150
 151 sub debug ($) { #{{{
 152         return unless $config{verbose};
 153         log_message(debug => @_);
 154 } #}}}
 155
 156 my $log_open=0;
 157 sub log_message ($$) { #{{{
 158         my $type=shift;
 159
 160         if ($config{syslog}) {
 161                 require Sys::Syslog;
 162                 unless ($log_open) {
 163                         Sys::Syslog::setlogsock('unix');
 164                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 165                         $log_open=1;
 166                 }
 167                 eval {
 168                         Sys::Syslog::syslog($type, join(" ", @_));
 169                 }
 170         }
 171         elsif (! $config{cgi}) {
 172                 print "@_\n";
 173         }
 174         else {
 175                 print STDERR "@_\n";
 176         }
 177 } #}}}
 178
 179 sub possibly_foolish_untaint ($) { #{{{
 180         my $tainted=shift;
 181         my ($untainted)=$tainted=~/(.*)/;
 182         return $untainted;
 183 } #}}}
 184
 185 sub basename ($) { #{{{
 186         my $file=shift;
 187
 188         $file=~s!.*/+!!;
 189         return $file;
 190 } #}}}
 191
 192 sub dirname ($) { #{{{
 193         my $file=shift;
 194
 195         $file=~s!/*[^/]+$!!;
 196         return $file;
 197 } #}}}
 198
 199 sub pagetype ($) { #{{{
 200         my $page=shift;
 201
 202         if ($page =~ /\.([^.]+)$/) {
 203                 return $1 if exists $hooks{htmlize}{$1};
 204         }
 205         return undef;
 206 } #}}}
 207
 208 sub pagename ($) { #{{{
 209         my $file=shift;
 210
 211         my $type=pagetype($file);
 212         my $page=$file;
 213         $page=~s/\Q.$type\E*$// if defined $type;
 214         return $page;
 215 } #}}}
 216
 217 sub htmlpage ($) { #{{{
 218         my $page=shift;
 219
 220         return $page.".html";
 221 } #}}}
 222
 223 sub srcfile ($) { #{{{
 224         my $file=shift;
 225
 226         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 227         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 228         error("internal error: $file cannot be found");
 229 } #}}}
 230
 231 sub readfile ($;$) { #{{{
 232         my $file=shift;
 233         my $binary=shift;
 234
 235         if (-l $file) {
 236                 error("cannot read a symlink ($file)");
 237         }
 238
 239         local $/=undef;
 240         open (IN, $file) || error("failed to read $file: $!");
 241         binmode(IN) if ($binary);
 242         my $ret=<IN>;
 243         close IN;
 244         return $ret;
 245 } #}}}
 246
 247 sub writefile ($$$;$) { #{{{
 248         my $file=shift; # can include subdirs
 249         my $destdir=shift; # directory to put file in
 250         my $content=shift;
 251         my $binary=shift;
 252
 253         my $test=$file;
 254         while (length $test) {
 255                 if (-l "$destdir/$test") {
 256                         error("cannot write to a symlink ($test)");
 257                 }
 258                 $test=dirname($test);
 259         }
 260
 261         my $dir=dirname("$destdir/$file");
 262         if (! -d $dir) {
 263                 my $d="";
 264                 foreach my $s (split(m!/+!, $dir)) {
 265                         $d.="$s/";
 266                         if (! -d $d) {
 267                                 mkdir($d) || error("failed to create directory $d: $!");
 268                         }
 269                 }
 270         }
 271
 272         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 273         binmode(OUT) if ($binary);
 274         print OUT $content;
 275         close OUT;
 276 } #}}}
 277
 278 my %cleared;
 279 sub will_render ($$;$) { #{{{
 280         my $page=shift;
 281         my $dest=shift;
 282         my $clear=shift;
 283
 284         # Important security check.
 285         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 286             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 287                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 288         }
 289
 290         if (! $clear || $cleared{$page}) {
 291                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 292         }
 293         else {
 294                 $renderedfiles{$page}=[$dest];
 295                 $cleared{$page}=1;
 296         }
 297 } #}}}
 298
 299 sub bestlink ($$) { #{{{
 300         my $page=shift;
 301         my $link=shift;
 302
 303         my $cwd=$page;
 304         if ($link=~s/^\/+//) {
 305                 # absolute links
 306                 $cwd="";
 307         }
 308
 309         do {
 310                 my $l=$cwd;
 311                 $l.="/" if length $l;
 312                 $l.=$link;
 313
 314                 if (exists $links{$l}) {
 315                         return $l;
 316                 }
 317                 elsif (exists $pagecase{lc $l}) {
 318                         return $pagecase{lc $l};
 319                 }
 320         } while $cwd=~s!/?[^/]+$!!;
 321
 322         if (length $config{userdir} && exists $links{"$config{userdir}/".lc($link)}) {
 323                 return "$config{userdir}/".lc($link);
 324         }
 325
 326         #print STDERR "warning: page $page, broken link: $link\n";
 327         return "";
 328 } #}}}
 329
 330 sub isinlinableimage ($) { #{{{
 331         my $file=shift;
 332
 333         $file=~/\.(png|gif|jpg|jpeg)$/i;
 334 } #}}}
 335
 336 sub pagetitle ($;$) { #{{{
 337         my $page=shift;
 338         my $unescaped=shift;
 339
 340         if ($unescaped) {
 341                 $page=~s/__(\d+)__/chr($1)/eg;
 342         }
 343         else {
 344                 $page=~s/__(\d+)__/&#$1;/g;
 345         }
 346         $page=~y/_/ /;
 347
 348         return $page;
 349 } #}}}
 350
 351 sub titlepage ($) { #{{{
 352         my $title=shift;
 353         $title=~y/ /_/;
 354         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 355         return $title;
 356 } #}}}
 357
 358 sub cgiurl (@) { #{{{
 359         my %params=@_;
 360
 361         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 362 } #}}}
 363
 364 sub baseurl (;$) { #{{{
 365         my $page=shift;
 366
 367         return "$config{url}/" if ! defined $page;
 368
 369         $page=~s/[^\/]+$//;
 370         $page=~s/[^\/]+\//..\//g;
 371         return $page;
 372 } #}}}
 373
 374 sub abs2rel ($$) { #{{{
 375         # Work around very innefficient behavior in File::Spec if abs2rel
 376         # is passed two relative paths. It's much faster if paths are
 377         # absolute! (Debian bug #376658; fixed in debian unstable now)
 378         my $path="/".shift;
 379         my $base="/".shift;
 380
 381         require File::Spec;
 382         my $ret=File::Spec->abs2rel($path, $base);
 383         $ret=~s/^// if defined $ret;
 384         return $ret;
 385 } #}}}
 386
 387 sub displaytime ($) { #{{{
 388         my $time=shift;
 389
 390         eval q{use POSIX};
 391         error($@) if $@;
 392         # strftime doesn't know about encodings, so make sure
 393         # its output is properly treated as utf8
 394         return decode_utf8(POSIX::strftime(
 395                         $config{timeformat}, localtime($time)));
 396 } #}}}
 397
 398 sub htmllink ($$$;$$$) { #{{{
 399         my $lpage=shift; # the page doing the linking
 400         my $page=shift; # the page that will contain the link (different for inline)
 401         my $link=shift;
 402         my $noimageinline=shift; # don't turn links into inline html images
 403         my $forcesubpage=shift; # force a link to a subpage
 404         my $linktext=shift; # set to force the link text to something
 405
 406         my $bestlink;
 407         if (! $forcesubpage) {
 408                 $bestlink=bestlink($lpage, $link);
 409         }
 410         else {
 411                 $bestlink="$lpage/".lc($link);
 412         }
 413
 414         $linktext=pagetitle(basename($link)) unless defined $linktext;
 415
 416         return "<span class=\"selflink\">$linktext</span>"
 417                 if length $bestlink && $page eq $bestlink;
 418
 419         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 420                 $bestlink=htmlpage($bestlink);
 421         }
 422         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 423                 return $linktext unless length $config{cgiurl};
 424                 return "<span><a href=\"".
 425                         cgiurl(do => "create", page => lc($link), from => $page).
 426                         "\">?</a>$linktext</span>"
 427         }
 428
 429         $bestlink=abs2rel($bestlink, dirname($page));
 430
 431         if (! $noimageinline && isinlinableimage($bestlink)) {
 432                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 433         }
 434         return "<a href=\"$bestlink\">$linktext</a>";
 435 } #}}}
 436
 437 sub htmlize ($$$) { #{{{
 438         my $page=shift;
 439         my $type=shift;
 440         my $content=shift;
 441
 442         if (exists $hooks{htmlize}{$type}) {
 443                 $content=$hooks{htmlize}{$type}{call}->(
 444                         page => $page,
 445                         content => $content,
 446                 );
 447         }
 448         else {
 449                 error("htmlization of $type not supported");
 450         }
 451
 452         run_hooks(sanitize => sub {
 453                 $content=shift->(
 454                         page => $page,
 455                         content => $content,
 456                 );
 457         });
 458
 459         return $content;
 460 } #}}}
 461
 462 sub linkify ($$$) { #{{{
 463         my $lpage=shift; # the page containing the links
 464         my $page=shift; # the page the link will end up on (different for inline)
 465         my $content=shift;
 466
 467         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 468                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 469                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 470         }eg;
 471
 472         return $content;
 473 } #}}}
 474
 475 my %preprocessing;
 476 sub preprocess ($$$;$) { #{{{
 477         my $page=shift; # the page the data comes from
 478         my $destpage=shift; # the page the data will appear in (different for inline)
 479         my $content=shift;
 480         my $scan=shift;
 481
 482         my $handle=sub {
 483                 my $escape=shift;
 484                 my $command=shift;
 485                 my $params=shift;
 486                 if (length $escape) {
 487                         return "[[$command $params]]";
 488                 }
 489                 elsif (exists $hooks{preprocess}{$command}) {
 490                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 491                         # Note: preserve order of params, some plugins may
 492                         # consider it significant.
 493                         my @params;
 494                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 495                                 my $key=$1;
 496                                 my $val;
 497                                 if (defined $2) {
 498                                         $val=$2;
 499                                         $val=~s/\r\n/\n/mg;
 500                                         $val=~s/^\n+//g;
 501                                         $val=~s/\n+$//g;
 502                                 }
 503                                 elsif (defined $3) {
 504                                         $val=$3;
 505                                 }
 506                                 elsif (defined $4) {
 507                                         $val=$4;
 508                                 }
 509
 510                                 if (defined $key) {
 511                                         push @params, $key, $val;
 512                                 }
 513                                 else {
 514                                         push @params, $val, '';
 515                                 }
 516                         }
 517                         if ($preprocessing{$page}++ > 3) {
 518                                 # Avoid loops of preprocessed pages preprocessing
 519                                 # other pages that preprocess them, etc.
 520                                 #translators: The first parameter is a
 521                                 #translators: preprocessor directive name,
 522                                 #translators: the second a page name, the
 523                                 #translators: third a number.
 524                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 525                                         $command, $page, $preprocessing{$page}).
 526                                 "]]";
 527                         }
 528                         my $ret=$hooks{preprocess}{$command}{call}->(
 529                                 @params,
 530                                 page => $page,
 531                                 destpage => $destpage,
 532                         );
 533                         $preprocessing{$page}--;
 534                         return $ret;
 535                 }
 536                 else {
 537                         return "[[$command $params]]";
 538                 }
 539         };
 540
 541         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 542         return $content;
 543 } #}}}
 544
 545 sub filter ($$) { #{{{
 546         my $page=shift;
 547         my $content=shift;
 548
 549         run_hooks(filter => sub {
 550                 $content=shift->(page => $page, content => $content);
 551         });
 552
 553         return $content;
 554 } #}}}
 555
 556 sub indexlink () { #{{{
 557         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 558 } #}}}
 559
 560 sub lockwiki () { #{{{
 561         # Take an exclusive lock on the wiki to prevent multiple concurrent
 562         # run issues. The lock will be dropped on program exit.
 563         if (! -d $config{wikistatedir}) {
 564                 mkdir($config{wikistatedir});
 565         }
 566         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 567                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 568         if (! flock(WIKILOCK, 2 | 4)) {
 569                 debug("wiki seems to be locked, waiting for lock");
 570                 my $wait=600; # arbitrary, but don't hang forever to
 571                               # prevent process pileup
 572                 for (1..600) {
 573                         return if flock(WIKILOCK, 2 | 4);
 574                         sleep 1;
 575                 }
 576                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 577         }
 578 } #}}}
 579
 580 sub unlockwiki () { #{{{
 581         close WIKILOCK;
 582 } #}}}
 583
 584 sub loadindex () { #{{{
 585         open (IN, "$config{wikistatedir}/index") || return;
 586         while (<IN>) {
 587                 $_=possibly_foolish_untaint($_);
 588                 chomp;
 589                 my %items;
 590                 $items{link}=[];
 591                 $items{dest}=[];
 592                 foreach my $i (split(/ /, $_)) {
 593                         my ($item, $val)=split(/=/, $i, 2);
 594                         push @{$items{$item}}, decode_entities($val);
 595                 }
 596
 597                 next unless exists $items{src}; # skip bad lines for now
 598
 599                 my $page=pagename($items{src}[0]);
 600                 if (! $config{rebuild}) {
 601                         $pagesources{$page}=$items{src}[0];
 602                         $oldpagemtime{$page}=$items{mtime}[0];
 603                         $oldlinks{$page}=[@{$items{link}}];
 604                         $links{$page}=[@{$items{link}}];
 605                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 606                         $renderedfiles{$page}=[@{$items{dest}}];
 607                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 608                         $pagecase{lc $page}=$page;
 609                 }
 610                 $pagectime{$page}=$items{ctime}[0];
 611         }
 612         close IN;
 613 } #}}}
 614
 615 sub saveindex () { #{{{
 616         run_hooks(savestate => sub { shift->() });
 617
 618         if (! -d $config{wikistatedir}) {
 619                 mkdir($config{wikistatedir});
 620         }
 621         open (OUT, ">$config{wikistatedir}/index") ||
 622                 error("cannot write to $config{wikistatedir}/index: $!");
 623         foreach my $page (keys %oldpagemtime) {
 624                 next unless $oldpagemtime{$page};
 625                 my $line="mtime=$oldpagemtime{$page} ".
 626                         "ctime=$pagectime{$page} ".
 627                         "src=$pagesources{$page}";
 628                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 629                 my %count;
 630                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 631                 if (exists $depends{$page}) {
 632                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 633                 }
 634                 print OUT $line."\n";
 635         }
 636         close OUT;
 637 } #}}}
 638
 639 sub template_file ($) { #{{{
 640         my $template=shift;
 641
 642         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 643                 return "$dir/$template" if -e "$dir/$template";
 644         }
 645         return undef;
 646 } #}}}
 647
 648 sub template_params (@) { #{{{
 649         my $filename=template_file(shift);
 650
 651         if (! defined $filename) {
 652                 return if wantarray;
 653                 return "";
 654         }
 655
 656         require HTML::Template;
 657         my @ret=(
 658                 filter => sub {
 659                         my $text_ref = shift;
 660                         $$text_ref=&Encode::decode_utf8($$text_ref);
 661                 },
 662                 filename => $filename,
 663                 loop_context_vars => 1,
 664                 die_on_bad_params => 0,
 665                 @_
 666         );
 667         return wantarray ? @ret : {@ret};
 668 } #}}}
 669
 670 sub template ($;@) { #{{{
 671         HTML::Template->new(template_params(@_));
 672 } #}}}
 673
 674 sub misctemplate ($$;@) { #{{{
 675         my $title=shift;
 676         my $pagebody=shift;
 677
 678         my $template=template("misc.tmpl");
 679         $template->param(
 680                 title => $title,
 681                 indexlink => indexlink(),
 682                 wikiname => $config{wikiname},
 683                 pagebody => $pagebody,
 684                 baseurl => baseurl(),
 685                 @_,
 686         );
 687         run_hooks(pagetemplate => sub {
 688                 shift->(page => "", destpage => "", template => $template);
 689         });
 690         return $template->output;
 691 }#}}}
 692
 693 sub hook (@) { # {{{
 694         my %param=@_;
 695
 696         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 697                 error "hook requires type, call, and id parameters";
 698         }
 699
 700         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 701
 702         $hooks{$param{type}}{$param{id}}=\%param;
 703 } # }}}
 704
 705 sub run_hooks ($$) { # {{{
 706         # Calls the given sub for each hook of the given type,
 707         # passing it the hook function to call.
 708         my $type=shift;
 709         my $sub=shift;
 710
 711         if (exists $hooks{$type}) {
 712                 my @deferred;
 713                 foreach my $id (keys %{$hooks{$type}}) {
 714                         if ($hooks{$type}{$id}{last}) {
 715                                 push @deferred, $id;
 716                                 next;
 717                         }
 718                         $sub->($hooks{$type}{$id}{call});
 719                 }
 720                 foreach my $id (@deferred) {
 721                         $sub->($hooks{$type}{$id}{call});
 722                 }
 723         }
 724 } #}}}
 725
 726 sub globlist_to_pagespec ($) { #{{{
 727         my @globlist=split(' ', shift);
 728
 729         my (@spec, @skip);
 730         foreach my $glob (@globlist) {
 731                 if ($glob=~/^!(.*)/) {
 732                         push @skip, $glob;
 733                 }
 734                 else {
 735                         push @spec, $glob;
 736                 }
 737         }
 738
 739         my $spec=join(" or ", @spec);
 740         if (@skip) {
 741                 my $skip=join(" and ", @skip);
 742                 if (length $spec) {
 743                         $spec="$skip and ($spec)";
 744                 }
 745                 else {
 746                         $spec=$skip;
 747                 }
 748         }
 749         return $spec;
 750 } #}}}
 751
 752 sub is_globlist ($) { #{{{
 753         my $s=shift;
 754         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 755 } #}}}
 756
 757 sub safequote ($) { #{{{
 758         my $s=shift;
 759         $s=~s/[{}]//g;
 760         return "q{$s}";
 761 } #}}}
 762
 763 sub pagespec_merge ($$) { #{{{
 764         my $a=shift;
 765         my $b=shift;
 766
 767         return $a if $a eq $b;
 768
 769         # Support for old-style GlobLists.
 770         if (is_globlist($a)) {
 771                 $a=globlist_to_pagespec($a);
 772         }
 773         if (is_globlist($b)) {
 774                 $b=globlist_to_pagespec($b);
 775         }
 776
 777         return "($a) or ($b)";
 778 } #}}}
 779
 780 sub pagespec_translate ($) { #{{{
 781         # This assumes that $page is in scope in the function
 782         # that evalulates the translated pagespec code.
 783         my $spec=shift;
 784
 785         # Support for old-style GlobLists.
 786         if (is_globlist($spec)) {
 787                 $spec=globlist_to_pagespec($spec);
 788         }
 789
 790         # Convert spec to perl code.
 791         my $code="";
 792         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 793                 my $word=$1;
 794                 if (lc $word eq "and") {
 795                         $code.=" &&";
 796                 }
 797                 elsif (lc $word eq "or") {
 798                         $code.=" ||";
 799                 }
 800                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 801                         $code.=" ".$word;
 802                 }
 803                 elsif ($word =~ /^(link|backlink|created_before|created_after|creation_month|creation_year|creation_day)\((.+)\)$/) {
 804                         $code.=" match_$1(\$page, ".safequote($2).")";
 805                 }
 806                 else {
 807                         $code.=" match_glob(\$page, ".safequote($word).")";
 808                 }
 809         }
 810
 811         return $code;
 812 } #}}}
 813
 814 sub add_depends ($$) { #{{{
 815         my $page=shift;
 816         my $pagespec=shift;
 817
 818         if (! exists $depends{$page}) {
 819                 $depends{$page}=$pagespec;
 820         }
 821         else {
 822                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 823         }
 824 } # }}}
 825
 826 sub file_pruned ($$) { #{{{
 827         require File::Spec;
 828         my $file=File::Spec->canonpath(shift);
 829         my $base=File::Spec->canonpath(shift);
 830         $file=~s#^\Q$base\E/*##;
 831
 832         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 833         $file =~ m/$regexp/;
 834 } #}}}
 835
 836 my $gettext_obj;
 837 sub gettext { #{{{
 838         # Only use gettext in the rare cases it's needed.
 839         if (exists $ENV{LANG} || exists $ENV{LC_ALL} || exists $ENV{LC_MESSAGES}) {
 840                 if (! $gettext_obj) {
 841                         $gettext_obj=eval q{
 842                                 use Locale::gettext q{textdomain};
 843                                 Locale::gettext->domain('ikiwiki')
 844                         };
 845                         if ($@) {
 846                                 print STDERR "$@";
 847                                 $gettext_obj=undef;
 848                                 return shift;
 849                         }
 850                 }
 851                 return $gettext_obj->get(shift);
 852         }
 853         else {
 854                 return shift;
 855         }
 856 } #}}}
 857
 858 sub pagespec_match ($$) { #{{{
 859         my $page=shift;
 860         my $spec=shift;
 861
 862         return eval pagespec_translate($spec);
 863 } #}}}
 864
 865 sub match_glob ($$) { #{{{
 866         my $page=shift;
 867         my $glob=shift;
 868
 869         # turn glob into safe regexp
 870         $glob=quotemeta($glob);
 871         $glob=~s/\\\*/.*/g;
 872         $glob=~s/\\\?/./g;
 873
 874         return $page=~/^$glob$/i;
 875 } #}}}
 876
 877 sub match_link ($$) { #{{{
 878         my $page=shift;
 879         my $link=lc(shift);
 880
 881         my $links = $links{$page} or return undef;
 882         foreach my $p (@$links) {
 883                 return 1 if lc $p eq $link;
 884         }
 885         return 0;
 886 } #}}}
 887
 888 sub match_backlink ($$) { #{{{
 889         match_link(pop, pop);
 890 } #}}}
 891
 892 sub match_created_before ($$) { #{{{
 893         my $page=shift;
 894         my $testpage=shift;
 895
 896         if (exists $pagectime{$testpage}) {
 897                 return $pagectime{$page} < $pagectime{$testpage};
 898         }
 899         else {
 900                 return 0;
 901         }
 902 } #}}}
 903
 904 sub match_created_after ($$) { #{{{
 905         my $page=shift;
 906         my $testpage=shift;
 907
 908         if (exists $pagectime{$testpage}) {
 909                 return $pagectime{$page} > $pagectime{$testpage};
 910         }
 911         else {
 912                 return 0;
 913         }
 914 } #}}}
 915
 916 sub match_creation_day ($$) { #{{{
 917         return ((gmtime($pagectime{shift()}))[3] == shift);
 918 } #}}}
 919
 920 sub match_creation_month ($$) { #{{{
 921         return ((gmtime($pagectime{shift()}))[4] + 1 == shift);
 922 } #}}}
 923
 924 sub match_creation_year ($$) { #{{{
 925         return ((gmtime($pagectime{shift()}))[5] + 1900 == shift);
 926 } #}}}
 927
 928 1