IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %renderedfiles %oldrenderedfiles %pagesources %destsources
  14             %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  %config %links %renderedfiles %pagesources %destsources);
  21 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  22 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  23 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  24
  25 # Optimisation.
  26 use Memoize;
  27 memoize("abs2rel");
  28 memoize("pagespec_translate");
  29 memoize("file_pruned");
  30
  31 sub defaultconfig () { #{{{
  32         return
  33         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  34                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  35                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  36                 qr/(^|\/)_MTN\//,
  37                 qr/\.dpkg-tmp$/],
  38         wiki_link_regexp => qr{
  39                 \[\[                    # beginning of link
  40                 (?:
  41                         ([^\]\|]+)      # 1: link text
  42                         \|              # followed by '|'
  43                 )?                      # optional
  44
  45                 ([^\s\]#]+)             # 2: page to link to
  46                 (?:
  47                         \#              # '#', beginning of anchor
  48                         ([^\s\]]+)      # 3: anchor text
  49                 )?                      # optional
  50
  51                 \]\]                    # end of link
  52         }x,
  53         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  54         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  55         verbose => 0,
  56         syslog => 0,
  57         wikiname => "wiki",
  58         default_pageext => "mdwn",
  59         htmlext => "html",
  60         cgi => 0,
  61         post_commit => 0,
  62         rcs => '',
  63         notify => 0,
  64         url => '',
  65         cgiurl => '',
  66         historyurl => '',
  67         diffurl => '',
  68         rss => 0,
  69         atom => 0,
  70         discussion => 1,
  71         rebuild => 0,
  72         refresh => 0,
  73         getctime => 0,
  74         w3mmode => 0,
  75         wrapper => undef,
  76         wrappermode => undef,
  77         svnrepo => undef,
  78         svnpath => "trunk",
  79         gitorigin_branch => "origin",
  80         gitmaster_branch => "master",
  81         srcdir => undef,
  82         destdir => undef,
  83         pingurl => [],
  84         templatedir => "$installdir/share/ikiwiki/templates",
  85         underlaydir => "$installdir/share/ikiwiki/basewiki",
  86         setup => undef,
  87         adminuser => undef,
  88         adminemail => undef,
  89         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  90                       lockedit conditional}],
  91         libdir => undef,
  92         timeformat => '%c',
  93         locale => undef,
  94         sslcookie => 0,
  95         httpauth => 0,
  96         userdir => "",
  97         usedirs => 1,
  98         numbacklinks => 10,
  99         account_creation_password => "",
 100 } #}}}
 101
 102 sub checkconfig () { #{{{
 103         # locale stuff; avoid LC_ALL since it overrides everything
 104         if (defined $ENV{LC_ALL}) {
 105                 $ENV{LANG} = $ENV{LC_ALL};
 106                 delete $ENV{LC_ALL};
 107         }
 108         if (defined $config{locale}) {
 109                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 110                         $ENV{LANG}=$config{locale};
 111                         $gettext_obj=undef;
 112                 }
 113         }
 114
 115         if ($config{w3mmode}) {
 116                 eval q{use Cwd q{abs_path}};
 117                 error($@) if $@;
 118                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 119                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 120                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 121                         unless $config{cgiurl} =~ m!file:///!;
 122                 $config{url}="file://".$config{destdir};
 123         }
 124
 125         if ($config{cgi} && ! length $config{url}) {
 126                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 127         }
 128
 129         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 130                 unless exists $config{wikistatedir};
 131
 132         if ($config{rcs}) {
 133                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 134                 if ($@) {
 135                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 136                 }
 137         }
 138         else {
 139                 require IkiWiki::Rcs::Stub;
 140         }
 141
 142         run_hooks(checkconfig => sub { shift->() });
 143
 144         return 1;
 145 } #}}}
 146
 147 sub loadplugins () { #{{{
 148         if (defined $config{libdir}) {
 149                 unshift @INC, possibly_foolish_untaint($config{libdir});
 150         }
 151
 152         loadplugin($_) foreach @{$config{plugin}};
 153
 154         run_hooks(getopt => sub { shift->() });
 155         if (grep /^-/, @ARGV) {
 156                 print STDERR "Unknown option: $_\n"
 157                         foreach grep /^-/, @ARGV;
 158                 usage();
 159         }
 160
 161         return 1;
 162 } #}}}
 163
 164 sub loadplugin ($) { #{{{
 165         my $plugin=shift;
 166
 167         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 168
 169         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 170                          "$installdir/lib/ikiwiki") {
 171                 if (defined $dir && -x "$dir/plugins/$plugin") {
 172                         require IkiWiki::Plugin::external;
 173                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 174                         return 1;
 175                 }
 176         }
 177
 178         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 179         eval qq{use $mod};
 180         if ($@) {
 181                 error("Failed to load plugin $mod: $@");
 182         }
 183         return 1;
 184 } #}}}
 185
 186 sub error ($;$) { #{{{
 187         my $message=shift;
 188         my $cleaner=shift;
 189         if ($config{cgi}) {
 190                 print "Content-type: text/html\n\n";
 191                 print misctemplate(gettext("Error"),
 192                         "<p>".gettext("Error").": $message</p>");
 193         }
 194         log_message('err' => $message) if $config{syslog};
 195         if (defined $cleaner) {
 196                 $cleaner->();
 197         }
 198         die $message."\n";
 199 } #}}}
 200
 201 sub debug ($) { #{{{
 202         return unless $config{verbose};
 203         return log_message(debug => @_);
 204 } #}}}
 205
 206 my $log_open=0;
 207 sub log_message ($$) { #{{{
 208         my $type=shift;
 209
 210         if ($config{syslog}) {
 211                 require Sys::Syslog;
 212                 if (! $log_open) {
 213                         Sys::Syslog::setlogsock('unix');
 214                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 215                         $log_open=1;
 216                 }
 217                 return eval {
 218                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 219                 };
 220         }
 221         elsif (! $config{cgi}) {
 222                 return print "@_\n";
 223         }
 224         else {
 225                 return print STDERR "@_\n";
 226         }
 227 } #}}}
 228
 229 sub possibly_foolish_untaint ($) { #{{{
 230         my $tainted=shift;
 231         my ($untainted)=$tainted=~/(.*)/s;
 232         return $untainted;
 233 } #}}}
 234
 235 sub basename ($) { #{{{
 236         my $file=shift;
 237
 238         $file=~s!.*/+!!;
 239         return $file;
 240 } #}}}
 241
 242 sub dirname ($) { #{{{
 243         my $file=shift;
 244
 245         $file=~s!/*[^/]+$!!;
 246         return $file;
 247 } #}}}
 248
 249 sub pagetype ($) { #{{{
 250         my $page=shift;
 251
 252         if ($page =~ /\.([^.]+)$/) {
 253                 return $1 if exists $hooks{htmlize}{$1};
 254         }
 255         return;
 256 } #}}}
 257
 258 sub pagename ($) { #{{{
 259         my $file=shift;
 260
 261         my $type=pagetype($file);
 262         my $page=$file;
 263         $page=~s/\Q.$type\E*$// if defined $type;
 264         return $page;
 265 } #}}}
 266
 267 sub targetpage ($$) { #{{{
 268         my $page=shift;
 269         my $ext=shift;
 270
 271         if (! $config{usedirs} || $page =~ /^index$/ ) {
 272                 return $page.".".$ext;
 273         } else {
 274                 return $page."/index.".$ext;
 275         }
 276 } #}}}
 277
 278 sub htmlpage ($) { #{{{
 279         my $page=shift;
 280
 281         return targetpage($page, $config{htmlext});
 282 } #}}}
 283
 284 sub srcfile ($) { #{{{
 285         my $file=shift;
 286
 287         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 288         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 289         error("internal error: $file cannot be found in $config{srcdir} or $config{underlaydir}");
 290         return;
 291 } #}}}
 292
 293 sub readfile ($;$$) { #{{{
 294         my $file=shift;
 295         my $binary=shift;
 296         my $wantfd=shift;
 297
 298         if (-l $file) {
 299                 error("cannot read a symlink ($file)");
 300         }
 301
 302         local $/=undef;
 303         open (my $in, "<", $file) || error("failed to read $file: $!");
 304         binmode($in) if ($binary);
 305         return \*$in if $wantfd;
 306         my $ret=<$in>;
 307         close $in || error("failed to read $file: $!");
 308         return $ret;
 309 } #}}}
 310
 311 sub writefile ($$$;$$) { #{{{
 312         my $file=shift; # can include subdirs
 313         my $destdir=shift; # directory to put file in
 314         my $content=shift;
 315         my $binary=shift;
 316         my $writer=shift;
 317
 318         my $test=$file;
 319         while (length $test) {
 320                 if (-l "$destdir/$test") {
 321                         error("cannot write to a symlink ($test)");
 322                 }
 323                 $test=dirname($test);
 324         }
 325         my $newfile="$destdir/$file.ikiwiki-new";
 326         if (-l $newfile) {
 327                 error("cannot write to a symlink ($newfile)");
 328         }
 329
 330         my $dir=dirname($newfile);
 331         if (! -d $dir) {
 332                 my $d="";
 333                 foreach my $s (split(m!/+!, $dir)) {
 334                         $d.="$s/";
 335                         if (! -d $d) {
 336                                 mkdir($d) || error("failed to create directory $d: $!");
 337                         }
 338                 }
 339         }
 340
 341         my $cleanup = sub { unlink($newfile) };
 342         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 343         binmode($out) if ($binary);
 344         if ($writer) {
 345                 $writer->(\*$out, $cleanup);
 346         }
 347         else {
 348                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 349         }
 350         close $out || error("failed saving $newfile: $!", $cleanup);
 351         rename($newfile, "$destdir/$file") ||
 352                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 353
 354         return 1;
 355 } #}}}
 356
 357 my %cleared;
 358 sub will_render ($$;$) { #{{{
 359         my $page=shift;
 360         my $dest=shift;
 361         my $clear=shift;
 362
 363         # Important security check.
 364         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 365             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 366                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 367         }
 368
 369         if (! $clear || $cleared{$page}) {
 370                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 371         }
 372         else {
 373                 foreach my $old (@{$renderedfiles{$page}}) {
 374                         delete $destsources{$old};
 375                 }
 376                 $renderedfiles{$page}=[$dest];
 377                 $cleared{$page}=1;
 378         }
 379         $destsources{$dest}=$page;
 380
 381         return 1;
 382 } #}}}
 383
 384 sub bestlink ($$) { #{{{
 385         my $page=shift;
 386         my $link=shift;
 387
 388         my $cwd=$page;
 389         if ($link=~s/^\/+//) {
 390                 # absolute links
 391                 $cwd="";
 392         }
 393
 394         do {
 395                 my $l=$cwd;
 396                 $l.="/" if length $l;
 397                 $l.=$link;
 398
 399                 if (exists $links{$l}) {
 400                         return $l;
 401                 }
 402                 elsif (exists $pagecase{lc $l}) {
 403                         return $pagecase{lc $l};
 404                 }
 405         } while $cwd=~s!/?[^/]+$!!;
 406
 407         if (length $config{userdir}) {
 408                 my $l = "$config{userdir}/".lc($link);
 409                 if (exists $links{$l}) {
 410                         return $l;
 411                 }
 412                 elsif (exists $pagecase{lc $l}) {
 413                         return $pagecase{lc $l};
 414                 }
 415         }
 416
 417         #print STDERR "warning: page $page, broken link: $link\n";
 418         return "";
 419 } #}}}
 420
 421 sub isinlinableimage ($) { #{{{
 422         my $file=shift;
 423
 424         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 425 } #}}}
 426
 427 sub pagetitle ($;$) { #{{{
 428         my $page=shift;
 429         my $unescaped=shift;
 430
 431         if ($unescaped) {
 432                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 433         }
 434         else {
 435                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 436         }
 437
 438         return $page;
 439 } #}}}
 440
 441 sub titlepage ($) { #{{{
 442         my $title=shift;
 443         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 444         return $title;
 445 } #}}}
 446
 447 sub linkpage ($) { #{{{
 448         my $link=shift;
 449         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 450         return $link;
 451 } #}}}
 452
 453 sub cgiurl (@) { #{{{
 454         my %params=@_;
 455
 456         return $config{cgiurl}."?".
 457                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 458 } #}}}
 459
 460 sub baseurl (;$) { #{{{
 461         my $page=shift;
 462
 463         return "$config{url}/" if ! defined $page;
 464
 465         $page=htmlpage($page);
 466         $page=~s/[^\/]+$//;
 467         $page=~s/[^\/]+\//..\//g;
 468         return $page;
 469 } #}}}
 470
 471 sub abs2rel ($$) { #{{{
 472         # Work around very innefficient behavior in File::Spec if abs2rel
 473         # is passed two relative paths. It's much faster if paths are
 474         # absolute! (Debian bug #376658; fixed in debian unstable now)
 475         my $path="/".shift;
 476         my $base="/".shift;
 477
 478         require File::Spec;
 479         my $ret=File::Spec->abs2rel($path, $base);
 480         $ret=~s/^// if defined $ret;
 481         return $ret;
 482 } #}}}
 483
 484 sub displaytime ($) { #{{{
 485         my $time=shift;
 486
 487         # strftime doesn't know about encodings, so make sure
 488         # its output is properly treated as utf8
 489         return decode_utf8(POSIX::strftime(
 490                         $config{timeformat}, localtime($time)));
 491 } #}}}
 492
 493 sub beautify_url ($) { #{{{
 494         my $url=shift;
 495
 496         $url =~ s!/index.$config{htmlext}$!/!;
 497         $url =~ s!^$!./!; # Browsers don't like empty links...
 498
 499         return $url;
 500 } #}}}
 501
 502 sub urlto ($$) { #{{{
 503         my $to=shift;
 504         my $from=shift;
 505
 506         if (! length $to) {
 507                 return beautify_url(baseurl($from));
 508         }
 509
 510         if (! $destsources{$to}) {
 511                 $to=htmlpage($to);
 512         }
 513
 514         my $link = abs2rel($to, dirname(htmlpage($from)));
 515
 516         return beautify_url($link);
 517 } #}}}
 518
 519 sub htmllink ($$$;@) { #{{{
 520         my $lpage=shift; # the page doing the linking
 521         my $page=shift; # the page that will contain the link (different for inline)
 522         my $link=shift;
 523         my %opts=@_;
 524
 525         my $bestlink;
 526         if (! $opts{forcesubpage}) {
 527                 $bestlink=bestlink($lpage, $link);
 528         }
 529         else {
 530                 $bestlink="$lpage/".lc($link);
 531         }
 532
 533         my $linktext;
 534         if (defined $opts{linktext}) {
 535                 $linktext=$opts{linktext};
 536         }
 537         else {
 538                 $linktext=pagetitle(basename($link));
 539         }
 540
 541         return "<span class=\"selflink\">$linktext</span>"
 542                 if length $bestlink && $page eq $bestlink;
 543
 544         if (! $destsources{$bestlink}) {
 545                 $bestlink=htmlpage($bestlink);
 546
 547                 if (! $destsources{$bestlink}) {
 548                         return $linktext unless length $config{cgiurl};
 549                         return "<span><a href=\"".
 550                                 cgiurl(
 551                                         do => "create",
 552                                         page => pagetitle(lc($link), 1),
 553                                         from => $lpage
 554                                 ).
 555                                 "\">?</a>$linktext</span>"
 556                 }
 557         }
 558
 559         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 560         $bestlink=beautify_url($bestlink);
 561
 562         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 563                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 564         }
 565
 566         if (defined $opts{anchor}) {
 567                 $bestlink.="#".$opts{anchor};
 568         }
 569
 570         my @attrs;
 571         if (defined $opts{rel}) {
 572                 push @attrs, ' rel="'.$opts{rel}.'"';
 573         }
 574
 575         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 576 } #}}}
 577
 578 sub htmlize ($$$) { #{{{
 579         my $page=shift;
 580         my $type=shift;
 581         my $content=shift;
 582
 583         if (exists $hooks{htmlize}{$type}) {
 584                 $content=$hooks{htmlize}{$type}{call}->(
 585                         page => $page,
 586                         content => $content,
 587                 );
 588         }
 589         else {
 590                 error("htmlization of $type not supported");
 591         }
 592
 593         run_hooks(sanitize => sub {
 594                 $content=shift->(
 595                         page => $page,
 596                         content => $content,
 597                 );
 598         });
 599
 600         return $content;
 601 } #}}}
 602
 603 sub linkify ($$$) { #{{{
 604         my $lpage=shift; # the page containing the links
 605         my $page=shift; # the page the link will end up on (different for inline)
 606         my $content=shift;
 607
 608         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 609                 defined $2
 610                         ? ( $1
 611                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 612                                 : htmllink($lpage, $page, linkpage($3),
 613                                         anchor => $4, linktext => pagetitle($2)))
 614                         : ( $1
 615                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 616                                 : htmllink($lpage, $page, linkpage($3),
 617                                         anchor => $4))
 618         }eg;
 619
 620         return $content;
 621 } #}}}
 622
 623 my %preprocessing;
 624 our $preprocess_preview=0;
 625 sub preprocess ($$$;$$) { #{{{
 626         my $page=shift; # the page the data comes from
 627         my $destpage=shift; # the page the data will appear in (different for inline)
 628         my $content=shift;
 629         my $scan=shift;
 630         my $preview=shift;
 631
 632         # Using local because it needs to be set within any nested calls
 633         # of this function.
 634         local $preprocess_preview=$preview if defined $preview;
 635
 636         my $handle=sub {
 637                 my $escape=shift;
 638                 my $command=shift;
 639                 my $params=shift;
 640                 if (length $escape) {
 641                         return "[[$command $params]]";
 642                 }
 643                 elsif (exists $hooks{preprocess}{$command}) {
 644                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 645                         # Note: preserve order of params, some plugins may
 646                         # consider it significant.
 647                         my @params;
 648                         while ($params =~ m{
 649                                 (?:(\w+)=)?             # 1: named parameter key?
 650                                 (?:
 651                                         """(.*?)"""     # 2: triple-quoted value
 652                                 |
 653                                         "([^"]+)"       # 3: single-quoted value
 654                                 |
 655                                         (\S+)           # 4: unquoted value
 656                                 )
 657                                 (?:\s+|$)               # delimiter to next param
 658                         }sgx) {
 659                                 my $key=$1;
 660                                 my $val;
 661                                 if (defined $2) {
 662                                         $val=$2;
 663                                         $val=~s/\r\n/\n/mg;
 664                                         $val=~s/^\n+//g;
 665                                         $val=~s/\n+$//g;
 666                                 }
 667                                 elsif (defined $3) {
 668                                         $val=$3;
 669                                 }
 670                                 elsif (defined $4) {
 671                                         $val=$4;
 672                                 }
 673
 674                                 if (defined $key) {
 675                                         push @params, $key, $val;
 676                                 }
 677                                 else {
 678                                         push @params, $val, '';
 679                                 }
 680                         }
 681                         if ($preprocessing{$page}++ > 3) {
 682                                 # Avoid loops of preprocessed pages preprocessing
 683                                 # other pages that preprocess them, etc.
 684                                 #translators: The first parameter is a
 685                                 #translators: preprocessor directive name,
 686                                 #translators: the second a page name, the
 687                                 #translators: third a number.
 688                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 689                                         $command, $page, $preprocessing{$page}).
 690                                 "]]";
 691                         }
 692                         my $ret=$hooks{preprocess}{$command}{call}->(
 693                                 @params,
 694                                 page => $page,
 695                                 destpage => $destpage,
 696                                 preview => $preprocess_preview,
 697                         );
 698                         $preprocessing{$page}--;
 699                         return $ret;
 700                 }
 701                 else {
 702                         return "[[$command $params]]";
 703                 }
 704         };
 705
 706         $content =~ s{
 707                 (\\?)           # 1: escape?
 708                 \[\[            # directive open
 709                 (\w+)           # 2: command
 710                 \s+
 711                 (               # 3: the parameters..
 712                         (?:
 713                                 (?:\w+=)?               # named parameter key?
 714                                 (?:
 715                                         """.*?"""       # triple-quoted value
 716                                         |
 717                                         "[^"]+"         # single-quoted value
 718                                         |
 719                                         [^\s\]]+        # unquoted value
 720                                 )
 721                                 \s*                     # whitespace or end
 722                                                         # of directive
 723                         )
 724                 *)              # 0 or more parameters
 725                 \]\]            # directive closed
 726         }{$handle->($1, $2, $3)}sexg;
 727         return $content;
 728 } #}}}
 729
 730 sub filter ($$$) { #{{{
 731         my $page=shift;
 732         my $destpage=shift;
 733         my $content=shift;
 734
 735         run_hooks(filter => sub {
 736                 $content=shift->(page => $page, destpage => $destpage,
 737                         content => $content);
 738         });
 739
 740         return $content;
 741 } #}}}
 742
 743 sub indexlink () { #{{{
 744         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 745 } #}}}
 746
 747 my $wikilock;
 748
 749 sub lockwiki (;$) { #{{{
 750         my $wait=@_ ? shift : 1;
 751         # Take an exclusive lock on the wiki to prevent multiple concurrent
 752         # run issues. The lock will be dropped on program exit.
 753         if (! -d $config{wikistatedir}) {
 754                 mkdir($config{wikistatedir});
 755         }
 756         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 757                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 758         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 759                 if ($wait) {
 760                         debug("wiki seems to be locked, waiting for lock");
 761                         my $wait=600; # arbitrary, but don't hang forever to
 762                                       # prevent process pileup
 763                         for (1..$wait) {
 764                                 return if flock($wikilock, 2 | 4);
 765                                 sleep 1;
 766                         }
 767                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 768                 }
 769                 else {
 770                         return 0;
 771                 }
 772         }
 773         return 1;
 774 } #}}}
 775
 776 sub unlockwiki () { #{{{
 777         return close($wikilock) if $wikilock;
 778         return;
 779 } #}}}
 780
 781 my $commitlock;
 782
 783 sub commit_hook_enabled () { #{{{
 784         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 785                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 786         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 787                 close($commitlock) || error("failed closing commitlock: $!");
 788                 return 0;
 789         }
 790         close($commitlock) || error("failed closing commitlock: $!");
 791         return 1;
 792 } #}}}
 793
 794 sub disable_commit_hook () { #{{{
 795         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 796                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 797         if (! flock($commitlock, 2)) { # LOCK_EX
 798                 error("failed to get commit lock");
 799         }
 800         return 1;
 801 } #}}}
 802
 803 sub enable_commit_hook () { #{{{
 804         return close($commitlock) if $commitlock;
 805         return;
 806 } #}}}
 807
 808 sub loadindex () { #{{{
 809         open (my $in, "<", "$config{wikistatedir}/index") || return;
 810         while (<$in>) {
 811                 $_=possibly_foolish_untaint($_);
 812                 chomp;
 813                 my %items;
 814                 $items{link}=[];
 815                 $items{dest}=[];
 816                 foreach my $i (split(/ /, $_)) {
 817                         my ($item, $val)=split(/=/, $i, 2);
 818                         push @{$items{$item}}, decode_entities($val);
 819                 }
 820
 821                 next unless exists $items{src}; # skip bad lines for now
 822
 823                 my $page=pagename($items{src}[0]);
 824                 if (! $config{rebuild}) {
 825                         $pagesources{$page}=$items{src}[0];
 826                         $pagemtime{$page}=$items{mtime}[0];
 827                         $oldlinks{$page}=[@{$items{link}}];
 828                         $links{$page}=[@{$items{link}}];
 829                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 830                         $destsources{$_}=$page foreach @{$items{dest}};
 831                         $renderedfiles{$page}=[@{$items{dest}}];
 832                         $pagecase{lc $page}=$page;
 833                 }
 834                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 835                 $pagectime{$page}=$items{ctime}[0];
 836         }
 837         return close($in);
 838 } #}}}
 839
 840 sub saveindex () { #{{{
 841         run_hooks(savestate => sub { shift->() });
 842
 843         if (! -d $config{wikistatedir}) {
 844                 mkdir($config{wikistatedir});
 845         }
 846         my $newfile="$config{wikistatedir}/index.new";
 847         my $cleanup = sub { unlink($newfile) };
 848         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 849         foreach my $page (keys %pagemtime) {
 850                 next unless $pagemtime{$page};
 851                 my $line="mtime=$pagemtime{$page} ".
 852                         "ctime=$pagectime{$page} ".
 853                         "src=$pagesources{$page}";
 854                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 855                 my %count;
 856                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 857                 if (exists $depends{$page}) {
 858                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 859                 }
 860                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 861         }
 862         close $out || error("failed saving to $newfile: $!", $cleanup);
 863         rename($newfile, "$config{wikistatedir}/index") ||
 864                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 865
 866         return 1;
 867 } #}}}
 868
 869 sub template_file ($) { #{{{
 870         my $template=shift;
 871
 872         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 873                 return "$dir/$template" if -e "$dir/$template";
 874         }
 875         return;
 876 } #}}}
 877
 878 sub template_params (@) { #{{{
 879         my $filename=template_file(shift);
 880
 881         if (! defined $filename) {
 882                 return if wantarray;
 883                 return "";
 884         }
 885
 886         my @ret=(
 887                 filter => sub {
 888                         my $text_ref = shift;
 889                         ${$text_ref} = Encode::decode_utf8(${$text_ref});
 890                 },
 891                 filename => $filename,
 892                 loop_context_vars => 1,
 893                 die_on_bad_params => 0,
 894                 @_
 895         );
 896         return wantarray ? @ret : {@ret};
 897 } #}}}
 898
 899 sub template ($;@) { #{{{
 900         require HTML::Template;
 901         return HTML::Template->new(template_params(@_));
 902 } #}}}
 903
 904 sub misctemplate ($$;@) { #{{{
 905         my $title=shift;
 906         my $pagebody=shift;
 907
 908         my $template=template("misc.tmpl");
 909         $template->param(
 910                 title => $title,
 911                 indexlink => indexlink(),
 912                 wikiname => $config{wikiname},
 913                 pagebody => $pagebody,
 914                 baseurl => baseurl(),
 915                 @_,
 916         );
 917         run_hooks(pagetemplate => sub {
 918                 shift->(page => "", destpage => "", template => $template);
 919         });
 920         return $template->output;
 921 }#}}}
 922
 923 sub hook (@) { # {{{
 924         my %param=@_;
 925
 926         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 927                 error 'hook requires type, call, and id parameters';
 928         }
 929
 930         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 931
 932         $hooks{$param{type}}{$param{id}}=\%param;
 933         return 1;
 934 } # }}}
 935
 936 sub run_hooks ($$) { # {{{
 937         # Calls the given sub for each hook of the given type,
 938         # passing it the hook function to call.
 939         my $type=shift;
 940         my $sub=shift;
 941
 942         if (exists $hooks{$type}) {
 943                 my @deferred;
 944                 foreach my $id (keys %{$hooks{$type}}) {
 945                         if ($hooks{$type}{$id}{last}) {
 946                                 push @deferred, $id;
 947                                 next;
 948                         }
 949                         $sub->($hooks{$type}{$id}{call});
 950                 }
 951                 foreach my $id (@deferred) {
 952                         $sub->($hooks{$type}{$id}{call});
 953                 }
 954         }
 955
 956         return 1;
 957 } #}}}
 958
 959 sub globlist_to_pagespec ($) { #{{{
 960         my @globlist=split(' ', shift);
 961
 962         my (@spec, @skip);
 963         foreach my $glob (@globlist) {
 964                 if ($glob=~/^!(.*)/) {
 965                         push @skip, $glob;
 966                 }
 967                 else {
 968                         push @spec, $glob;
 969                 }
 970         }
 971
 972         my $spec=join(' or ', @spec);
 973         if (@skip) {
 974                 my $skip=join(' and ', @skip);
 975                 if (length $spec) {
 976                         $spec="$skip and ($spec)";
 977                 }
 978                 else {
 979                         $spec=$skip;
 980                 }
 981         }
 982         return $spec;
 983 } #}}}
 984
 985 sub is_globlist ($) { #{{{
 986         my $s=shift;
 987         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
 988 } #}}}
 989
 990 sub safequote ($) { #{{{
 991         my $s=shift;
 992         $s=~s/[{}]//g;
 993         return "q{$s}";
 994 } #}}}
 995
 996 sub add_depends ($$) { #{{{
 997         my $page=shift;
 998         my $pagespec=shift;
 999
1000         if (! exists $depends{$page}) {
1001                 $depends{$page}=$pagespec;
1002         }
1003         else {
1004                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1005         }
1006
1007         return 1;
1008 } # }}}
1009
1010 sub file_pruned ($$) { #{{{
1011         require File::Spec;
1012         my $file=File::Spec->canonpath(shift);
1013         my $base=File::Spec->canonpath(shift);
1014         $file =~ s#^\Q$base\E/*##;
1015
1016         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1017         return $file =~ m/$regexp/;
1018 } #}}}
1019
1020 sub gettext { #{{{
1021         # Only use gettext in the rare cases it's needed.
1022         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1023             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1024             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1025                 if (! $gettext_obj) {
1026                         $gettext_obj=eval q{
1027                                 use Locale::gettext q{textdomain};
1028                                 Locale::gettext->domain('ikiwiki')
1029                         };
1030                         if ($@) {
1031                                 print STDERR "$@";
1032                                 $gettext_obj=undef;
1033                                 return shift;
1034                         }
1035                 }
1036                 return $gettext_obj->get(shift);
1037         }
1038         else {
1039                 return shift;
1040         }
1041 } #}}}
1042
1043 sub pagespec_merge ($$) { #{{{
1044         my $a=shift;
1045         my $b=shift;
1046
1047         return $a if $a eq $b;
1048
1049         # Support for old-style GlobLists.
1050         if (is_globlist($a)) {
1051                 $a=globlist_to_pagespec($a);
1052         }
1053         if (is_globlist($b)) {
1054                 $b=globlist_to_pagespec($b);
1055         }
1056
1057         return "($a) or ($b)";
1058 } #}}}
1059
1060 sub pagespec_translate ($) { #{{{
1061         # This assumes that $page is in scope in the function
1062         # that evalulates the translated pagespec code.
1063         my $spec=shift;
1064
1065         # Support for old-style GlobLists.
1066         if (is_globlist($spec)) {
1067                 $spec=globlist_to_pagespec($spec);
1068         }
1069
1070         # Convert spec to perl code.
1071         my $code="";
1072         while ($spec=~m{
1073                 \s*             # ignore whitespace
1074                 (               # 1: match a single word
1075                         \!              # !
1076                 |
1077                         \(              # (
1078                 |
1079                         \)              # )
1080                 |
1081                         \w+\([^\)]*\)   # command(params)
1082                 |
1083                         [^\s()]+        # any other text
1084                 )
1085                 \s*             # ignore whitespace
1086         }igx) {
1087                 my $word=$1;
1088                 if (lc $word eq 'and') {
1089                         $code.=' &&';
1090                 }
1091                 elsif (lc $word eq 'or') {
1092                         $code.=' ||';
1093                 }
1094                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1095                         $code.=' '.$word;
1096                 }
1097                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1098                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1099                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1100                         }
1101                         else {
1102                                 $code.=' 0';
1103                         }
1104                 }
1105                 else {
1106                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1107                 }
1108         }
1109
1110         return $code;
1111 } #}}}
1112
1113 sub pagespec_match ($$;@) { #{{{
1114         my $page=shift;
1115         my $spec=shift;
1116         my @params=@_;
1117
1118         # Backwards compatability with old calling convention.
1119         if (@params == 1) {
1120                 unshift @params, 'location';
1121         }
1122
1123         my $ret=eval pagespec_translate($spec);
1124         return IkiWiki::FailReason->new('syntax error') if $@;
1125         return $ret;
1126 } #}}}
1127
1128 package IkiWiki::FailReason;
1129
1130 use overload ( #{{{
1131         '""'    => sub { ${$_[0]} },
1132         '0+'    => sub { 0 },
1133         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1134         fallback => 1,
1135 ); #}}}
1136
1137 sub new { #{{{
1138         return bless \$_[1], $_[0];
1139 } #}}}
1140
1141 package IkiWiki::SuccessReason;
1142
1143 use overload ( #{{{
1144         '""'    => sub { ${$_[0]} },
1145         '0+'    => sub { 1 },
1146         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1147         fallback => 1,
1148 ); #}}}
1149
1150 sub new { #{{{
1151         return bless \$_[1], $_[0];
1152 }; #}}}
1153
1154 package IkiWiki::PageSpec;
1155
1156 sub match_glob ($$;@) { #{{{
1157         my $page=shift;
1158         my $glob=shift;
1159         my %params=@_;
1160
1161         my $from=exists $params{location} ? $params{location} : '';
1162
1163         # relative matching
1164         if ($glob =~ m!^\./!) {
1165                 $from=~s#/?[^/]+$##;
1166                 $glob=~s#^\./##;
1167                 $glob="$from/$glob" if length $from;
1168         }
1169
1170         # turn glob into safe regexp
1171         $glob=quotemeta($glob);
1172         $glob=~s/\\\*/.*/g;
1173         $glob=~s/\\\?/./g;
1174
1175         if ($page=~/^$glob$/i) {
1176                 return IkiWiki::SuccessReason->new("$glob matches $page");
1177         }
1178         else {
1179                 return IkiWiki::FailReason->new("$glob does not match $page");
1180         }
1181 } #}}}
1182
1183 sub match_link ($$;@) { #{{{
1184         my $page=shift;
1185         my $link=lc(shift);
1186         my %params=@_;
1187
1188         my $from=exists $params{location} ? $params{location} : '';
1189
1190         # relative matching
1191         if ($link =~ m!^\.! && defined $from) {
1192                 $from=~s#/?[^/]+$##;
1193                 $link=~s#^\./##;
1194                 $link="$from/$link" if length $from;
1195         }
1196
1197         my $links = $IkiWiki::links{$page};
1198         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1199         my $bestlink = IkiWiki::bestlink($from, $link);
1200         foreach my $p (@{$links}) {
1201                 if (length $bestlink) {
1202                         return IkiWiki::SuccessReason->new("$page links to $link")
1203                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1204                 }
1205                 else {
1206                         return IkiWiki::SuccessReason->new("$page links to page matching $link")
1207                                 if match_glob($p, $link, %params);
1208                 }
1209         }
1210         return IkiWiki::FailReason->new("$page does not link to $link");
1211 } #}}}
1212
1213 sub match_backlink ($$;@) { #{{{
1214         return match_link($_[1], $_[0], @_);
1215 } #}}}
1216
1217 sub match_created_before ($$;@) { #{{{
1218         my $page=shift;
1219         my $testpage=shift;
1220
1221         if (exists $IkiWiki::pagectime{$testpage}) {
1222                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1223                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1224                 }
1225                 else {
1226                         return IkiWiki::FailReason->new("$page not created before $testpage");
1227                 }
1228         }
1229         else {
1230                 return IkiWiki::FailReason->new("$testpage has no ctime");
1231         }
1232 } #}}}
1233
1234 sub match_created_after ($$;@) { #{{{
1235         my $page=shift;
1236         my $testpage=shift;
1237
1238         if (exists $IkiWiki::pagectime{$testpage}) {
1239                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1240                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1241                 }
1242                 else {
1243                         return IkiWiki::FailReason->new("$page not created after $testpage");
1244                 }
1245         }
1246         else {
1247                 return IkiWiki::FailReason->new("$testpage has no ctime");
1248         }
1249 } #}}}
1250
1251 sub match_creation_day ($$;@) { #{{{
1252         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1253                 return IkiWiki::SuccessReason->new('creation_day matched');
1254         }
1255         else {
1256                 return IkiWiki::FailReason->new('creation_day did not match');
1257         }
1258 } #}}}
1259
1260 sub match_creation_month ($$;@) { #{{{
1261         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1262                 return IkiWiki::SuccessReason->new('creation_month matched');
1263         }
1264         else {
1265                 return IkiWiki::FailReason->new('creation_month did not match');
1266         }
1267 } #}}}
1268
1269 sub match_creation_year ($$;@) { #{{{
1270         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1271                 return IkiWiki::SuccessReason->new('creation_year matched');
1272         }
1273         else {
1274                 return IkiWiki::FailReason->new('creation_year did not match');
1275         }
1276 } #}}}
1277
1278 sub match_user ($$;@) { #{{{
1279         shift;
1280         my $user=shift;
1281         my %params=@_;
1282
1283         return IkiWiki::FailReason->new('cannot match user')
1284                 unless exists $params{user};
1285         if ($user eq $params{user}) {
1286                 return IkiWiki::SuccessReason->new("user is $user")
1287         }
1288         else {
1289                 return IkiWiki::FailReason->new("user is not $user");
1290         }
1291 } #}}}
1292
1293 1