IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub redirect ($$) { #{{{
  25         my $q=shift;
  26         my $url=shift;
  27         if (! $config{w3mmode}) {
  28                 print $q->redirect($url);
  29         }
  30         else {
  31                 print "Content-type: text/plain\n";
  32                 print "W3m-control: GOTO $url\n\n";
  33         }
  34 } #}}}
  35
  36 sub check_canedit ($$$;$) { #{{{
  37         my $page=shift;
  38         my $q=shift;
  39         my $session=shift;
  40         my $nonfatal=shift;
  41
  42         my $canedit;
  43         run_hooks(canedit => sub {
  44                 return if defined $canedit;
  45                 my $ret=shift->($page, $q, $session);
  46                 if (defined $ret && $ret eq "") {
  47                         $canedit=1;
  48                 }
  49                 elsif (defined $ret) {
  50                         $canedit=0;
  51                         error($ret) unless $nonfatal;
  52                 }
  53         });
  54         return $canedit;
  55 } #}}}
  56
  57 sub decode_form_utf8 ($) { #{{{
  58         my $form = shift;
  59         foreach my $f ($form->field) {
  60                 next if Encode::is_utf8(scalar $form->field($f));
  61                 $form->field(name  => $f,
  62                              value => decode_utf8($form->field($f)),
  63                              force => 1,
  64                             );
  65         }
  66 } #}}}
  67
  68 sub cgi_recentchanges ($) { #{{{
  69         my $q=shift;
  70
  71         # Optimisation: building recentchanges means calculating lots of
  72         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  73         # during page builds as the return values may change, but they
  74         # won't here.)
  75         eval q{use Memoize};
  76         error($@) if $@;
  77         memoize("htmllink");
  78
  79         eval q{use Time::Duration};
  80         error($@) if $@;
  81
  82         my $changelog=[rcs_recentchanges(100)];
  83         foreach my $change (@$changelog) {
  84                 $change->{when} = concise(ago($change->{when}));
  85
  86                 $change->{user} = userlink($change->{user});
  87
  88                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
  89                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
  90                 $change->{pages} = [
  91                         map {
  92                                 $_->{link} = htmllink("", "", $_->{page},
  93                                         noimageinline => 1,
  94                                         linktext => pagetitle($_->{page}));
  95                                 $_;
  96                         } @{$change->{pages}}
  97                 ];
  98                 push @{$change->{pages}}, { link => '...' } if $is_excess;
  99         }
 100
 101         my $template=template("recentchanges.tmpl");
 102         $template->param(
 103                 title => "RecentChanges",
 104                 indexlink => indexlink(),
 105                 wikiname => $config{wikiname},
 106                 changelog => $changelog,
 107                 baseurl => baseurl(),
 108         );
 109         run_hooks(pagetemplate => sub {
 110                 shift->(page => "", destpage => "", template => $template);
 111         });
 112         print $q->header(-charset => 'utf-8'), $template->output;
 113 } #}}}
 114
 115 # Check if the user is signed in. If not, redirect to the signin form and
 116 # save their place to return to later.
 117 sub needsignin ($$) { #{{{
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if (! defined $session->param("name") ||
 122             ! userinfo_get($session->param("name"), "regdate")) {
 123                 if (! defined $session->param("postsignin")) {
 124                         $session->param(postsignin => $ENV{QUERY_STRING});
 125                 }
 126                 cgi_signin($q, $session);
 127                 cgi_savesession($session);
 128                 exit;
 129         }
 130 } #}}}
 131
 132 sub cgi_signin ($$) { #{{{
 133         my $q=shift;
 134         my $session=shift;
 135
 136         eval q{use CGI::FormBuilder};
 137         error($@) if $@;
 138         my $form = CGI::FormBuilder->new(
 139                 title => "signin",
 140                 name => "signin",
 141                 header => 1,
 142                 charset => "utf-8",
 143                 method => 'POST',
 144                 required => 'NONE',
 145                 javascript => 0,
 146                 params => $q,
 147                 action => $config{cgiurl},
 148                 header => 0,
 149                 template => {type => 'div'},
 150                 stylesheet => baseurl()."style.css",
 151         );
 152         my $buttons=["Login"];
 153
 154         if ($q->param("do") ne "signin" && !$form->submitted) {
 155                 $form->text(gettext("You need to log in first."));
 156         }
 157         $form->field(name => "do", type => "hidden", value => "signin",
 158                 force => 1);
 159
 160         run_hooks(formbuilder_setup => sub {
 161                 shift->(form => $form, cgi => $q, session => $session);
 162         });
 163
 164         decode_form_utf8($form);
 165
 166         if (exists $hooks{formbuilder}) {
 167                 run_hooks(formbuilder => sub {
 168                         shift->(form => $form, cgi => $q, session => $session,
 169                                 buttons => $buttons);
 170                 });
 171         }
 172         else {
 173                 if ($form->submitted) {
 174                         $form->validate;
 175                 }
 176                 printheader($session);
 177                 print misctemplate($form->title, $form->render(submit => $buttons));
 178         }
 179 } #}}}
 180
 181 sub cgi_postsignin ($$) { #{{{
 182         my $q=shift;
 183         my $session=shift;
 184
 185         # Continue with whatever was being done before the signin process.
 186         if (defined $session->param("postsignin")) {
 187                 my $postsignin=CGI->new($session->param("postsignin"));
 188                 $session->clear("postsignin");
 189                 cgi($postsignin, $session);
 190                 cgi_savesession($session);
 191                 exit;
 192         }
 193         else {
 194                 # This can occur, for example, if a user went to the signin
 195                 # url via a bookmark.
 196                 redirect($q, $config{url});
 197         }
 198 } #}}}
 199
 200 sub cgi_prefs ($$) { #{{{
 201         my $q=shift;
 202         my $session=shift;
 203
 204         needsignin($q, $session);
 205
 206         eval q{use CGI::FormBuilder};
 207         error($@) if $@;
 208         my $form = CGI::FormBuilder->new(
 209                 title => "preferences",
 210                 name => "preferences",
 211                 header => 0,
 212                 charset => "utf-8",
 213                 method => 'POST',
 214                 validate => {
 215                         email => 'EMAIL',
 216                 },
 217                 required => 'NONE',
 218                 javascript => 0,
 219                 params => $q,
 220                 action => $config{cgiurl},
 221                 template => {type => 'div'},
 222                 stylesheet => baseurl()."style.css",
 223                 fieldsets => [
 224                         [login => gettext("Login")],
 225                         [preferences => gettext("Preferences")],
 226                         [admin => gettext("Admin")]
 227                 ],
 228         );
 229         my $buttons=["Save Preferences", "Logout", "Cancel"];
 230
 231         run_hooks(formbuilder_setup => sub {
 232                 shift->(form => $form, cgi => $q, session => $session);
 233         });
 234
 235         $form->field(name => "do", type => "hidden");
 236         $form->field(name => "email", size => 50, fieldset => "preferences");
 237         $form->field(name => "subscriptions", size => 50,
 238                 fieldset => "preferences",
 239                 comment => "(".htmllink("", "", "PageSpec", noimageinline => 1).")");
 240         $form->field(name => "banned_users", size => 50,
 241                 fieldset => "admin");
 242
 243         my $user_name=$session->param("name");
 244         if (! is_admin($user_name)) {
 245                 $form->field(name => "banned_users", type => "hidden");
 246         }
 247
 248         if (! $form->submitted) {
 249                 $form->field(name => "email", force => 1,
 250                         value => userinfo_get($user_name, "email"));
 251                 $form->field(name => "subscriptions", force => 1,
 252                         value => userinfo_get($user_name, "subscriptions"));
 253                 if (is_admin($user_name)) {
 254                         $form->field(name => "banned_users", force => 1,
 255                                 value => join(" ", get_banned_users()));
 256                 }
 257         }
 258
 259         decode_form_utf8($form);
 260
 261         if ($form->submitted eq 'Logout') {
 262                 $session->delete();
 263                 redirect($q, $config{url});
 264                 return;
 265         }
 266         elsif ($form->submitted eq 'Cancel') {
 267                 redirect($q, $config{url});
 268                 return;
 269         }
 270         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 271                 foreach my $field (qw(email subscriptions)) {
 272                         if (defined $form->field($field) && length $form->field($field)) {
 273                                 userinfo_set($user_name, $field, $form->field($field)) ||
 274                                         error("failed to set $field");
 275                         }
 276                 }
 277                 if (is_admin($user_name)) {
 278                         set_banned_users(grep { ! is_admin($_) }
 279                                         split(' ',
 280                                                 $form->field("banned_users"))) ||
 281                                 error("failed saving changes");
 282                 }
 283                 $form->text(gettext("Preferences saved."));
 284         }
 285
 286         if (exists $hooks{formbuilder}) {
 287                 run_hooks(formbuilder => sub {
 288                         shift->(form => $form, cgi => $q, session => $session,
 289                                 buttons => $buttons);
 290                 });
 291         }
 292         else {
 293                 printheader($session);
 294                 print misctemplate($form->title, $form->render(submit => $buttons));
 295         }
 296 } #}}}
 297
 298 sub cgi_editpage ($$) { #{{{
 299         my $q=shift;
 300         my $session=shift;
 301
 302         my @fields=qw(do rcsinfo subpage from page type editcontent comments);
 303         my @buttons=("Save Page", "Preview", "Cancel");
 304
 305         eval q{use CGI::FormBuilder};
 306         error($@) if $@;
 307         my $form = CGI::FormBuilder->new(
 308                 fields => \@fields,
 309                 header => 1,
 310                 charset => "utf-8",
 311                 method => 'POST',
 312                 validate => {
 313                         editcontent => '/.+/',
 314                 },
 315                 required => [qw{editcontent}],
 316                 javascript => 0,
 317                 params => $q,
 318                 action => $config{cgiurl},
 319                 table => 0,
 320                 template => scalar template_params("editpage.tmpl"),
 321                 wikiname => $config{wikiname},
 322         );
 323
 324         run_hooks(formbuilder_setup => sub {
 325                 shift->(form => $form, cgi => $q, session => $session);
 326         });
 327
 328         decode_form_utf8($form);
 329
 330         # This untaint is safe because titlepage removes any problematic
 331         # characters.
 332         my ($page)=$form->field('page');
 333         $page=titlepage(possibly_foolish_untaint($page));
 334         if (! defined $page || ! length $page || file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 335                 error("bad page name");
 336         }
 337
 338         my $from;
 339         if (defined $form->field('from')) {
 340                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 341         }
 342
 343         my $file;
 344         my $type;
 345         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 346                 $file=$pagesources{$page};
 347                 $type=pagetype($file);
 348                 if (! defined $type) {
 349                         error(sprintf(gettext("%s is not an editable page"), $page));
 350                 }
 351                 if (! $form->submitted) {
 352                         $form->field(name => "rcsinfo",
 353                                 value => rcs_prepedit($file), force => 1);
 354                 }
 355         }
 356         else {
 357                 $type=$form->param('type');
 358                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 359                         $type=possibly_foolish_untaint($type);
 360                 }
 361                 elsif (defined $from) {
 362                         # favor the type of linking page
 363                         $type=pagetype($pagesources{$from});
 364                 }
 365                 $type=$config{default_pageext} unless defined $type;
 366                 $file=$page.".".$type;
 367                 if (! $form->submitted) {
 368                         $form->field(name => "rcsinfo", value => "", force => 1);
 369                 }
 370         }
 371
 372         $form->field(name => "do", type => 'hidden');
 373         $form->field(name => "from", type => 'hidden');
 374         $form->field(name => "rcsinfo", type => 'hidden');
 375         $form->field(name => "subpage", type => 'hidden');
 376         $form->field(name => "page", value => pagetitle($page, 1), force => 1);
 377         $form->field(name => "type", value => $type, force => 1);
 378         $form->field(name => "comments", type => "text", size => 80);
 379         $form->field(name => "editcontent", type => "textarea", rows => 20,
 380                 cols => 80);
 381         $form->tmpl_param("can_commit", $config{rcs});
 382         $form->tmpl_param("indexlink", indexlink());
 383         $form->tmpl_param("helponformattinglink",
 384                 htmllink("", "", "HelpOnFormatting", noimageinline => 1));
 385         $form->tmpl_param("baseurl", baseurl());
 386
 387         if ($form->submitted eq "Cancel") {
 388                 if ($form->field("do") eq "create" && defined $from) {
 389                         redirect($q, "$config{url}/".htmlpage($from));
 390                 }
 391                 elsif ($form->field("do") eq "create") {
 392                         redirect($q, $config{url});
 393                 }
 394                 else {
 395                         redirect($q, "$config{url}/".htmlpage($page));
 396                 }
 397                 return;
 398         }
 399         elsif ($form->submitted eq "Preview") {
 400                 $form->tmpl_param("page_preview",
 401                         htmlize($page, $type,
 402                         linkify($page, "",
 403                         preprocess($page, $page,
 404                         filter($page, $form->field('editcontent')), 0, 1))));
 405         }
 406         else {
 407                 $form->tmpl_param("page_preview", "");
 408         }
 409         $form->tmpl_param("page_conflict", "");
 410
 411         if (! $form->submitted || $form->submitted eq "Preview" ||
 412             ! $form->validate) {
 413                 if ($form->field("do") eq "create") {
 414                         my @page_locs;
 415                         my $best_loc;
 416                         if (! defined $from || ! length $from ||
 417                             $from ne $form->field('from') ||
 418                             file_pruned($from, $config{srcdir}) ||
 419                             $from=~/^\// ||
 420                             $form->submitted eq "Preview") {
 421                                 @page_locs=$best_loc=$page;
 422                         }
 423                         else {
 424                                 my $dir=$from."/";
 425                                 $dir=~s![^/]+/+$!!;
 426
 427                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 428                                     $page eq gettext('discussion')) {
 429                                         $best_loc="$from/$page";
 430                                 }
 431                                 else {
 432                                         $best_loc=$dir.$page;
 433                                 }
 434
 435                                 push @page_locs, $dir.$page;
 436                                 push @page_locs, "$from/$page";
 437                                 while (length $dir) {
 438                                         $dir=~s![^/]+/+$!!;
 439                                         push @page_locs, $dir.$page;
 440                                 }
 441                         }
 442                         push @page_locs, "$config{userdir}/$page"
 443                                 if length $config{userdir};
 444
 445                         @page_locs = grep {
 446                                 ! exists $pagecase{lc $_}
 447                         } @page_locs;
 448                         if (! @page_locs) {
 449                                 # hmm, someone else made the page in the
 450                                 # meantime?
 451                                 redirect($q, "$config{url}/".htmlpage($page));
 452                                 return;
 453                         }
 454
 455                         my @editable_locs = grep {
 456                                 check_canedit($_, $q, $session, 1)
 457                         } @page_locs;
 458                         if (! @editable_locs) {
 459                                 # let it throw an error this time
 460                                 map { check_canedit($_, $q, $session) } @page_locs;
 461                         }
 462
 463                         my @page_types;
 464                         if (exists $hooks{htmlize}) {
 465                                 @page_types=keys %{$hooks{htmlize}};
 466                         }
 467
 468                         $form->tmpl_param("page_select", 1);
 469                         $form->field(name => "page", type => 'select',
 470                                 options => [ map { pagetitle($_, 1) } @editable_locs ],
 471                                 value => pagetitle($best_loc, 1));
 472                         $form->field(name => "type", type => 'select',
 473                                 options => \@page_types);
 474                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 475                 }
 476                 elsif ($form->field("do") eq "edit") {
 477                         check_canedit($page, $q, $session);
 478                         if (! defined $form->field('editcontent') ||
 479                             ! length $form->field('editcontent')) {
 480                                 my $content="";
 481                                 if (exists $pagesources{$page}) {
 482                                         $content=readfile(srcfile($pagesources{$page}));
 483                                         $content=~s/\n/\r\n/g;
 484                                 }
 485                                 $form->field(name => "editcontent", value => $content,
 486                                         force => 1);
 487                         }
 488                         $form->tmpl_param("page_select", 0);
 489                         $form->field(name => "page", type => 'hidden');
 490                         $form->field(name => "type", type => 'hidden');
 491                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 492                 }
 493
 494                 print $form->render(submit => \@buttons);
 495         }
 496         else {
 497                 # save page
 498                 check_canedit($page, $q, $session);
 499                 if (! -e "$config{srcdir}/$file" &&
 500                     $form->field("do") ne "create") {
 501                         $form->tmpl_param("page_gone", 1);
 502                         $form->field(name => "do", value => "create", force => 1);
 503                         $form->tmpl_param("page_select", 0);
 504                         $form->field(name => "page", type => 'hidden');
 505                         $form->field(name => "type", type => 'hidden');
 506                         $form->title(sprintf(gettext("editing %s"), $page));
 507                         print $form->render(submit => \@buttons);
 508                         return;
 509                 }
 510                 elsif (-e "$config{srcdir}/$file" &&
 511                        $form->field("do") eq "create") {
 512                         $form->tmpl_param("creation_conflict", 1);
 513                         $form->field(name => "do", value => "edit", force => 1);
 514                         $form->tmpl_param("page_select", 0);
 515                         $form->field(name => "page", type => 'hidden');
 516                         $form->field(name => "type", type => 'hidden');
 517                         $form->title(sprintf(gettext("editing %s"), $page));
 518                         $form->field("editcontent",
 519                                 value => readfile("$config{srcdir}/$file").
 520                                          "\n\n\n".$form->field("editcontent"),
 521                                 force => 1);
 522                         print $form->render(submit => \@buttons);
 523                         return;
 524                 }
 525
 526                 my $content=$form->field('editcontent');
 527
 528                 $content=~s/\r\n/\n/g;
 529                 $content=~s/\r/\n/g;
 530
 531                 $config{cgi}=0; # avoid cgi error message
 532                 eval { writefile($file, $config{srcdir}, $content) };
 533                 $config{cgi}=1;
 534                 if ($@) {
 535                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 536                                 force => 1);
 537                         $form->tmpl_param("failed_save", 1);
 538                         $form->tmpl_param("error_message", $@);
 539                         $form->field("editcontent", value => $content, force => 1);
 540                         $form->tmpl_param("page_select", 0);
 541                         $form->field(name => "page", type => 'hidden');
 542                         $form->field(name => "type", type => 'hidden');
 543                         $form->title(sprintf(gettext("editing %s"), $page));
 544                         print $form->render(submit => \@buttons);
 545                         return;
 546                 }
 547
 548                 my $conflict;
 549                 if ($config{rcs}) {
 550                         my $message="";
 551                         if (defined $form->field('comments') &&
 552                             length $form->field('comments')) {
 553                                 $message=$form->field('comments');
 554                         }
 555
 556                         if ($form->field("do") eq "create") {
 557                                 rcs_add($file);
 558                         }
 559
 560                         # Prevent deadlock with post-commit hook by
 561                         # signaling to it that it should not try to
 562                         # do anything (except send commit mails).
 563                         disable_commit_hook();
 564                         $conflict=rcs_commit($file, $message,
 565                                 $form->field("rcsinfo"),
 566                                 $session->param("name"), $ENV{REMOTE_ADDR});
 567                         enable_commit_hook();
 568                         rcs_update();
 569                 }
 570
 571                 # Refresh even if there was a conflict, since other changes
 572                 # may have been committed while the post-commit hook was
 573                 # disabled.
 574                 require IkiWiki::Render;
 575                 refresh();
 576                 saveindex();
 577
 578                 if (defined $conflict) {
 579                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 580                                 force => 1);
 581                         $form->tmpl_param("page_conflict", 1);
 582                         $form->field("editcontent", value => $conflict, force => 1);
 583                         $form->field("do", "edit", force => 1);
 584                         $form->tmpl_param("page_select", 0);
 585                         $form->field(name => "page", type => 'hidden');
 586                         $form->field(name => "type", type => 'hidden');
 587                         $form->title(sprintf(gettext("editing %s"), $page));
 588                         print $form->render(submit => \@buttons);
 589                         return;
 590                 }
 591                 else {
 592                         # The trailing question mark tries to avoid broken
 593                         # caches and get the most recent version of the page.
 594                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 595                 }
 596         }
 597 } #}}}
 598
 599 sub cgi_getsession ($) { #{{{
 600         my $q=shift;
 601
 602         eval q{use CGI::Session};
 603         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 604
 605         my $oldmask=umask(077);
 606         my $session = CGI::Session->new("driver:DB_File", $q,
 607                 { FileName => "$config{wikistatedir}/sessions.db" });
 608         umask($oldmask);
 609
 610         return $session;
 611 } #}}}
 612
 613 sub cgi_savesession ($) { #{{{
 614         my $session=shift;
 615
 616         # Force session flush with safe umask.
 617         my $oldmask=umask(077);
 618         $session->flush;
 619         umask($oldmask);
 620 } #}}}
 621
 622 sub cgi (;$$) { #{{{
 623         my $q=shift;
 624         my $session=shift;
 625
 626         if (! $q) {
 627                 eval q{use CGI};
 628                 error($@) if $@;
 629
 630                 $q=CGI->new;
 631
 632                 run_hooks(cgi => sub { shift->($q) });
 633         }
 634
 635         my $do=$q->param('do');
 636         if (! defined $do || ! length $do) {
 637                 my $error = $q->cgi_error;
 638                 if ($error) {
 639                         error("Request not processed: $error");
 640                 }
 641                 else {
 642                         error("\"do\" parameter missing");
 643                 }
 644         }
 645
 646         # Things that do not need a session.
 647         if ($do eq 'recentchanges') {
 648                 cgi_recentchanges($q);
 649                 return;
 650         }
 651         elsif ($do eq 'hyperestraier') {
 652                 cgi_hyperestraier();
 653         }
 654
 655         # Need to lock the wiki before getting a session.
 656         lockwiki();
 657
 658         if (! $session) {
 659                 $session=cgi_getsession($q);
 660         }
 661
 662         # Auth hooks can sign a user in.
 663         if ($do ne 'signin' && ! defined $session->param("name")) {
 664                 run_hooks(auth => sub {
 665                         shift->($q, $session)
 666                 });
 667                 if (defined $session->param("name")) {
 668                         # Make sure whatever user was authed is in the
 669                         # userinfo db.
 670                         if (! userinfo_get($session->param("name"), "regdate")) {
 671                                 userinfo_setall($session->param("name"), {
 672                                         email => "",
 673                                         password => "",
 674                                         regdate => time,
 675                                 }) || error("failed adding user");
 676                         }
 677                 }
 678         }
 679
 680         if (defined $session->param("name") &&
 681             userinfo_get($session->param("name"), "banned")) {
 682                 print $q->header(-status => "403 Forbidden");
 683                 $session->delete();
 684                 print gettext("You are banned.");
 685                 cgi_savesession($session);
 686         }
 687         elsif ($do eq 'signin') {
 688                 cgi_signin($q, $session);
 689                 cgi_savesession($session);
 690         }
 691         elsif (defined $session->param("postsignin")) {
 692                 cgi_postsignin($q, $session);
 693         }
 694         elsif ($do eq 'prefs') {
 695                 cgi_prefs($q, $session);
 696         }
 697         elsif ($do eq 'create' || $do eq 'edit') {
 698                 cgi_editpage($q, $session);
 699         }
 700         elsif ($do eq 'blog') {
 701                 my $page=decode_utf8($q->param('title'));
 702                 $page=~s/\///g; # no slashes in blog posts
 703                 # if the page already exists, munge it to be unique
 704                 my $from=$q->param('from');
 705                 my $add="";
 706                 while (exists $pagecase{lc($from."/".titlepage($page).$add)}) {
 707                         $add=1 unless length $add;
 708                         $add++;
 709                 }
 710                 $q->param('page', $page.$add);
 711                 # now run same as create
 712                 $q->param('do', 'create');
 713                 cgi_editpage($q, $session);
 714         }
 715         elsif ($do eq 'postsignin') {
 716                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 717         }
 718         else {
 719                 error("unknown do parameter");
 720         }
 721 } #}}}
 722
 723 sub userlink ($) { #{{{
 724         my $user=shift;
 725
 726         eval q{use CGI 'escapeHTML'};
 727         error($@) if $@;
 728         if ($user =~ m!^https?://! &&
 729             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
 730                 # Munge user-urls, as used by eg, OpenID.
 731                 my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
 732                 my $display=$oid->display;
 733                 # Convert "user.somehost.com" to "user [somehost.com]".
 734                 if ($display !~ /\[/) {
 735                         $display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
 736                 }
 737                 # Convert "http://somehost.com/user" to "user [somehost.com]".
 738                 if ($display !~ /\[/) {
 739                         $display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
 740                 }
 741                 $display=~s!^https?://!!; # make sure this is removed
 742                 return "<a href=\"$user\">".escapeHTML($display)."</a>";
 743         }
 744         else {
 745                 return htmllink("", "", escapeHTML(
 746                         length $config{userdir} ? $config{userdir}."/".$user : $user
 747                 ), noimageinline => 1);
 748         }
 749 } #}}}
 750
 751 1