IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("istranslatable");
  27 memoize("_istranslation");
  28 memoize("percenttranslated");
  29
  30 sub import {
  31         hook(type => "getsetup", id => "po", call => \&getsetup);
  32         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  33         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  34         hook(type => "scan", id => "po", call => \&scan, last =>1);
  35         hook(type => "filter", id => "po", call => \&filter);
  36         hook(type => "htmlize", id => "po", call => \&htmlize);
  37         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  38         hook(type => "postscan", id => "po", call => \&postscan);
  39         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  40         hook(type => "delete", id => "po", call => \&mydelete);
  41         hook(type => "change", id => "po", call => \&change);
  42         hook(type => "cansave", id => "po", call => \&cansave);
  43         hook(type => "canremove", id => "po", call => \&canremove);
  44         hook(type => "canrename", id => "po", call => \&canrename);
  45         hook(type => "editcontent", id => "po", call => \&editcontent);
  46
  47         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  48         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  49         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  50         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  51         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  52         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  53         $origsubs{'urlto'}=\&IkiWiki::urlto;
  54         inject(name => "IkiWiki::urlto", call => \&myurlto);
  55         $origsubs{'nicepagetitle'}=\&IkiWiki::nicepagetitle;
  56         inject(name => "IkiWiki::nicepagetitle", call => \&mynicepagetitle);
  57 }
  58
  59
  60 # ,----
  61 # | Table of contents
  62 # `----
  63
  64 # 1. Hooks
  65 # 2. Injected functions
  66 # 3. Blackboxes for private data
  67 # 4. Helper functions
  68 # 5. PageSpec's
  69
  70
  71 # ,----
  72 # | Hooks
  73 # `----
  74
  75 sub getsetup () {
  76         return
  77                 plugin => {
  78                         safe => 0,
  79                         rebuild => 1,
  80                 },
  81                 po_master_language => {
  82                         type => "string",
  83                         example => {
  84                                 'code' => 'en',
  85                                 'name' => 'English'
  86                         },
  87                         description => "master language (non-PO files)",
  88                         safe => 1,
  89                         rebuild => 1,
  90                 },
  91                 po_slave_languages => {
  92                         type => "string",
  93                         example => {
  94                                 'fr' => 'Français',
  95                                 'es' => 'Castellano',
  96                                 'de' => 'Deutsch'
  97                         },
  98                         description => "slave languages (PO files)",
  99                         safe => 1,
 100                         rebuild => 1,
 101                 },
 102                 po_translatable_pages => {
 103                         type => "pagespec",
 104                         example => "!*/Discussion",
 105                         description => "PageSpec controlling which pages are translatable",
 106                         link => "ikiwiki/PageSpec",
 107                         safe => 1,
 108                         rebuild => 1,
 109                 },
 110                 po_link_to => {
 111                         type => "string",
 112                         example => "current",
 113                         description => "internal linking behavior (default/current/negotiated)",
 114                         safe => 1,
 115                         rebuild => 1,
 116                 },
 117                 po_translation_status_in_links => {
 118                         type => "boolean",
 119                         example => 1,
 120                         description => "display translation status in links to translations",
 121                         safe => 1,
 122                         rebuild => 1,
 123                 },
 124 }
 125
 126 sub checkconfig () {
 127         foreach my $field (qw{po_master_language po_slave_languages}) {
 128                 if (! exists $config{$field} || ! defined $config{$field}) {
 129                         error(sprintf(gettext("Must specify %s"), $field));
 130                 }
 131         }
 132         if (! (keys %{$config{po_slave_languages}})) {
 133                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 134         }
 135         map {
 136                 islanguagecode($_)
 137                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 138         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 139         if (! exists $config{po_translatable_pages} ||
 140             ! defined $config{po_translatable_pages}) {
 141                 $config{po_translatable_pages}="";
 142         }
 143         if (! exists $config{po_link_to} ||
 144             ! defined $config{po_link_to}) {
 145                 $config{po_link_to}='default';
 146         }
 147         elsif (! grep {
 148                         $config{po_link_to} eq $_
 149                 } ('default', 'current', 'negotiated')) {
 150                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 151                                 $config{po_link_to}));
 152                 $config{po_link_to}='default';
 153         }
 154         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 155                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 156                 $config{po_link_to}='default';
 157         }
 158         if (! exists $config{po_translation_status_in_links} ||
 159             ! defined $config{po_translation_status_in_links}) {
 160                 $config{po_translation_status_in_links}=1;
 161         }
 162         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 163 }
 164
 165 sub needsbuild () {
 166         my $needsbuild=shift;
 167
 168         # backup @needsbuild content so that change() can know whether
 169         # a given master page was rendered because its source file was changed
 170         @origneedsbuild=(@$needsbuild);
 171
 172         flushmemoizecache();
 173         buildtranslationscache();
 174
 175         # make existing translations depend on the corresponding master page
 176         foreach my $master (keys %translations) {
 177                 map add_depends($_, $master), values %{otherlanguages($master)};
 178         }
 179 }
 180
 181 # Massage the recorded state of internal links so that:
 182 # - it matches the actually generated links, rather than the links as written
 183 #   in the pages' source
 184 # - backlinks are consistent in all cases
 185 sub scan (@) {
 186         my %params=@_;
 187         my $page=$params{page};
 188         my $content=$params{content};
 189
 190         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 191
 192         if (istranslation($page)) {
 193                 foreach my $destpage (@{$links{$page}}) {
 194                         if (istranslatable($destpage)) {
 195                                 # replace one occurence of $destpage in $links{$page}
 196                                 # (we only want to replace the one that was added by
 197                                 # IkiWiki::Plugin::link::scan, other occurences may be
 198                                 # there for other reasons)
 199                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 200                                         if (@{$links{$page}}[$i] eq $destpage) {
 201                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 202                                                 last;
 203                                         }
 204                                 }
 205                         }
 206                 }
 207         }
 208         elsif (! istranslatable($page) && ! istranslation($page)) {
 209                 foreach my $destpage (@{$links{$page}}) {
 210                         if (istranslatable($destpage)) {
 211                                 # make sure any destpage's translations has
 212                                 # $page in its backlinks
 213                                 push @{$links{$page}},
 214                                         values %{otherlanguages($destpage)};
 215                         }
 216                 }
 217         }
 218 }
 219
 220 # We use filter to convert PO to the master page's format,
 221 # since the rest of ikiwiki should not work on PO files.
 222 sub filter (@) {
 223         my %params = @_;
 224
 225         my $page = $params{page};
 226         my $destpage = $params{destpage};
 227         my $content = $params{content};
 228         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 229                 $content = po_to_markup($page, $content);
 230                 setalreadyfiltered($page, $destpage);
 231         }
 232         return $content;
 233 }
 234
 235 sub htmlize (@) {
 236         my %params=@_;
 237
 238         my $page = $params{page};
 239         my $content = $params{content};
 240
 241         # ignore PO files this plugin did not create
 242         return $content unless istranslation($page);
 243
 244         # force content to be htmlize'd as if it was the same type as the master page
 245         return IkiWiki::htmlize($page, $page,
 246                                 pagetype(srcfile($pagesources{masterpage($page)})),
 247                                 $content);
 248 }
 249
 250 sub pagetemplate (@) {
 251         my %params=@_;
 252         my $page=$params{page};
 253         my $destpage=$params{destpage};
 254         my $template=$params{template};
 255
 256         my ($masterpage, $lang) = istranslation($page);
 257
 258         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 259                 $template->param(percenttranslated => percenttranslated($page));
 260         }
 261         if ($template->query(name => "istranslation")) {
 262                 $template->param(istranslation => scalar istranslation($page));
 263         }
 264         if ($template->query(name => "istranslatable")) {
 265                 $template->param(istranslatable => istranslatable($page));
 266         }
 267         if ($template->query(name => "HOMEPAGEURL")) {
 268                 $template->param(homepageurl => homepageurl($page));
 269         }
 270         if ($template->query(name => "otherlanguages")) {
 271                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 272                 map add_depends($page, $_), (values %{otherlanguages($page)});
 273         }
 274         # Rely on IkiWiki::Render's genpage() to decide wether
 275         # a discussion link should appear on $page; this is not
 276         # totally accurate, though: some broken links may be generated
 277         # when cgiurl is disabled.
 278         # This compromise avoids some code duplication, and will probably
 279         # prevent future breakage when ikiwiki internals change.
 280         # Known limitations are preferred to future random bugs.
 281         if ($template->param('discussionlink') && istranslation($page)) {
 282                 $template->param('discussionlink' => htmllink(
 283                                                         $page,
 284                                                         $destpage,
 285                                                         $masterpage . '/' . gettext("Discussion"),
 286                                                         noimageinline => 1,
 287                                                         forcesubpage => 0,
 288                                                         linktext => gettext("Discussion"),
 289                                                         ));
 290         }
 291         # Remove broken parentlink to ./index.html on home page's translations.
 292         # It works because this hook has the "last" parameter set, to ensure it
 293         # runs after parentlinks' own pagetemplate hook.
 294         if ($template->param('parentlinks')
 295             && istranslation($page)
 296             && $masterpage eq "index") {
 297                 $template->param('parentlinks' => []);
 298         }
 299 } # }}}
 300
 301 sub postscan (@) {
 302         my %params = @_;
 303         my $page = $params{page};
 304
 305         # backlinks involve back-dependencies, so that nicepagetitle effects,
 306         # such as translation status displayed in links, are updated
 307         use IkiWiki::Render;
 308         map add_depends($page, $_), keys %{$IkiWiki::backlinks{$page}};
 309 }
 310
 311 # Add the renamed page translations to the list of to-be-renamed pages.
 312 sub renamepages($$$) {
 313         my ($torename, $cgi, $session) = (shift, shift, shift);
 314
 315         # copy the initial array, so that we can iterate on it AND
 316         # modify it at the same time, without iterating on the items we
 317         # pushed on it ourselves
 318         my @torename=@{$torename};
 319
 320         # Save the page(s) the user asked to rename, so that our
 321         # canrename hook can tell the difference between:
 322         #  - a translation being renamed as a consequence of its master page
 323         #    being renamed
 324         #  - a user trying to directly rename a translation
 325         # This is why this hook has to be run first, before @torename is modified
 326         # by other plugins.
 327         $session->param(po_orig_torename => [ @torename ]);
 328         IkiWiki::cgi_savesession($session);
 329
 330         foreach my $rename (@torename) {
 331                 next unless istranslatable($rename->{src});
 332                 my %otherpages=%{otherlanguages($rename->{src})};
 333                 while (my ($lang, $otherpage) = each %otherpages) {
 334                         push @{$torename}, {
 335                                 src => $otherpage,
 336                                 srcfile => $pagesources{$otherpage},
 337                                 dest => otherlanguage($rename->{dest}, $lang),
 338                                 destfile => $rename->{dest}.".".$lang.".po",
 339                                 required => 0,
 340                         };
 341                 }
 342         }
 343 }
 344
 345 sub mydelete(@) {
 346         my @deleted=@_;
 347
 348         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 349 }
 350
 351 sub change(@) {
 352         my @rendered=@_;
 353
 354         my $updated_po_files=0;
 355
 356         # Refresh/create POT and PO files as needed.
 357         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 358                 my $page=pagename($file);
 359                 my $masterfile=srcfile($file);
 360                 my $updated_pot_file=0;
 361                 # Only refresh Pot file if it does not exist, or if
 362                 # $pagesources{$page} was changed: don't if only the HTML was
 363                 # refreshed, e.g. because of a dependency.
 364                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 365                     || ! -e potfile($masterfile)) {
 366                         refreshpot($masterfile);
 367                         $updated_pot_file=1;
 368                 }
 369                 my @pofiles;
 370                 map {
 371                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 372                 } (pofiles($masterfile));
 373                 if (@pofiles) {
 374                         refreshpofiles($masterfile, @pofiles);
 375                         map { IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 376                         $updated_po_files=1;
 377                 }
 378         }
 379
 380         if ($updated_po_files) {
 381                 commit_and_refresh(
 382                         gettext("updated PO files"),
 383                         "IkiWiki::Plugin::po::change");
 384         }
 385 }
 386
 387 sub cansave ($$$$) {
 388         my ($page, $content, $cgi, $session) = (shift, shift, shift, shift);
 389
 390         debug("po plugin running in cansave")
 391 }
 392
 393 sub canremove ($$$) {
 394         my ($page, $cgi, $session) = (shift, shift, shift);
 395
 396         if (istranslation($page)) {
 397                 return gettext("Can not remove a translation. Removing the master page, ".
 398                                "though, removes its translations as well.");
 399         }
 400         return undef;
 401 }
 402
 403 sub canrename ($$@) {
 404         my ($cgi, $session) = (shift, shift);
 405         my %params = @_;
 406
 407         if (istranslation($params{src})) {
 408                 my $masterpage = masterpage($params{src});
 409                 # Tell the difference between:
 410                 #  - a translation being renamed as a consequence of its master page
 411                 #    being renamed, which is allowed
 412                 #  - a user trying to directly rename a translation, which is forbidden
 413                 # by looking for the master page in the list of to-be-renamed pages we
 414                 # saved early in the renaming process.
 415                 my $orig_torename = $session->param("po_orig_torename");
 416                 unless (scalar grep { $_->{src} eq $masterpage } @{$orig_torename}) {
 417                         return gettext("Can not rename a translation. Renaming the master page, ".
 418                                        "though, renames its translations as well.");
 419                 }
 420         }
 421         return undef;
 422 }
 423
 424 # As we're previewing or saving a page, the content may have
 425 # changed, so tell the next filter() invocation it must not be lazy.
 426 sub editcontent () {
 427         my %params=@_;
 428
 429         unsetalreadyfiltered($params{page}, $params{page});
 430         return $params{content};
 431 }
 432
 433
 434 # ,----
 435 # | Injected functions
 436 # `----
 437
 438 # Implement po_link_to 'current' and 'negotiated' settings.
 439 sub mybestlink ($$) {
 440         my $page=shift;
 441         my $link=shift;
 442
 443         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 444         if (length $res
 445             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 446             && istranslatable($res)
 447             && istranslation($page)) {
 448                 return $res . "." . lang($page);
 449         }
 450         return $res;
 451 }
 452
 453 sub mybeautify_urlpath ($) {
 454         my $url=shift;
 455
 456         my $res=$origsubs{'beautify_urlpath'}->($url);
 457         if ($config{po_link_to} eq "negotiated") {
 458                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 459                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 460                 map {
 461                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 462                 } (keys %{$config{po_slave_languages}});
 463         }
 464         return $res;
 465 }
 466
 467 sub mytargetpage ($$) {
 468         my $page=shift;
 469         my $ext=shift;
 470
 471         if (istranslation($page) || istranslatable($page)) {
 472                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 473                 if (! $config{usedirs} || $masterpage eq 'index') {
 474                         return $masterpage . "." . $lang . "." . $ext;
 475                 }
 476                 else {
 477                         return $masterpage . "/index." . $lang . "." . $ext;
 478                 }
 479         }
 480         return $origsubs{'targetpage'}->($page, $ext);
 481 }
 482
 483 sub myurlto ($$;$) {
 484         my $to=shift;
 485         my $from=shift;
 486         my $absolute=shift;
 487
 488         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 489         if (! length $to
 490             && $config{po_link_to} eq "current"
 491             && istranslatable('index')) {
 492                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 493         }
 494         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 495         # so that one is redirected to the just-edited page rather than to the
 496         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 497         # we only do so when our beautify_urlpath would actually do what we want to
 498         # avoid, i.e. when po_link_to = negotiated
 499         if ($config{po_link_to} eq "negotiated") {
 500                 my @caller = caller(1);
 501                 my $run_by_editpage = 0;
 502                 $run_by_editpage = 1 if (exists $caller[3] && defined $caller[3]
 503                                          && $caller[3] eq "IkiWiki::cgi_editpage");
 504                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 505                         if $run_by_editpage;
 506                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 507                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 508                         if $run_by_editpage;
 509                 return $res;
 510         }
 511         else {
 512                 return $origsubs{'urlto'}->($to,$from,$absolute)
 513         }
 514 }
 515
 516 sub mynicepagetitle ($;$) {
 517         my ($page, $unescaped) = (shift, shift);
 518
 519         my $res = $origsubs{'nicepagetitle'}->($page, $unescaped);
 520         return $res unless istranslation($page);
 521         return $res unless $config{po_translation_status_in_links};
 522         return $res.' ('.percenttranslated($page).' %)';
 523 }
 524
 525 # ,----
 526 # | Blackboxes for private data
 527 # `----
 528
 529 {
 530         my %filtered;
 531
 532         sub alreadyfiltered($$) {
 533                 my $page=shift;
 534                 my $destpage=shift;
 535
 536                 return ( exists $filtered{$page}{$destpage}
 537                          && $filtered{$page}{$destpage} eq 1 );
 538         }
 539
 540         sub setalreadyfiltered($$) {
 541                 my $page=shift;
 542                 my $destpage=shift;
 543
 544                 $filtered{$page}{$destpage}=1;
 545         }
 546
 547         sub unsetalreadyfiltered($$) {
 548                 my $page=shift;
 549                 my $destpage=shift;
 550
 551                 if (exists $filtered{$page}{$destpage}) {
 552                         delete $filtered{$page}{$destpage};
 553                 }
 554         }
 555
 556         sub resetalreadyfiltered() {
 557                 undef %filtered;
 558         }
 559 }
 560
 561 # ,----
 562 # | Helper functions
 563 # `----
 564
 565 sub maybe_add_leading_slash ($;$) {
 566         my $str=shift;
 567         my $add=shift;
 568         $add=1 unless defined $add;
 569         return '/' . $str if $add;
 570         return $str;
 571 }
 572
 573 sub istranslatablefile ($) {
 574         my $file=shift;
 575
 576         return 0 unless defined $file;
 577         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 578         return 0 if $file =~ /\.pot$/;
 579         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 580         return;
 581 }
 582
 583 sub istranslatable ($) {
 584         my $page=shift;
 585
 586         $page=~s#^/##;
 587         return 1 if istranslatablefile($pagesources{$page});
 588         return;
 589 }
 590
 591 sub _istranslation ($) {
 592         my $page=shift;
 593
 594         my $hasleadingslash = ($page=~s#^/##);
 595         my $file=$pagesources{$page};
 596         return 0 unless (defined $file
 597                          && defined pagetype($file)
 598                          && pagetype($file) eq 'po');
 599         return 0 if $file =~ /\.pot$/;
 600
 601         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 602         return 0 unless (defined $masterpage && defined $lang
 603                          && length $masterpage && length $lang
 604                          && defined $pagesources{$masterpage}
 605                          && defined $config{po_slave_languages}{$lang});
 606
 607         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 608                 if istranslatable($masterpage);
 609 }
 610
 611 sub istranslation ($) {
 612         my $page=shift;
 613
 614         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 615                 my $hasleadingslash = ($masterpage=~s#^/##);
 616                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 617                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 618         }
 619         return;
 620 }
 621
 622 sub masterpage ($) {
 623         my $page=shift;
 624
 625         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 626                 return $masterpage;
 627         }
 628         return $page;
 629 }
 630
 631 sub lang ($) {
 632         my $page=shift;
 633
 634         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 635                 return $lang;
 636         }
 637         return $config{po_master_language}{code};
 638 }
 639
 640 sub islanguagecode ($) {
 641         my $code=shift;
 642
 643         return ($code =~ /^[a-z]{2}$/);
 644 }
 645
 646 sub otherlanguage ($$) {
 647         my $page=shift;
 648         my $code=shift;
 649
 650         return masterpage($page) if $code eq $config{po_master_language}{code};
 651         return masterpage($page) . '.' . $code;
 652 }
 653
 654 sub otherlanguages ($) {
 655         my $page=shift;
 656
 657         my %ret;
 658         return \%ret unless (istranslation($page) || istranslatable($page));
 659         my $curlang=lang($page);
 660         foreach my $lang
 661                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 662                 next if $lang eq $curlang;
 663                 $ret{$lang}=otherlanguage($page, $lang);
 664         }
 665         return \%ret;
 666 }
 667
 668 sub potfile ($) {
 669         my $masterfile=shift;
 670
 671         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 672         $dir='' if $dir eq './';
 673         return File::Spec->catpath('', $dir, $name . ".pot");
 674 }
 675
 676 sub pofile ($$) {
 677         my $masterfile=shift;
 678         my $lang=shift;
 679
 680         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 681         $dir='' if $dir eq './';
 682         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 683 }
 684
 685 sub pofiles ($) {
 686         my $masterfile=shift;
 687
 688         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 689 }
 690
 691 sub refreshpot ($) {
 692         my $masterfile=shift;
 693
 694         my $potfile=potfile($masterfile);
 695         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 696         my $doc=Locale::Po4a::Chooser::new('text',%options);
 697         $doc->{TT}{utf_mode} = 1;
 698         $doc->{TT}{file_in_charset} = 'utf-8';
 699         $doc->{TT}{file_out_charset} = 'utf-8';
 700         $doc->read($masterfile);
 701         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 702         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 703         # compulsory since this module prevents us from using the porefs option.
 704         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 705         $doc->{TT}{po_out}->set_charset('utf-8');
 706         # do the actual work
 707         $doc->parse;
 708         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 709         $doc->writepo($potfile);
 710 }
 711
 712 sub refreshpofiles ($@) {
 713         my $masterfile=shift;
 714         my @pofiles=@_;
 715
 716         my $potfile=potfile($masterfile);
 717         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 718
 719         foreach my $pofile (@pofiles) {
 720                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 721                 if (-e $pofile) {
 722                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 723                                 or error("[po/refreshpofiles:$pofile] failed to update");
 724                 }
 725                 else {
 726                         File::Copy::syscopy($potfile,$pofile)
 727                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 728                 }
 729         }
 730 }
 731
 732 sub buildtranslationscache() {
 733         # use istranslation's side-effect
 734         map istranslation($_), (keys %pagesources);
 735 }
 736
 737 sub resettranslationscache() {
 738         undef %translations;
 739 }
 740
 741 sub flushmemoizecache() {
 742         Memoize::flush_cache("istranslatable");
 743         Memoize::flush_cache("_istranslation");
 744         Memoize::flush_cache("percenttranslated");
 745 }
 746
 747 sub urlto_with_orig_beautiful_urlpath($$) {
 748         my $to=shift;
 749         my $from=shift;
 750
 751         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 752         my $res=urlto($to, $from);
 753         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 754
 755         return $res;
 756 }
 757
 758 sub percenttranslated ($) {
 759         my $page=shift;
 760
 761         $page=~s/^\///;
 762         return gettext("N/A") unless istranslation($page);
 763         my $file=srcfile($pagesources{$page});
 764         my $masterfile = srcfile($pagesources{masterpage($page)});
 765         my %options = (
 766                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 767         );
 768         my $doc=Locale::Po4a::Chooser::new('text',%options);
 769         $doc->process(
 770                 'po_in_name'    => [ $file ],
 771                 'file_in_name'  => [ $masterfile ],
 772                 'file_in_charset'  => 'utf-8',
 773                 'file_out_charset' => 'utf-8',
 774         ) or error("[po/percenttranslated:$page]: failed to translate");
 775         my ($percent,$hit,$queries) = $doc->stats();
 776         return $percent;
 777 }
 778
 779 sub languagename ($) {
 780         my $code=shift;
 781
 782         return $config{po_master_language}{name}
 783                 if $code eq $config{po_master_language}{code};
 784         return $config{po_slave_languages}{$code}
 785                 if defined $config{po_slave_languages}{$code};
 786         return;
 787 }
 788
 789 sub otherlanguagesloop ($) {
 790         my $page=shift;
 791
 792         my @ret;
 793         my %otherpages=%{otherlanguages($page)};
 794         while (my ($lang, $otherpage) = each %otherpages) {
 795                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 796                         push @ret, {
 797                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 798                                 code => $lang,
 799                                 language => languagename($lang),
 800                                 master => 1,
 801                         };
 802                 }
 803                 else {
 804                         push @ret, {
 805                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 806                                 code => $lang,
 807                                 language => languagename($lang),
 808                                 percent => percenttranslated($otherpage),
 809                         }
 810                 }
 811         }
 812         return sort {
 813                         return -1 if $a->{code} eq $config{po_master_language}{code};
 814                         return 1 if $b->{code} eq $config{po_master_language}{code};
 815                         return $a->{language} cmp $b->{language};
 816                 } @ret;
 817 }
 818
 819 sub homepageurl (;$) {
 820         my $page=shift;
 821
 822         return urlto('', $page);
 823 }
 824
 825 sub deletetranslations ($) {
 826         my $deletedmasterfile=shift;
 827
 828         my $deletedmasterpage=pagename($deletedmasterfile);
 829         my @todelete;
 830         map {
 831                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 832                 my $absfile = "$config{srcdir}/$file";
 833                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 834                         push @todelete, $file;
 835                 }
 836         } keys %{$config{po_slave_languages}};
 837
 838         map {
 839                 if ($config{rcs}) {
 840                         IkiWiki::rcs_remove($_);
 841                 }
 842                 else {
 843                         IkiWiki::prune("$config{srcdir}/$_");
 844                 }
 845         } @todelete;
 846
 847         if (scalar @todelete) {
 848                 commit_and_refresh(
 849                         gettext("removed obsolete PO files"),
 850                         "IkiWiki::Plugin::po::deletetranslations");
 851         }
 852 }
 853
 854 sub commit_and_refresh ($$) {
 855         my ($msg, $author) = (shift, shift);
 856
 857         if ($config{rcs}) {
 858                 IkiWiki::disable_commit_hook();
 859                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
 860                 IkiWiki::enable_commit_hook();
 861                 IkiWiki::rcs_update();
 862         }
 863         # Reinitialize module's private variables.
 864         resetalreadyfiltered();
 865         resettranslationscache();
 866         flushmemoizecache();
 867         # Trigger a wiki refresh.
 868         require IkiWiki::Render;
 869         # without preliminary saveindex/loadindex, refresh()
 870         # complains about a lot of uninitialized variables
 871         IkiWiki::saveindex();
 872         IkiWiki::loadindex();
 873         IkiWiki::refresh();
 874         IkiWiki::saveindex();
 875 }
 876
 877 # on success, returns the filtered content.
 878 # on error, if $nonfatal, warn and return undef; else, error out.
 879 sub po_to_markup ($$;$) {
 880         my ($page, $content) = (shift, shift);
 881         my $nonfatal = shift;
 882
 883         $content = '' unless defined $content;
 884         $content = decode_utf8(encode_utf8($content));
 885         # CRLF line terminators make poor Locale::Po4a feel bad
 886         $content=~s/\r\n/\n/g;
 887
 888         # There are incompatibilities between some File::Temp versions
 889         # (including 0.18, bundled with Lenny's perl-modules package)
 890         # and others (e.g. 0.20, previously present in the archive as
 891         # a standalone package): under certain circumstances, some
 892         # return a relative filename, whereas others return an absolute one;
 893         # we here use this module in a way that is at least compatible
 894         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
 895         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 896                                     DIR => File::Spec->tmpdir,
 897                                     UNLINK => 1)->filename;
 898         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 899                                      DIR => File::Spec->tmpdir,
 900                                      UNLINK => 1)->filename;
 901
 902         sub failure ($) {
 903                 my $msg = '[po/filter:'.$page.'] ' . shift;
 904                 if ($nonfatal) {
 905                         warn $msg;
 906                         return undef;
 907                 }
 908                 error($msg, sub { unlink $infile, $outfile});
 909         }
 910
 911         writefile(basename($infile), File::Spec->tmpdir, $content)
 912                 or return failure("failed to write $infile");
 913
 914         my $masterfile = srcfile($pagesources{masterpage($page)});
 915         my %options = (
 916                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 917         );
 918         my $doc=Locale::Po4a::Chooser::new('text',%options);
 919         $doc->process(
 920                 'po_in_name'    => [ $infile ],
 921                 'file_in_name'  => [ $masterfile ],
 922                 'file_in_charset'  => 'utf-8',
 923                 'file_out_charset' => 'utf-8',
 924         ) or return failure("failed to translate");
 925         $doc->write($outfile) or return failure("could not write $outfile");
 926
 927         $content = readfile($outfile) or return failure("could not read $outfile");
 928
 929         # Unlinking should happen automatically, thanks to File::Temp,
 930         # but it does not work here, probably because of the way writefile()
 931         # and Locale::Po4a::write() work.
 932         unlink $infile, $outfile;
 933
 934         return $content;
 935 }
 936
 937 # ,----
 938 # | PageSpec's
 939 # `----
 940
 941 package IkiWiki::PageSpec;
 942 use warnings;
 943 use strict;
 944 use IkiWiki 2.00;
 945
 946 sub match_istranslation ($;@) {
 947         my $page=shift;
 948
 949         if (IkiWiki::Plugin::po::istranslation($page)) {
 950                 return IkiWiki::SuccessReason->new("is a translation page");
 951         }
 952         else {
 953                 return IkiWiki::FailReason->new("is not a translation page");
 954         }
 955 }
 956
 957 sub match_istranslatable ($;@) {
 958         my $page=shift;
 959
 960         if (IkiWiki::Plugin::po::istranslatable($page)) {
 961                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 962         }
 963         else {
 964                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 965         }
 966 }
 967
 968 sub match_lang ($$;@) {
 969         my $page=shift;
 970         my $wanted=shift;
 971
 972         my $regexp=IkiWiki::glob2re($wanted);
 973         my $lang=IkiWiki::Plugin::po::lang($page);
 974         if ($lang!~/^$regexp$/i) {
 975                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 976         }
 977         else {
 978                 return IkiWiki::SuccessReason->new("file language is $wanted");
 979         }
 980 }
 981
 982 sub match_currentlang ($$;@) {
 983         my $page=shift;
 984         shift;
 985         my %params=@_;
 986
 987         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 988
 989         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 990         my $lang=IkiWiki::Plugin::po::lang($page);
 991
 992         if ($lang eq $currentlang) {
 993                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 994         }
 995         else {
 996                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 997         }
 998 }
 999
1000 1