IkiWiki/Plugin/editpage.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::editpage;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use open qw{:utf8 :std};
   8
   9 sub import {
  10         hook(type => "getsetup", id => "editpage", call => \&getsetup);
  11         hook(type => "refresh", id => "editpage", call => \&refresh);
  12         hook(type => "sessioncgi", id => "editpage", call => \&IkiWiki::cgi_editpage);
  13 }
  14
  15 sub getsetup () {
  16         return
  17                 plugin => {
  18                         safe => 1,
  19                         rebuild => 1,
  20                         section => "core",
  21                 },
  22 }
  23
  24 sub refresh () {
  25         if (exists $wikistate{editpage} && exists $wikistate{editpage}{previews}) {
  26                 # Expire old preview files after one hour.
  27                 my $expire=time - (60 * 60);
  28
  29                 my @previews;
  30                 foreach my $file (@{$wikistate{editpage}{previews}}) {
  31                         my $mtime=(stat("$config{destdir}/$file"))[9];
  32                         if (defined $mtime && $mtime <= $expire) {
  33                                 # Avoid deleting a preview that was later saved.
  34                                 my $delete=1;
  35                                 foreach my $page (keys %renderedfiles) {
  36                                         if (grep { $_ eq $file } @{$renderedfiles{$page}}) {
  37                                                 $delete=0;
  38                                         }
  39                                 }
  40                                 if ($delete) {
  41                                         debug(sprintf(gettext("removing old preview %s"), $file));
  42                                         IkiWiki::prune("$config{destdir}/$file", $config{destdir});
  43                                 }
  44                         }
  45                         elsif (defined $mtime) {
  46                                 push @previews, $file;
  47                         }
  48                 }
  49                 $wikistate{editpage}{previews}=\@previews;
  50         }
  51 }
  52
  53 # Back to ikiwiki namespace for the rest, this code is very much
  54 # internal to ikiwiki even though it's separated into a plugin,
  55 # and other plugins use the function below.
  56 package IkiWiki;
  57
  58 sub cgi_editpage ($$) {
  59         my $q=shift;
  60         my $session=shift;
  61
  62         my $do=$q->param('do');
  63         return unless $do eq 'create' || $do eq 'edit';
  64
  65         decode_cgi_utf8($q);
  66
  67         my @fields=qw(do rcsinfo subpage from page type editcontent editmessage);
  68         my @buttons=("Save Page", "Preview", "Cancel");
  69         eval q{use CGI::FormBuilder};
  70         error($@) if $@;
  71         my $form = CGI::FormBuilder->new(
  72                 fields => \@fields,
  73                 charset => "utf-8",
  74                 method => 'POST',
  75                 required => [qw{editcontent}],
  76                 javascript => 0,
  77                 params => $q,
  78                 action => IkiWiki::cgiurl(),
  79                 header => 0,
  80                 table => 0,
  81                 template => { template("editpage.tmpl") },
  82         );
  83
  84         decode_form_utf8($form);
  85         run_hooks(formbuilder_setup => sub {
  86                 shift->(form => $form, cgi => $q, session => $session,
  87                         buttons => \@buttons);
  88         });
  89         decode_form_utf8($form);
  90
  91         # This untaint is safe because we check file_pruned and
  92         # wiki_file_regexp.
  93         my ($page)=$form->field('page')=~/$config{wiki_file_regexp}/;
  94         if (! defined $page) {
  95                 error(gettext("bad page name"));
  96         }
  97         $page=possibly_foolish_untaint($page);
  98         my $absolute=($page =~ s#^/+##); # absolute name used to force location
  99         if (! defined $page || ! length $page ||
 100             file_pruned($page)) {
 101                 error(gettext("bad page name"));
 102         }
 103
 104         my $baseurl = urlto($page);
 105
 106         my $from;
 107         if (defined $form->field('from')) {
 108                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 109         }
 110
 111         my $file;
 112         my $type;
 113         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 114                 $file=$pagesources{$page};
 115                 $type=pagetype($file);
 116                 if (! defined $type || $type=~/^_/) {
 117                         error(sprintf(gettext("%s is not an editable page"), $page));
 118                 }
 119                 if (! $form->submitted) {
 120                         $form->field(name => "rcsinfo",
 121                                 value => rcs_prepedit($file), force => 1);
 122                 }
 123                 $form->field(name => "editcontent", validate => '/.*/');
 124         }
 125         else {
 126                 $type=$form->param('type');
 127                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 128                         $type=possibly_foolish_untaint($type);
 129                 }
 130                 elsif (defined $from && exists $pagesources{$from}) {
 131                         # favor the type of linking page
 132                         $type=pagetype($pagesources{$from});
 133                 }
 134                 $type=$config{default_pageext}
 135                         if ! defined $type || $type=~/^_/; # not internal type
 136                 $file=newpagefile($page, $type);
 137                 if (! $form->submitted) {
 138                         $form->field(name => "rcsinfo", value => "", force => 1);
 139                 }
 140                 $form->field(name => "editcontent", validate => '/.+/');
 141         }
 142
 143         $form->field(name => "do", type => 'hidden');
 144         $form->field(name => "sid", type => "hidden", value => $session->id,
 145                 force => 1);
 146         $form->field(name => "from", type => 'hidden');
 147         $form->field(name => "rcsinfo", type => 'hidden');
 148         $form->field(name => "subpage", type => 'hidden');
 149         $form->field(name => "page", value => $page, force => 1);
 150         $form->field(name => "type", value => $type, force => 1);
 151         $form->field(name => "editmessage", type => "text", size => 80);
 152         $form->field(name => "editcontent", type => "textarea", rows => 20,
 153                 cols => 80);
 154         $form->tmpl_param("can_commit", $config{rcs});
 155         $form->tmpl_param("helponformattinglink",
 156                 htmllink($page, $page, "ikiwiki/formatting",
 157                         noimageinline => 1,
 158                         linktext => "FormattingHelp"));
 159
 160         my $previewing=0;
 161         if ($form->submitted eq "Cancel") {
 162                 if ($form->field("do") eq "create" && defined $from) {
 163                         redirect($q, urlto($from));
 164                 }
 165                 elsif ($form->field("do") eq "create") {
 166                         redirect($q, baseurl(undef));
 167                 }
 168                 else {
 169                         redirect($q, $baseurl);
 170                 }
 171                 exit;
 172         }
 173         elsif ($form->submitted eq "Preview") {
 174                 $previewing=1;
 175
 176                 my $new=not exists $pagesources{$page};
 177                 # temporarily record its type
 178                 $pagesources{$page}=$page.".".$type if $new;
 179                 my %wasrendered=map { $_ => 1 } @{$renderedfiles{$page}};
 180
 181                 my $content=$form->field('editcontent');
 182
 183                 run_hooks(editcontent => sub {
 184                         $content=shift->(
 185                                 content => $content,
 186                                 page => $page,
 187                                 cgi => $q,
 188                                 session => $session,
 189                         );
 190                 });
 191                 my $preview=htmlize($page, $page, $type,
 192                         linkify($page, $page,
 193                         preprocess($page, $page,
 194                         filter($page, $page, $content), 0, 1)));
 195                 run_hooks(format => sub {
 196                         $preview=shift->(
 197                                 page => $page,
 198                                 content => $preview,
 199                         );
 200                 });
 201                 $form->tmpl_param("page_preview", $preview);
 202
 203                 # Previewing may have created files on disk.
 204                 # Keep a list of these to be deleted later.
 205                 my %previews = map { $_ => 1 } @{$wikistate{editpage}{previews}};
 206                 foreach my $f (@{$renderedfiles{$page}}) {
 207                         $previews{$f}=1 unless $wasrendered{$f};
 208                 }
 209
 210                 # Throw out any other state changes made during previewing,
 211                 # and save the previews list.
 212                 loadindex();
 213                 @{$wikistate{editpage}{previews}} = keys %previews;
 214                 saveindex();
 215         }
 216         elsif ($form->submitted eq "Save Page") {
 217                 $form->tmpl_param("page_preview", "");
 218         }
 219
 220         if ($form->submitted ne "Save Page" || ! $form->validate) {
 221                 if ($form->field("do") eq "create") {
 222                         my @page_locs;
 223                         my $best_loc;
 224                         if (! defined $from || ! length $from ||
 225                             $from ne $form->field('from') ||
 226                             file_pruned($from) ||
 227                             $absolute ||
 228                             $form->submitted) {
 229                                 @page_locs=$best_loc=$page;
 230                                 unshift @page_locs, lc($page)
 231                                         if ! $form->submitted && lc($page) ne $page;
 232                         }
 233                         elsif (lc $page eq lc $config{discussionpage}) {
 234                                 @page_locs=$best_loc="$from/".lc($page);
 235                         }
 236                         else {
 237                                 my $dir=$from."/";
 238                                 $dir=~s![^/]+/+$!!;
 239
 240                                 if ((defined $form->field('subpage') &&
 241                                      length $form->field('subpage'))) {
 242                                         $best_loc="$from/$page";
 243                                 }
 244                                 else {
 245                                         $best_loc=$dir.$page;
 246                                 }
 247
 248                                 my $mixedcase=lc($page) ne $page;
 249
 250                                 push @page_locs, $dir.lc($page) if $mixedcase;
 251                                 push @page_locs, $dir.$page;
 252                                 push @page_locs, $from."/".lc($page) if $mixedcase;
 253                                 push @page_locs, $from."/".$page;
 254                                 while (length $dir) {
 255                                         $dir=~s![^/]+/+$!!;
 256                                         push @page_locs, $dir.lc($page) if $mixedcase;
 257                                         push @page_locs, $dir.$page;
 258                                 }
 259
 260                                 my $userpage=IkiWiki::userpage($page);
 261                                 push @page_locs, $userpage
 262                                         if ! grep { $_ eq $userpage } @page_locs;
 263                         }
 264
 265                         @page_locs = grep {
 266                                 ! exists $pagecase{lc $_}
 267                         } @page_locs;
 268                         if (! @page_locs) {
 269                                 # hmm, someone else made the page in the
 270                                 # meantime?
 271                                 if ($previewing) {
 272                                         # let them go ahead with the edit
 273                                         # and resolve the conflict at save
 274                                         # time
 275                                         @page_locs=$page;
 276                                 }
 277                                 else {
 278                                         redirect($q, $baseurl);
 279                                         exit;
 280                                 }
 281                         }
 282
 283                         my @editable_locs = grep {
 284                                 check_canedit($_, $q, $session, 1)
 285                         } @page_locs;
 286                         if (! @editable_locs) {
 287                                 # now let it throw an error, or prompt for
 288                                 # login
 289                                 map { check_canedit($_, $q, $session) }
 290                                         ($best_loc, @page_locs);
 291                         }
 292
 293                         my @page_types;
 294                         if (exists $hooks{htmlize}) {
 295                                 foreach my $key (grep { !/^_/ } keys %{$hooks{htmlize}}) {
 296                                         push @page_types, [$key, $hooks{htmlize}{$key}{longname} || $key];
 297                                 }
 298                         }
 299                         @page_types=sort @page_types;
 300
 301                         $form->tmpl_param("page_select", 1);
 302                         $form->field(name => "page", type => 'select',
 303                                 options => [ map { [ $_, pagetitle($_, 1) ] } @editable_locs ],
 304                                 value => $best_loc);
 305                         $form->field(name => "type", type => 'select',
 306                                 options => \@page_types);
 307                         $form->title(sprintf(gettext("creating %s"), pagetitle(basename($page))));
 308
 309                 }
 310                 elsif ($form->field("do") eq "edit") {
 311                         check_canedit($page, $q, $session);
 312                         if (! defined $form->field('editcontent') ||
 313                             ! length $form->field('editcontent')) {
 314                                 my $content="";
 315                                 if (exists $pagesources{$page}) {
 316                                         $content=readfile(srcfile($pagesources{$page}));
 317                                         $content=~s/\n/\r\n/g;
 318                                 }
 319                                 $form->field(name => "editcontent", value => $content,
 320                                         force => 1);
 321                         }
 322                         $form->tmpl_param("page_select", 0);
 323                         $form->field(name => "page", type => 'hidden');
 324                         $form->field(name => "type", type => 'hidden');
 325                         $form->title(sprintf(gettext("editing %s"), pagetitle(basename($page))));
 326                 }
 327
 328                 showform($form, \@buttons, $session, $q, page => $page);
 329         }
 330         else {
 331                 # save page
 332                 check_canedit($page, $q, $session);
 333                 checksessionexpiry($q, $session, $q->param('sid'));
 334
 335                 my $exists=-e "$config{srcdir}/$file";
 336
 337                 if ($form->field("do") ne "create" && ! $exists &&
 338                     ! defined srcfile($file, 1)) {
 339                         $form->tmpl_param("message", template("editpagegone.tmpl")->output);
 340                         $form->field(name => "do", value => "create", force => 1);
 341                         $form->tmpl_param("page_select", 0);
 342                         $form->field(name => "page", type => 'hidden');
 343                         $form->field(name => "type", type => 'hidden');
 344                         $form->title(sprintf(gettext("editing %s"), $page));
 345                         showform($form, \@buttons, $session, $q,
 346                                 page => $page);
 347                         exit;
 348                 }
 349                 elsif ($form->field("do") eq "create" && $exists) {
 350                         $form->tmpl_param("message", template("editcreationconflict.tmpl")->output);
 351                         $form->field(name => "do", value => "edit", force => 1);
 352                         $form->tmpl_param("page_select", 0);
 353                         $form->field(name => "page", type => 'hidden');
 354                         $form->field(name => "type", type => 'hidden');
 355                         $form->title(sprintf(gettext("editing %s"), $page));
 356                         $form->field("editcontent",
 357                                 value => readfile("$config{srcdir}/$file").
 358                                          "\n\n\n".$form->field("editcontent"),
 359                                 force => 1);
 360                         showform($form, \@buttons, $session, $q,
 361                                 page => $page);
 362                         exit;
 363                 }
 364
 365                 my $message="";
 366                 if (defined $form->field('editmessage') &&
 367                     length $form->field('editmessage')) {
 368                         $message=$form->field('editmessage');
 369                 }
 370
 371                 my $content=$form->field('editcontent');
 372                 check_content(content => $content, page => $page,
 373                         cgi => $q, session => $session,
 374                         subject => $message);
 375                 run_hooks(editcontent => sub {
 376                         $content=shift->(
 377                                 content => $content,
 378                                 page => $page,
 379                                 cgi => $q,
 380                                 session => $session,
 381                         );
 382                 });
 383                 $content=~s/\r\n/\n/g;
 384                 $content=~s/\r/\n/g;
 385                 $content.="\n" if $content !~ /\n$/;
 386
 387                 $config{cgi}=0; # avoid cgi error message
 388                 eval { writefile($file, $config{srcdir}, $content) };
 389                 $config{cgi}=1;
 390                 if ($@) {
 391                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 392                                 force => 1);
 393                         my $mtemplate=template("editfailedsave.tmpl");
 394                         $mtemplate->param(error_message => $@);
 395                         $form->tmpl_param("message", $mtemplate->output);
 396                         $form->field("editcontent", value => $content, force => 1);
 397                         $form->tmpl_param("page_select", 0);
 398                         $form->field(name => "page", type => 'hidden');
 399                         $form->field(name => "type", type => 'hidden');
 400                         $form->title(sprintf(gettext("editing %s"), $page));
 401                         showform($form, \@buttons, $session, $q,
 402                                 page => $page);
 403                         exit;
 404                 }
 405
 406                 my $conflict;
 407                 if ($config{rcs}) {
 408                         if (! $exists) {
 409                                 rcs_add($file);
 410                         }
 411
 412                         # Prevent deadlock with post-commit hook by
 413                         # signaling to it that it should not try to
 414                         # do anything.
 415                         disable_commit_hook();
 416                         $conflict=rcs_commit(
 417                                 file => $file,
 418                                 message => $message,
 419                                 token => $form->field("rcsinfo"),
 420                                 session => $session,
 421                         );
 422                         enable_commit_hook();
 423                         rcs_update();
 424                 }
 425
 426                 # Refresh even if there was a conflict, since other changes
 427                 # may have been committed while the post-commit hook was
 428                 # disabled.
 429                 require IkiWiki::Render;
 430                 refresh();
 431                 saveindex();
 432
 433                 if (defined $conflict) {
 434                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 435                                 force => 1);
 436                         $form->tmpl_param("message", template("editconflict.tmpl")->output);
 437                         $form->field("editcontent", value => $conflict, force => 1);
 438                         $form->field("do", "edit", force => 1);
 439                         $form->tmpl_param("page_select", 0);
 440                         $form->field(name => "page", type => 'hidden');
 441                         $form->field(name => "type", type => 'hidden');
 442                         $form->title(sprintf(gettext("editing %s"), $page));
 443                         showform($form, \@buttons, $session, $q,
 444                                 page => $page);
 445                 }
 446                 else {
 447                         # The trailing question mark tries to avoid broken
 448                         # caches and get the most recent version of the page.
 449                         redirect($q, $baseurl."?updated");
 450                 }
 451         }
 452
 453         exit;
 454 }
 455
 456 1