IkiWiki/Plugin/pinger.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::pinger;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 my %pages;
   9 my $pinged=0;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "pinger", call => \&getsetup);
  13         hook(type => "needsbuild", id => "pinger", call => \&needsbuild);
  14         hook(type => "preprocess", id => "ping", call => \&preprocess);
  15         hook(type => "delete", id => "pinger", call => \&ping);
  16         hook(type => "change", id => "pinger", call => \&ping);
  17 }
  18
  19 sub getsetup () {
  20         return
  21                 plugin => {
  22                         safe => 1,
  23                         rebuild => 0,
  24                 },
  25                 pinger_timeout => {
  26                         type => "integer",
  27                         example => 15,
  28                         description => "how many seconds to try pinging before timing out",
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32 }
  33
  34 sub needsbuild (@) {
  35         my $needsbuild=shift;
  36         foreach my $page (keys %pagestate) {
  37                 if (exists $pagestate{$page}{pinger}) {
  38                         $pages{$page}=1;
  39                         if (exists $pagesources{$page} &&
  40                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  41                                 # remove state, will be re-added if
  42                                 # the ping directive is still present
  43                                 # on rebuild.
  44                                 delete $pagestate{$page}{pinger};
  45                         }
  46                 }
  47         }
  48         return $needsbuild;
  49 }
  50
  51 sub preprocess (@) {
  52         my %params=@_;
  53         if (! exists $params{from} || ! exists $params{to}) {
  54                 error gettext("requires 'from' and 'to' parameters");
  55         }
  56         if ($params{from} eq $config{url}) {
  57                 $pagestate{$params{destpage}}{pinger}{$params{to}}=1;
  58                 $pages{$params{destpage}}=1;
  59                 return sprintf(gettext("Will ping %s"), $params{to});
  60         }
  61         else {
  62                 return sprintf(gettext("Ignoring ping directive for wiki %s (this wiki is %s)"), $params{from}, $config{url});
  63         }
  64 }
  65
  66 sub ping {
  67         if (! $pinged && %pages) {
  68                 $pinged=1;
  69
  70                 my $ua;
  71                 eval q{use LWPx::ParanoidAgent};
  72                 if (!$@) {
  73                         $ua=LWPx::ParanoidAgent->new;
  74                 }
  75                 else {
  76                         eval q{use LWP};
  77                         if ($@) {
  78                                 debug(gettext("LWP not found, not pinging"));
  79                                 return;
  80                         }
  81                         $ua=LWP::UserAgent->new;
  82                 }
  83                 $ua->timeout($config{pinger_timeout} || 15);
  84
  85                 # daemonise here so slow pings don't slow down wiki updates
  86                 defined(my $pid = fork) or error("Can't fork: $!");
  87                 return if $pid;
  88                 chdir '/';
  89                 open STDIN, '/dev/null';
  90                 open STDOUT, '>/dev/null';
  91                 POSIX::setsid() or error("Can't start a new session: $!");
  92                 open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
  93
  94                 # Don't need to keep a lock on the wiki as a daemon.
  95                 IkiWiki::unlockwiki();
  96
  97                 my %urls;
  98                 foreach my $page (%pages) {
  99                         if (exists $pagestate{$page}{pinger}) {
 100                                 $urls{$_}=1 foreach keys %{$pagestate{$page}{pinger}};
 101                         }
 102                 }
 103                 foreach my $url (keys %urls) {
 104                         # Try to avoid pinging ourselves. If this check
 105                         # fails, it's not the end of the world, since we
 106                         # only ping when a page was changed, so a ping loop
 107                         # will still be avoided.
 108                         next if $url=~/^\Q$config{cgiurl}\E/;
 109
 110                         $ua->get($url);
 111                 }
 112
 113                 exit 0;
 114         }
 115 }
 116
 117 1