IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 2.00;
   9
  10 my %imgdefaults;
  11
  12 sub import { #{{{
  13         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  14 } #}}}
  15
  16 sub preprocess (@) { #{{{
  17         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  18         my %params=@_;
  19
  20         if (! exists $imgdefaults{$params{page}}) {
  21                 $imgdefaults{$params{page}} = {};
  22         }
  23         my $size = $params{size} || $imgdefaults{$params{page}}->{size} || 'full';
  24         my $alt = $params{alt} || $imgdefaults{$params{page}}->{alt} || '';
  25
  26         if ($image eq 'defaults') {
  27                 $imgdefaults{$params{page}} = {
  28                         size => $size,
  29                         alt => $alt,
  30                 };
  31                 return '';
  32         }
  33
  34         push @{$links{$params{page}}}, $image;
  35         my $file = bestlink($params{page}, $image);
  36
  37         my $dir = $params{page};
  38         my $base = IkiWiki::basename($file);
  39
  40         eval q{use Image::Magick};
  41         error($@) if $@;
  42         my $im = Image::Magick->new;
  43         my $imglink;
  44         my $r;
  45
  46         if ($size ne 'full') {
  47                 my ($w, $h) = ($size =~ /^(\d+)x(\d+)$/);
  48                 return "[[img ".sprintf(gettext('bad size "%s"'), $size)."]]"
  49                         unless (defined $w && defined $h);
  50
  51                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  52                 $imglink = "$dir/${w}x${h}-$base";
  53
  54                 will_render($params{page}, $imglink);
  55
  56                 if (-e $outfile && (-M srcfile($file) >= -M $outfile)) {
  57                         $r = $im->Read($outfile);
  58                         return "[[img ".sprintf(gettext("failed to read %s: %s"), $outfile, $r)."]]" if $r;
  59                 }
  60                 else {
  61                         $r = $im->Read(srcfile($file));
  62                         return "[[img ".sprintf(gettext("failed to read %s: %s"), $file, $r)."]]" if $r;
  63
  64                         $r = $im->Resize(geometry => "${w}x${h}");
  65                         return "[[img ".sprintf(gettext("failed to resize: %s"), $r)."]]" if $r;
  66
  67                         # don't actually write file in preview mode
  68                         if (! $params{preview}) {
  69                                 my @blob = $im->ImageToBlob();
  70                                 writefile($imglink, $config{destdir}, $blob[0], 1);
  71                         }
  72                         else {
  73                                 $imglink = $file;
  74                         }
  75                 }
  76         }
  77         else {
  78                 $r = $im->Read(srcfile($file));
  79                 return "[[img ".sprintf(gettext("failed to read %s: %s"), $file, $r)."]]" if $r;
  80                 $imglink = $file;
  81         }
  82
  83         add_depends($imglink, $params{page});
  84
  85         my ($fileurl, $imgurl);
  86         if (! $params{preview}) {
  87                 $fileurl=urlto($file, $params{destpage});
  88                 $imgurl=urlto($imglink, $params{destpage});
  89         }
  90         else {
  91                 $fileurl="$config{url}/$file";
  92                 $imgurl="$config{url}/$imglink";
  93         }
  94
  95         if (! defined($im->Get("width")) || ! defined($im->Get("height"))) {
  96                 return "[[img ".sprintf(gettext("failed to determine size of image %s"), $file)."]]";
  97         }
  98
  99         my $imgtag='<img src="'.$imgurl.
 100                 '" alt="'.$alt.'" width="'.$im->Get("width").
 101                 '" height="'.$im->Get("height").'"'.
 102                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 103                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 104                 ' />';
 105
 106         if (! defined $params{link} || lc($params{link}) eq 'yes') {
 107                 return  '<a href="'.$fileurl.'">'.$imgtag.'</a>';
 108         }
 109         else {
 110                 return $imgtag;
 111         }
 112 } #}}}
 113
 114 1