IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 1.00;
   8 use URI;
   9
  10 sub import { #{{{
  11         hook(type => "getopt", id => "inline", call => \&getopt);
  12         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  13         hook(type => "preprocess", id => "inline",
  14                 call => \&IkiWiki::preprocess_inline);
  15         hook(type => "pagetemplate", id => "inline",
  16                 call => \&IkiWiki::pagetemplate_inline);
  17         # Hook to change to do pinging since it's called late.
  18         # This ensures each page only pings once and prevents slow
  19         # pings interrupting page builds.
  20         hook(type => "change", id => "inline",
  21                 call => \&IkiWiki::pingurl);
  22 } # }}}
  23
  24 sub getopt () { #{{{
  25         eval q{use Getopt::Long};
  26         error($@) if $@;
  27         Getopt::Long::Configure('pass_through');
  28         GetOptions(
  29                 "rss!" => \$config{rss},
  30                 "atom!" => \$config{atom},
  31         );
  32 }
  33
  34 sub checkconfig () { #{{{
  35         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  36                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  37         }
  38         if ($config{rss}) {
  39                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  40         }
  41         if ($config{atom}) {
  42                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  43         }
  44 } #}}}
  45
  46 # Back to ikiwiki namespace for the rest, this code is very much
  47 # internal to ikiwiki even though it's separated into a plugin.
  48 package IkiWiki;
  49
  50 my %toping;
  51 my %feedlinks;
  52
  53 sub yesno ($) { #{{{
  54         my $val=shift;
  55         return (defined $val && lc($val) eq "yes");
  56 } #}}}
  57
  58 sub preprocess_inline (@) { #{{{
  59         my %params=@_;
  60
  61         if (! exists $params{pages}) {
  62                 return "";
  63         }
  64         my $raw=yesno($params{raw});
  65         my $archive=yesno($params{archive});
  66         my $rss=($config{rss} && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
  67         my $atom=($config{atom} && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
  68         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
  69         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
  70         if (! exists $params{show} && ! $archive) {
  71                 $params{show}=10;
  72         }
  73         my $desc;
  74         if (exists $params{description}) {
  75                 $desc = $params{description}
  76         } else {
  77                 $desc = $config{wikiname};
  78         }
  79         my $actions=yesno($params{actions});
  80
  81         my @list;
  82         foreach my $page (keys %pagesources) {
  83                 next if $page eq $params{page};
  84                 if (pagespec_match($page, $params{pages})) {
  85                         push @list, $page;
  86                 }
  87         }
  88
  89         if (exists $params{sort} && $params{sort} eq 'title') {
  90                 @list=sort @list;
  91         }
  92         elsif (! exists $params{sort} || $params{sort} eq 'age') {
  93                 @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
  94         }
  95         else {
  96                 return sprintf(gettext("unknown sort type %s"), $params{sort});
  97         }
  98
  99         if (exists $params{skip}) {
 100                 @list=@list[$params{skip} .. scalar @list - 1];
 101         }
 102
 103         if ($params{show} && @list > $params{show}) {
 104                 @list=@list[0..$params{show} - 1];
 105         }
 106
 107         add_depends($params{page}, $params{pages});
 108
 109         my $rssurl=rsspage(basename($params{page}));
 110         my $atomurl=atompage(basename($params{page}));
 111         my $ret="";
 112
 113         if (exists $params{rootpage} && $config{cgiurl}) {
 114                 # Add a blog post form, with feed buttons.
 115                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 116                 $formtemplate->param(cgiurl => $config{cgiurl});
 117                 $formtemplate->param(rootpage => $params{rootpage});
 118                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 119                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 120                 $ret.=$formtemplate->output;
 121         }
 122         elsif ($feeds) {
 123                 # Add feed buttons.
 124                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 125                 $linktemplate->param(rssurl => $rssurl) if $rss;
 126                 $linktemplate->param(atomurl => $atomurl) if $atom;
 127                 $ret.=$linktemplate->output;
 128         }
 129
 130         my $template=template(
 131                 ($archive ? "inlinepagetitle.tmpl" : "inlinepage.tmpl"),
 132                 blind_cache => 1,
 133         ) unless $raw;
 134
 135         foreach my $page (@list) {
 136                 my $file = $pagesources{$page};
 137                 my $type = pagetype($file);
 138                 if (! $raw || ($raw && ! defined $type)) {
 139                         unless ($archive && $quick) {
 140                                 # Get the content before populating the
 141                                 # template, since getting the content uses
 142                                 # the same template if inlines are nested.
 143                                 my $content=get_inline_content($page, $params{destpage});
 144                                 $template->param(content => $content);
 145                         }
 146                         # Don't use htmllink because this way the
 147                         # title is separate and can be overridden by
 148                         # other plugins.
 149                         my $link=bestlink($params{page}, $page);
 150                         $link=htmlpage($link) if defined $type;
 151                         $link=abs2rel($link, dirname($params{destpage}));
 152                         $template->param(pageurl => $link);
 153                         $template->param(title => pagetitle(basename($page)));
 154                         $template->param(ctime => displaytime($pagectime{$page}));
 155
 156                         if ($actions) {
 157                                 my $file = $pagesources{$page};
 158                                 my $type = pagetype($file);
 159                                 if ($config{discussion}) {
 160                                         my $discussionlink=gettext("discussion");
 161                                         if ($page !~ /.*\/\Q$discussionlink\E$/ &&
 162                                             (length $config{cgiurl} ||
 163                                              exists $links{$page."/".$discussionlink})) {
 164                                                 $template->param(have_actions => 1);
 165                                                 $template->param(discussionlink => htmllink($page, $params{page}, "Discussion", 1, 1));
 166                                         }
 167                                 }
 168                                 if (length $config{cgiurl} && defined $type) {
 169                                         $template->param(have_actions => 1);
 170                                         $template->param(editurl => cgiurl(do => "edit", page => $page));
 171                                 }
 172                         }
 173
 174                         run_hooks(pagetemplate => sub {
 175                                 shift->(page => $page, destpage => $params{page},
 176                                         template => $template,);
 177                         });
 178
 179                         $ret.=$template->output;
 180                         $template->clear_params;
 181                 }
 182                 else {
 183                         if (defined $type) {
 184                                 $ret.="\n".
 185                                       linkify($page, $params{page},
 186                                       preprocess($page, $params{page},
 187                                       filter($page,
 188                                       readfile(srcfile($file)))));
 189                         }
 190                 }
 191         }
 192
 193         if ($feeds && $rss) {
 194                 will_render($params{page}, rsspage($params{page}));
 195                 writefile(rsspage($params{page}), $config{destdir},
 196                         genfeed("rss", $rssurl, $desc, $params{page}, @list));
 197                 $toping{$params{page}}=1 unless $config{rebuild};
 198                 $feedlinks{$params{destpage}}=qq{<link rel="alternate" type="application/rss+xml" title="RSS" href="$rssurl" />};
 199         }
 200         if ($feeds && $atom) {
 201                 will_render($params{page}, atompage($params{page}));
 202                 writefile(atompage($params{page}), $config{destdir},
 203                         genfeed("atom", $atomurl, $desc, $params{page}, @list));
 204                 $toping{$params{page}}=1 unless $config{rebuild};
 205                 $feedlinks{$params{destpage}}=qq{<link rel="alternate" type="application/atom+xml" title="Atom" href="$atomurl" />};
 206         }
 207
 208         return $ret;
 209 } #}}}
 210
 211 sub pagetemplate_inline (@) { #{{{
 212         my %params=@_;
 213         my $page=$params{page};
 214         my $template=$params{template};
 215
 216         $template->param(feedlinks => $feedlinks{$page})
 217                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 218 } #}}}
 219
 220 sub get_inline_content ($$) { #{{{
 221         my $page=shift;
 222         my $destpage=shift;
 223
 224         my $file=$pagesources{$page};
 225         my $type=pagetype($file);
 226         if (defined $type) {
 227                 return htmlize($page, $type,
 228                        linkify($page, $destpage,
 229                        preprocess($page, $destpage,
 230                        filter($page,
 231                        readfile(srcfile($file))))));
 232         }
 233         else {
 234                 return "";
 235         }
 236 } #}}}
 237
 238 sub date_822 ($) { #{{{
 239         my $time=shift;
 240
 241         eval q{use POSIX};
 242         error($@) if $@;
 243         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 244         POSIX::setlocale(&POSIX::LC_TIME, "C");
 245         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 246         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 247         return $ret;
 248 } #}}}
 249
 250 sub date_3339 ($) { #{{{
 251         my $time=shift;
 252
 253         eval q{use POSIX};
 254         error($@) if $@;
 255         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 256         POSIX::setlocale(&POSIX::LC_TIME, "C");
 257         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", localtime($time));
 258         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 259         return $ret;
 260 } #}}}
 261
 262 sub absolute_urls ($$) { #{{{
 263         # sucky sub because rss sucks
 264         my $content=shift;
 265         my $baseurl=shift;
 266
 267         my $url=$baseurl;
 268         $url=~s/[^\/]+$//;
 269
 270         $content=~s/(<a(?:\s+(?:class|id)="?\w+"?)?)\s+href="(#[^"]+)"/$1 href="$baseurl$2"/ig;
 271         $content=~s/(<a(?:\s+(?:class|id)="?\w+"?)?)\s+href="(?!\w+:\/\/)([^"]+)"/$1 href="$url$2"/ig;
 272         $content=~s/(<img(?:\s+(?:class|id)="?\w+"?)?)\s+src="(?!\w+:\/\/)([^"]+)"/$1 src="$url$2"/ig;
 273         return $content;
 274 } #}}}
 275
 276 sub rsspage ($) { #{{{
 277         my $page=shift;
 278
 279         return $page.".rss";
 280 } #}}}
 281
 282 sub atompage ($) { #{{{
 283         my $page=shift;
 284
 285         return $page.".atom";
 286 } #}}}
 287
 288 sub genfeed ($$$$@) { #{{{
 289         my $feedtype=shift;
 290         my $feedurl=shift;
 291         my $feeddesc=shift;
 292         my $page=shift;
 293         my @pages=@_;
 294
 295         my $url=URI->new(encode_utf8($config{url}."/".htmlpage($page)));
 296
 297         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 298         my $content="";
 299         my $lasttime = 0;
 300         foreach my $p (@pages) {
 301                 my $u=URI->new(encode_utf8($config{url}."/".htmlpage($p)));
 302
 303                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 304
 305                 $itemtemplate->param(
 306                         title => pagetitle(basename($p), 1),
 307                         url => $u,
 308                         permalink => $u,
 309                         date_822 => date_822($pagectime{$p}),
 310                         date_3339 => date_3339($pagectime{$p}),
 311                 );
 312
 313                 if ($itemtemplate->query(name => "enclosure")) {
 314                         my $file=$pagesources{$p};
 315                         my $type=pagetype($file);
 316                         if (defined $type) {
 317                                 $itemtemplate->param(content => $pcontent);
 318                         }
 319                         else {
 320                                 my ($a, $b, $c, $d, $e, $f, $g, $size) = stat(srcfile($file));
 321                                 my $mime="unknown";
 322                                 eval q{use File::MimeInfo};
 323                                 if (! $@) {
 324                                         $mime = mimetype($file);
 325                                 }
 326                                 $itemtemplate->param(
 327                                         enclosure => $u,
 328                                         type => $mime,
 329                                         length => $size,
 330                                 );
 331                         }
 332                 }
 333                 else {
 334                         $itemtemplate->param(content => $pcontent);
 335                 }
 336
 337                 run_hooks(pagetemplate => sub {
 338                         shift->(page => $p, destpage => $page,
 339                                 template => $itemtemplate);
 340                 });
 341
 342                 $content.=$itemtemplate->output;
 343                 $itemtemplate->clear_params;
 344
 345                 $lasttime = $pagectime{$p} if $pagectime{$p} > $lasttime;
 346         }
 347
 348         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 349         $template->param(
 350                 title => $page ne "index" ? pagetitle($page, 1) : $config{wikiname},
 351                 wikiname => $config{wikiname},
 352                 pageurl => $url,
 353                 content => $content,
 354                 feeddesc => $feeddesc,
 355                 feeddate => date_3339($lasttime),
 356                 feedurl => $feedurl,
 357                 version => $IkiWiki::version,
 358         );
 359         run_hooks(pagetemplate => sub {
 360                 shift->(page => $page, destpage => $page,
 361                         template => $template);
 362         });
 363
 364         return $template->output;
 365 } #}}}
 366
 367 sub pingurl (@) { #{{{
 368         return unless @{$config{pingurl}} && %toping;
 369
 370         eval q{require RPC::XML::Client};
 371         if ($@) {
 372                 debug(gettext("RPC::XML::Client not found, not pinging"));
 373                 return;
 374         }
 375
 376         # daemonize here so slow pings don't slow down wiki updates
 377         defined(my $pid = fork) or error("Can't fork: $!");
 378         return if $pid;
 379         chdir '/';
 380         eval q{use POSIX 'setsid'};
 381         setsid() or error("Can't start a new session: $!");
 382         open STDIN, '/dev/null';
 383         open STDOUT, '>/dev/null';
 384         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 385
 386         # Don't need to keep a lock on the wiki as a daemon.
 387         IkiWiki::unlockwiki();
 388
 389         foreach my $page (keys %toping) {
 390                 my $title=pagetitle(basename($page), 0);
 391                 my $url="$config{url}/".htmlpage($page);
 392                 foreach my $pingurl (@{$config{pingurl}}) {
 393                         debug("Pinging $pingurl for $page");
 394                         eval {
 395                                 my $client = RPC::XML::Client->new($pingurl);
 396                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 397                                         $title, $url);
 398                                 my $res = $client->send_request($req);
 399                                 if (! ref $res) {
 400                                         debug("Did not receive response to ping");
 401                                 }
 402                                 my $r=$res->value;
 403                                 if (! exists $r->{flerror} || $r->{flerror}) {
 404                                         debug("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 405                                 }
 406                         };
 407                         if ($@) {
 408                                 debug "Ping failed: $@";
 409                         }
 410                 }
 411         }
 412
 413         exit 0; # daemon done
 414 } #}}}
 415
 416 1