IkiWiki/Rcs/svn.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use POSIX qw(setlocale LC_CTYPE);
   7
   8 package IkiWiki;
   9
  10 # svn needs LC_CTYPE set to a UTF-8 locale, so try to find one. Any will do.
  11 sub find_lc_ctype() {
  12         my $current = setlocale(LC_CTYPE());
  13         return $current if $current =~ m/UTF-?8$/i;
  14
  15         # Make some obvious attempts to avoid calling `locale -a`
  16         foreach my $locale ("$current.UTF-8", "en_US.UTF-8", "en_GB.UTF-8") {
  17                 return $locale if setlocale(LC_CTYPE(), $locale);
  18         }
  19
  20         # Try to get all available locales and pick the first UTF-8 one found.
  21         if (my @locale = grep(/UTF-?8$/i, `locale -a`)) {
  22                 chomp @locale;
  23                 return $locale[0] if setlocale(LC_CTYPE(), $locale[0]);
  24         }
  25
  26         # fallback to the current locale
  27         return $current;
  28 } # }}}
  29 $ENV{LC_CTYPE} = $ENV{LC_CTYPE} || find_lc_ctype();
  30
  31 sub svn_info ($$) { #{{{
  32         my $field=shift;
  33         my $file=shift;
  34
  35         my $info=`LANG=C svn info $file`;
  36         my ($ret)=$info=~/^$field: (.*)$/m;
  37         return $ret;
  38 } #}}}
  39
  40 sub rcs_update () { #{{{
  41         if (-d "$config{srcdir}/.svn") {
  42                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
  43                         warn("svn update failed\n");
  44                 }
  45         }
  46 } #}}}
  47
  48 sub rcs_prepedit ($) { #{{{
  49         # Prepares to edit a file under revision control. Returns a token
  50         # that must be passed into rcs_commit when the file is ready
  51         # for committing.
  52         # The file is relative to the srcdir.
  53         my $file=shift;
  54
  55         if (-d "$config{srcdir}/.svn") {
  56                 # For subversion, return the revision of the file when
  57                 # editing begins.
  58                 my $rev=svn_info("Revision", "$config{srcdir}/$file");
  59                 return defined $rev ? $rev : "";
  60         }
  61 } #}}}
  62
  63 sub rcs_commit ($$$;$$) { #{{{
  64         # Tries to commit the page; returns undef on _success_ and
  65         # a version of the page with the rcs's conflict markers on failure.
  66         # The file is relative to the srcdir.
  67         my $file=shift;
  68         my $message=shift;
  69         my $rcstoken=shift;
  70         my $user=shift;
  71         my $ipaddr=shift;
  72
  73         if (defined $user) {
  74                 $message="web commit by $user".(length $message ? ": $message" : "");
  75         }
  76         elsif (defined $ipaddr) {
  77                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
  78         }
  79
  80         if (-d "$config{srcdir}/.svn") {
  81                 # Check to see if the page has been changed by someone
  82                 # else since rcs_prepedit was called.
  83                 my ($oldrev)=$rcstoken=~/^([0-9]+)$/; # untaint
  84                 my $rev=svn_info("Revision", "$config{srcdir}/$file");
  85                 if (defined $rev && defined $oldrev && $rev != $oldrev) {
  86                         # Merge their changes into the file that we've
  87                         # changed.
  88                         chdir($config{srcdir}); # svn merge wants to be here
  89                         if (system("svn", "merge", "--quiet", "-r$oldrev:$rev",
  90                                    "$config{srcdir}/$file") != 0) {
  91                                 warn("svn merge -r$oldrev:$rev failed\n");
  92                         }
  93                 }
  94
  95                 if (system("svn", "commit", "--quiet",
  96                            "--encoding", "UTF-8", "-m",
  97                            possibly_foolish_untaint($message),
  98                            "$config{srcdir}") != 0) {
  99                         my $conflict=readfile("$config{srcdir}/$file");
 100                         if (system("svn", "revert", "--quiet", "$config{srcdir}/$file") != 0) {
 101                                 warn("svn revert failed\n");
 102                         }
 103                         return $conflict;
 104                 }
 105         }
 106         return undef # success
 107 } #}}}
 108
 109 sub rcs_add ($) { #{{{
 110         # filename is relative to the root of the srcdir
 111         my $file=shift;
 112
 113         if (-d "$config{srcdir}/.svn") {
 114                 my $parent=dirname($file);
 115                 while (! -d "$config{srcdir}/$parent/.svn") {
 116                         $file=$parent;
 117                         $parent=dirname($file);
 118                 }
 119
 120                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
 121                         warn("svn add failed\n");
 122                 }
 123         }
 124 } #}}}
 125
 126 sub rcs_recentchanges ($) { #{{{
 127         my $num=shift;
 128         my @ret;
 129
 130         return unless -d "$config{srcdir}/.svn";
 131
 132         eval q{
 133                 use Date::Parse;
 134                 use XML::SAX;
 135                 use XML::Simple;
 136         };
 137         error($@) if $@;
 138
 139         # avoid using XML::SAX::PurePerl, it's buggy with UTF-8 data
 140         my @parsers = map { ${$_}{Name} } @{XML::SAX->parsers()};
 141         do {
 142                 $XML::Simple::PREFERRED_PARSER = pop @parsers;
 143         } until $XML::Simple::PREFERRED_PARSER ne 'XML::SAX::PurePerl';
 144
 145         # --limit is only supported on Subversion 1.2.0+
 146         my $svn_version=`svn --version -q`;
 147         my $svn_limit='';
 148         $svn_limit="--limit $num"
 149                 if $svn_version =~ /\d\.(\d)\.\d/ && $1 >= 2;
 150
 151         my $svn_url=svn_info("URL", $config{srcdir});
 152         my $xml = XMLin(scalar `svn $svn_limit --xml -v log '$svn_url'`,
 153                 ForceArray => [ 'logentry', 'path' ],
 154                 GroupTags => { paths => 'path' },
 155                 KeyAttr => { path => 'content' },
 156         );
 157         foreach my $logentry (@{$xml->{logentry}}) {
 158                 my (@pages, @message);
 159
 160                 my $rev = $logentry->{revision};
 161                 my $user = $logentry->{author};
 162
 163                 my $when=time - str2time($logentry->{date}, 'UTC');
 164
 165                 foreach my $msgline (split(/\n/, $logentry->{msg})) {
 166                         push @message, { line => $msgline };
 167                 }
 168
 169                 my $committype="web";
 170                 if (defined $message[0] &&
 171                     $message[0]->{line}=~/$config{web_commit_regexp}/) {
 172                         $user=defined $2 ? "$2" : "$3";
 173                         $message[0]->{line}=$4;
 174                 }
 175                 else {
 176                         $committype="svn";
 177                 }
 178
 179                 foreach (keys %{$logentry->{paths}}) {
 180                         next unless /^\/\Q$config{svnpath}\E\/([^ ]+)(?:$|\s)/;
 181                         my $file=$1;
 182                         my $diffurl=$config{diffurl};
 183                         $diffurl=~s/\[\[file\]\]/$file/g;
 184                         $diffurl=~s/\[\[r1\]\]/$rev - 1/eg;
 185                         $diffurl=~s/\[\[r2\]\]/$rev/g;
 186                         push @pages, {
 187                                 page => pagename($file),
 188                                 diffurl => $diffurl,
 189                         } if length $file;
 190                 }
 191                 push @ret, { rev => $rev,
 192                         user => $user,
 193                         committype => $committype,
 194                         when => $when,
 195                         message => [@message],
 196                         pages => [@pages],
 197                 } if @pages;
 198                 return @ret if @ret >= $num;
 199         }
 200
 201         return @ret;
 202 } #}}}
 203
 204 sub rcs_notify () { #{{{
 205         if (! exists $ENV{REV}) {
 206                 error(gettext("REV is not set, not running from svn post-commit hook, cannot send notifications"));
 207         }
 208         my $rev=int(possibly_foolish_untaint($ENV{REV}));
 209
 210         my $user=`svnlook author $config{svnrepo} -r $rev`;
 211         chomp $user;
 212
 213         my $message=`svnlook log $config{svnrepo} -r $rev`;
 214         if ($message=~/$config{web_commit_regexp}/) {
 215                 $user=defined $2 ? "$2" : "$3";
 216                 $message=$4;
 217         }
 218
 219         my @changed_pages;
 220         foreach my $change (`svnlook changed $config{svnrepo} -r $rev`) {
 221                 chomp $change;
 222                 if ($change =~ /^[A-Z]+\s+\Q$config{svnpath}\E\/(.*)/) {
 223                         push @changed_pages, $1;
 224                 }
 225         }
 226
 227         require IkiWiki::UserInfo;
 228         send_commit_mails(
 229                 sub {
 230                         return $message;
 231                 },
 232                 sub {
 233                         `svnlook diff $config{svnrepo} -r $rev --no-diff-deleted`;
 234                 }, $user, @changed_pages);
 235 } #}}}
 236
 237 sub rcs_getctime ($) { #{{{
 238         my $file=shift;
 239
 240         my $svn_log_infoline=qr/^r\d+\s+\|\s+[^\s]+\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 241
 242         my $child = open(SVNLOG, "-|");
 243         if (! $child) {
 244                 exec("svn", "log", $file) || error("svn log $file failed to run");
 245         }
 246
 247         my $date;
 248         while (<SVNLOG>) {
 249                 if (/$svn_log_infoline/) {
 250                         $date=$1;
 251                 }
 252         }
 253         close SVNLOG || warn "svn log $file exited $?";
 254
 255         if (! defined $date) {
 256                 warn "failed to parse svn log for $file\n";
 257                 return 0;
 258         }
 259
 260         eval q{use Date::Parse};
 261         error($@) if $@;
 262         $date=str2time($date);
 263         debug("found ctime ".localtime($date)." for $file");
 264         return $date;
 265 } #}}}
 266
 267 1