IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198
 199                 $params{pages} = join(" or ", @list);
 200         }
 201         else {
 202                 @list = pagespec_match_list(
 203                         [ grep { $_ ne $params{page} } keys %pagesources ],
 204                         $params{pages}, location => $params{page});
 205
 206                 if (exists $params{sort} && $params{sort} eq 'title') {
 207                         @list=sort { pagetitle(basename($a)) cmp pagetitle(basename($b)) } @list;
 208                 }
 209                 elsif (exists $params{sort} && $params{sort} eq 'title_natural') {
 210                         eval q{use Sort::Naturally};
 211                         if ($@) {
 212                                 error(gettext("Sort::Naturally needed for title_natural sort"));
 213                         }
 214                         @list=sort { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) } @list;
 215                 }
 216                 elsif (exists $params{sort} && $params{sort} eq 'mtime') {
 217                         @list=sort { $pagemtime{$b} <=> $pagemtime{$a} } @list;
 218                 }
 219                 elsif (! exists $params{sort} || $params{sort} eq 'age') {
 220                         @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 221                 }
 222                 else {
 223                         error sprintf(gettext("unknown sort type %s"), $params{sort});
 224                 }
 225         }
 226
 227         if (yesno($params{reverse})) {
 228                 @list=reverse(@list);
 229         }
 230
 231         if (exists $params{skip}) {
 232                 @list=@list[$params{skip} .. scalar @list - 1];
 233         }
 234
 235         my @feedlist;
 236         if ($feeds) {
 237                 if (exists $params{feedshow} &&
 238                     $params{feedshow} && @list > $params{feedshow}) {
 239                         @feedlist=@list[0..$params{feedshow} - 1];
 240                 }
 241                 else {
 242                         @feedlist=@list;
 243                 }
 244         }
 245
 246         if ($params{show} && @list > $params{show}) {
 247                 @list=@list[0..$params{show} - 1];
 248         }
 249
 250         add_depends($params{page}, $params{pages});
 251         # Explicitly add all currently displayed pages as dependencies, so
 252         # that if they are removed or otherwise changed, the inline will be
 253         # sure to be updated.
 254         foreach my $p ($#list >= $#feedlist ? @list : @feedlist) {
 255                 add_depends($params{page}, $p);
 256         }
 257
 258         if ($feeds && exists $params{feedpages}) {
 259                 @feedlist=pagespec_match_list(\@feedlist, $params{feedpages}, location => $params{page});
 260         }
 261
 262         my ($feedbase, $feednum);
 263         if ($feeds) {
 264                 # Ensure that multiple feeds on a page go to unique files.
 265
 266                 # Feedfile can lead to conflicts if usedirs is not enabled,
 267                 # so avoid supporting it in that case.
 268                 delete $params{feedfile} if ! $config{usedirs};
 269                 # Tight limits on legal feedfiles, to avoid security issues
 270                 # and conflicts.
 271                 if (defined $params{feedfile}) {
 272                         if ($params{feedfile} =~ /\// ||
 273                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 274                                 error("illegal feedfile");
 275                         }
 276                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 277                 }
 278                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 279
 280                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 281                 if (exists $knownfeeds{$feedid}) {
 282                         $feednum=$knownfeeds{$feedid};
 283                 }
 284                 else {
 285                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 286                                 if ($feeds) {
 287                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 288                                 }
 289                         }
 290                         else {
 291                                 $feednum=$knownfeeds{$feedid}="";
 292                                 if ($feeds) {
 293                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 294                                 }
 295                         }
 296                 }
 297         }
 298
 299         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 300         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 301
 302         my $ret="";
 303
 304         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 305             (exists $params{postform} && yesno($params{postform}))) &&
 306             IkiWiki->can("cgi_editpage")) {
 307                 # Add a blog post form, with feed buttons.
 308                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 309                 $formtemplate->param(cgiurl => $config{cgiurl});
 310                 my $rootpage;
 311                 if (exists $params{rootpage}) {
 312                         $rootpage=bestlink($params{page}, $params{rootpage});
 313                         if (!length $rootpage) {
 314                                 $rootpage=$params{rootpage};
 315                         }
 316                 }
 317                 else {
 318                         $rootpage=$params{page};
 319                 }
 320                 $formtemplate->param(rootpage => $rootpage);
 321                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 322                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 323                 if (exists $params{postformtext}) {
 324                         $formtemplate->param(postformtext =>
 325                                 $params{postformtext});
 326                 }
 327                 else {
 328                         $formtemplate->param(postformtext =>
 329                                 gettext("Add a new post titled:"));
 330                 }
 331                 $ret.=$formtemplate->output;
 332
 333                 # The post form includes the feed buttons, so
 334                 # emptyfeeds cannot be hidden.
 335                 $emptyfeeds=1;
 336         }
 337         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 338                 # Add feed buttons.
 339                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 340                 $linktemplate->param(rssurl => $rssurl) if $rss;
 341                 $linktemplate->param(atomurl => $atomurl) if $atom;
 342                 $ret.=$linktemplate->output;
 343         }
 344
 345         if (! $feedonly) {
 346                 require HTML::Template;
 347                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 348                 if (! @params) {
 349                         error sprintf(gettext("nonexistant template %s"), $params{template});
 350                 }
 351                 my $template=HTML::Template->new(@params) unless $raw;
 352
 353                 foreach my $page (@list) {
 354                         my $file = $pagesources{$page};
 355                         my $type = pagetype($file);
 356                         if (! $raw || ($raw && ! defined $type)) {
 357                                 unless ($archive && $quick) {
 358                                         # Get the content before populating the
 359                                         # template, since getting the content uses
 360                                         # the same template if inlines are nested.
 361                                         my $content=get_inline_content($page, $params{destpage});
 362                                         $template->param(content => $content);
 363                                 }
 364                                 $template->param(pageurl => urlto($page, $params{destpage}));
 365                                 $template->param(inlinepage => $page);
 366                                 $template->param(title => pagetitle(basename($page)));
 367                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 368                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 369                                 $template->param(first => 1) if $page eq $list[0];
 370                                 $template->param(last => 1) if $page eq $list[$#list];
 371
 372                                 if ($actions) {
 373                                         my $file = $pagesources{$page};
 374                                         my $type = pagetype($file);
 375                                         if ($config{discussion}) {
 376                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
 377                                                     (length $config{cgiurl} ||
 378                                                      exists $links{$page."/".$config{discussionpage}})) {
 379                                                         $template->param(have_actions => 1);
 380                                                         $template->param(discussionlink =>
 381                                                                 htmllink($page,
 382                                                                         $params{destpage},
 383                                                                         $config{discussionpage},
 384                                                                         noimageinline => 1,
 385                                                                         forcesubpage => 1));
 386                                                 }
 387                                         }
 388                                         if (length $config{cgiurl} && defined $type) {
 389                                                 $template->param(have_actions => 1);
 390                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 391                                         }
 392                                 }
 393
 394                                 run_hooks(pagetemplate => sub {
 395                                         shift->(page => $page, destpage => $params{destpage},
 396                                                 template => $template,);
 397                                 });
 398
 399                                 $ret.=$template->output;
 400                                 $template->clear_params;
 401                         }
 402                         else {
 403                                 if (defined $type) {
 404                                         $ret.="\n".
 405                                               linkify($page, $params{destpage},
 406                                               preprocess($page, $params{destpage},
 407                                               filter($page, $params{destpage},
 408                                               readfile(srcfile($file)))));
 409                                 }
 410                         }
 411                 }
 412         }
 413
 414         if ($feeds && ($emptyfeeds || @feedlist)) {
 415                 if ($rss) {
 416                         my $rssp=$feedbase."rss".$feednum;
 417                         will_render($params{destpage}, $rssp);
 418                         if (! $params{preview}) {
 419                                 writefile($rssp, $config{destdir},
 420                                         genfeed("rss",
 421                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 422                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 423                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 424                         }
 425                 }
 426                 if ($atom) {
 427                         my $atomp=$feedbase."atom".$feednum;
 428                         will_render($params{destpage}, $atomp);
 429                         if (! $params{preview}) {
 430                                 writefile($atomp, $config{destdir},
 431                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 432                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 433                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 434                         }
 435                 }
 436         }
 437
 438         return $ret if $raw || $nested;
 439         push @inline, $ret;
 440         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 441 }
 442
 443 sub pagetemplate_inline (@) {
 444         my %params=@_;
 445         my $page=$params{page};
 446         my $template=$params{template};
 447
 448         $template->param(feedlinks => $feedlinks{$page})
 449                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 450 }
 451
 452 sub get_inline_content ($$) {
 453         my $page=shift;
 454         my $destpage=shift;
 455
 456         my $file=$pagesources{$page};
 457         my $type=pagetype($file);
 458         if (defined $type) {
 459                 $nested++;
 460                 my $ret=htmlize($page, $destpage, $type,
 461                        linkify($page, $destpage,
 462                        preprocess($page, $destpage,
 463                        filter($page, $destpage,
 464                        readfile(srcfile($file))))));
 465                 $nested--;
 466                 return $ret;
 467         }
 468         else {
 469                 return "";
 470         }
 471 }
 472
 473 sub date_822 ($) {
 474         my $time=shift;
 475
 476         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 477         POSIX::setlocale(&POSIX::LC_TIME, "C");
 478         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 479         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 480         return $ret;
 481 }
 482
 483 sub date_3339 ($) {
 484         my $time=shift;
 485
 486         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 487         POSIX::setlocale(&POSIX::LC_TIME, "C");
 488         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 489         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 490         return $ret;
 491 }
 492
 493 sub absolute_urls ($$) {
 494         # sucky sub because rss sucks
 495         my $content=shift;
 496         my $baseurl=shift;
 497
 498         my $url=$baseurl;
 499         $url=~s/[^\/]+$//;
 500
 501         # what is the non path part of the url?
 502         my $top_uri = URI->new($url);
 503         $top_uri->path_query(""); # reset the path
 504         my $urltop = $top_uri->as_string;
 505
 506         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 507         # relative to another wiki page
 508         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 509         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 510         # relative to the top of the site
 511         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 512         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 513         return $content;
 514 }
 515
 516 sub genfeed ($$$$$@) {
 517         my $feedtype=shift;
 518         my $feedurl=shift;
 519         my $feeddesc=shift;
 520         my $guid=shift;
 521         my $page=shift;
 522         my @pages=@_;
 523
 524         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 525
 526         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 527         my $content="";
 528         my $lasttime = 0;
 529         foreach my $p (@pages) {
 530                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 531                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 532
 533                 $itemtemplate->param(
 534                         title => pagetitle(basename($p)),
 535                         url => $u,
 536                         permalink => $u,
 537                         cdate_822 => date_822($pagectime{$p}),
 538                         mdate_822 => date_822($pagemtime{$p}),
 539                         cdate_3339 => date_3339($pagectime{$p}),
 540                         mdate_3339 => date_3339($pagemtime{$p}),
 541                 );
 542
 543                 if (exists $pagestate{$p}) {
 544                         if (exists $pagestate{$p}{meta}{guid}) {
 545                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 546                         }
 547
 548                         if (exists $pagestate{$p}{meta}{updated}) {
 549                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 550                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 551                         }
 552                 }
 553
 554                 if ($itemtemplate->query(name => "enclosure")) {
 555                         my $file=$pagesources{$p};
 556                         my $type=pagetype($file);
 557                         if (defined $type) {
 558                                 $itemtemplate->param(content => $pcontent);
 559                         }
 560                         else {
 561                                 my $size=(srcfile_stat($file))[8];
 562                                 my $mime="unknown";
 563                                 eval q{use File::MimeInfo};
 564                                 if (! $@) {
 565                                         $mime = mimetype($file);
 566                                 }
 567                                 $itemtemplate->param(
 568                                         enclosure => $u,
 569                                         type => $mime,
 570                                         length => $size,
 571                                 );
 572                         }
 573                 }
 574                 else {
 575                         $itemtemplate->param(content => $pcontent);
 576                 }
 577
 578                 run_hooks(pagetemplate => sub {
 579                         shift->(page => $p, destpage => $page,
 580                                 template => $itemtemplate);
 581                 });
 582
 583                 $content.=$itemtemplate->output;
 584                 $itemtemplate->clear_params;
 585
 586                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 587         }
 588
 589         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 590         $template->param(
 591                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 592                 wikiname => $config{wikiname},
 593                 pageurl => $url,
 594                 content => $content,
 595                 feeddesc => $feeddesc,
 596                 guid => $guid,
 597                 feeddate => date_3339($lasttime),
 598                 feedurl => $feedurl,
 599                 version => $IkiWiki::version,
 600         );
 601         run_hooks(pagetemplate => sub {
 602                 shift->(page => $page, destpage => $page,
 603                         template => $template);
 604         });
 605
 606         return $template->output;
 607 }
 608
 609 sub pingurl (@) {
 610         return unless @{$config{pingurl}} && %toping;
 611
 612         eval q{require RPC::XML::Client};
 613         if ($@) {
 614                 debug(gettext("RPC::XML::Client not found, not pinging"));
 615                 return;
 616         }
 617
 618         # daemonize here so slow pings don't slow down wiki updates
 619         defined(my $pid = fork) or error("Can't fork: $!");
 620         return if $pid;
 621         chdir '/';
 622         POSIX::setsid() or error("Can't start a new session: $!");
 623         open STDIN, '/dev/null';
 624         open STDOUT, '>/dev/null';
 625         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 626
 627         # Don't need to keep a lock on the wiki as a daemon.
 628         IkiWiki::unlockwiki();
 629
 630         foreach my $page (keys %toping) {
 631                 my $title=pagetitle(basename($page), 0);
 632                 my $url=urlto($page, "", 1);
 633                 foreach my $pingurl (@{$config{pingurl}}) {
 634                         debug("Pinging $pingurl for $page");
 635                         eval {
 636                                 my $client = RPC::XML::Client->new($pingurl);
 637                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 638                                         $title, $url);
 639                                 my $res = $client->send_request($req);
 640                                 if (! ref $res) {
 641                                         error("Did not receive response to ping");
 642                                 }
 643                                 my $r=$res->value;
 644                                 if (! exists $r->{flerror} || $r->{flerror}) {
 645                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 646                                 }
 647                         };
 648                         if ($@) {
 649                                 error "Ping failed: $@";
 650                         }
 651                 }
 652         }
 653
 654         exit 0; # daemon done
 655 }
 656
 657 1