IkiWiki/Plugin/aggregate.pm

   1 #!/usr/bin/perl
   2 # Blog aggregation plugin.
   3 package IkiWiki::Plugin::aggregate;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8 use HTML::Entities;
   9 use HTML::Parser;
  10 use HTML::Tagset;
  11 use URI;
  12 use open qw{:utf8 :std};
  13
  14 my %feeds;
  15 my %guids;
  16
  17 sub import { #{{{
  18         hook(type => "getopt", id => "aggregate", call => \&getopt);
  19         hook(type => "checkconfig", id => "aggregate", call => \&checkconfig);
  20         hook(type => "filter", id => "aggregate", call => \&filter);
  21         hook(type => "preprocess", id => "aggregate", call => \&preprocess);
  22         hook(type => "delete", id => "aggregate", call => \&delete);
  23         hook(type => "savestate", id => "aggregate", call => \&savestate);
  24 } # }}}
  25
  26 sub getopt () { #{{{
  27         eval q{use Getopt::Long};
  28         error($@) if $@;
  29         Getopt::Long::Configure('pass_through');
  30         GetOptions("aggregate" => \$config{aggregate});
  31 } #}}}
  32
  33 sub checkconfig () { #{{{
  34         if ($config{aggregate} && ! ($config{post_commit} &&
  35                                      IkiWiki::commit_hook_enabled())) {
  36                 if (! IkiWiki::lockwiki(0)) {
  37                         debug("wiki is locked by another process, not aggregating");
  38                         exit 1;
  39                 }
  40
  41                 loadstate();
  42                 IkiWiki::loadindex();
  43                 aggregate();
  44                 expire();
  45                 savestate();
  46                 clearstate();
  47
  48                 IkiWiki::unlockwiki();
  49         }
  50 } #}}}
  51
  52 sub filter (@) { #{{{
  53         my %params=@_;
  54         my $page=$params{page};
  55
  56         loadstate(); # if not already loaded
  57         # Mark all feeds originating on this page as removable;
  58         # preprocess will unmark those that still exist.
  59         remove_feeds($page);
  60
  61         return $params{content};
  62 } # }}}
  63
  64 sub preprocess (@) { #{{{
  65         my %params=@_;
  66
  67         foreach my $required (qw{name url}) {
  68                 if (! exists $params{$required}) {
  69                         return "[[aggregate ".sprintf(gettext("missing %s parameter"), $required)."]]";
  70                 }
  71         }
  72
  73         my $feed={};
  74         my $name=$params{name};
  75         if (exists $feeds{$name}) {
  76                 $feed=$feeds{$name};
  77         }
  78         else {
  79                 $feeds{$name}=$feed;
  80         }
  81         $feed->{name}=$name;
  82         $feed->{sourcepage}=$params{page};
  83         $feed->{url}=$params{url};
  84         my $dir=exists $params{dir} ? $params{dir} : $params{page}."/".IkiWiki::titlepage($params{name});
  85         $dir=~s/^\/+//;
  86         ($dir)=$dir=~/$config{wiki_file_regexp}/;
  87         $feed->{dir}=$dir;
  88         $feed->{feedurl}=defined $params{feedurl} ? $params{feedurl} : "";
  89         $feed->{updateinterval}=defined $params{updateinterval} ? $params{updateinterval} * 60 : 15 * 60;
  90         $feed->{expireage}=defined $params{expireage} ? $params{expireage} : 0;
  91         $feed->{expirecount}=defined $params{expirecount} ? $params{expirecount} : 0;
  92         delete $feed->{remove};
  93         delete $feed->{expired};
  94         $feed->{lastupdate}=0 unless defined $feed->{lastupdate};
  95         $feed->{numposts}=0 unless defined $feed->{numposts};
  96         $feed->{newposts}=0 unless defined $feed->{newposts};
  97         $feed->{message}=gettext("new feed") unless defined $feed->{message};
  98         $feed->{error}=0 unless defined $feed->{error};
  99         $feed->{tags}=[];
 100         while (@_) {
 101                 my $key=shift;
 102                 my $value=shift;
 103                 if ($key eq 'tag') {
 104                         push @{$feed->{tags}}, $value;
 105                 }
 106         }
 107
 108         return "<a href=\"".$feed->{url}."\">".$feed->{name}."</a>: ".
 109                ($feed->{error} ? "<em>" : "").$feed->{message}.
 110                ($feed->{error} ? "</em>" : "").
 111                " (".$feed->{numposts}." ".gettext("posts").
 112                ($feed->{newposts} ? "; ".$feed->{newposts}.
 113                                     " ".gettext("new") : "").
 114                ")";
 115 } # }}}
 116
 117 sub delete (@) { #{{{
 118         my @files=@_;
 119
 120         # Remove feed data for removed pages.
 121         foreach my $file (@files) {
 122                 my $page=pagename($file);
 123                 remove_feeds($page);
 124         }
 125 } #}}}
 126
 127 my $state_loaded=0;
 128 sub loadstate () { #{{{
 129         return if $state_loaded;
 130         if (-e "$config{wikistatedir}/aggregate") {
 131                 open(IN, "$config{wikistatedir}/aggregate") ||
 132                         die "$config{wikistatedir}/aggregate: $!";
 133                 while (<IN>) {
 134                         $_=IkiWiki::possibly_foolish_untaint($_);
 135                         chomp;
 136                         my $data={};
 137                         foreach my $i (split(/ /, $_)) {
 138                                 my ($field, $val)=split(/=/, $i, 2);
 139                                 if ($field eq "name" || $field eq "feed" ||
 140                                     $field eq "guid" || $field eq "message") {
 141                                         $data->{$field}=decode_entities($val, " \t\n");
 142                                 }
 143                                 elsif ($field eq "tag") {
 144                                         push @{$data->{tags}}, $val;
 145                                 }
 146                                 else {
 147                                         $data->{$field}=$val;
 148                                 }
 149                         }
 150
 151                         if (exists $data->{name}) {
 152                                 $feeds{$data->{name}}=$data;
 153                         }
 154                         elsif (exists $data->{guid}) {
 155                                 $guids{$data->{guid}}=$data;
 156                         }
 157                 }
 158
 159                 close IN;
 160
 161                 $state_loaded=1;
 162         }
 163 } #}}}
 164
 165 sub savestate () { #{{{
 166         eval q{use HTML::Entities};
 167         error($@) if $@;
 168         my $newfile="$config{wikistatedir}/aggregate.new";
 169         # TODO: This cleanup function could use improvement. Any newly
 170         # aggregated files are left behind unrecorded, and should be deleted.
 171         my $cleanup = sub { unlink($newfile) };
 172         open (OUT, ">$newfile") || error("open $newfile: $!", $cleanup);
 173         foreach my $data (values %feeds, values %guids) {
 174                 if ($data->{remove}) {
 175                         if ($data->{name}) {
 176                                 foreach my $guid (values %guids) {
 177                                         if ($guid->{feed} eq $data->{name}) {
 178                                                 $guid->{remove}=1;
 179                                         }
 180                                 }
 181                         }
 182                         else {
 183                                 unlink pagefile($data->{page});
 184                         }
 185                         next;
 186                 }
 187                 elsif ($data->{expired} && exists $data->{page}) {
 188                         unlink pagefile($data->{page});
 189                         delete $data->{page};
 190                         delete $data->{md5};
 191                 }
 192
 193                 my @line;
 194                 foreach my $field (keys %$data) {
 195                         if ($field eq "name" || $field eq "feed" ||
 196                             $field eq "guid" || $field eq "message") {
 197                                 push @line, "$field=".encode_entities($data->{$field}, " \t\n");
 198                         }
 199                         elsif ($field eq "tags") {
 200                                 push @line, "tag=$_" foreach @{$data->{tags}};
 201                         }
 202                         else {
 203                                 push @line, "$field=".$data->{$field};
 204                         }
 205                 }
 206                 print OUT join(" ", @line)."\n" || error("write $newfile: $!", $cleanup);
 207         }
 208         close OUT || error("save $newfile: $!", $cleanup);
 209         rename($newfile, "$config{wikistatedir}/aggregate") ||
 210                 error("rename $newfile: $!", $cleanup);
 211 } #}}}
 212
 213 sub clearstate () { #{{{
 214         %feeds=();
 215         %guids=();
 216         $state_loaded=0;
 217 } #}}}
 218
 219 sub expire () { #{{{
 220         foreach my $feed (values %feeds) {
 221                 next unless $feed->{expireage} || $feed->{expirecount};
 222                 my $count=0;
 223                 foreach my $item (sort { $IkiWiki::pagectime{$b->{page}} <=> $IkiWiki::pagectime{$a->{page}} }
 224                                   grep { exists $_->{page} && $_->{feed} eq $feed->{name} && $IkiWiki::pagectime{$_->{page}} }
 225                                   values %guids) {
 226                         if ($feed->{expireage}) {
 227                                 my $days_old = (time - $IkiWiki::pagectime{$item->{page}}) / 60 / 60 / 24;
 228                                 if ($days_old > $feed->{expireage}) {
 229                                         debug(sprintf(gettext("expiring %s (%s days old)"),
 230                                                 $item->{page}, $days_old));
 231                                         $item->{expired}=1;
 232                                 }
 233                         }
 234                         elsif ($feed->{expirecount} &&
 235                                $count >= $feed->{expirecount}) {
 236                                 debug(sprintf(gettext("expiring %s"), $item->{page}));
 237                                 $item->{expired}=1;
 238                         }
 239                         else {
 240                                 $count++;
 241                         }
 242                 }
 243         }
 244 } #}}}
 245
 246 sub aggregate () { #{{{
 247         eval q{use XML::Feed};
 248         error($@) if $@;
 249         eval q{use URI::Fetch};
 250         error($@) if $@;
 251         eval q{use HTML::Entities};
 252         error($@) if $@;
 253
 254         foreach my $feed (values %feeds) {
 255                 next unless $config{rebuild} ||
 256                         time - $feed->{lastupdate} >= $feed->{updateinterval};
 257                 $feed->{lastupdate}=time;
 258                 $feed->{newposts}=0;
 259                 $feed->{message}=sprintf(gettext("processed ok at %s"),
 260                         displaytime($feed->{lastupdate}));
 261                 $feed->{error}=0;
 262                 $IkiWiki::forcerebuild{$feed->{sourcepage}}=1;
 263
 264                 debug(sprintf(gettext("checking feed %s ..."), $feed->{name}));
 265
 266                 if (! length $feed->{feedurl}) {
 267                         my @urls=XML::Feed->find_feeds($feed->{url});
 268                         if (! @urls) {
 269                                 $feed->{message}=sprintf(gettext("could not find feed at %s"), $feed->{url});
 270                                 $feed->{error}=1;
 271                                 debug($feed->{message});
 272                                 next;
 273                         }
 274                         $feed->{feedurl}=pop @urls;
 275                 }
 276                 my $res=URI::Fetch->fetch($feed->{feedurl});
 277                 if (! $res) {
 278                         $feed->{message}=URI::Fetch->errstr;
 279                         $feed->{error}=1;
 280                         debug($feed->{message});
 281                         next;
 282                 }
 283                 if ($res->status == URI::Fetch::URI_GONE()) {
 284                         $feed->{message}=gettext("feed not found");
 285                         $feed->{error}=1;
 286                         debug($feed->{message});
 287                         next;
 288                 }
 289                 my $content=$res->content;
 290                 my $f=eval{XML::Feed->parse(\$content)};
 291                 if ($@) {
 292                         # One common cause of XML::Feed crashing is a feed
 293                         # that contains invalid UTF-8 sequences. Convert
 294                         # feed to ascii to try to work around.
 295                         $feed->{message}.=" ".sprintf(gettext("(invalid UTF-8 stripped from feed)"));
 296                         $content=Encode::decode_utf8($content);
 297                         $f=eval{XML::Feed->parse(\$content)};
 298                 }
 299                 if ($@) {
 300                         $feed->{message}=gettext("feed crashed XML::Feed!")." ($@)";
 301                         $feed->{error}=1;
 302                         debug($feed->{message});
 303                         next;
 304                 }
 305                 if (! $f) {
 306                         $feed->{message}=XML::Feed->errstr;
 307                         $feed->{error}=1;
 308                         debug($feed->{message});
 309                         next;
 310                 }
 311
 312                 foreach my $entry ($f->entries) {
 313                         add_page(
 314                                 feed => $feed,
 315                                 title => defined $entry->title ? decode_entities($entry->title) : "untitled",
 316                                 link => $entry->link,
 317                                 content => defined $entry->content->body ? $entry->content->body : "",
 318                                 guid => defined $entry->id ? $entry->id : time."_".$feed->name,
 319                                 ctime => $entry->issued ? ($entry->issued->epoch || time) : time,
 320                         );
 321                 }
 322         }
 323 } #}}}
 324
 325 sub add_page (@) { #{{{
 326         my %params=@_;
 327
 328         my $feed=$params{feed};
 329         my $guid={};
 330         my $mtime;
 331         if (exists $guids{$params{guid}}) {
 332                 # updating an existing post
 333                 $guid=$guids{$params{guid}};
 334                 return if $guid->{expired};
 335         }
 336         else {
 337                 # new post
 338                 $guid->{guid}=$params{guid};
 339                 $guids{$params{guid}}=$guid;
 340                 $mtime=$params{ctime};
 341                 $feed->{numposts}++;
 342                 $feed->{newposts}++;
 343
 344                 # assign it an unused page
 345                 my $page=IkiWiki::titlepage($params{title});
 346                 # escape slashes and periods in title so it doesn't specify
 347                 # directory name or trigger ".." disallowing code.
 348                 $page=~s!([/.])!"__".ord($1)."__"!eg;
 349                 $page=$feed->{dir}."/".$page;
 350                 ($page)=$page=~/$config{wiki_file_regexp}/;
 351                 if (! defined $page || ! length $page) {
 352                         $page=$feed->{dir}."/item";
 353                 }
 354                 my $c="";
 355                 while (exists $IkiWiki::pagecase{lc $page.$c} ||
 356                        -e pagefile($page.$c)) {
 357                         $c++
 358                 }
 359
 360                 # Make sure that the file name isn't too long.
 361                 # NB: This doesn't check for path length limits.
 362                 my $max=POSIX::pathconf($config{srcdir}, &POSIX::_PC_NAME_MAX);
 363                 if (defined $max && length(htmlfn($page)) >= $max) {
 364                         $c="";
 365                         $page=$feed->{dir}."/item";
 366                         while (exists $IkiWiki::pagecase{lc $page.$c} ||
 367                                -e pagefile($page.$c)) {
 368                                 $c++
 369                         }
 370                 }
 371
 372                 $guid->{page}=$page;
 373                 debug(sprintf(gettext("creating new page %s"), $page));
 374         }
 375         $guid->{feed}=$feed->{name};
 376
 377         # To write or not to write? Need to avoid writing unchanged pages
 378         # to avoid unneccessary rebuilding. The mtime from rss cannot be
 379         # trusted; let's use a digest.
 380         eval q{use Digest::MD5 'md5_hex'};
 381         error($@) if $@;
 382         require Encode;
 383         my $digest=md5_hex(Encode::encode_utf8($params{content}));
 384         return unless ! exists $guid->{md5} || $guid->{md5} ne $digest || $config{rebuild};
 385         $guid->{md5}=$digest;
 386
 387         # Create the page.
 388         my $template=template("aggregatepost.tmpl", blind_cache => 1);
 389         $template->param(title => $params{title})
 390                 if defined $params{title} && length($params{title});
 391         $template->param(content => htmlescape(htmlabs($params{content}, $feed->{feedurl})));
 392         $template->param(name => $feed->{name});
 393         $template->param(url => $feed->{url});
 394         $template->param(permalink => urlabs($params{link}, $feed->{feedurl}))
 395                 if defined $params{link};
 396         if (ref $feed->{tags}) {
 397                 $template->param(tags => [map { tag => $_ }, @{$feed->{tags}}]);
 398         }
 399         writefile(htmlfn($guid->{page}), $config{srcdir},
 400                 $template->output);
 401
 402         # Set the mtime, this lets the build process get the right creation
 403         # time on record for the new page.
 404         utime $mtime, $mtime, pagefile($guid->{page}) if defined $mtime;
 405 } #}}}
 406
 407 sub htmlescape ($) { #{{{
 408         # escape accidental wikilinks and preprocessor stuff
 409         my $html=shift;
 410         $html=~s/(?<!\\)\[\[/\\\[\[/g;
 411         return $html;
 412 } #}}}
 413
 414 sub urlabs ($$) { #{{{
 415         my $url=shift;
 416         my $urlbase=shift;
 417
 418         URI->new_abs($url, $urlbase)->as_string;
 419 } #}}}
 420
 421 sub htmlabs ($$) { #{{{
 422         # Convert links in html from relative to absolute.
 423         # Note that this is a heuristic, which is not specified by the rss
 424         # spec and may not be right for all feeds. Also, see Debian
 425         # bug #381359.
 426         my $html=shift;
 427         my $urlbase=shift;
 428
 429         my $ret="";
 430         my $p = HTML::Parser->new(api_version => 3);
 431         $p->handler(default => sub { $ret.=join("", @_) }, "text");
 432         $p->handler(start => sub {
 433                 my ($tagname, $pos, $text) = @_;
 434                 if (ref $HTML::Tagset::linkElements{$tagname}) {
 435                         while (4 <= @$pos) {
 436                                 # use attribute sets from right to left
 437                                 # to avoid invalidating the offsets
 438                                 # when replacing the values
 439                                 my($k_offset, $k_len, $v_offset, $v_len) =
 440                                         splice(@$pos, -4);
 441                                 my $attrname = lc(substr($text, $k_offset, $k_len));
 442                                 next unless grep { $_ eq $attrname } @{$HTML::Tagset::linkElements{$tagname}};
 443                                 next unless $v_offset; # 0 v_offset means no value
 444                                 my $v = substr($text, $v_offset, $v_len);
 445                                 $v =~ s/^([\'\"])(.*)\1$/$2/;
 446                                 my $new_v=urlabs($v, $urlbase);
 447                                 $new_v =~ s/\"/&quot;/g; # since we quote with ""
 448                                 substr($text, $v_offset, $v_len) = qq("$new_v");
 449                         }
 450                 }
 451                 $ret.=$text;
 452         }, "tagname, tokenpos, text");
 453         $p->parse($html);
 454         $p->eof;
 455
 456         return $ret;
 457 } #}}}
 458
 459 sub remove_feeds () { #{{{
 460         my $page=shift;
 461
 462         my %removed;
 463         foreach my $id (keys %feeds) {
 464                 if ($feeds{$id}->{sourcepage} eq $page) {
 465                         $feeds{$id}->{remove}=1;
 466                         $removed{$id}=1;
 467                 }
 468         }
 469 } #}}}
 470
 471 sub pagefile ($) { #{{{
 472         my $page=shift;
 473
 474         return "$config{srcdir}/".htmlfn($page);
 475 } #}}}
 476
 477 sub htmlfn ($) { #{{{
 478         return shift().".".$config{htmlext};
 479 } #}}}
 480
 481 1