IkiWiki/Plugin/orphans.pm

   1 #!/usr/bin/perl
   2 # Provides a list of pages no other page links to.
   3 package IkiWiki::Plugin::orphans;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8
   9 sub import { #{{{
  10         hook(type => "getsetup", id => "orphans", call => \&getsetup);
  11         hook(type => "preprocess", id => "orphans", call => \&preprocess);
  12 } # }}}
  13
  14 sub getsetup () { #{{{
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                 },
  20 } #}}}
  21
  22 sub preprocess (@) { #{{{
  23         my %params=@_;
  24         $params{pages}="*" unless defined $params{pages};
  25
  26         # Needs to update whenever a page is added or removed, so
  27         # register a dependency.
  28         add_depends($params{page}, $params{pages});
  29
  30         my %linkedto;
  31         foreach my $p (keys %links) {
  32                 map { $linkedto{bestlink($p, $_)}=1 if length $_ }
  33                         @{$links{$p}};
  34         }
  35
  36         my @orphans;
  37         my $discussion=gettext("discussion");
  38         foreach my $page (keys %pagesources) {
  39                 next if $linkedto{$page} || $page eq 'index';
  40                 next unless pagespec_match($page, $params{pages}, location => $params{page});
  41                 # If the page has a link to some other page, it's
  42                 # indirectly linked to a page via that page's backlinks.
  43                 next if grep {
  44                         length $_ &&
  45                         ($_ !~ /\/\Q$discussion\E$/i || ! $config{discussion}) &&
  46                         bestlink($page, $_) !~ /^($page|)$/
  47                 } @{$links{$page}};
  48                 push @orphans, $page;
  49         }
  50
  51         return gettext("All pages are linked to by other pages.") unless @orphans;
  52         return "<ul>\n".
  53                 join("\n",
  54                         map {
  55                                 "<li>".
  56                                 htmllink($params{page}, $params{destpage}, $_,
  57                                          noimageinline => 1).
  58                                 "</li>"
  59                         } sort @orphans).
  60                 "</ul>\n";
  61 } # }}}
  62
  63 1