t/git-cgi.t

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4
   5 use Test::More;
   6
   7 BEGIN {
   8         my $git = `which git`;
   9         chomp $git;
  10         plan(skip_all => 'git not available') unless -x $git;
  11
  12         plan(skip_all => "CGI not available")
  13                 unless eval q{
  14                         use CGI qw();
  15                         1;
  16                 };
  17
  18         plan(skip_all => "IPC::Run not available")
  19                 unless eval q{
  20                         use IPC::Run qw(run);
  21                         1;
  22                 };
  23
  24         use_ok('IkiWiki');
  25         use_ok('YAML::XS');
  26 }
  27
  28 # We check for English error messages
  29 $ENV{LC_ALL} = 'C';
  30
  31 use Cwd qw(getcwd);
  32 use Errno qw(ENOENT);
  33
  34 my $installed = $ENV{INSTALLED_TESTS};
  35
  36 my @command;
  37 if ($installed) {
  38         @command = qw(ikiwiki);
  39 }
  40 else {
  41         ok(! system("make -s ikiwiki.out"));
  42         @command = ("perl", "-I".getcwd."/blib/lib", './ikiwiki.out',
  43                 '--underlaydir='.getcwd.'/underlays/basewiki',
  44                 '--set', 'underlaydirbase='.getcwd.'/underlays',
  45                 '--templatedir='.getcwd.'/templates');
  46 }
  47
  48 sub write_old_file {
  49         my $name = shift;
  50         my $dir = shift;
  51         my $content = shift;
  52         writefile($name, $dir, $content);
  53         ok(utime(333333333, 333333333, "$dir/$name"));
  54 }
  55
  56 sub write_setup_file {
  57         my %setup = (
  58                 wikiname => 'this is the name of my wiki',
  59                 srcdir => getcwd.'/t/tmp/in/doc',
  60                 destdir => getcwd.'/t/tmp/out',
  61                 url => 'http://example.com',
  62                 cgiurl => 'http://example.com/cgi-bin/ikiwiki.cgi',
  63                 cgi_wrapper => getcwd.'/t/tmp/ikiwiki.cgi',
  64                 cgi_wrappermode => '0751',
  65                 add_plugins => [qw(anonok lockedit recentchanges)],
  66                 disable_plugins => [qw(emailauth openid passwordauth)],
  67                 anonok_pagespec => 'writable/*',
  68                 locked_pages => '!writable/*',
  69                 rcs => 'git',
  70                 git_wrapper => getcwd.'/t/tmp/in/.git/hooks/post-commit',
  71                 git_wrappermode => '0754',
  72                 gitorigin_branch => '',
  73         );
  74         unless ($installed) {
  75                 $setup{ENV} = { 'PERL5LIB' => getcwd.'/blib/lib' };
  76         }
  77         writefile("test.setup", "t/tmp",
  78                 "# IkiWiki::Setup::Yaml - YAML formatted setup file\n" .
  79                 Dump(\%setup));
  80 }
  81
  82 sub thoroughly_rebuild {
  83         ok(unlink("t/tmp/ikiwiki.cgi") || $!{ENOENT});
  84         ok(unlink("t/tmp/in/.git/hooks/post-commit") || $!{ENOENT});
  85         ok(! system(@command, qw(--setup t/tmp/test.setup --rebuild --wrappers)));
  86 }
  87
  88 sub check_cgi_mode_bits {
  89         my $mode;
  90
  91         (undef, undef, $mode, undef, undef,
  92                 undef, undef, undef, undef, undef,
  93                 undef, undef, undef) = stat('t/tmp/ikiwiki.cgi');
  94         is ($mode & 07777, 0751);
  95         (undef, undef, $mode, undef, undef,
  96                 undef, undef, undef, undef, undef,
  97                 undef, undef, undef) = stat('t/tmp/in/.git/hooks/post-commit');
  98         is ($mode & 07777, 0754);
  99 }
 100
 101 sub run_cgi {
 102         my (%args) = @_;
 103         my ($in, $out);
 104         my $method = $args{method} || 'GET';
 105         my $environ = $args{environ} || {};
 106         my $params = $args{params} || { do => 'prefs' };
 107
 108         my %defaults = (
 109                 SCRIPT_NAME     => '/cgi-bin/ikiwiki.cgi',
 110                 HTTP_HOST       => 'example.com',
 111         );
 112
 113         my $cgi = CGI->new($args{params});
 114         my $query_string = $cgi->query_string();
 115
 116         if ($method eq 'POST') {
 117                 $defaults{REQUEST_METHOD} = 'POST';
 118                 $in = $query_string;
 119                 $defaults{CONTENT_LENGTH} = length $in;
 120         } else {
 121                 $defaults{REQUEST_METHOD} = 'GET';
 122                 $defaults{QUERY_STRING} = $query_string;
 123         }
 124
 125         my %envvars = (
 126                 %defaults,
 127                 %$environ,
 128         );
 129         run(["./t/tmp/ikiwiki.cgi"], \$in, \$out, init => sub {
 130                 map {
 131                         $ENV{$_} = $envvars{$_}
 132                 } keys(%envvars);
 133         });
 134
 135         return $out;
 136 }
 137
 138 sub run_git {
 139         my (undef, $filename, $line) = caller;
 140         my $args = shift;
 141         my $desc = shift || join(' ', 'git', @$args);
 142         my ($in, $out);
 143         ok(run(['git', @$args], \$in, \$out, init => sub {
 144                 chdir 't/tmp/in' or die $!;
 145                 $ENV{EMAIL} = 'nobody@ikiwiki-tests.invalid';
 146         }), "$desc at $filename:$line");
 147         return $out;
 148 }
 149
 150 sub test {
 151         my $content;
 152         my $status;
 153
 154         ok(! system(qw(rm -rf t/tmp)));
 155         ok(! system(qw(mkdir t/tmp)));
 156
 157         write_old_file('.gitignore', 't/tmp/in', "/doc/.ikiwiki/\n");
 158         write_old_file('doc/writable/one.mdwn', 't/tmp/in', 'This is the first test page');
 159         write_old_file('doc/writable/two.mdwn', 't/tmp/in', 'This is the second test page');
 160         write_old_file('doc/writable/three.mdwn', 't/tmp/in', 'This is the third test page');
 161
 162         unless ($installed) {
 163                 ok(! system(qw(cp -pRL doc/wikiicons t/tmp/in/doc/)));
 164                 ok(! system(qw(cp -pRL doc/recentchanges.mdwn t/tmp/in/doc/)));
 165         }
 166
 167         run_git(['init']);
 168         run_git(['add', '.']);
 169         run_git(['commit', '-m', 'Initial commit']);
 170
 171         write_setup_file();
 172         thoroughly_rebuild();
 173         check_cgi_mode_bits();
 174
 175         ok(-e 't/tmp/out/writable/one/index.html');
 176         $content = readfile('t/tmp/out/writable/one/index.html');
 177         like($content, qr{This is the first test page});
 178         my $orig_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 179
 180         # Test the git hook, which accepts git commits
 181         writefile('doc/writable/one.mdwn', 't/tmp/in',
 182                 'This is new content for the first test page');
 183         run_git(['add', '.']);
 184         run_git(['commit', '-m', 'Git commit']);
 185         my $first_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 186         isnt($orig_sha1, $first_revertable_sha1);
 187
 188         ok(-e 't/tmp/out/writable/one/index.html');
 189         $content = readfile('t/tmp/out/writable/one/index.html');
 190         like($content, qr{This is new content for the first test page});
 191
 192         # Test a web commit
 193         $content = run_cgi(method => 'POST',
 194                 params => {
 195                         do => 'edit',
 196                         page => 'writable/two',
 197                         type => 'mdwn',
 198                         editmessage => 'Web commit',
 199                         editcontent => 'Here is new content for the second page',
 200                         _submit => 'Save Page',
 201                         _submitted => '1',
 202                 },
 203         );
 204         like($content, qr{^Status:\s*302\s}m);
 205         like($content, qr{^Location:\s*http://example\.com/writable/two/\?updated}m);
 206         my $second_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 207         isnt($orig_sha1, $second_revertable_sha1);
 208         isnt($first_revertable_sha1, $second_revertable_sha1);
 209
 210         ok(-e 't/tmp/out/writable/two/index.html');
 211         $content = readfile('t/tmp/out/writable/two/index.html');
 212         like($content, qr{Here is new content for the second page});
 213
 214         # Another edit
 215         writefile('doc/writable/three.mdwn', 't/tmp/in',
 216                 'Also new content for the third page');
 217         run_git(['add', '.']);
 218         run_git(['commit', '-m', 'Git commit']);
 219         ok(-e 't/tmp/out/writable/three/index.html');
 220         $content = readfile('t/tmp/out/writable/three/index.html');
 221         like($content, qr{Also new content for the third page});
 222         my $third_revertable_sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 223         isnt($orig_sha1, $third_revertable_sha1);
 224         isnt($second_revertable_sha1, $third_revertable_sha1);
 225
 226         run_git(['mv', 'doc/writable/one.mdwn', 'doc/one.mdwn']);
 227         run_git(['mv', 'doc/writable/two.mdwn', 'two.mdwn']);
 228         run_git(['commit', '-m', 'Rename files to test CVE-2016-10026']);
 229         ok(! -e 't/tmp/out/writable/two/index.html');
 230         ok(! -e 't/tmp/out/writable/one/index.html');
 231         ok(-e 't/tmp/out/one/index.html');
 232         my $sha1_before_revert = run_git(['rev-list', '--max-count=1', 'HEAD']);
 233         isnt($sha1_before_revert, $third_revertable_sha1);
 234
 235         $content = run_cgi(method => 'post',
 236                 params => {
 237                         do => 'revert',
 238                         revertmessage => 'CVE-2016-10026',
 239                         rev => $first_revertable_sha1,
 240                         _submit => 'Revert',
 241                         _submitted_revert => '1',
 242                 },
 243         );
 244         like($content, qr{is locked and cannot be edited});
 245         # The tree is left clean
 246         run_git(['diff', '--exit-code']);
 247         run_git(['diff', '--cached', '--exit-code']);
 248         my $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 249         is($sha1, $sha1_before_revert);
 250
 251         ok(-e 't/tmp/out/one/index.html');
 252         ok(! -e 't/tmp/in/doc/writable/one.mdwn');
 253         ok(-e 't/tmp/in/doc/one.mdwn');
 254         $content = readfile('t/tmp/out/one/index.html');
 255         like($content, qr{This is new content for the first test page});
 256
 257         $content = run_cgi(method => 'post',
 258                 params => {
 259                         do => 'revert',
 260                         revertmessage => 'CVE-2016-10026',
 261                         rev => $second_revertable_sha1,
 262                         _submit => 'Revert',
 263                         _submitted_revert => '1',
 264                 },
 265         );
 266         like($content, qr{you are not allowed to change two\.mdwn});
 267         run_git(['diff', '--exit-code']);
 268         run_git(['diff', '--cached', '--exit-code']);
 269         $sha1 = run_git(['rev-list', '--max-count=1', 'HEAD']);
 270         is($sha1, $sha1_before_revert);
 271
 272         ok(! -e 't/tmp/out/writable/two/index.html');
 273         ok(! -e 't/tmp/out/two/index.html');
 274         ok(! -e 't/tmp/in/doc/writable/two.mdwn');
 275         ok(-e 't/tmp/in/two.mdwn');
 276         $content = readfile('t/tmp/in/two.mdwn');
 277         like($content, qr{Here is new content for the second page});
 278
 279         # This one can legitimately be reverted
 280         $content = run_cgi(method => 'post',
 281                 params => {
 282                         do => 'revert',
 283                         revertmessage => 'not CVE-2016-10026',
 284                         rev => $third_revertable_sha1,
 285                         _submit => 'Revert',
 286                         _submitted_revert => '1',
 287                 },
 288         );
 289         like($content, qr{^Status:\s*302\s}m);
 290         like($content, qr{^Location:\s*http://example\.com/recentchanges/}m);
 291         run_git(['diff', '--exit-code']);
 292         run_git(['diff', '--cached', '--exit-code']);
 293         ok(-e 't/tmp/out/writable/three/index.html');
 294         $content = readfile('t/tmp/out/writable/three/index.html');
 295         like($content, qr{This is the third test page});
 296 }
 297
 298 test();
 299
 300 done_testing();