IkiWiki/UserInfo.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use Storable;
   6
   7 package IkiWiki;
   8
   9 sub userinfo_retrieve () { #{{{
  10         my $userinfo=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
  11         return $userinfo;
  12 } #}}}
  13
  14 sub userinfo_store ($) { #{{{
  15         my $userinfo=shift;
  16
  17         my $oldmask=umask(077);
  18         my $ret=Storable::lock_store($userinfo, "$config{wikistatedir}/userdb");
  19         umask($oldmask);
  20         return $ret;
  21 } #}}}
  22
  23 sub userinfo_get ($$) { #{{{
  24         my $user=shift;
  25         my $field=shift;
  26
  27         my $userinfo=userinfo_retrieve();
  28         if (! defined $userinfo ||
  29             ! exists $userinfo->{$user} || ! ref $userinfo->{$user} ||
  30             ! exists $userinfo->{$user}->{$field}) {
  31                 return "";
  32         }
  33         return $userinfo->{$user}->{$field};
  34 } #}}}
  35
  36 sub userinfo_set ($$$) { #{{{
  37         my $user=shift;
  38         my $field=shift;
  39         my $value=shift;
  40
  41         my $userinfo=userinfo_retrieve();
  42         if (! defined $userinfo ||
  43             ! exists $userinfo->{$user} || ! ref $userinfo->{$user}) {
  44                 return "";
  45         }
  46
  47         $userinfo->{$user}->{$field}=$value;
  48         return userinfo_store($userinfo);
  49 } #}}}
  50
  51 sub userinfo_setall ($$) { #{{{
  52         my $user=shift;
  53         my $info=shift;
  54
  55         my $userinfo=userinfo_retrieve();
  56         if (! defined $userinfo) {
  57                 $userinfo={};
  58         }
  59         $userinfo->{$user}=$info;
  60         return userinfo_store($userinfo);
  61 } #}}}
  62
  63 sub is_admin ($) { #{{{
  64         my $user_name=shift;
  65
  66         return grep { $_ eq $user_name } @{$config{adminuser}};
  67 } #}}}
  68
  69 sub commit_notify_list ($@) { #{{{
  70         my $committer=shift;
  71
  72         my @pages;
  73         foreach my $file (@_) {
  74                 push @pages, grep { $pagesources{$_} eq $file } keys %pagesources;
  75         }
  76
  77         my @ret;
  78         my $userinfo=userinfo_retrieve();
  79         foreach my $user (keys %{$userinfo}) {
  80                 next if $user eq $committer;
  81                 if (exists $userinfo->{$user}->{subscriptions} &&
  82                     length $userinfo->{$user}->{subscriptions} &&
  83                     exists $userinfo->{$user}->{email} &&
  84                     length $userinfo->{$user}->{email} &&
  85                     grep { globlist_match($_, $userinfo->{$user}->{subscriptions}) } @pages) {
  86                         push @ret, $userinfo->{$user}->{email};
  87                 }
  88         }
  89         return @ret;
  90 } #}}}
  91
  92 1