IkiWiki/Plugin/svn.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::svn;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use POSIX qw(setlocale LC_CTYPE);
   8
   9 sub import {
  10         hook(type => "checkconfig", id => "svn", call => \&checkconfig);
  11         hook(type => "getsetup", id => "svn", call => \&getsetup);
  12         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  13         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  14         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  15         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  16         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  17         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  18         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  19         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  20         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  21         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  22         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  23 }
  24
  25 sub checkconfig () {
  26         if (! defined $config{svnpath}) {
  27                 $config{svnpath}="trunk";
  28         }
  29         if (exists $config{svnpath}) {
  30                 # code depends on the path not having extraneous slashes
  31                 $config{svnpath}=~tr#/#/#s;
  32                 $config{svnpath}=~s/\/$//;
  33                 $config{svnpath}=~s/^\///;
  34         }
  35         if (defined $config{svn_wrapper} && length $config{svn_wrapper}) {
  36                 push @{$config{wrappers}}, {
  37                         wrapper => $config{svn_wrapper},
  38                         wrappermode => (defined $config{svn_wrappermode} ? $config{svn_wrappermode} : "04755"),
  39                 };
  40         }
  41 }
  42
  43 sub getsetup () {
  44         return
  45                 plugin => {
  46                         safe => 0, # rcs plugin
  47                         rebuild => undef,
  48                         section => "rcs",
  49                 },
  50                 svnrepo => {
  51                         type => "string",
  52                         example => "/svn/wiki",
  53                         description => "subversion repository location",
  54                         safe => 0, # path
  55                         rebuild => 0,
  56                 },
  57                 svnpath => {
  58                         type => "string",
  59                         example => "trunk",
  60                         description => "path inside repository where the wiki is located",
  61                         safe => 0, # paranoia
  62                         rebuild => 0,
  63                 },
  64                 svn_wrapper => {
  65                         type => "string",
  66                         example => "/svn/wikirepo/hooks/post-commit",
  67                         description => "svn post-commit hook to generate",
  68                         safe => 0, # file
  69                         rebuild => 0,
  70                 },
  71                 svn_wrappermode => {
  72                         type => "string",
  73                         example => '04755',
  74                         description => "mode for svn_wrapper (can safely be made suid)",
  75                         safe => 0,
  76                         rebuild => 0,
  77                 },
  78                 historyurl => {
  79                         type => "string",
  80                         example => "http://svn.example.org/trunk/[[file]]",
  81                         description => "viewvc url to show file history ([[file]] substituted)",
  82                         safe => 1,
  83                         rebuild => 1,
  84                 },
  85                 diffurl => {
  86                         type => "string",
  87                         example => "http://svn.example.org/trunk/[[file]]?root=wiki&amp;r1=[[r1]]&amp;r2=[[r2]]",
  88                         description => "viewvc url to show a diff ([[file]], [[r1]], and [[r2]] substituted)",
  89                         safe => 1,
  90                         rebuild => 1,
  91                 },
  92 }
  93
  94 # svn needs LC_CTYPE set to a UTF-8 locale, so try to find one. Any will do.
  95 sub find_lc_ctype() {
  96         my $current = setlocale(LC_CTYPE());
  97         return $current if $current =~ m/UTF-?8$/i;
  98
  99         # Make some obvious attempts to avoid calling `locale -a`
 100         foreach my $locale ("$current.UTF-8", "en_US.UTF-8", "en_GB.UTF-8") {
 101                 return $locale if setlocale(LC_CTYPE(), $locale);
 102         }
 103
 104         # Try to get all available locales and pick the first UTF-8 one found.
 105         if (my @locale = grep(/UTF-?8$/i, `locale -a`)) {
 106                 chomp @locale;
 107                 return $locale[0] if setlocale(LC_CTYPE(), $locale[0]);
 108         }
 109
 110         # fallback to the current locale
 111         return $current;
 112 }
 113 $ENV{LC_CTYPE} = $ENV{LC_CTYPE} || find_lc_ctype();
 114
 115 sub svn_info ($$) {
 116         my $field=shift;
 117         my $file=shift;
 118
 119         my $info=`LANG=C svn info $file`;
 120         my ($ret)=$info=~/^$field: (.*)$/m;
 121         return $ret;
 122 }
 123
 124 sub rcs_update () {
 125         if (-d "$config{srcdir}/.svn") {
 126                 if (system("svn", "update", "--quiet", $config{srcdir}) != 0) {
 127                         warn("svn update failed\n");
 128                 }
 129         }
 130 }
 131
 132 sub rcs_prepedit ($) {
 133         # Prepares to edit a file under revision control. Returns a token
 134         # that must be passed into rcs_commit when the file is ready
 135         # for committing.
 136         # The file is relative to the srcdir.
 137         my $file=shift;
 138
 139         if (-d "$config{srcdir}/.svn") {
 140                 # For subversion, return the revision of the file when
 141                 # editing begins.
 142                 my $rev=svn_info("Revision", "$config{srcdir}/$file");
 143                 return defined $rev ? $rev : "";
 144         }
 145 }
 146
 147 sub commitmessage (@) {
 148         my %params=@_;
 149
 150         if (defined $params{session}) {
 151                 if (defined $params{session}->param("name")) {
 152                         return "web commit by ".
 153                                 $params{session}->param("name").
 154                                 (length $params{message} ? ": $params{message}" : "");
 155                 }
 156                 elsif (defined $params{session}->remote_addr()) {
 157                         return "web commit from ".
 158                                 $params{session}->remote_addr().
 159                                 (length $params{message} ? ": $params{message}" : "");
 160                 }
 161         }
 162         return $params{message};
 163 }
 164
 165 sub rcs_commit (@) {
 166         # Tries to commit the page; returns undef on _success_ and
 167         # a version of the page with the rcs's conflict markers on failure.
 168         # The file is relative to the srcdir.
 169         my %params=@_;
 170
 171         if (-d "$config{srcdir}/.svn") {
 172                 # Check to see if the page has been changed by someone
 173                 # else since rcs_prepedit was called.
 174                 my ($oldrev)=$params{token}=~/^([0-9]+)$/; # untaint
 175                 my $rev=svn_info("Revision", "$config{srcdir}/$params{file}");
 176                 if (defined $rev && defined $oldrev && $rev != $oldrev) {
 177                         # Merge their changes into the file that we've
 178                         # changed.
 179                         if (system("svn", "merge", "--quiet", "-r$oldrev:$rev",
 180                                    "$config{srcdir}/$params{file}", "$config{srcdir}/$params{file}") != 0) {
 181                                 warn("svn merge -r$oldrev:$rev failed\n");
 182                         }
 183                 }
 184
 185                 if (system("svn", "commit", "--quiet",
 186                            "--encoding", "UTF-8", "-m",
 187                            IkiWiki::possibly_foolish_untaint(commitmessage(%params)),
 188                            $config{srcdir}) != 0) {
 189                         my $conflict=readfile("$config{srcdir}/$params{file}");
 190                         if (system("svn", "revert", "--quiet", "$config{srcdir}/$params{file}") != 0) {
 191                                 warn("svn revert failed\n");
 192                         }
 193                         return $conflict;
 194                 }
 195         }
 196         return undef # success
 197 }
 198
 199 sub rcs_commit_staged (@) {
 200         # Commits all staged changes. Changes can be staged using rcs_add,
 201         # rcs_remove, and rcs_rename.
 202         my %params=@_;
 203
 204         if (system("svn", "commit", "--quiet",
 205                    "--encoding", "UTF-8", "-m",
 206                    IkiWiki::possibly_foolish_untaint(commitmessage(%params)),
 207                    $config{srcdir}) != 0) {
 208                 warn("svn commit failed\n");
 209                 return 1; # failure
 210         }
 211         return undef # success
 212 }
 213
 214 sub rcs_add ($) {
 215         # filename is relative to the root of the srcdir
 216         my $file=shift;
 217
 218         if (-d "$config{srcdir}/.svn") {
 219                 my $parent=IkiWiki::dirname($file);
 220                 while (! -d "$config{srcdir}/$parent/.svn") {
 221                         $file=$parent;
 222                         $parent=IkiWiki::dirname($file);
 223                 }
 224
 225                 if (system("svn", "add", "--quiet", "$config{srcdir}/$file") != 0) {
 226                         warn("svn add failed\n");
 227                 }
 228         }
 229 }
 230
 231 sub rcs_remove ($) {
 232         # filename is relative to the root of the srcdir
 233         my $file=shift;
 234
 235         if (-d "$config{srcdir}/.svn") {
 236                 if (system("svn", "rm", "--force", "--quiet", "$config{srcdir}/$file") != 0) {
 237                         warn("svn rm failed\n");
 238                 }
 239         }
 240 }
 241
 242 sub rcs_rename ($$) {
 243         # filenames relative to the root of the srcdir
 244         my ($src, $dest)=@_;
 245
 246         if (-d "$config{srcdir}/.svn") {
 247                 # Add parent directory for $dest
 248                 my $parent=IkiWiki::dirname($dest);
 249                 if (! -d "$config{srcdir}/$parent/.svn") {
 250                         while (! -d "$config{srcdir}/$parent/.svn") {
 251                                 $parent=IkiWiki::dirname($dest);
 252                         }
 253                         if (system("svn", "add", "--quiet", "$config{srcdir}/$parent") != 0) {
 254                                 warn("svn add $parent failed\n");
 255                         }
 256                 }
 257
 258                 if (system("svn", "mv", "--force", "--quiet",
 259                     "$config{srcdir}/$src", "$config{srcdir}/$dest") != 0) {
 260                         warn("svn rename failed\n");
 261                 }
 262         }
 263 }
 264
 265 sub rcs_recentchanges ($) {
 266         my $num=shift;
 267         my @ret;
 268
 269         return unless -d "$config{srcdir}/.svn";
 270
 271         eval q{
 272                 use Date::Parse;
 273                 use XML::SAX;
 274                 use XML::Simple;
 275         };
 276         error($@) if $@;
 277
 278         # avoid using XML::SAX::PurePerl, it's buggy with UTF-8 data
 279         my @parsers = map { ${$_}{Name} } @{XML::SAX->parsers()};
 280         do {
 281                 $XML::Simple::PREFERRED_PARSER = pop @parsers;
 282         } until $XML::Simple::PREFERRED_PARSER ne 'XML::SAX::PurePerl';
 283
 284         # --limit is only supported on Subversion 1.2.0+
 285         my $svn_version=`svn --version -q`;
 286         my $svn_limit='';
 287         $svn_limit="--limit $num"
 288                 if $svn_version =~ /\d\.(\d)\.\d/ && $1 >= 2;
 289
 290         my $svn_url=svn_info("URL", $config{srcdir});
 291         my $xml = XMLin(scalar `svn $svn_limit --xml -v log '$svn_url'`,
 292                 ForceArray => [ 'logentry', 'path' ],
 293                 GroupTags => { paths => 'path' },
 294                 KeyAttr => { path => 'content' },
 295         );
 296         foreach my $logentry (@{$xml->{logentry}}) {
 297                 my (@pages, @message);
 298
 299                 my $rev = $logentry->{revision};
 300                 my $user = $logentry->{author};
 301
 302                 my $when=str2time($logentry->{date}, 'UTC');
 303
 304                 foreach my $msgline (split(/\n/, $logentry->{msg})) {
 305                         push @message, { line => $msgline };
 306                 }
 307
 308                 my $committype="web";
 309                 if (defined $message[0] &&
 310                     $message[0]->{line}=~/$config{web_commit_regexp}/) {
 311                         $user=defined $2 ? "$2" : "$3";
 312                         $message[0]->{line}=$4;
 313                 }
 314                 else {
 315                         $committype="svn";
 316                 }
 317
 318                 foreach my $file (keys %{$logentry->{paths}}) {
 319                         if (length $config{svnpath}) {
 320                                 next unless $file=~/^\/\Q$config{svnpath}\E\/([^ ]+)(?:$|\s)/;
 321                                 $file=$1;
 322                         }
 323
 324                         my $diffurl=defined $config{diffurl} ? $config{diffurl} : "";
 325                         $diffurl=~s/\[\[file\]\]/$file/g;
 326                         $diffurl=~s/\[\[r1\]\]/$rev - 1/eg;
 327                         $diffurl=~s/\[\[r2\]\]/$rev/g;
 328
 329                         push @pages, {
 330                                 page => pagename($file),
 331                                 diffurl => $diffurl,
 332                         } if length $file;
 333                 }
 334                 push @ret, {
 335                         rev => $rev,
 336                         user => $user,
 337                         committype => $committype,
 338                         when => $when,
 339                         message => [@message],
 340                         pages => [@pages],
 341                 } if @pages;
 342                 return @ret if @ret >= $num;
 343         }
 344
 345         return @ret;
 346 }
 347
 348 sub rcs_diff ($) {
 349         my $rev=IkiWiki::possibly_foolish_untaint(int(shift));
 350         return `svnlook diff $config{svnrepo} -r$rev --no-diff-deleted`;
 351 }
 352
 353 {
 354
 355 my ($lastfile, $lastmtime, $lastctime);
 356
 357 sub findtimes ($) {
 358         my $file=shift;
 359
 360         if (defined $lastfile && $lastfile eq $file) {
 361                 return $lastmtime, $lastctime;
 362         }
 363         $lastfile=$file;
 364
 365         my $svn_log_infoline=qr/^r\d+\s+\|\s+[^\s]+\s+\|\s+(\d+-\d+-\d+\s+\d+:\d+:\d+\s+[-+]?\d+).*/;
 366
 367         my $child = open(SVNLOG, "-|");
 368         if (! $child) {
 369                 exec("svn", "log", "$config{srcdir}/$file") || error("svn log failed to run");
 370         }
 371
 372         my ($cdate, $mdate);
 373         while (<SVNLOG>) {
 374                 if (/$svn_log_infoline/) {
 375                         $cdate=$1;
 376                         $mdate=$1 unless defined $mdate;
 377                 }
 378         }
 379         close SVNLOG || error "svn log exited $?";
 380
 381         if (! defined $cdate) {
 382                 error "failed to parse svn log for $file";
 383         }
 384
 385         eval q{use Date::Parse};
 386         error($@) if $@;
 387
 388         $lastctime=str2time($cdate);
 389         $lastmtime=str2time($mdate);
 390         return $lastmtime, $lastctime;
 391 }
 392
 393 }
 394
 395 sub rcs_getctime ($) {
 396         my $file=shift;
 397
 398         return (findtimes($file))[1];
 399 }
 400
 401 sub rcs_getmtime ($) {
 402         my $file=shift;
 403
 404         return (findtimes($file))[0];
 405 }
 406
 407 1