ikiwiki

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3
   4 package IkiWiki;
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use HTML::Template;
   9 use lib '.'; # For use without installation, removed by Makefile.
  10
  11 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime
  12             %renderedfiles %pagesources %inlinepages};
  13
  14 sub usage () { #{{{
  15         die "usage: ikiwiki [options] source dest\n";
  16 } #}}}
  17
  18 sub getconfig () { #{{{
  19         if (! exists $ENV{WRAPPED_OPTIONS}) {
  20                 %config=(
  21                         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$)},
  22                         wiki_link_regexp => qr/\[\[(?:([^\s\]\|]+)\|)?([^\s\]]+)\]\]/,
  23                         wiki_processor_regexp => qr/\[\[(\w+)\s+([^\]]+)\]\]/,
  24                         wiki_file_regexp => qr/(^[-A-Za-z0-9_.:\/+]+$)/,
  25                         verbose => 0,
  26                         wikiname => "wiki",
  27                         default_pageext => ".mdwn",
  28                         cgi => 0,
  29                         svn => 1,
  30                         url => '',
  31                         cgiurl => '',
  32                         historyurl => '',
  33                         diffurl => '',
  34                         anonok => 0,
  35                         rss => 0,
  36                         rebuild => 0,
  37                         refresh => 0,
  38                         getctime => 0,
  39                         wrapper => undef,
  40                         wrappermode => undef,
  41                         srcdir => undef,
  42                         destdir => undef,
  43                         templatedir => "/usr/share/ikiwiki/templates",
  44                         setup => undef,
  45                         adminuser => undef,
  46                 );
  47
  48                 eval q{use Getopt::Long};
  49                 GetOptions(
  50                         "setup|s=s" => \$config{setup},
  51                         "wikiname=s" => \$config{wikiname},
  52                         "verbose|v!" => \$config{verbose},
  53                         "rebuild!" => \$config{rebuild},
  54                         "refresh!" => \$config{refresh},
  55                         "getctime" => \$config{getctime},
  56                         "wrappermode=i" => \$config{wrappermode},
  57                         "svn!" => \$config{svn},
  58                         "anonok!" => \$config{anonok},
  59                         "rss!" => \$config{rss},
  60                         "cgi!" => \$config{cgi},
  61                         "url=s" => \$config{url},
  62                         "cgiurl=s" => \$config{cgiurl},
  63                         "historyurl=s" => \$config{historyurl},
  64                         "diffurl=s" => \$config{diffurl},
  65                         "exclude=s@" => sub {
  66                                 $config{wiki_file_prune_regexp}=qr/$config{wiki_file_prune_regexp}|$_[1]/;
  67                         },
  68                         "adminuser=s@" => sub {
  69                                 push @{$config{adminuser}}, $_[1]
  70                         },
  71                         "templatedir=s" => sub {
  72                                 $config{templatedir}=possibly_foolish_untaint($_[1])
  73                         },
  74                         "wrapper:s" => sub {
  75                                 $config{wrapper}=$_[1] ? $_[1] : "ikiwiki-wrap"
  76                         },
  77                 ) || usage();
  78
  79                 if (! $config{setup}) {
  80                         usage() unless @ARGV == 2;
  81                         $config{srcdir} = possibly_foolish_untaint(shift @ARGV);
  82                         $config{destdir} = possibly_foolish_untaint(shift @ARGV);
  83                         checkconfig();
  84                 }
  85         }
  86         else {
  87                 # wrapper passes a full config structure in the environment
  88                 # variable
  89                 eval possibly_foolish_untaint($ENV{WRAPPED_OPTIONS});
  90                 checkconfig();
  91         }
  92 } #}}}
  93
  94 sub checkconfig () { #{{{
  95         if ($config{cgi} && ! length $config{url}) {
  96                 error("Must specify url to wiki with --url when using --cgi\n");
  97         }
  98         if ($config{rss} && ! length $config{url}) {
  99                 error("Must specify url to wiki with --url when using --rss\n");
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{svn}) {
 106                 require IkiWiki::Rcs::SVN;
 107                 $config{rcs}=1;
 108         }
 109         else {
 110                 require IkiWiki::Rcs::Stub;
 111                 $config{rcs}=0;
 112         }
 113 } #}}}
 114
 115 sub error ($) { #{{{
 116         if ($config{cgi}) {
 117                 print "Content-type: text/html\n\n";
 118                 print misctemplate("Error", "<p>Error: @_</p>");
 119         }
 120         die @_;
 121 } #}}}
 122
 123 sub possibly_foolish_untaint ($) { #{{{
 124         my $tainted=shift;
 125         my ($untainted)=$tainted=~/(.*)/;
 126         return $untainted;
 127 } #}}}
 128
 129 sub debug ($) { #{{{
 130         return unless $config{verbose};
 131         if (! $config{cgi}) {
 132                 print "@_\n";
 133         }
 134         else {
 135                 print STDERR "@_\n";
 136         }
 137 } #}}}
 138
 139 sub basename ($) { #{{{
 140         my $file=shift;
 141
 142         $file=~s!.*/!!;
 143         return $file;
 144 } #}}}
 145
 146 sub dirname ($) { #{{{
 147         my $file=shift;
 148
 149         $file=~s!/?[^/]+$!!;
 150         return $file;
 151 } #}}}
 152
 153 sub pagetype ($) { #{{{
 154         my $page=shift;
 155
 156         if ($page =~ /\.mdwn$/) {
 157                 return ".mdwn";
 158         }
 159         else {
 160                 return "unknown";
 161         }
 162 } #}}}
 163
 164 sub pagename ($) { #{{{
 165         my $file=shift;
 166
 167         my $type=pagetype($file);
 168         my $page=$file;
 169         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 170         return $page;
 171 } #}}}
 172
 173 sub htmlpage ($) { #{{{
 174         my $page=shift;
 175
 176         return $page.".html";
 177 } #}}}
 178
 179 sub readfile ($) { #{{{
 180         my $file=shift;
 181
 182         if (-l $file) {
 183                 error("cannot read a symlink ($file)");
 184         }
 185
 186         local $/=undef;
 187         open (IN, "$file") || error("failed to read $file: $!");
 188         my $ret=<IN>;
 189         close IN;
 190         return $ret;
 191 } #}}}
 192
 193 sub writefile ($$) { #{{{
 194         my $file=shift;
 195         my $content=shift;
 196
 197         if (-l $file) {
 198                 error("cannot write to a symlink ($file)");
 199         }
 200
 201         my $dir=dirname($file);
 202         if (! -d $dir) {
 203                 my $d="";
 204                 foreach my $s (split(m!/+!, $dir)) {
 205                         $d.="$s/";
 206                         if (! -d $d) {
 207                                 mkdir($d) || error("failed to create directory $d: $!");
 208                         }
 209                 }
 210         }
 211
 212         open (OUT, ">$file") || error("failed to write $file: $!");
 213         print OUT $content;
 214         close OUT;
 215 } #}}}
 216
 217 sub bestlink ($$) { #{{{
 218         # Given a page and the text of a link on the page, determine which
 219         # existing page that link best points to. Prefers pages under a
 220         # subdirectory with the same name as the source page, failing that
 221         # goes down the directory tree to the base looking for matching
 222         # pages.
 223         my $page=shift;
 224         my $link=lc(shift);
 225
 226         my $cwd=$page;
 227         do {
 228                 my $l=$cwd;
 229                 $l.="/" if length $l;
 230                 $l.=$link;
 231
 232                 if (exists $links{$l}) {
 233                         #debug("for $page, \"$link\", use $l");
 234                         return $l;
 235                 }
 236         } while $cwd=~s!/?[^/]+$!!;
 237
 238         #print STDERR "warning: page $page, broken link: $link\n";
 239         return "";
 240 } #}}}
 241
 242 sub isinlinableimage ($) { #{{{
 243         my $file=shift;
 244
 245         $file=~/\.(png|gif|jpg|jpeg)$/i;
 246 } #}}}
 247
 248 sub pagetitle ($) { #{{{
 249         my $page=shift;
 250         $page=~s/__(\d+)__/&#$1;/g;
 251         $page=~y/_/ /;
 252         return $page;
 253 } #}}}
 254
 255 sub titlepage ($) { #{{{
 256         my $title=shift;
 257         $title=~y/ /_/;
 258         $title=~s/([^-A-Za-z0-9_:+\/])/"__".ord($1)."__"/eg;
 259         return $title;
 260 } #}}}
 261
 262 sub htmllink ($$;$$$) { #{{{
 263         my $page=shift;
 264         my $link=shift;
 265         my $noimageinline=shift; # don't turn links into inline html images
 266         my $forcesubpage=shift; # force a link to a subpage
 267         my $linktext=shift; # set to force the link text to something
 268
 269         my $bestlink;
 270         if (! $forcesubpage) {
 271                 $bestlink=bestlink($page, $link);
 272         }
 273         else {
 274                 $bestlink="$page/".lc($link);
 275         }
 276
 277         $linktext=pagetitle(basename($link)) unless defined $linktext;
 278
 279         return $linktext if length $bestlink && $page eq $bestlink;
 280
 281         # TODO BUG: %renderedfiles may not have it, if the linked to page
 282         # was also added and isn't yet rendered! Note that this bug is
 283         # masked by the bug mentioned below that makes all new files
 284         # be rendered twice.
 285         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 286                 $bestlink=htmlpage($bestlink);
 287         }
 288         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 289                 return "<span><a href=\"$config{cgiurl}?do=create&page=$link&from=$page\">?</a>$linktext</span>"
 290         }
 291
 292         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 293
 294         if (! $noimageinline && isinlinableimage($bestlink)) {
 295                 return "<img src=\"$bestlink\">";
 296         }
 297         return "<a href=\"$bestlink\">$linktext</a>";
 298 } #}}}
 299
 300 sub indexlink () { #{{{
 301         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 302 } #}}}
 303
 304 sub lockwiki () { #{{{
 305         # Take an exclusive lock on the wiki to prevent multiple concurrent
 306         # run issues. The lock will be dropped on program exit.
 307         if (! -d $config{wikistatedir}) {
 308                 mkdir($config{wikistatedir});
 309         }
 310         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 311                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 312         if (! flock(WIKILOCK, 2 | 4)) {
 313                 debug("wiki seems to be locked, waiting for lock");
 314                 my $wait=600; # arbitrary, but don't hang forever to
 315                               # prevent process pileup
 316                 for (1..600) {
 317                         return if flock(WIKILOCK, 2 | 4);
 318                         sleep 1;
 319                 }
 320                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 321         }
 322 } #}}}
 323
 324 sub unlockwiki () { #{{{
 325         close WIKILOCK;
 326 } #}}}
 327
 328 sub loadindex () { #{{{
 329         open (IN, "$config{wikistatedir}/index") || return;
 330         while (<IN>) {
 331                 $_=possibly_foolish_untaint($_);
 332                 chomp;
 333                 my %items;
 334                 $items{link}=[];
 335                 foreach my $i (split(/ /, $_)) {
 336                         my ($item, $val)=split(/=/, $i, 2);
 337                         push @{$items{$item}}, $val;
 338                 }
 339
 340                 next unless exists $items{src}; # skip bad lines for now
 341
 342                 my $page=pagename($items{src}[0]);
 343                 if (! $config{rebuild}) {
 344                         $pagesources{$page}=$items{src}[0];
 345                         $oldpagemtime{$page}=$items{mtime}[0];
 346                         $oldlinks{$page}=[@{$items{link}}];
 347                         $links{$page}=[@{$items{link}}];
 348                         $inlinepages{$page}=join(" ", @{$items{inlinepage}})
 349                                 if exists $items{inlinepage};
 350                         $renderedfiles{$page}=$items{dest}[0];
 351                 }
 352                 $pagectime{$page}=$items{ctime}[0];
 353         }
 354         close IN;
 355 } #}}}
 356
 357 sub saveindex () { #{{{
 358         if (! -d $config{wikistatedir}) {
 359                 mkdir($config{wikistatedir});
 360         }
 361         open (OUT, ">$config{wikistatedir}/index") ||
 362                 error("cannot write to $config{wikistatedir}/index: $!");
 363         foreach my $page (keys %oldpagemtime) {
 364                 next unless $oldpagemtime{$page};
 365                 my $line="mtime=$oldpagemtime{$page} ".
 366                         "ctime=$pagectime{$page} ".
 367                         "src=$pagesources{$page} ".
 368                         "dest=$renderedfiles{$page}";
 369                 $line.=" link=$_" foreach @{$links{$page}};
 370                 if (exists $inlinepages{$page}) {
 371                         $line.=" inlinepage=$_" foreach split " ", $inlinepages{$page};
 372                 }
 373                 print OUT $line."\n";
 374         }
 375         close OUT;
 376 } #}}}
 377
 378 sub misctemplate ($$) { #{{{
 379         my $title=shift;
 380         my $pagebody=shift;
 381
 382         my $template=HTML::Template->new(
 383                 filename => "$config{templatedir}/misc.tmpl"
 384         );
 385         $template->param(
 386                 title => $title,
 387                 indexlink => indexlink(),
 388                 wikiname => $config{wikiname},
 389                 pagebody => $pagebody,
 390         );
 391         return $template->output;
 392 }#}}}
 393
 394 sub userinfo_get ($$) { #{{{
 395         my $user=shift;
 396         my $field=shift;
 397
 398         eval q{use Storable};
 399         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 400         if (! defined $userdata || ! ref $userdata ||
 401             ! exists $userdata->{$user} || ! ref $userdata->{$user} ||
 402             ! exists $userdata->{$user}->{$field}) {
 403                 return "";
 404         }
 405         return $userdata->{$user}->{$field};
 406 } #}}}
 407
 408 sub userinfo_set ($$$) { #{{{
 409         my $user=shift;
 410         my $field=shift;
 411         my $value=shift;
 412
 413         eval q{use Storable};
 414         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 415         if (! defined $userdata || ! ref $userdata ||
 416             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 417                 return "";
 418         }
 419
 420         $userdata->{$user}->{$field}=$value;
 421         my $oldmask=umask(077);
 422         my $ret=Storable::lock_store($userdata, "$config{wikistatedir}/userdb");
 423         umask($oldmask);
 424         return $ret;
 425 } #}}}
 426
 427 sub userinfo_setall ($$) { #{{{
 428         my $user=shift;
 429         my $info=shift;
 430
 431         eval q{use Storable};
 432         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 433         if (! defined $userdata || ! ref $userdata) {
 434                 $userdata={};
 435         }
 436         $userdata->{$user}=$info;
 437         my $oldmask=umask(077);
 438         my $ret=Storable::lock_store($userdata, "$config{wikistatedir}/userdb");
 439         umask($oldmask);
 440         return $ret;
 441 } #}}}
 442
 443 sub is_admin ($) { #{{{
 444         my $user_name=shift;
 445
 446         return grep { $_ eq $user_name } @{$config{adminuser}};
 447 } #}}}
 448
 449 sub glob_match ($$) { #{{{
 450         my $page=shift;
 451         my $glob=shift;
 452
 453         # turn glob into safe regexp
 454         $glob=quotemeta($glob);
 455         $glob=~s/\\\*/.*/g;
 456         $glob=~s/\\\?/./g;
 457         $glob=~s!\\/!/!g;
 458
 459         $page=~/^$glob$/i;
 460 } #}}}
 461
 462 sub globlist_match ($$) { #{{{
 463         my $page=shift;
 464         my @globlist=split(" ", shift);
 465
 466         # check any negated globs first
 467         foreach my $glob (@globlist) {
 468                 return 0 if $glob=~/^!(.*)/ && glob_match($page, $1);
 469         }
 470
 471         foreach my $glob (@globlist) {
 472                 return 1 if glob_match($page, $glob);
 473         }
 474
 475         return 0;
 476 } #}}}
 477
 478 sub main () { #{{{
 479         getconfig();
 480
 481         if ($config{cgi}) {
 482                 lockwiki();
 483                 loadindex();
 484                 require IkiWiki::CGI;
 485                 cgi();
 486         }
 487         elsif ($config{setup}) {
 488                 require IkiWiki::Setup;
 489                 setup();
 490         }
 491         elsif ($config{wrapper}) {
 492                 lockwiki();
 493                 require IkiWiki::Wrapper;
 494                 gen_wrapper();
 495         }
 496         else {
 497                 lockwiki();
 498                 loadindex();
 499                 require IkiWiki::Render;
 500                 rcs_update();
 501                 rcs_getctime() if $config{getctime};
 502                 refresh();
 503                 saveindex();
 504         }
 505 } #}}}
 506
 507 main;