IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("_istranslation");
  27 memoize("percenttranslated");
  28
  29 sub import { #{{{
  30         hook(type => "getsetup", id => "po", call => \&getsetup);
  31         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  32         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  33         hook(type => "scan", id => "po", call => \&scan, last =>1);
  34         hook(type => "filter", id => "po", call => \&filter);
  35         hook(type => "htmlize", id => "po", call => \&htmlize);
  36         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  37         hook(type => "change", id => "po", call => \&change);
  38         hook(type => "editcontent", id => "po", call => \&editcontent);
  39
  40         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  41         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  42         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  43         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  44         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  45         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  46         $origsubs{'urlto'}=\&IkiWiki::urlto;
  47         inject(name => "IkiWiki::urlto", call => \&myurlto);
  48 } #}}}
  49
  50
  51 # ,----
  52 # | Table of contents
  53 # `----
  54
  55 # 1. Hooks
  56 # 2. Injected functions
  57 # 3. Blackboxes for private data
  58 # 4. Helper functions
  59 # 5. PageSpec's
  60
  61
  62 # ,----
  63 # | Hooks
  64 # `----
  65
  66 sub getsetup () { #{{{
  67         return
  68                 plugin => {
  69                         safe => 0,
  70                         rebuild => 1,
  71                 },
  72                 po_master_language => {
  73                         type => "string",
  74                         example => {
  75                                 'code' => 'en',
  76                                 'name' => 'English'
  77                         },
  78                         description => "master language (non-PO files)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 po_slave_languages => {
  83                         type => "string",
  84                         example => {
  85                                 'fr' => 'Français',
  86                                 'es' => 'Castellano',
  87                                 'de' => 'Deutsch'
  88                         },
  89                         description => "slave languages (PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_translatable_pages => {
  94                         type => "pagespec",
  95                         example => "!*/Discussion",
  96                         description => "PageSpec controlling which pages are translatable",
  97                         link => "ikiwiki/PageSpec",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_link_to => {
 102                         type => "string",
 103                         example => "current",
 104                         description => "internal linking behavior (default/current/negotiated)",
 105                         safe => 1,
 106                         rebuild => 1,
 107                 },
 108 } #}}}
 109
 110 sub checkconfig () { #{{{
 111         foreach my $field (qw{po_master_language po_slave_languages}) {
 112                 if (! exists $config{$field} || ! defined $config{$field}) {
 113                         error(sprintf(gettext("Must specify %s"), $field));
 114                 }
 115         }
 116         if (! (keys %{$config{po_slave_languages}})) {
 117                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 118         }
 119         map {
 120                 islanguagecode($_)
 121                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 122         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 123         if (! exists $config{po_translatable_pages} ||
 124             ! defined $config{po_translatable_pages}) {
 125                 $config{po_translatable_pages}="";
 126         }
 127         if (! exists $config{po_link_to} ||
 128             ! defined $config{po_link_to}) {
 129                 $config{po_link_to}='default';
 130         }
 131         elsif (! grep {
 132                         $config{po_link_to} eq $_
 133                 } ('default', 'current', 'negotiated')) {
 134                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 135                                 $config{po_link_to}));
 136                 $config{po_link_to}='default';
 137         }
 138         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 139                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 140                 $config{po_link_to}='default';
 141         }
 142         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 143 } #}}}
 144
 145 sub needsbuild () { #{{{
 146         my $needsbuild=shift;
 147
 148         # backup @needsbuild content so that change() can know whether
 149         # a given master page was rendered because its source file was changed
 150         @origneedsbuild=(@$needsbuild);
 151
 152         buildtranslationscache();
 153
 154         # make existing translations depend on the corresponding master page
 155         foreach my $master (keys %translations) {
 156                 map add_depends($_, $master), values %{otherlanguages($master)};
 157         }
 158 } #}}}
 159
 160 # Massage the recorded state of internal links so that:
 161 # - it matches the actually generated links, rather than the links as written
 162 #   in the pages' source
 163 # - backlinks are consistent in all cases
 164 sub scan (@) { #{{{
 165         my %params=@_;
 166         my $page=$params{page};
 167         my $content=$params{content};
 168
 169         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 170
 171         if (istranslation($page)) {
 172                 foreach my $destpage (@{$links{$page}}) {
 173                         if (istranslatable($destpage)) {
 174                                 # replace one occurence of $destpage in $links{$page}
 175                                 # (we only want to replace the one that was added by
 176                                 # IkiWiki::Plugin::link::scan, other occurences may be
 177                                 # there for other reasons)
 178                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 179                                         if (@{$links{$page}}[$i] eq $destpage) {
 180                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 181                                                 last;
 182                                         }
 183                                 }
 184                         }
 185                 }
 186         }
 187         elsif (! istranslatable($page) && ! istranslation($page)) {
 188                 foreach my $destpage (@{$links{$page}}) {
 189                         if (istranslatable($destpage)) {
 190                                 # make sure any destpage's translations has
 191                                 # $page in its backlinks
 192                                 push @{$links{$page}},
 193                                         values %{otherlanguages($destpage)};
 194                         }
 195                 }
 196         }
 197 } #}}}
 198
 199 # We use filter to convert PO to the master page's format,
 200 # since the rest of ikiwiki should not work on PO files.
 201 sub filter (@) { #{{{
 202         my %params = @_;
 203
 204         my $page = $params{page};
 205         my $destpage = $params{destpage};
 206         my $content = decode_utf8(encode_utf8($params{content}));
 207
 208         return $content if ( ! istranslation($page)
 209                              || alreadyfiltered($page, $destpage) );
 210
 211         # CRLF line terminators make poor Locale::Po4a feel bad
 212         $content=~s/\r\n/\n/g;
 213
 214         # Implementation notes
 215         #
 216         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 217         #    to learn how to disguise a variable as a file.
 218         # 2. There are incompatibilities between some File::Temp versions
 219         #    (including 0.18, bundled with Lenny's perl-modules package)
 220         #    and others (e.g. 0.20, previously present in the archive as
 221         #    a standalone package): under certain circumstances, some
 222         #    return a relative filename, whereas others return an absolute one;
 223         #    we here use this module in a way that is at least compatible
 224         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 225         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 226                                     DIR => File::Spec->tmpdir,
 227                                     UNLINK => 1)->filename;
 228         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 229                                      DIR => File::Spec->tmpdir,
 230                                      UNLINK => 1)->filename;
 231
 232         writefile(basename($infile), File::Spec->tmpdir, $content);
 233
 234         my $masterfile = srcfile($pagesources{masterpage($page)});
 235         my (@pos,@masters);
 236         push @pos,$infile;
 237         push @masters,$masterfile;
 238         my %options = (
 239                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 240         );
 241         my $doc=Locale::Po4a::Chooser::new('text',%options);
 242         $doc->process(
 243                 'po_in_name'    => \@pos,
 244                 'file_in_name'  => \@masters,
 245                 'file_in_charset'  => 'utf-8',
 246                 'file_out_charset' => 'utf-8',
 247         ) or error("[po/filter:$page]: failed to translate");
 248         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 249         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 250
 251         # Unlinking should happen automatically, thanks to File::Temp,
 252         # but it does not work here, probably because of the way writefile()
 253         # and Locale::Po4a::write() work.
 254         unlink $infile, $outfile;
 255
 256         setalreadyfiltered($page, $destpage);
 257         return $content;
 258 } #}}}
 259
 260 sub htmlize (@) { #{{{
 261         my %params=@_;
 262
 263         my $page = $params{page};
 264         my $content = $params{content};
 265         my $masterfile = srcfile($pagesources{masterpage($page)});
 266
 267         # force content to be htmlize'd as if it was the same type as the master page
 268         return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
 269 } #}}}
 270
 271 sub pagetemplate (@) { #{{{
 272         my %params=@_;
 273         my $page=$params{page};
 274         my $destpage=$params{destpage};
 275         my $template=$params{template};
 276
 277         my ($masterpage, $lang) = istranslation($page);
 278
 279         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 280                 $template->param(percenttranslated => percenttranslated($page));
 281         }
 282         if ($template->query(name => "istranslation")) {
 283                 $template->param(istranslation => scalar istranslation($page));
 284         }
 285         if ($template->query(name => "istranslatable")) {
 286                 $template->param(istranslatable => istranslatable($page));
 287         }
 288         if ($template->query(name => "HOMEPAGEURL")) {
 289                 $template->param(homepageurl => homepageurl($page));
 290         }
 291         if ($template->query(name => "otherlanguages")) {
 292                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 293                 map add_depends($page, $_), (values %{otherlanguages($page)});
 294         }
 295         # Rely on IkiWiki::Render's genpage() to decide wether
 296         # a discussion link should appear on $page; this is not
 297         # totally accurate, though: some broken links may be generated
 298         # when cgiurl is disabled.
 299         # This compromise avoids some code duplication, and will probably
 300         # prevent future breakage when ikiwiki internals change.
 301         # Known limitations are preferred to future random bugs.
 302         if ($template->param('discussionlink') && istranslation($page)) {
 303                 $template->param('discussionlink' => htmllink(
 304                                                         $page,
 305                                                         $destpage,
 306                                                         $masterpage . '/' . gettext("Discussion"),
 307                                                         noimageinline => 1,
 308                                                         forcesubpage => 0,
 309                                                         linktext => gettext("Discussion"),
 310                                                         ));
 311         }
 312         # Remove broken parentlink to ./index.html on home page's translations.
 313         # It works because this hook has the "last" parameter set, to ensure it
 314         # runs after parentlinks' own pagetemplate hook.
 315         if ($template->param('parentlinks')
 316             && istranslation($page)
 317             && $masterpage eq "index") {
 318                 $template->param('parentlinks' => []);
 319         }
 320 } # }}}
 321
 322 sub change(@) { #{{{
 323         my @rendered=@_;
 324
 325         my $updated_po_files=0;
 326
 327         # Refresh/create POT and PO files as needed.
 328         foreach my $page (map pagename($_), @rendered) {
 329                 next unless istranslatable($page);
 330                 my $file=srcfile($pagesources{$page});
 331                 my $updated_pot_file=0;
 332                 # Only refresh Pot file if it does not exist, or if
 333                 # $pagesources{$page} was changed: don't if only the HTML was
 334                 # refreshed, e.g. because of a dependency.
 335                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 336                     || ! -e potfile($file)) {
 337                         refreshpot($file);
 338                         $updated_pot_file=1;
 339                 }
 340                 my @pofiles;
 341                 map {
 342                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 343                 } (pofiles($file));
 344                 if (@pofiles) {
 345                         refreshpofiles($file, @pofiles);
 346                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 347                         $updated_po_files=1;
 348                 }
 349         }
 350
 351         if ($updated_po_files) {
 352                 # Check staged changes in.
 353                 if ($config{rcs}) {
 354                         IkiWiki::disable_commit_hook();
 355                         IkiWiki::rcs_commit_staged(gettext("updated PO files"),
 356                                 "IkiWiki::Plugin::po::change", "127.0.0.1");
 357                         IkiWiki::enable_commit_hook();
 358                         IkiWiki::rcs_update();
 359                 }
 360                 # Reinitialize module's private variables.
 361                 resetalreadyfiltered();
 362                 resettranslationscache();
 363                 # Trigger a wiki refresh.
 364                 require IkiWiki::Render;
 365                 IkiWiki::refresh();
 366                 IkiWiki::saveindex();
 367         }
 368 } #}}}
 369
 370 # As we're previewing or saving a page, the content may have
 371 # changed, so tell the next filter() invocation it must not be lazy.
 372 sub editcontent () { #{{{
 373         my %params=@_;
 374
 375         unsetalreadyfiltered($params{page}, $params{page});
 376         return $params{content};
 377 } #}}}
 378
 379
 380 # ,----
 381 # | Injected functions
 382 # `----
 383
 384 # Implement po_link_to=current
 385 sub mybestlink ($$) { #{{{
 386         my $page=shift;
 387         my $link=shift;
 388
 389         my $res=$origsubs{'bestlink'}->($page, $link);
 390         if (length $res
 391             && $config{po_link_to} eq "current"
 392             && istranslatable($res)
 393             && istranslation($page)) {
 394                 return $res . "." . lang($page);
 395         }
 396         return $res;
 397 } #}}}
 398
 399 sub mybeautify_urlpath ($) { #{{{
 400         my $url=shift;
 401
 402         my $res=$origsubs{'beautify_urlpath'}->($url);
 403         if ($config{po_link_to} eq "negotiated") {
 404                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 405         }
 406         return $res;
 407 } #}}}
 408
 409 sub mytargetpage ($$) { #{{{
 410         my $page=shift;
 411         my $ext=shift;
 412
 413         if (istranslation($page) || istranslatable($page)) {
 414                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 415                 if (! $config{usedirs} || $masterpage eq 'index') {
 416                         return $masterpage . "." . $lang . "." . $ext;
 417                 }
 418                 else {
 419                         return $masterpage . "/index." . $lang . "." . $ext;
 420                 }
 421         }
 422         return $origsubs{'targetpage'}->($page, $ext);
 423 } #}}}
 424
 425 sub myurlto ($$;$) { #{{{
 426         my $to=shift;
 427         my $from=shift;
 428         my $absolute=shift;
 429
 430         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 431         if (! length $to
 432             && $config{po_link_to} eq "current"
 433             && istranslatable('index')) {
 434                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 435         }
 436         return $origsubs{'urlto'}->($to,$from,$absolute);
 437 } #}}}
 438
 439
 440 # ,----
 441 # | Blackboxes for private data
 442 # `----
 443
 444 {
 445         my %filtered;
 446
 447         sub alreadyfiltered($$) { #{{{
 448                 my $page=shift;
 449                 my $destpage=shift;
 450
 451                 return ( exists $filtered{$page}{$destpage}
 452                          && $filtered{$page}{$destpage} eq 1 );
 453         } #}}}
 454
 455         sub setalreadyfiltered($$) { #{{{
 456                 my $page=shift;
 457                 my $destpage=shift;
 458
 459                 $filtered{$page}{$destpage}=1;
 460         } #}}}
 461
 462         sub unsetalreadyfiltered($$) { #{{{
 463                 my $page=shift;
 464                 my $destpage=shift;
 465
 466                 if (exists $filtered{$page}{$destpage}) {
 467                         delete $filtered{$page}{$destpage};
 468                 }
 469         } #}}}
 470
 471         sub resetalreadyfiltered() { #{{{
 472                 undef %filtered;
 473         } #}}}
 474 }
 475
 476
 477 # ,----
 478 # | Helper functions
 479 # `----
 480
 481 sub istranslatable ($) { #{{{
 482         my $page=shift;
 483
 484         my $file=$pagesources{$page};
 485
 486         return 0 unless defined $file;
 487         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 488         return 0 if $file =~ /\.pot$/;
 489         return pagespec_match($page, $config{po_translatable_pages});
 490 } #}}}
 491
 492 sub _istranslation ($) { #{{{
 493         my $page=shift;
 494
 495         my $file=$pagesources{$page};
 496
 497         return 0 unless (defined $file
 498                          && defined pagetype($file)
 499                          && pagetype($file) eq 'po');
 500         return 0 if $file =~ /\.pot$/;
 501
 502         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 503         return 0 unless (defined $masterpage && defined $lang
 504                          && length $masterpage && length $lang
 505                          && defined $pagesources{$masterpage}
 506                          && defined $config{po_slave_languages}{$lang});
 507
 508         return ($masterpage, $lang) if istranslatable($masterpage);
 509 } #}}}
 510
 511 sub istranslation ($) { #{{{
 512         my $page=shift;
 513
 514         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 515                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 516                 return ($masterpage, $lang);
 517         }
 518         return;
 519 } #}}}
 520
 521 sub masterpage ($) { #{{{
 522         my $page=shift;
 523
 524         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 525                 return $masterpage;
 526         }
 527         return $page;
 528 } #}}}
 529
 530 sub lang ($) { #{{{
 531         my $page=shift;
 532
 533         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 534                 return $lang;
 535         }
 536         return $config{po_master_language}{code};
 537 } #}}}
 538
 539 sub islanguagecode ($) { #{{{
 540         my $code=shift;
 541
 542         return ($code =~ /^[a-z]{2}$/);
 543 } #}}}
 544
 545 sub otherlanguages($) { #{{{
 546         my $page=shift;
 547
 548         my %ret;
 549         if (istranslatable($page)) {
 550                 %ret = %{$translations{$page}};
 551         }
 552         elsif (istranslation($page)) {
 553                 my $masterpage = masterpage($page);
 554                 $ret{$config{po_master_language}{code}} = $masterpage;
 555                 foreach my $lang (sort keys %{$translations{$masterpage}}) {
 556                         next if $lang eq lang($page);
 557                         $ret{$lang} = $translations{$masterpage}{$lang};
 558                 }
 559         }
 560         return \%ret;
 561 } #}}}
 562
 563 sub potfile ($) { #{{{
 564         my $masterfile=shift;
 565
 566         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 567         $dir='' if $dir eq './';
 568         return File::Spec->catpath('', $dir, $name . ".pot");
 569 } #}}}
 570
 571 sub pofile ($$) { #{{{
 572         my $masterfile=shift;
 573         my $lang=shift;
 574
 575         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 576         $dir='' if $dir eq './';
 577         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 578 } #}}}
 579
 580 sub pofiles ($) { #{{{
 581         my $masterfile=shift;
 582
 583         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 584 } #}}}
 585
 586 sub refreshpot ($) { #{{{
 587         my $masterfile=shift;
 588
 589         my $potfile=potfile($masterfile);
 590         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 591         my $doc=Locale::Po4a::Chooser::new('text',%options);
 592         $doc->{TT}{utf_mode} = 1;
 593         $doc->{TT}{file_in_charset} = 'utf-8';
 594         $doc->{TT}{file_out_charset} = 'utf-8';
 595         $doc->read($masterfile);
 596         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 597         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 598         # compulsory since this module prevents us from using the porefs option.
 599         my %po_options = ('porefs' => 'none');
 600         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 601         $doc->{TT}{po_out}->set_charset('utf-8');
 602         # do the actual work
 603         $doc->parse;
 604         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 605         $doc->writepo($potfile);
 606 } #}}}
 607
 608 sub refreshpofiles ($@) { #{{{
 609         my $masterfile=shift;
 610         my @pofiles=@_;
 611
 612         my $potfile=potfile($masterfile);
 613         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 614
 615         foreach my $pofile (@pofiles) {
 616                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 617                 if (-e $pofile) {
 618                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 619                                 or error("[po/refreshpofiles:$pofile] failed to update");
 620                 }
 621                 else {
 622                         File::Copy::syscopy($potfile,$pofile)
 623                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 624                 }
 625         }
 626 } #}}}
 627
 628 sub buildtranslationscache() { #{{{
 629         # use istranslation's side-effect
 630         map istranslation($_), (keys %pagesources);
 631 } #}}}
 632
 633 sub resettranslationscache() { #{{{
 634         undef %translations;
 635 } #}}}
 636
 637 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 638         my $to=shift;
 639         my $from=shift;
 640
 641         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 642         my $res=urlto($to, $from);
 643         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 644
 645         return $res;
 646 } #}}}
 647
 648 sub percenttranslated ($) { #{{{
 649         my $page=shift;
 650
 651         return gettext("N/A") unless istranslation($page);
 652         my $file=srcfile($pagesources{$page});
 653         my $masterfile = srcfile($pagesources{masterpage($page)});
 654         my (@pos,@masters);
 655         push @pos,$file;
 656         push @masters,$masterfile;
 657         my %options = (
 658                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 659         );
 660         my $doc=Locale::Po4a::Chooser::new('text',%options);
 661         $doc->process(
 662                 'po_in_name'    => \@pos,
 663                 'file_in_name'  => \@masters,
 664                 'file_in_charset'  => 'utf-8',
 665                 'file_out_charset' => 'utf-8',
 666         ) or error("[po/percenttranslated:$page]: failed to translate");
 667         my ($percent,$hit,$queries) = $doc->stats();
 668         return $percent;
 669 } #}}}
 670
 671 sub languagename ($) { #{{{
 672         my $code=shift;
 673
 674         return $config{po_master_language}{name}
 675                 if $code eq $config{po_master_language}{code};
 676         return $config{po_slave_languages}{$code}
 677                 if defined $config{po_slave_languages}{$code};
 678         return;
 679 } #}}}
 680
 681 sub otherlanguagesloop ($) { #{{{
 682         my $page=shift;
 683
 684         my @ret;
 685         my %otherpages=%{otherlanguages($page)};
 686         while (my ($lang, $otherpage) = each %otherpages) {
 687                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 688                         push @ret, {
 689                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 690                                 code => $lang,
 691                                 language => languagename($lang),
 692                                 master => 1,
 693                         };
 694                 }
 695                 else {
 696                         push @ret, {
 697                                 url => urlto($otherpage, $page),
 698                                 code => $lang,
 699                                 language => languagename($lang),
 700                                 percent => percenttranslated($otherpage),
 701                         }
 702                 }
 703         }
 704         return sort {
 705                         return -1 if $a->{code} eq $config{po_master_language}{code};
 706                         return 1 if $b->{code} eq $config{po_master_language}{code};
 707                         return $a->{language} cmp $b->{language};
 708                 } @ret;
 709 } #}}}
 710
 711 sub homepageurl (;$) { #{{{
 712         my $page=shift;
 713
 714         return urlto('', $page);
 715 } #}}}
 716
 717 # ,----
 718 # | PageSpec's
 719 # `----
 720
 721 package IkiWiki::PageSpec;
 722 use warnings;
 723 use strict;
 724 use IkiWiki 2.00;
 725
 726 sub match_istranslation ($;@) { #{{{
 727         my $page=shift;
 728
 729         if (IkiWiki::Plugin::po::istranslation($page)) {
 730                 return IkiWiki::SuccessReason->new("is a translation page");
 731         }
 732         else {
 733                 return IkiWiki::FailReason->new("is not a translation page");
 734         }
 735 } #}}}
 736
 737 sub match_istranslatable ($;@) { #{{{
 738         my $page=shift;
 739
 740         if (IkiWiki::Plugin::po::istranslatable($page)) {
 741                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 742         }
 743         else {
 744                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 745         }
 746 } #}}}
 747
 748 sub match_lang ($$;@) { #{{{
 749         my $page=shift;
 750         my $wanted=shift;
 751
 752         my $regexp=IkiWiki::glob2re($wanted);
 753         my $lang=IkiWiki::Plugin::po::lang($page);
 754         if ($lang!~/^$regexp$/i) {
 755                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 756         }
 757         else {
 758                 return IkiWiki::SuccessReason->new("file language is $wanted");
 759         }
 760 } #}}}
 761
 762 sub match_currentlang ($$;@) { #{{{
 763         my $page=shift;
 764         shift;
 765         my %params=@_;
 766
 767         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 768
 769         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 770         my $lang=IkiWiki::Plugin::po::lang($page);
 771
 772         if ($lang eq $currentlang) {
 773                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 774         }
 775         else {
 776                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 777         }
 778 } #}}}
 779
 780 1