IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008-2009 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 3.00;
  12 use Encode;
  13 eval q{use Locale::Po4a::Common qw(nowrapi18n !/.*/)};
  14 if ($@) {
  15         print STDERR gettext("warning: Old po4a detected! Recommend upgrade to 0.35.")."\n";
  16         eval q{use Locale::Po4a::Common qw(!/.*/)};
  17         die $@ if $@;
  18 }
  19 use Locale::Po4a::Chooser;
  20 use Locale::Po4a::Po;
  21 use File::Basename;
  22 use File::Copy;
  23 use File::Spec;
  24 use File::Temp;
  25 use Memoize;
  26 use UNIVERSAL;
  27
  28 my %translations;
  29 my @origneedsbuild;
  30 my %origsubs;
  31
  32 memoize("istranslatable");
  33 memoize("_istranslation");
  34 memoize("percenttranslated");
  35
  36 sub import {
  37         hook(type => "getsetup", id => "po", call => \&getsetup);
  38         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  39         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  40         hook(type => "scan", id => "po", call => \&scan, last => 1);
  41         hook(type => "filter", id => "po", call => \&filter);
  42         hook(type => "htmlize", id => "po", call => \&htmlize);
  43         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  44         hook(type => "rename", id => "po", call => \&renamepages, first => 1);
  45         hook(type => "delete", id => "po", call => \&mydelete);
  46         hook(type => "change", id => "po", call => \&change);
  47         hook(type => "checkcontent", id => "po", call => \&checkcontent);
  48         hook(type => "canremove", id => "po", call => \&canremove);
  49         hook(type => "canrename", id => "po", call => \&canrename);
  50         hook(type => "editcontent", id => "po", call => \&editcontent);
  51         hook(type => "formbuilder_setup", id => "po", call => \&formbuilder_setup, last => 1);
  52         hook(type => "formbuilder", id => "po", call => \&formbuilder);
  53
  54         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  55         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  56         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  57         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  58         $origsubs{'urlto'}=\&IkiWiki::urlto;
  59         inject(name => "IkiWiki::urlto", call => \&myurlto);
  60         $origsubs{'cgiurl'}=\&IkiWiki::cgiurl;
  61         inject(name => "IkiWiki::cgiurl", call => \&mycgiurl);
  62 }
  63
  64
  65 # ,----
  66 # | Table of contents
  67 # `----
  68
  69 # 1. Hooks
  70 # 2. Injected functions
  71 # 3. Blackboxes for private data
  72 # 4. Helper functions
  73 # 5. PageSpecs
  74
  75
  76 # ,----
  77 # | Hooks
  78 # `----
  79
  80 sub getsetup () {
  81         return
  82                 plugin => {
  83                         safe => 0,
  84                         rebuild => 1,
  85                 },
  86                 po_master_language => {
  87                         type => "string",
  88                         example => {
  89                                 'code' => 'en',
  90                                 'name' => 'English'
  91                         },
  92                         description => "master language (non-PO files)",
  93                         safe => 1,
  94                         rebuild => 1,
  95                 },
  96                 po_slave_languages => {
  97                         type => "string",
  98                         example => {
  99                                 'fr' => 'Français',
 100                                 'es' => 'Español',
 101                                 'de' => 'Deutsch'
 102                         },
 103                         description => "slave languages (PO files)",
 104                         safe => 1,
 105                         rebuild => 1,
 106                 },
 107                 po_translatable_pages => {
 108                         type => "pagespec",
 109                         example => "* and !*/Discussion",
 110                         description => "PageSpec controlling which pages are translatable",
 111                         link => "ikiwiki/PageSpec",
 112                         safe => 1,
 113                         rebuild => 1,
 114                 },
 115                 po_link_to => {
 116                         type => "string",
 117                         example => "current",
 118                         description => "internal linking behavior (default/current/negotiated)",
 119                         safe => 1,
 120                         rebuild => 1,
 121                 },
 122 }
 123
 124 sub checkconfig () {
 125         foreach my $field (qw{po_master_language}) {
 126                 if (! exists $config{$field} || ! defined $config{$field}) {
 127                         error(sprintf(gettext("Must specify %s when using the %s plugin"),
 128                                       $field, 'po'));
 129                 }
 130         }
 131
 132         map {
 133                 islanguagecode($_)
 134                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 135         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 136
 137         if (! exists $config{po_translatable_pages} ||
 138             ! defined $config{po_translatable_pages}) {
 139                 $config{po_translatable_pages}="";
 140         }
 141         if (! exists $config{po_link_to} ||
 142             ! defined $config{po_link_to}) {
 143                 $config{po_link_to}='default';
 144         }
 145         elsif ($config{po_link_to} !~ /^(default|current|negotiated)$/) {
 146                 warn(sprintf(gettext('%s is not a valid value for po_link_to, falling back to po_link_to=default'),
 147                              $config{po_link_to}));
 148                 $config{po_link_to}='default';
 149         }
 150         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 151                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 152                 $config{po_link_to}='default';
 153         }
 154         unless ($config{po_link_to} eq 'default') {
 155                 $origsubs{'bestlink'}=\&IkiWiki::bestlink;
 156                 inject(name => "IkiWiki::bestlink", call => \&mybestlink);
 157         }
 158
 159         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 160
 161         # Translated versions of the underlays are added if available.
 162         foreach my $underlay ("basewiki",
 163                               map { m/^\Q$config{underlaydirbase}\E\/*(.*)/ }
 164                                   reverse @{$config{underlaydirs}}) {
 165                 next if $underlay=~/^locale\//;
 166
 167                 # Underlays containing the po files for slave languages.
 168                 foreach my $ll (keys %{$config{po_slave_languages}}) {
 169                         add_underlay("po/$ll/$underlay")
 170                                 if -d "$config{underlaydirbase}/po/$ll/$underlay";
 171                 }
 172
 173                 if ($config{po_master_language}{code} ne 'en') {
 174                         # Add underlay containing translated source files
 175                         # for the master language.
 176                         add_underlay("locale/$config{po_master_language}{code}/$underlay");
 177                 }
 178         }
 179 }
 180
 181 sub needsbuild () {
 182         my $needsbuild=shift;
 183
 184         # backup @needsbuild content so that change() can know whether
 185         # a given master page was rendered because its source file was changed
 186         @origneedsbuild=(@$needsbuild);
 187
 188         flushmemoizecache();
 189         buildtranslationscache();
 190
 191         # make existing translations depend on the corresponding master page
 192         foreach my $master (keys %translations) {
 193                 map add_depends($_, $master), values %{otherlanguages($master)};
 194         }
 195 }
 196
 197 # Massage the recorded state of internal links so that:
 198 # - it matches the actually generated links, rather than the links as written
 199 #   in the pages' source
 200 # - backlinks are consistent in all cases
 201 sub scan (@) {
 202         my %params=@_;
 203         my $page=$params{page};
 204         my $content=$params{content};
 205
 206         if (istranslation($page)) {
 207                 foreach my $destpage (@{$links{$page}}) {
 208                         if (istranslatable($destpage)) {
 209                                 # replace the occurence of $destpage in $links{$page}
 210                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 211                                         if (@{$links{$page}}[$i] eq $destpage) {
 212                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 213                                                 last;
 214                                         }
 215                                 }
 216                         }
 217                 }
 218         }
 219         elsif (! istranslatable($page) && ! istranslation($page)) {
 220                 foreach my $destpage (@{$links{$page}}) {
 221                         if (istranslatable($destpage)) {
 222                                 # make sure any destpage's translations has
 223                                 # $page in its backlinks
 224                                 push @{$links{$page}},
 225                                         values %{otherlanguages($destpage)};
 226                         }
 227                 }
 228         }
 229 }
 230
 231 # We use filter to convert PO to the master page's format,
 232 # since the rest of ikiwiki should not work on PO files.
 233 sub filter (@) {
 234         my %params = @_;
 235
 236         my $page = $params{page};
 237         my $destpage = $params{destpage};
 238         my $content = $params{content};
 239         if (istranslation($page) && ! alreadyfiltered($page, $destpage)) {
 240                 $content = po_to_markup($page, $content);
 241                 setalreadyfiltered($page, $destpage);
 242         }
 243         return $content;
 244 }
 245
 246 sub htmlize (@) {
 247         my %params=@_;
 248
 249         my $page = $params{page};
 250         my $content = $params{content};
 251
 252         # ignore PO files this plugin did not create
 253         return $content unless istranslation($page);
 254
 255         # force content to be htmlize'd as if it was the same type as the master page
 256         return IkiWiki::htmlize($page, $page,
 257                 pagetype(srcfile($pagesources{masterpage($page)})),
 258                 $content);
 259 }
 260
 261 sub pagetemplate (@) {
 262         my %params=@_;
 263         my $page=$params{page};
 264         my $destpage=$params{destpage};
 265         my $template=$params{template};
 266
 267         my ($masterpage, $lang) = istranslation($page);
 268
 269         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 270                 $template->param(percenttranslated => percenttranslated($page));
 271         }
 272         if ($template->query(name => "istranslation")) {
 273                 $template->param(istranslation => scalar istranslation($page));
 274         }
 275         if ($template->query(name => "istranslatable")) {
 276                 $template->param(istranslatable => istranslatable($page));
 277         }
 278         if ($template->query(name => "HOMEPAGEURL")) {
 279                 $template->param(homepageurl => homepageurl($page));
 280         }
 281         if ($template->query(name => "otherlanguages")) {
 282                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 283                 map add_depends($page, $_), (values %{otherlanguages($page)});
 284         }
 285         if ($config{discussion} && istranslation($page)) {
 286                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 287                    (length $config{cgiurl} ||
 288                     exists $links{$masterpage."/".lc($config{discussionpage})})) {
 289                         $template->param('discussionlink' => htmllink(
 290                                 $page,
 291                                 $destpage,
 292                                 $masterpage . '/' . $config{discussionpage},
 293                                 noimageinline => 1,
 294                                 forcesubpage => 0,
 295                                 linktext => $config{discussionpage},
 296                 ));
 297                 }
 298         }
 299         # Remove broken parentlink to ./index.html on home page's translations.
 300         # It works because this hook has the "last" parameter set, to ensure it
 301         # runs after parentlinks' own pagetemplate hook.
 302         if ($template->param('parentlinks')
 303             && istranslation($page)
 304             && $masterpage eq "index") {
 305                 $template->param('parentlinks' => []);
 306         }
 307         if (ishomepage($page) && $template->query(name => "title")) {
 308                 $template->param(title => $config{wikiname});
 309         }
 310 } # }}}
 311
 312 # Add the renamed page translations to the list of to-be-renamed pages.
 313 sub renamepages (@) {
 314         my %params = @_;
 315
 316         my %torename = %{$params{torename}};
 317         my $session = $params{session};
 318
 319         # Save the page(s) the user asked to rename, so that our
 320         # canrename hook can tell the difference between:
 321         #  - a translation being renamed as a consequence of its master page
 322         #    being renamed
 323         #  - a user trying to directly rename a translation
 324         # This is why this hook has to be run first, before the list of pages
 325         # to rename is modified by other plugins.
 326         my @orig_torename;
 327         @orig_torename=@{$session->param("po_orig_torename")}
 328                 if defined $session->param("po_orig_torename");
 329         push @orig_torename, $torename{src};
 330         $session->param(po_orig_torename => \@orig_torename);
 331         IkiWiki::cgi_savesession($session);
 332
 333         return () unless istranslatable($torename{src});
 334
 335         my @ret;
 336         my %otherpages=%{otherlanguages($torename{src})};
 337         while (my ($lang, $otherpage) = each %otherpages) {
 338                 push @ret, {
 339                         src => $otherpage,
 340                         srcfile => $pagesources{$otherpage},
 341                         dest => otherlanguage($torename{dest}, $lang),
 342                         destfile => $torename{dest}.".".$lang.".po",
 343                         required => 0,
 344                 };
 345         }
 346         return @ret;
 347 }
 348
 349 sub mydelete (@) {
 350         my @deleted=@_;
 351
 352         map { deletetranslations($_) } grep istranslatablefile($_), @deleted;
 353 }
 354
 355 sub change (@) {
 356         my @rendered=@_;
 357
 358         # All meta titles are first extracted at scan time, i.e. before we turn
 359         # PO files back into translated markdown; escaping of double-quotes in
 360         # PO files breaks the meta plugin's parsing enough to save ugly titles
 361         # to %pagestate at this time.
 362         #
 363         # Then, at render time, every page passes in turn through the Great
 364         # Rendering Chain (filter->preprocess->linkify->htmlize), and the meta
 365         # plugin's preprocess hook is this time in a position to correctly
 366         # extract the titles from slave pages.
 367         #
 368         # This is, unfortunately, too late: if the page A, linking to the page
 369         # B, is rendered before B, it will display the wrongly-extracted meta
 370         # title as the link text to B.
 371         #
 372         # On the one hand, such a corner case only happens on rebuild: on
 373         # refresh, every rendered page is fixed to contain correct meta titles.
 374         # On the other hand, it can take some time to get every page fixed.
 375         # We therefore re-render every rendered page after a rebuild to fix them
 376         # at once. As this more or less doubles the time needed to rebuild the
 377         # wiki, we do so only when really needed.
 378
 379         if (@rendered
 380             && exists $config{rebuild} && defined $config{rebuild} && $config{rebuild}
 381             && UNIVERSAL::can("IkiWiki::Plugin::meta", "getsetup")
 382             && exists $config{meta_overrides_page_title}
 383             && defined $config{meta_overrides_page_title}
 384             && $config{meta_overrides_page_title}) {
 385                 debug(sprintf(gettext("rebuilding all pages to fix meta titles")));
 386                 resetalreadyfiltered();
 387                 require IkiWiki::Render;
 388                 foreach my $file (@rendered) {
 389                         debug(sprintf(gettext("building %s"), $file));
 390                         IkiWiki::render($file);
 391                 }
 392         }
 393
 394         my $updated_po_files=0;
 395
 396         # Refresh/create POT and PO files as needed.
 397         # (But avoid doing so if they are in an underlay directory.)
 398         foreach my $file (grep {istranslatablefile($_)} @rendered) {
 399                 my $masterfile=srcfile($file);
 400                 my $page=pagename($file);
 401                 my $updated_pot_file=0;
 402                 # Only refresh POT file if it does not exist, or if
 403                 # $pagesources{$page} was changed: don't if only the HTML was
 404                 # refreshed, e.g. because of a dependency.
 405                 if ($masterfile eq "$config{srcdir}/$file" &&
 406                    ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 407                     || ! -e potfile($masterfile))) {
 408                         refreshpot($masterfile);
 409                         $updated_pot_file=1;
 410                 }
 411                 my @pofiles;
 412                 foreach my $po (pofiles($masterfile)) {
 413                         next if ! $updated_pot_file && ! -e $po;
 414                         next if grep { $po=~/\Q$_\E/ } @{$config{underlaydirs}};
 415                         push @pofiles, $po;
 416                 }
 417                 if (@pofiles) {
 418                         refreshpofiles($masterfile, @pofiles);
 419                         map { s/^\Q$config{srcdir}\E\/*//; IkiWiki::rcs_add($_) } @pofiles if $config{rcs};
 420                         $updated_po_files=1;
 421                 }
 422         }
 423
 424         if ($updated_po_files) {
 425                 commit_and_refresh(
 426                         gettext("updated PO files"),
 427                         "IkiWiki::Plugin::po::change");
 428         }
 429 }
 430
 431 sub checkcontent (@) {
 432         my %params=@_;
 433
 434         if (istranslation($params{page})) {
 435                 my $res = isvalidpo($params{content});
 436                 if ($res) {
 437                         return undef;
 438                 }
 439                 else {
 440                         return "$res";
 441                 }
 442         }
 443         return undef;
 444 }
 445
 446 sub canremove (@) {
 447         my %params = @_;
 448
 449         if (istranslation($params{page})) {
 450                 return gettext("Can not remove a translation. If the master page is removed, ".
 451                                "however, its translations will be removed as well.");
 452         }
 453         return undef;
 454 }
 455
 456 sub canrename (@) {
 457         my %params = @_;
 458         my $session = $params{session};
 459
 460         if (istranslation($params{src})) {
 461                 my $masterpage = masterpage($params{src});
 462                 # Tell the difference between:
 463                 #  - a translation being renamed as a consequence of its master page
 464                 #    being renamed, which is allowed
 465                 #  - a user trying to directly rename a translation, which is forbidden
 466                 # by looking for the master page in the list of to-be-renamed pages we
 467                 # saved early in the renaming process.
 468                 my $orig_torename = $session->param("po_orig_torename");
 469                 unless (grep { $_ eq $masterpage } @{$orig_torename}) {
 470                         return gettext("Can not rename a translation. If the master page is renamed, ".
 471                                        "however, its translations will be renamed as well.");
 472                 }
 473         }
 474         return undef;
 475 }
 476
 477 # As we're previewing or saving a page, the content may have
 478 # changed, so tell the next filter() invocation it must not be lazy.
 479 sub editcontent () {
 480         my %params=@_;
 481
 482         unsetalreadyfiltered($params{page}, $params{page});
 483         return $params{content};
 484 }
 485
 486 sub formbuilder_setup (@) {
 487         my %params=@_;
 488         my $form=$params{form};
 489         my $q=$params{cgi};
 490
 491         return unless defined $form->field("do");
 492
 493         if ($form->field("do") eq "create") {
 494                 # Warn the user: new pages must be written in master language.
 495                 my $template=template("pocreatepage.tmpl");
 496                 $template->param(LANG => $config{po_master_language}{name});
 497                 $form->tmpl_param(message => $template->output);
 498         }
 499         elsif ($form->field("do") eq "edit") {
 500                 # Remove the rename/remove buttons on slave pages.
 501                 # This has to be done after the rename/remove plugins have added
 502                 # their buttons, which is why this hook must be run last.
 503                 # The canrename/canremove hooks already ensure this is forbidden
 504                 # at the backend level, so this is only UI sugar.
 505                 if (istranslation($form->field("page"))) {
 506                         map {
 507                                 for (my $i = 0; $i < @{$params{buttons}}; $i++) {
 508                                         if (@{$params{buttons}}[$i] eq $_) {
 509                                                 delete  @{$params{buttons}}[$i];
 510                                                 last;
 511                                         }
 512                                 }
 513                         } qw(Rename Remove);
 514                 }
 515         }
 516 }
 517
 518 sub formbuilder (@) {
 519         my %params=@_;
 520         my $form=$params{form};
 521         my $q=$params{cgi};
 522
 523         return unless defined $form->field("do");
 524
 525         # Do not allow to create pages of type po: they are automatically created.
 526         # The main reason to do so is to bypass the "favor the type of linking page
 527         # on page creation" logic, which is unsuitable when a broken link is clicked
 528         # on a slave (PO) page.
 529         # This cannot be done in the formbuilder_setup hook as the list of types is
 530         # computed later.
 531         if ($form->field("do") eq "create") {
 532                 foreach my $field ($form->field) {
 533                         next unless "$field" eq "type";
 534                         next unless $field->type eq 'select';
 535                         my $orig_value = $field->value;
 536                         # remove po from the list of types
 537                         my @types = grep { $_->[0] ne 'po' } $field->options;
 538                         $field->options(\@types) if @types;
 539                         # favor the type of linking page's masterpage
 540                         if ($orig_value eq 'po') {
 541                                 my ($from, $type);
 542                                 if (defined $form->field('from')) {
 543                                         ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 544                                         $from = masterpage($from);
 545                                 }
 546                                 if (defined $from && exists $pagesources{$from}) {
 547                                         $type=pagetype($pagesources{$from});
 548                                 }
 549                                 $type=$config{default_pageext} unless defined $type;
 550                                 $field->value($type) ;
 551                         }
 552                 }
 553         }
 554 }
 555
 556 # ,----
 557 # | Injected functions
 558 # `----
 559
 560 # Implement po_link_to 'current' and 'negotiated' settings.
 561 # Not injected otherwise.
 562 sub mybestlink ($$) {
 563         my $page=shift;
 564         my $link=shift;
 565
 566         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 567         if (length $res
 568             && istranslatable($res)
 569             && istranslation($page)) {
 570                 return $res . "." . lang($page);
 571         }
 572         return $res;
 573 }
 574
 575 sub mybeautify_urlpath ($) {
 576         my $url=shift;
 577
 578         my $res=$origsubs{'beautify_urlpath'}->($url);
 579         if ($config{po_link_to} eq "negotiated") {
 580                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 581                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 582                 map {
 583                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 584                 } (keys %{$config{po_slave_languages}});
 585         }
 586         return $res;
 587 }
 588
 589 sub mytargetpage ($$) {
 590         my $page=shift;
 591         my $ext=shift;
 592
 593         if (istranslation($page) || istranslatable($page)) {
 594                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 595                 if (! $config{usedirs} || $masterpage eq 'index') {
 596                         return $masterpage . "." . $lang . "." . $ext;
 597                 }
 598                 else {
 599                         return $masterpage . "/index." . $lang . "." . $ext;
 600                 }
 601         }
 602         return $origsubs{'targetpage'}->($page, $ext);
 603 }
 604
 605 sub myurlto ($$;$) {
 606         my $to=shift;
 607         my $from=shift;
 608         my $absolute=shift;
 609
 610         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 611         if (! length $to
 612             && $config{po_link_to} eq "current"
 613             && istranslatable('index')) {
 614                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 615         }
 616         # avoid using our injected beautify_urlpath if run by cgi_editpage,
 617         # so that one is redirected to the just-edited page rather than to the
 618         # negociated translation; to prevent unnecessary fiddling with caller/inject,
 619         # we only do so when our beautify_urlpath would actually do what we want to
 620         # avoid, i.e. when po_link_to = negotiated.
 621         # also avoid doing so when run by cgi_goto, so that the links on recentchanges
 622         # page actually lead to the exact page they pretend to.
 623         if ($config{po_link_to} eq "negotiated") {
 624                 my @caller = caller(1);
 625                 my $use_orig = 0;
 626                 $use_orig = 1 if (exists $caller[3] && defined $caller[3]
 627                                  && ($caller[3] eq "IkiWiki::cgi_editpage" ||
 628                                      $caller[3] eq "IkiWiki::Plugin::goto::cgi_goto")
 629                                  );
 630                 inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'})
 631                         if $use_orig;
 632                 my $res = $origsubs{'urlto'}->($to,$from,$absolute);
 633                 inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath)
 634                         if $use_orig;
 635                 return $res;
 636         }
 637         else {
 638                 return $origsubs{'urlto'}->($to,$from,$absolute)
 639         }
 640 }
 641
 642 sub mycgiurl (@) {
 643         my %params=@_;
 644
 645         # slave pages have no subpages
 646         if (istranslation($params{'from'})) {
 647                 $params{'from'} = masterpage($params{'from'});
 648         }
 649         return $origsubs{'cgiurl'}->(%params);
 650 }
 651
 652 # ,----
 653 # | Blackboxes for private data
 654 # `----
 655
 656 {
 657         my %filtered;
 658
 659         sub alreadyfiltered($$) {
 660                 my $page=shift;
 661                 my $destpage=shift;
 662
 663                 return exists $filtered{$page}{$destpage}
 664                          && $filtered{$page}{$destpage} eq 1;
 665         }
 666
 667         sub setalreadyfiltered($$) {
 668                 my $page=shift;
 669                 my $destpage=shift;
 670
 671                 $filtered{$page}{$destpage}=1;
 672         }
 673
 674         sub unsetalreadyfiltered($$) {
 675                 my $page=shift;
 676                 my $destpage=shift;
 677
 678                 if (exists $filtered{$page}{$destpage}) {
 679                         delete $filtered{$page}{$destpage};
 680                 }
 681         }
 682
 683         sub resetalreadyfiltered() {
 684                 undef %filtered;
 685         }
 686 }
 687
 688 # ,----
 689 # | Helper functions
 690 # `----
 691
 692 sub maybe_add_leading_slash ($;$) {
 693         my $str=shift;
 694         my $add=shift;
 695         $add=1 unless defined $add;
 696         return '/' . $str if $add;
 697         return $str;
 698 }
 699
 700 sub istranslatablefile ($) {
 701         my $file=shift;
 702
 703         return 0 unless defined $file;
 704         my $type=pagetype($file);
 705         return 0 if ! defined $type || $type eq 'po';
 706         return 0 if $file =~ /\.pot$/;
 707         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 708         return;
 709 }
 710
 711 sub istranslatable ($) {
 712         my $page=shift;
 713
 714         $page=~s#^/##;
 715         return 1 if istranslatablefile($pagesources{$page});
 716         return;
 717 }
 718
 719 sub _istranslation ($) {
 720         my $page=shift;
 721
 722         $page='' unless defined $page && length $page;
 723         my $hasleadingslash = ($page=~s#^/##);
 724         my $file=$pagesources{$page};
 725         return 0 unless defined $file
 726                          && defined pagetype($file)
 727                          && pagetype($file) eq 'po';
 728         return 0 if $file =~ /\.pot$/;
 729
 730         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 731         return 0 unless defined $masterpage && defined $lang
 732                          && length $masterpage && length $lang
 733                          && defined $pagesources{$masterpage}
 734                          && defined $config{po_slave_languages}{$lang};
 735
 736         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 737                 if istranslatable($masterpage);
 738 }
 739
 740 sub istranslation ($) {
 741         my $page=shift;
 742
 743         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 744                 my $hasleadingslash = ($masterpage=~s#^/##);
 745                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 746                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 747         }
 748         return "";
 749 }
 750
 751 sub masterpage ($) {
 752         my $page=shift;
 753
 754         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 755                 return $masterpage;
 756         }
 757         return $page;
 758 }
 759
 760 sub lang ($) {
 761         my $page=shift;
 762
 763         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 764                 return $lang;
 765         }
 766         return $config{po_master_language}{code};
 767 }
 768
 769 sub islanguagecode ($) {
 770         my $code=shift;
 771
 772         return $code =~ /^[a-z]{2}$/;
 773 }
 774
 775 sub otherlanguage ($$) {
 776         my $page=shift;
 777         my $code=shift;
 778
 779         return masterpage($page) if $code eq $config{po_master_language}{code};
 780         return masterpage($page) . '.' . $code;
 781 }
 782
 783 sub otherlanguages ($) {
 784         my $page=shift;
 785
 786         my %ret;
 787         return \%ret unless istranslation($page) || istranslatable($page);
 788         my $curlang=lang($page);
 789         foreach my $lang
 790                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 791                 next if $lang eq $curlang;
 792                 $ret{$lang}=otherlanguage($page, $lang);
 793         }
 794         return \%ret;
 795 }
 796
 797 sub potfile ($) {
 798         my $masterfile=shift;
 799
 800         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 801         $dir='' if $dir eq './';
 802         return File::Spec->catpath('', $dir, $name . ".pot");
 803 }
 804
 805 sub pofile ($$) {
 806         my $masterfile=shift;
 807         my $lang=shift;
 808
 809         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 810         $dir='' if $dir eq './';
 811         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 812 }
 813
 814 sub pofiles ($) {
 815         my $masterfile=shift;
 816
 817         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 818 }
 819
 820 sub refreshpot ($) {
 821         my $masterfile=shift;
 822
 823         my $potfile=potfile($masterfile);
 824         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 825         my $doc=Locale::Po4a::Chooser::new('text',%options);
 826         $doc->{TT}{utf_mode} = 1;
 827         $doc->{TT}{file_in_charset} = 'utf-8';
 828         $doc->{TT}{file_out_charset} = 'utf-8';
 829         $doc->read($masterfile);
 830         # let's cheat a bit to force porefs option to be passed to
 831         # Locale::Po4a::Po; this is undocument use of internal
 832         # Locale::Po4a::TransTractor's data, compulsory since this module
 833         # prevents us from using the porefs option.
 834         $doc->{TT}{po_out}=Locale::Po4a::Po->new({ 'porefs' => 'none' });
 835         $doc->{TT}{po_out}->set_charset('utf-8');
 836         # do the actual work
 837         $doc->parse;
 838         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 839         $doc->writepo($potfile);
 840 }
 841
 842 sub refreshpofiles ($@) {
 843         my $masterfile=shift;
 844         my @pofiles=@_;
 845
 846         my $potfile=potfile($masterfile);
 847         if (! -e $potfile) {
 848                 error("po(refreshpofiles) ".sprintf(gettext("POT file (%s) does not exist"), $potfile));
 849         }
 850
 851         foreach my $pofile (@pofiles) {
 852                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 853
 854                 if (! -e $pofile) {
 855                         # If the po file exists in an underlay, copy it
 856                         # from there.
 857                         my ($pobase)=$pofile=~/^\Q$config{srcdir}\E\/?(.*)$/;
 858                         foreach my $dir (@{$config{underlaydirs}}) {
 859                                 if (-e "$dir/$pobase") {
 860                                         File::Copy::syscopy("$dir/$pobase",$pofile)
 861                                                 or error("po(refreshpofiles) ".
 862                                                          sprintf(gettext("failed to copy underlay PO file to %s"),
 863                                                                  $pofile));
 864                                 }
 865                         }
 866                 }
 867
 868                 if (-e $pofile) {
 869                         system("msgmerge", "--previous", "-q", "-U", "--backup=none", $pofile, $potfile) == 0
 870                                 or error("po(refreshpofiles) ".
 871                                          sprintf(gettext("failed to update %s"),
 872                                                  $pofile));
 873                 }
 874                 else {
 875                         File::Copy::syscopy($potfile,$pofile)
 876                                 or error("po(refreshpofiles) ".
 877                                          sprintf(gettext("failed to copy the POT file to %s"),
 878                                                  $pofile));
 879                 }
 880         }
 881 }
 882
 883 sub buildtranslationscache() {
 884         # use istranslation's side-effect
 885         map istranslation($_), (keys %pagesources);
 886 }
 887
 888 sub resettranslationscache() {
 889         undef %translations;
 890 }
 891
 892 sub flushmemoizecache() {
 893         Memoize::flush_cache("istranslatable");
 894         Memoize::flush_cache("_istranslation");
 895         Memoize::flush_cache("percenttranslated");
 896 }
 897
 898 sub urlto_with_orig_beautiful_urlpath($$) {
 899         my $to=shift;
 900         my $from=shift;
 901
 902         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 903         my $res=urlto($to, $from);
 904         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 905
 906         return $res;
 907 }
 908
 909 sub percenttranslated ($) {
 910         my $page=shift;
 911
 912         $page=~s/^\///;
 913         return gettext("N/A") unless istranslation($page);
 914         my $file=srcfile($pagesources{$page});
 915         my $masterfile = srcfile($pagesources{masterpage($page)});
 916         my %options = (
 917                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 918         );
 919         my $doc=Locale::Po4a::Chooser::new('text',%options);
 920         $doc->process(
 921                 'po_in_name'    => [ $file ],
 922                 'file_in_name'  => [ $masterfile ],
 923                 'file_in_charset'  => 'utf-8',
 924                 'file_out_charset' => 'utf-8',
 925         ) or error("po(percenttranslated) ".
 926                    sprintf(gettext("failed to translate %s"), $page));
 927         my ($percent,$hit,$queries) = $doc->stats();
 928         $percent =~ s/\.[0-9]+$//;
 929         return $percent;
 930 }
 931
 932 sub languagename ($) {
 933         my $code=shift;
 934
 935         return $config{po_master_language}{name}
 936                 if $code eq $config{po_master_language}{code};
 937         return $config{po_slave_languages}{$code}
 938                 if defined $config{po_slave_languages}{$code};
 939         return;
 940 }
 941
 942 sub otherlanguagesloop ($) {
 943         my $page=shift;
 944
 945         my @ret;
 946         my %otherpages=%{otherlanguages($page)};
 947         while (my ($lang, $otherpage) = each %otherpages) {
 948                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 949                         push @ret, {
 950                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 951                                 code => $lang,
 952                                 language => languagename($lang),
 953                                 master => 1,
 954                         };
 955                 }
 956                 elsif (istranslation($otherpage)) {
 957                         push @ret, {
 958                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 959                                 code => $lang,
 960                                 language => languagename($lang),
 961                                 percent => percenttranslated($otherpage),
 962                         }
 963                 }
 964         }
 965         return sort {
 966                 return -1 if $a->{code} eq $config{po_master_language}{code};
 967                 return 1 if $b->{code} eq $config{po_master_language}{code};
 968                 return $a->{language} cmp $b->{language};
 969         } @ret;
 970 }
 971
 972 sub homepageurl (;$) {
 973         my $page=shift;
 974
 975         return urlto('', $page);
 976 }
 977
 978 sub ishomepage ($) {
 979         my $page = shift;
 980
 981         return 1 if $page eq 'index';
 982         map { return 1 if $page eq 'index.'.$_ } keys %{$config{po_slave_languages}};
 983         return undef;
 984 }
 985
 986 sub deletetranslations ($) {
 987         my $deletedmasterfile=shift;
 988
 989         my $deletedmasterpage=pagename($deletedmasterfile);
 990         my @todelete;
 991         map {
 992                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 993                 my $absfile = "$config{srcdir}/$file";
 994                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 995                         push @todelete, $file;
 996                 }
 997         } keys %{$config{po_slave_languages}};
 998
 999         map {
1000                 if ($config{rcs}) {
1001                         IkiWiki::rcs_remove($_);
1002                 }
1003                 else {
1004                         IkiWiki::prune("$config{srcdir}/$_");
1005                 }
1006         } @todelete;
1007
1008         if (@todelete) {
1009                 commit_and_refresh(
1010                         gettext("removed obsolete PO files"),
1011                         "IkiWiki::Plugin::po::deletetranslations");
1012         }
1013 }
1014
1015 sub commit_and_refresh ($$) {
1016         my ($msg, $author) = (shift, shift);
1017
1018         if ($config{rcs}) {
1019                 IkiWiki::disable_commit_hook();
1020                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
1021                 IkiWiki::enable_commit_hook();
1022                 IkiWiki::rcs_update();
1023         }
1024         # Reinitialize module's private variables.
1025         resetalreadyfiltered();
1026         resettranslationscache();
1027         flushmemoizecache();
1028         # Trigger a wiki refresh.
1029         require IkiWiki::Render;
1030         # without preliminary saveindex/loadindex, refresh()
1031         # complains about a lot of uninitialized variables
1032         IkiWiki::saveindex();
1033         IkiWiki::loadindex();
1034         IkiWiki::refresh();
1035         IkiWiki::saveindex();
1036 }
1037
1038 # on success, returns the filtered content.
1039 # on error, if $nonfatal, warn and return undef; else, error out.
1040 sub po_to_markup ($$;$) {
1041         my ($page, $content) = (shift, shift);
1042         my $nonfatal = shift;
1043
1044         $content = '' unless defined $content;
1045         $content = decode_utf8(encode_utf8($content));
1046         # CRLF line terminators make poor Locale::Po4a feel bad
1047         $content=~s/\r\n/\n/g;
1048
1049         # There are incompatibilities between some File::Temp versions
1050         # (including 0.18, bundled with Lenny's perl-modules package)
1051         # and others (e.g. 0.20, previously present in the archive as
1052         # a standalone package): under certain circumstances, some
1053         # return a relative filename, whereas others return an absolute one;
1054         # we here use this module in a way that is at least compatible
1055         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1056         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
1057                                     DIR => File::Spec->tmpdir,
1058                                     UNLINK => 1)->filename;
1059         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
1060                                      DIR => File::Spec->tmpdir,
1061                                      UNLINK => 1)->filename;
1062
1063         my $fail = sub ($) {
1064                 my $msg = "po(po_to_markup) - $page : " . shift;
1065                 if ($nonfatal) {
1066                         warn $msg;
1067                         return undef;
1068                 }
1069                 error($msg, sub { unlink $infile, $outfile});
1070         };
1071
1072         writefile(basename($infile), File::Spec->tmpdir, $content)
1073                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1074
1075         my $masterfile = srcfile($pagesources{masterpage($page)});
1076         my %options = (
1077                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
1078         );
1079         my $doc=Locale::Po4a::Chooser::new('text',%options);
1080         $doc->process(
1081                 'po_in_name'    => [ $infile ],
1082                 'file_in_name'  => [ $masterfile ],
1083                 'file_in_charset'  => 'utf-8',
1084                 'file_out_charset' => 'utf-8',
1085         ) or return $fail->(gettext("failed to translate"));
1086         $doc->write($outfile)
1087                 or return $fail->(sprintf(gettext("failed to write %s"), $outfile));
1088
1089         $content = readfile($outfile)
1090                 or return $fail->(sprintf(gettext("failed to read %s"), $outfile));
1091
1092         # Unlinking should happen automatically, thanks to File::Temp,
1093         # but it does not work here, probably because of the way writefile()
1094         # and Locale::Po4a::write() work.
1095         unlink $infile, $outfile;
1096
1097         return $content;
1098 }
1099
1100 # returns a SuccessReason or FailReason object
1101 sub isvalidpo ($) {
1102         my $content = shift;
1103
1104         # NB: we don't use po_to_markup here, since Po4a parser does
1105         # not mind invalid PO content
1106         $content = '' unless defined $content;
1107         $content = decode_utf8(encode_utf8($content));
1108
1109         # There are incompatibilities between some File::Temp versions
1110         # (including 0.18, bundled with Lenny's perl-modules package)
1111         # and others (e.g. 0.20, previously present in the archive as
1112         # a standalone package): under certain circumstances, some
1113         # return a relative filename, whereas others return an absolute one;
1114         # we here use this module in a way that is at least compatible
1115         # with 0.18 and 0.20. Beware, hit'n'run refactorers!
1116         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-isvalidpo.XXXXXXXXXX",
1117                                     DIR => File::Spec->tmpdir,
1118                                     UNLINK => 1)->filename;
1119
1120         my $fail = sub ($) {
1121                 my $msg = '[po/isvalidpo] ' . shift;
1122                 unlink $infile;
1123                 return IkiWiki::FailReason->new("$msg");
1124         };
1125
1126         writefile(basename($infile), File::Spec->tmpdir, $content)
1127                 or return $fail->(sprintf(gettext("failed to write %s"), $infile));
1128
1129         my $res = (system("msgfmt", "--check", $infile, "-o", "/dev/null") == 0);
1130
1131         # Unlinking should happen automatically, thanks to File::Temp,
1132         # but it does not work here, probably because of the way writefile()
1133         # and Locale::Po4a::write() work.
1134         unlink $infile;
1135
1136         if ($res) {
1137             return IkiWiki::SuccessReason->new("valid gettext data");
1138         }
1139         return IkiWiki::FailReason->new(gettext("invalid gettext data, go back ".
1140                                         "to previous page to continue edit"));
1141 }
1142
1143 # ,----
1144 # | PageSpecs
1145 # `----
1146
1147 package IkiWiki::PageSpec;
1148
1149 sub match_istranslation ($;@) {
1150         my $page=shift;
1151
1152         if (IkiWiki::Plugin::po::istranslation($page)) {
1153                 return IkiWiki::SuccessReason->new("is a translation page");
1154         }
1155         else {
1156                 return IkiWiki::FailReason->new("is not a translation page");
1157         }
1158 }
1159
1160 sub match_istranslatable ($;@) {
1161         my $page=shift;
1162
1163         if (IkiWiki::Plugin::po::istranslatable($page)) {
1164                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
1165         }
1166         else {
1167                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
1168         }
1169 }
1170
1171 sub match_lang ($$;@) {
1172         my $page=shift;
1173         my $wanted=shift;
1174
1175         my $regexp=IkiWiki::glob2re($wanted);
1176         my $lang=IkiWiki::Plugin::po::lang($page);
1177         if ($lang !~ /^$regexp$/i) {
1178                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
1179         }
1180         else {
1181                 return IkiWiki::SuccessReason->new("file language is $wanted");
1182         }
1183 }
1184
1185 sub match_currentlang ($$;@) {
1186         my $page=shift;
1187         shift;
1188         my %params=@_;
1189
1190         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
1191
1192         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
1193         my $lang=IkiWiki::Plugin::po::lang($page);
1194
1195         if ($lang eq $currentlang) {
1196                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
1197         }
1198         else {
1199                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
1200         }
1201 }
1202
1203 1