IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use Data::Dumper;
   9 use IkiWiki;
  10
  11 sub gen_wrapper () {
  12         $config{srcdir}=File::Spec->rel2abs($config{srcdir});
  13         $config{destdir}=File::Spec->rel2abs($config{destdir});
  14         my $this=File::Spec->rel2abs($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER HTTPS REDIRECT_STATUS
  32                        REDIRECT_URL} if $config{cgi};
  33         my $envsave="";
  34         foreach my $var (@envsave) {
  35                 $envsave.=<<"EOF";
  36         if ((s=getenv("$var")))
  37                 addenv("$var", s);
  38 EOF
  39         }
  40
  41         my $test_receive="";
  42         if ($config{test_receive}) {
  43                 require IkiWiki::Receive;
  44                 $test_receive=IkiWiki::Receive::gen_wrapper();
  45         }
  46
  47         my $check_commit_hook="";
  48         my $pre_exec="";
  49         if ($config{post_commit}) {
  50                 # Optimise checking !commit_hook_enabled() ,
  51                 # so that ikiwiki does not have to be started if the
  52                 # hook is disabled.
  53                 #
  54                 # Note that perl's flock may be implemented using fcntl
  55                 # or lockf on some systems. If so, and if there is no
  56                 # interop between the locking systems, the true C flock will
  57                 # always succeed, and this optimisation won't work.
  58                 # The perl code will later correctly check the lock,
  59                 # so the right thing will still happen, though without
  60                 # the benefit of this optimisation.
  61                 $check_commit_hook=<<"EOF";
  62         {
  63                 int fd=open("$config{wikistatedir}/commitlock", O_CREAT | O_RDWR, 0666);
  64                 if (fd != -1) {
  65                         if (flock(fd, LOCK_SH | LOCK_NB) != 0)
  66                                 exit(0);
  67                         close(fd);
  68                 }
  69         }
  70 EOF
  71         }
  72         elsif ($config{cgi}) {
  73                 # Avoid more than one ikiwiki cgi running at a time by
  74                 # taking a cgi lock. Since ikiwiki uses several MB of
  75                 # memory, a pile up of processes could cause thrashing
  76                 # otherwise. The fd of the lock is stored in
  77                 # IKIWIKI_CGILOCK_FD so unlockwiki can close it.
  78                 $pre_exec=<<"EOF";
  79         {
  80                 int fd=open("$config{wikistatedir}/cgilock", O_CREAT | O_RDWR, 0666);
  81                 if (fd != -1 && flock(fd, LOCK_EX) == 0) {
  82                         char *fd_s;
  83                         asprintf(&fd_s, "%i", fd);
  84                         setenv("IKIWIKI_CGILOCK_FD", fd_s, 1);
  85                 }
  86         }
  87 EOF
  88         }
  89
  90         $Data::Dumper::Indent=0; # no newlines
  91         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  92         $configstring=~s/\\/\\\\/g;
  93         $configstring=~s/"/\\"/g;
  94         $configstring=~s/\n/\\n/g;
  95
  96         #translators: The first parameter is a filename, and the second is
  97         #translators: a (probably not translated) error message.
  98         open(OUT, ">$wrapper.c") || error(sprintf(gettext("failed to write %s: %s"), "$wrapper.c", $!));;
  99         print OUT <<"EOF";
 100 /* A wrapper for ikiwiki, can be safely made suid. */
 101 #include <stdio.h>
 102 #include <sys/types.h>
 103 #include <sys/stat.h>
 104 #include <fcntl.h>
 105 #include <unistd.h>
 106 #include <stdlib.h>
 107 #include <string.h>
 108 #include <sys/file.h>
 109
 110 extern char **environ;
 111 char *newenviron[$#envsave+6];
 112 int i=0;
 113
 114 addenv(char *var, char *val) {
 115         char *s=malloc(strlen(var)+1+strlen(val)+1);
 116         if (!s)
 117                 perror("malloc");
 118         sprintf(s, "%s=%s", var, val);
 119         newenviron[i++]=s;
 120 }
 121
 122 int main (int argc, char **argv) {
 123         char *s;
 124
 125 $check_commit_hook
 126 $test_receive
 127 $envsave
 128         newenviron[i++]="HOME=$ENV{HOME}";
 129         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
 130         newenviron[i]=NULL;
 131         environ=newenviron;
 132
 133         if (setregid(getegid(), -1) != 0 &&
 134             setregid(getegid(), -1) != 0) {
 135                 perror("failed to drop real gid");
 136                 exit(1);
 137         }
 138         if (setreuid(geteuid(), -1) != 0 &&
 139             setreuid(geteuid(), -1) != 0) {
 140                 perror("failed to drop real uid");
 141                 exit(1);
 142         }
 143
 144 $pre_exec
 145         execl("$this", "$this", NULL);
 146         perror("exec $this");
 147         exit(1);
 148 }
 149 EOF
 150         close OUT;
 151
 152         my $cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
 153         if (system($cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
 154                 #translators: The parameter is a C filename.
 155                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 156         }
 157         unlink("$wrapper.c");
 158         if (defined $config{wrappergroup}) {
 159                 my $gid=(getgrnam($config{wrappergroup}))[2];
 160                 if (! defined $gid) {
 161                         error(sprintf("bad wrappergroup"));
 162                 }
 163                 if (! chown(-1, $gid, "$wrapper.new")) {
 164                         error("chown $wrapper.new: $!");
 165                 }
 166         }
 167         if (defined $config{wrappermode} &&
 168             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 169                 error("chmod $wrapper.new: $!");
 170         }
 171         if (! rename("$wrapper.new", $wrapper)) {
 172                 error("rename $wrapper.new $wrapper: $!");
 173         }
 174         #translators: The parameter is a filename.
 175         printf(gettext("successfully generated %s"), $wrapper);
 176         print "\n";
 177 }
 178
 179 1