ikiwiki-transition

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4 use IkiWiki;
   5 use HTML::Entities;
   6
   7 my $regex = qr{
   8         (\\?)           # 1: escape?
   9         \[\[(!?)        # directive open; 2: optional prefix
  10         ([-\w]+)        # 3: command
  11         (               # 4: the parameters (including initial whitespace)
  12         \s+
  13                 (?:
  14                         (?:[-\w]+=)?            # named parameter key?
  15                         (?:
  16                                 """.*?"""       # triple-quoted value
  17                                 |
  18                                 "[^"]+"         # single-quoted value
  19                                 |
  20                                 [^\s\]]+        # unquoted value
  21                         )
  22                         \s*                     # whitespace or end
  23                                                 # of directive
  24                 )
  25         *)              # 0 or more parameters
  26         \]\]            # directive closed
  27 }sx;
  28
  29 sub handle_directive {
  30         my $escape = shift;
  31         my $prefix = shift;
  32         my $directive = shift;
  33         my $args = shift;
  34
  35         if (length $escape) {
  36                 return "${escape}[[${prefix}${directive}${args}]]"
  37         }
  38         if ($directive =~ m/^(if|more|table|template|toggleable)$/) {
  39                 $args =~ s{$regex}{handle_directive($1, $2, $3, $4)}eg;
  40         }
  41         return "[[!${directive}${args}]]"
  42 }
  43
  44 sub prefix_directives {
  45         my $setup=shift;
  46         if (! defined $setup) {
  47                 usage();
  48         }
  49
  50         require IkiWiki::Setup;
  51         require IkiWiki::Plugin::aggregate;
  52
  53         %config = IkiWiki::defaultconfig();
  54         IkiWiki::Setup::load($setup);
  55         IkiWiki::loadplugins();
  56         IkiWiki::checkconfig();
  57         IkiWiki::loadindex();
  58
  59         if (! %pagesources) {
  60                 error "ikiwiki has not built this wiki yet, cannot transition";
  61         }
  62
  63         foreach my $page (values %pagesources) {
  64                 next unless defined pagetype($page) &&
  65                             -f $config{srcdir}."/".$page;
  66                 my $content=readfile($config{srcdir}."/".$page);
  67                 my $oldcontent=$content;
  68                 $content=~s{$regex}{handle_directive($1, $2, $3, $4)}eg;
  69                 if ($oldcontent ne $content) {
  70                         writefile($page, $config{srcdir}, $content);
  71                 }
  72         }
  73 }
  74
  75 sub indexdb {
  76         my $dir=shift;
  77         if (! defined $dir) {
  78                 usage();
  79         }
  80         $config{wikistatedir}=$dir."/.ikiwiki";
  81
  82         # Note: No lockwiki here because ikiwiki already locks it
  83         # before calling this.
  84         if (! IkiWiki::oldloadindex()) {
  85                 die "failed to load index\n";
  86         }
  87         if (! IkiWiki::saveindex()) {
  88                 die "failed to save indexdb\n"
  89         }
  90         if (! IkiWiki::loadindex()) {
  91                 die "transition failed, cannot load new indexdb\n";
  92         }
  93         if (! unlink("$config{wikistatedir}/index")) {
  94                 die "unlink failed: $!\n";
  95         }
  96 }
  97
  98 sub hashpassword {
  99         my $dir=shift;
 100         if (! defined $dir) {
 101                 usage();
 102         }
 103         $config{wikistatedir}=$dir."/.ikiwiki";
 104
 105         eval q{use IkiWiki::UserInfo};
 106         eval q{use Authen::Passphrase::BlowfishCrypt};
 107         if ($@) {
 108                 error("ikiwiki-transition hashpassword: failed to load Authen::Passphrase, passwords not hashed");
 109         }
 110
 111         IkiWiki::lockwiki();
 112         IkiWiki::loadplugin("passwordauth");
 113         my $userinfo = IkiWiki::userinfo_retrieve();
 114         foreach my $user (keys %{$userinfo}) {
 115                 if (ref $userinfo->{$user} &&
 116                     exists $userinfo->{$user}->{password} &&
 117                     length $userinfo->{$user}->{password} &&
 118                     ! exists $userinfo->{$user}->{cryptpassword}) {
 119                         IkiWiki::Plugin::passwordauth::setpassword($user, $userinfo->{$user}->{password});
 120                 }
 121         }
 122 }
 123
 124 sub aggregateinternal {
 125         my $setup=shift;
 126         if (! defined $setup) {
 127                 usage();
 128         }
 129
 130         require IkiWiki::Setup;
 131         require IkiWiki::Plugin::aggregate;
 132
 133         %config = IkiWiki::defaultconfig();
 134         IkiWiki::Setup::load($setup);
 135         IkiWiki::checkconfig();
 136
 137         IkiWiki::Plugin::aggregate::migrate_to_internal();
 138 }
 139
 140 sub setupformat {
 141         my $setup=shift;
 142         if (! defined $setup) {
 143                 usage();
 144         }
 145
 146         require IkiWiki::Setup;
 147
 148         %config = IkiWiki::defaultconfig();
 149         IkiWiki::Setup::load($setup);
 150         IkiWiki::checkconfig();
 151
 152         # unpack old-format wrappers setting into new fields
 153         my $cgi_seen=0;
 154         my $rcs_seen=0;
 155         foreach my $wrapper (@{$config{wrappers}}) {
 156                 if ($wrapper->{cgi}) {
 157                         if ($cgi_seen) {
 158                                 die "don't know what to do with second cgi wrapper ".$wrapper->{wrapper}."\n";
 159                         }
 160                         $cgi_seen++;
 161                         print "setting cgi_wrapper to ".$wrapper->{wrapper}."\n";
 162                         $config{cgi_wrapper}=$wrapper->{wrapper};
 163                         $config{cgi_wrappermode}=$wrapper->{wrappermode}
 164                                 if exists $wrapper->{wrappermode};
 165                 }
 166                 elsif ($config{rcs}) {
 167                         if ($rcs_seen) {
 168                                 die "don't know what to do with second rcs wrapper ".$wrapper->{wrapper}."\n";
 169                         }
 170                         $rcs_seen++;
 171                         print "setting $config{rcs}_wrapper to ".$wrapper->{wrapper}."\n";
 172                         $config{$config{rcs}."_wrapper"}=$wrapper->{wrapper};
 173                         $config{$config{rcs}."_wrappermode"}=$wrapper->{wrappermode}
 174                                 if exists $wrapper->{wrappermode};
 175                 }
 176                 else {
 177                         die "don't know what to do with wrapper ".$wrapper->{wrapper}."\n";
 178                 }
 179         }
 180
 181         IkiWiki::Setup::dump($setup);
 182 }
 183
 184 sub moveprefs {
 185         my $setup=shift;
 186         if (! defined $setup) {
 187                 usage();
 188         }
 189
 190         require IkiWiki::Setup;
 191
 192         %config = IkiWiki::defaultconfig();
 193         IkiWiki::Setup::load($setup);
 194         IkiWiki::checkconfig();
 195
 196         eval q{use IkiWiki::UserInfo};
 197         error $@ if $@;
 198
 199         foreach my $field (qw{allowed_attachments locked_pages}) {
 200                 my $orig=$config{$field};
 201                 foreach my $admin (@{$config{adminuser}}) {
 202                         my $a=IkiWiki::userinfo_get($admin, $field);
 203                         if (defined $a && length $a &&
 204                             # might already have been moved
 205                             (! defined $orig || $a ne $orig)) {
 206                                 if (defined $config{$field} &&
 207                                     length $config{$field}) {
 208                                         $config{$field}=IkiWiki::pagespec_merge($config{$field}, $a);
 209                                 }
 210                                 else {
 211                                         $config{$field}=$a;
 212                                 }
 213                         }
 214                 }
 215         }
 216
 217         my %banned=map { $_ => 1 } @{$config{banned_users}}, IkiWiki::get_banned_users();
 218         $config{banned_users}=[sort keys %banned];
 219
 220         IkiWiki::Setup::dump($setup);
 221 }
 222
 223 sub deduplinks {
 224         my $dir=shift;
 225         if (! defined $dir) {
 226                 usage();
 227         }
 228         $config{wikistatedir}=$dir."/.ikiwiki";
 229         IkiWiki::loadindex();
 230         foreach my $page (keys %links) {
 231                 my %l;
 232                 $l{$_}=1 foreach @{$links{$page}};
 233                 $links{$page}=[keys %l]
 234         }
 235         IkiWiki::saveindex();
 236 }
 237
 238 sub usage {
 239         print STDERR "Usage: ikiwiki-transition type ...\n";
 240         print STDERR "Currently supported transition subcommands:\n";
 241         print STDERR "\tprefix_directives setupfile ...\n";
 242         print STDERR "\taggregateinternal setupfile\n";
 243         print STDERR "\tsetupformat setupfile\n";
 244         print STDERR "\tmoveprefs setupfile\n";
 245         print STDERR "\thashpassword srcdir\n";
 246         print STDERR "\tindexdb srcdir\n";
 247         print STDERR "\tdeduplinks srcdir\n";
 248         exit 1;
 249 }
 250
 251 usage() unless @ARGV;
 252
 253 my $mode=shift;
 254 if ($mode eq 'prefix_directives') {
 255         prefix_directives(@ARGV);
 256 }
 257 elsif ($mode eq 'hashpassword') {
 258         hashpassword(@ARGV);
 259 }
 260 elsif ($mode eq 'indexdb') {
 261         indexdb(@ARGV);
 262 }
 263 elsif ($mode eq 'aggregateinternal') {
 264         aggregateinternal(@ARGV);
 265 }
 266 elsif ($mode eq 'setupformat') {
 267         setupformat(@ARGV);
 268 }
 269 elsif ($mode eq 'moveprefs') {
 270         moveprefs(@ARGV);
 271 }
 272 elsif ($mode eq 'deduplinks') {
 273         deduplinks(@ARGV);
 274 }
 275 else {
 276         usage();
 277 }
 278
 279 package IkiWiki;
 280
 281 # A slightly modified version of the old loadindex function.
 282 sub oldloadindex {
 283         %oldrenderedfiles=%pagectime=();
 284         if (! $config{rebuild}) {
 285                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
 286                         %destsources=%renderedfiles=%pagecase=%pagestate=();
 287         }
 288         open (my $in, "<", "$config{wikistatedir}/index") || return;
 289         while (<$in>) {
 290                 chomp;
 291                 my %items;
 292                 $items{link}=[];
 293                 $items{dest}=[];
 294                 foreach my $i (split(/ /, $_)) {
 295                         my ($item, $val)=split(/=/, $i, 2);
 296                         push @{$items{$item}}, decode_entities($val);
 297                 }
 298
 299                 next unless exists $items{src}; # skip bad lines for now
 300
 301                 my $page=pagename($items{src}[0]);
 302                 if (! $config{rebuild}) {
 303                         $pagesources{$page}=$items{src}[0];
 304                         $pagemtime{$page}=$items{mtime}[0];
 305                         $oldlinks{$page}=[@{$items{link}}];
 306                         $links{$page}=[@{$items{link}}];
 307                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 308                         $destsources{$_}=$page foreach @{$items{dest}};
 309                         $renderedfiles{$page}=[@{$items{dest}}];
 310                         $pagecase{lc $page}=$page;
 311                         foreach my $k (grep /_/, keys %items) {
 312                                 my ($id, $key)=split(/_/, $k, 2);
 313                                 $pagestate{$page}{decode_entities($id)}{decode_entities($key)}=$items{$k}[0];
 314                         }
 315                 }
 316                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 317                 $pagectime{$page}=$items{ctime}[0];
 318         }
 319
 320         # saveindex relies on %hooks being populated, else it won't save
 321         # the page state owned by a given hook. But no plugins are loaded
 322         # by this program, so populate %hooks with all hook ids that
 323         # currently have page state.
 324         foreach my $page (keys %pagemtime) {
 325                 foreach my $id (keys %{$pagestate{$page}}) {
 326                         $hooks{_dummy}{$id}=1;
 327                 }
 328         }
 329
 330         return close($in);
 331 }
 332
 333 # Used to be in IkiWiki/UserInfo, but only used here now.
 334 sub get_banned_users () {
 335         my @ret;
 336         my $userinfo=userinfo_retrieve();
 337         foreach my $user (keys %{$userinfo}) {
 338                 push @ret, $user if $userinfo->{$user}->{banned};
 339         }
 340         return @ret;
 341 }
 342
 343 1