IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                 },
  23 }
  24
  25 sub preprocess (@) {
  26         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  27         my %params=@_;
  28
  29         if (exists $imgdefaults{$params{page}}) {
  30                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  31                         if (! exists $params{$key}) {
  32                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  33                         }
  34                 }
  35         }
  36
  37         if (! exists $params{size}) {
  38                 $params{size}='full';
  39         }
  40
  41         if ($image eq 'defaults') {
  42                 $imgdefaults{$params{page}} = \%params;
  43                 return '';
  44         }
  45
  46         add_link($params{page}, $image);
  47         # optimisation: detect scan mode, and avoid generating the image
  48         if (! defined wantarray) {
  49                 return;
  50         }
  51
  52         my $file = bestlink($params{page}, $image);
  53         my $srcfile = srcfile($file, 1);
  54         if (! length $file || ! defined $srcfile) {
  55                 return htmllink($params{page}, $params{destpage}, $image);
  56         }
  57
  58         my $dir = $params{page};
  59         my $base = IkiWiki::basename($file);
  60
  61         eval q{use Image::Magick};
  62         error gettext("Image::Magick is not installed") if $@;
  63         my $im = Image::Magick->new;
  64         my $imglink;
  65         my $r;
  66
  67         if ($params{size} ne 'full') {
  68                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  69                 error sprintf(gettext('bad size "%s"'), $params{size})
  70                         unless (defined $w && defined $h &&
  71                                 (length $w || length $h));
  72
  73                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  74                 $imglink = "$dir/${w}x${h}-$base";
  75
  76                 will_render($params{page}, $imglink);
  77
  78                 if (-e $outfile && (-M $srcfile >= -M $outfile)) {
  79                         $r = $im->Read($outfile);
  80                         error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
  81                 }
  82                 else {
  83                         $r = $im->Read($srcfile);
  84                         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  85
  86                         $r = $im->Resize(geometry => "${w}x${h}");
  87                         error sprintf(gettext("failed to resize: %s"), $r) if $r;
  88
  89                         # don't actually write file in preview mode
  90                         if (! $params{preview}) {
  91                                 my @blob = $im->ImageToBlob();
  92                                 writefile($imglink, $config{destdir}, $blob[0], 1);
  93                         }
  94                         else {
  95                                 $imglink = $file;
  96                         }
  97                 }
  98         }
  99         else {
 100                 $r = $im->Read($srcfile);
 101                 error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
 102                 $imglink = $file;
 103         }
 104
 105         add_depends($imglink, $params{page});
 106
 107         my ($fileurl, $imgurl);
 108         if (! $params{preview}) {
 109                 $fileurl=urlto($file, $params{destpage});
 110                 $imgurl=urlto($imglink, $params{destpage});
 111         }
 112         else {
 113                 $fileurl="$config{url}/$file";
 114                 $imgurl="$config{url}/$imglink";
 115         }
 116
 117         if (! defined($im->Get("width")) || ! defined($im->Get("height"))) {
 118                 error sprintf(gettext("failed to determine size of image %s"), $file)
 119         }
 120
 121         my $imgtag='<img src="'.$imgurl.
 122                 '" width="'.$im->Get("width").
 123                 '" height="'.$im->Get("height").'"'.
 124                 (exists $params{alt} ? '" alt="'.$params{alt}.'"' : '').
 125                 (exists $params{title} ? ' title="'.$params{title}.'"' : '').
 126                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 127                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 128                 ' />';
 129
 130         if (! defined $params{link} || lc($params{link}) eq 'yes') {
 131                 $imgtag='<a href="'.$fileurl.'">'.$imgtag.'</a>';
 132         }
 133         elsif ($params{link} =~ /^\w+:\/\//) {
 134                 $imgtag='<a href="'.$params{link}.'">'.$imgtag.'</a>';
 135         }
 136         elsif (length bestlink($params{page}, $params{link})) {
 137                 add_depends($params{page}, $params{link});
 138                 $imgtag=htmllink($params{page}, $params{destpage},
 139                         $params{link}, linktext => $imgtag,
 140                         noimageinline => 1);
 141         }
 142
 143         if (exists $params{caption}) {
 144                 return '<table class="img">'.
 145                         '<caption>'.$params{caption}.'</caption>'.
 146                         '<tr><td>'.$imgtag.'</td></tr>'.
 147                         '</table>';
 148         }
 149         else {
 150                 return $imgtag;
 151         }
 152 }
 153
 154 1