IkiWiki/Plugin/calendar.pm

   1 #! /usr/bin/perl
   2 # Copyright (c) 2006, 2007 Manoj Srivastava <srivasta@debian.org>
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17
  18 require 5.002;
  19 package IkiWiki::Plugin::calendar;
  20
  21 use warnings;
  22 use strict;
  23 use IkiWiki 2.00;
  24 use Time::Local;
  25 use POSIX;
  26
  27 my %cache;
  28 my %linkcache;
  29 my $time=time;
  30 my @now=localtime($time);
  31
  32 sub import { #{{{
  33         hook(type => "getsetup", id => "calendar", call => \&getsetup);
  34         hook(type => "needsbuild", id => "calendar", call => \&needsbuild);
  35         hook(type => "preprocess", id => "calendar", call => \&preprocess);
  36 } #}}}
  37
  38 sub getsetup () { #{{{
  39         return
  40                 plugin => {
  41                         safe => 1,
  42                         rebuild => undef,
  43                 },
  44                 archivebase => {
  45                         type => "string",
  46                         example => "archives",
  47                         description => "base of the archives hierarchy",
  48                         safe => 1,
  49                         rebuild => 1,
  50                 },
  51 } #}}}
  52
  53 sub is_leap_year (@) { #{{{
  54         my %params=@_;
  55         return ($params{year} % 4 == 0 && (($params{year} % 100 != 0) || $params{year} % 400 == 0));
  56 } #}}}
  57
  58 sub month_days { #{{{
  59         my %params=@_;
  60         my $days_in_month = (31,28,31,30,31,30,31,31,30,31,30,31)[$params{month}-1];
  61         if ($params{month} == 2 && is_leap_year(%params)) {
  62                 $days_in_month++;
  63         }
  64         return $days_in_month;
  65 } #}}}
  66
  67 sub format_month (@) { #{{{
  68         my %params=@_;
  69
  70         my $pagespec = $params{pages};
  71         my $year     = $params{year};
  72         my $month    = $params{month};
  73         my $pmonth   = $params{pmonth};
  74         my $nmonth   = $params{nmonth};
  75         my $pyear    = $params{pyear};
  76         my $nyear    = $params{nyear};
  77
  78         my @list;
  79         my $calendar="\n";
  80
  81         # When did this month start?
  82         my @monthstart = localtime(timelocal(0,0,0,1,$month-1,$year-1900));
  83
  84         my $future_dom = 0;
  85         my $today      = 0;
  86         if ($year == $now[5]+1900 && $month == $now[4]+1) {
  87                 $future_dom = $now[3]+1;
  88                 $today      = $now[3];
  89         }
  90
  91         # Find out month names for this, next, and previous months
  92         my $monthname=POSIX::strftime("%B", @monthstart);
  93         my $pmonthname=POSIX::strftime("%B", localtime(timelocal(0,0,0,1,$pmonth-1,$pyear-1900)));
  94         my $nmonthname=POSIX::strftime("%B", localtime(timelocal(0,0,0,1,$nmonth-1,$nyear-1900)));
  95
  96         my $archivebase = 'archives';
  97         $archivebase = $config{archivebase} if defined $config{archivebase};
  98         $archivebase = $params{archivebase} if defined $params{archivebase};
  99
 100         # Calculate URL's for monthly archives.
 101         my ($url, $purl, $nurl)=("$monthname",'','');
 102         if (exists $cache{$pagespec}{"$year/$month"}) {
 103                 $url = htmllink($params{page}, $params{destpage},
 104                         "$archivebase/$year/".sprintf("%02d", $month),
 105                         linktext => " $monthname ");
 106         }
 107         add_depends($params{page}, "$archivebase/$year/".sprintf("%02d", $month));
 108         if (exists $cache{$pagespec}{"$pyear/$pmonth"}) {
 109                 $purl = htmllink($params{page}, $params{destpage},
 110                         "$archivebase/$pyear/" . sprintf("%02d", $pmonth),
 111                         linktext => " $pmonthname ");
 112         }
 113         add_depends($params{page}, "$archivebase/$pyear/".sprintf("%02d", $pmonth));
 114         if (exists $cache{$pagespec}{"$nyear/$nmonth"}) {
 115                 $nurl = htmllink($params{page}, $params{destpage},
 116                         "$archivebase/$nyear/" . sprintf("%02d", $nmonth),
 117                         linktext => " $nmonthname ");
 118         }
 119         add_depends($params{page}, "$archivebase/$nyear/".sprintf("%02d", $nmonth));
 120
 121         # Start producing the month calendar
 122         $calendar=<<EOF;
 123 <table class="month-calendar">
 124         <caption class="month-calendar-head">
 125         $purl
 126         $url
 127         $nurl
 128         </caption>
 129         <tr>
 130 EOF
 131
 132         # Suppose we want to start the week with day $week_start_day
 133         # If $monthstart[6] == 1
 134         my $week_start_day = $params{week_start_day};
 135
 136         my $start_day = 1 + (7 - $monthstart[6] + $week_start_day) % 7;
 137         my %downame;
 138         my %dowabbr;
 139         for my $dow ($week_start_day..$week_start_day+6) {
 140                 my @day=localtime(timelocal(0,0,0,$start_day++,$month-1,$year-1900));
 141                 my $downame = POSIX::strftime("%A", @day);
 142                 my $dowabbr = POSIX::strftime("%a", @day);
 143                 $downame{$dow % 7}=$downame;
 144                 $dowabbr{$dow % 7}=$dowabbr;
 145                 $calendar.= qq{\t\t<th class="month-calendar-day-head $downame">$dowabbr</th>\n};
 146         }
 147
 148         $calendar.=<<EOF;
 149         </tr>
 150 EOF
 151
 152         my $wday;
 153         # we start with a week_start_day, and skip until we get to the first
 154         for ($wday=$week_start_day; $wday != $monthstart[6]; $wday++, $wday %= 7) {
 155                 $calendar.=qq{\t<tr>\n} if $wday == $week_start_day;
 156                 $calendar.=qq{\t\t<td class="month-calendar-day-noday $downame{$wday}">&nbsp;</td>\n};
 157         }
 158
 159         # At this point, either the first is a week_start_day, in which case
 160         # nothing has been printed, or else we are in the middle of a row.
 161         for (my $day = 1; $day <= month_days(year => $year, month => $month);
 162              $day++, $wday++, $wday %= 7) {
 163                 # At tihs point, on a week_start_day, we close out a row,
 164                 # and start a new one -- unless it is week_start_day on the
 165                 # first, where we do not close a row -- since none was started.
 166                 if ($wday == $week_start_day) {
 167                         $calendar.=qq{\t</tr>\n} unless $day == 1;
 168                         $calendar.=qq{\t<tr>\n};
 169                 }
 170
 171                 my $tag;
 172                 my $mtag = sprintf("%02d", $month);
 173                 if (defined $cache{$pagespec}{"$year/$mtag/$day"}) {
 174                         if ($day == $today) {
 175                                 $tag='month-calendar-day-this-day';
 176                         }
 177                         else {
 178                                 $tag='month-calendar-day-link';
 179                         }
 180                         $calendar.=qq{\t\t<td class="$tag $downame{$wday}">};
 181                         $calendar.=htmllink($params{page}, $params{destpage},
 182                                             pagename($linkcache{"$year/$mtag/$day"}),
 183                                             "linktext" => "$day");
 184                         push @list, pagename($linkcache{"$year/$mtag/$day"});
 185                         $calendar.=qq{</td>\n};
 186                 }
 187                 else {
 188                         if ($day == $today) {
 189                                 $tag='month-calendar-day-this-day';
 190                         }
 191                         elsif ($day == $future_dom) {
 192                                 $tag='month-calendar-day-future';
 193                         }
 194                         else {
 195                                 $tag='month-calendar-day-nolink';
 196                         }
 197                         $calendar.=qq{\t\t<td class="$tag $downame{$wday}">$day</td>\n};
 198                 }
 199         }
 200
 201         # finish off the week
 202         for (; $wday != $week_start_day; $wday++, $wday %= 7) {
 203                 $calendar.=qq{\t\t<td class="month-calendar-day-noday $downame{$wday}">&nbsp;</td>\n};
 204         }
 205         $calendar.=<<EOF;
 206         </tr>
 207 </table>
 208 EOF
 209
 210         # Add dependencies to update the calendar whenever pages
 211         # matching the pagespec are added or removed.
 212         add_depends($params{page}, $params{pages});
 213         # Explicitly add all currently linked pages as dependencies, so
 214         # that if they are removed, the calendar will be sure to be updated.
 215         add_depends($params{page}, join(" or ", @list));
 216
 217         return $calendar;
 218 } #}}}
 219
 220 sub format_year (@) { #{{{
 221         my %params=@_;
 222
 223         my $pagespec = $params{pages};
 224         my $year     = $params{year};
 225         my $month    = $params{month};
 226         my $pmonth   = $params{pmonth};
 227         my $nmonth   = $params{nmonth};
 228         my $pyear    = $params{pyear};
 229         my $nyear    = $params{nyear};
 230
 231         my $calendar="\n";
 232
 233         my $future_month = 0;
 234         $future_month = $now[4]+1 if ($year == $now[5]+1900);
 235
 236         my $archivebase = 'archives';
 237         $archivebase = $config{archivebase} if defined $config{archivebase};
 238         $archivebase = $params{archivebase} if defined $params{archivebase};
 239
 240         # calculate URL's for previous and next years
 241         my ($url, $purl, $nurl)=("$year",'','');
 242         if (exists $cache{$pagespec}{"$year"}) {
 243                 $url = htmllink($params{page}, $params{destpage},
 244                         "$archivebase/$year",
 245                         linktext => "$year");
 246         }
 247         add_depends($params{page}, "$archivebase/$year");
 248         if (exists $cache{$pagespec}{"$pyear"}) {
 249                 $purl = htmllink($params{page}, $params{destpage},
 250                         "$archivebase/$pyear",
 251                         linktext => "\&larr;");
 252         }
 253         add_depends($params{page}, "$archivebase/$pyear");
 254         if (exists $cache{$pagespec}{"$nyear"}) {
 255                 $nurl = htmllink($params{page}, $params{destpage},
 256                         "$archivebase/$nyear",
 257                         linktext => "\&rarr;");
 258         }
 259         add_depends($params{page}, "$archivebase/$nyear");
 260
 261         # Start producing the year calendar
 262         $calendar=<<EOF;
 263 <table class="year-calendar">
 264         <caption class="year-calendar-head">
 265         $purl
 266         $url
 267         $nurl
 268         </caption>
 269         <tr>
 270                 <th class="year-calendar-subhead" colspan="$params{months_per_row}">Months</th>
 271         </tr>
 272 EOF
 273
 274         for ($month = 1; $month <= 12; $month++) {
 275                 my @day=localtime(timelocal(0,0,0,15,$month-1,$year-1900));
 276                 my $murl;
 277                 my $monthname = POSIX::strftime("%B", @day);
 278                 my $monthabbr = POSIX::strftime("%b", @day);
 279                 $calendar.=qq{\t<tr>\n}  if ($month % $params{months_per_row} == 1);
 280                 my $tag;
 281                 my $mtag=sprintf("%02d", $month);
 282                 if ($month == $params{month}) {
 283                         if ($cache{$pagespec}{"$year/$mtag"}) {
 284                                 $tag = 'this_month_link';
 285                         }
 286                         else {
 287                                 $tag = 'this_month_nolink';
 288                         }
 289                 }
 290                 elsif ($cache{$pagespec}{"$year/$mtag"}) {
 291                         $tag = 'month_link';
 292                 }
 293                 elsif ($future_month && $month >= $future_month) {
 294                         $tag = 'month_future';
 295                 }
 296                 else {
 297                         $tag = 'month_nolink';
 298                 }
 299
 300                 if ($cache{$pagespec}{"$year/$mtag"}) {
 301                         $murl = htmllink($params{page}, $params{destpage},
 302                                 "$archivebase/$year/$mtag",
 303                                 linktext => "$monthabbr");
 304                         $calendar.=qq{\t<td class="$tag">};
 305                         $calendar.=$murl;
 306                         $calendar.=qq{\t</td>\n};
 307                 }
 308                 else {
 309                         $calendar.=qq{\t<td class="$tag">$monthabbr</td>\n};
 310                 }
 311                 add_depends($params{page}, "$archivebase/$year/$mtag");
 312
 313                 $calendar.=qq{\t</tr>\n} if ($month % $params{months_per_row} == 0);
 314         }
 315
 316         $calendar.=<<EOF;
 317 </table>
 318 EOF
 319
 320         return $calendar;
 321 } #}}}
 322
 323 sub preprocess (@) { #{{{
 324         my %params=@_;
 325         $params{pages} = "*"            unless defined $params{pages};
 326         $params{type}  = "month"        unless defined $params{type};
 327         $params{month} = sprintf("%02d", $params{month}) if defined  $params{month};
 328         $params{week_start_day} = 0     unless defined $params{week_start_day};
 329         $params{months_per_row} = 3     unless defined $params{months_per_row};
 330
 331         if (! defined $params{year} || ! defined $params{month}) {
 332                 # Record that the calendar next changes at midnight.
 333                 $pagestate{$params{destpage}}{calendar}{nextchange}=($time
 334                         + (60 - $now[0])                # seconds
 335                         + (59 - $now[1]) * 60           # minutes
 336                         + (23 - $now[2]) * 60 * 60      # hours
 337                 );
 338
 339                 $params{year}  = 1900 + $now[5] unless defined $params{year};
 340                 $params{month} = 1    + $now[4] unless defined $params{month};
 341         }
 342         else {
 343                 delete $pagestate{$params{destpage}}{calendar};
 344         }
 345
 346         # Calculate month names for next month, and previous months
 347         my $pmonth = $params{month} - 1;
 348         my $nmonth = $params{month} + 1;
 349         my $pyear  = $params{year}  - 1;
 350         my $nyear  = $params{year}  + 1;
 351
 352         # Adjust for January and December
 353         if ($params{month} == 1) {
 354                 $pmonth = 12;
 355                 $pyear--;
 356         }
 357         if ($params{month} == 12) {
 358                 $nmonth = 1;
 359                 $nyear++;
 360         }
 361
 362         $params{pmonth}=$pmonth;
 363         $params{nmonth}=$nmonth;
 364         $params{pyear} =$pyear;
 365         $params{nyear} =$nyear;
 366
 367         my $calendar="\n";
 368         my $pagespec=$params{pages};
 369         my $page =$params{page};
 370
 371         if (! defined $cache{$pagespec}) {
 372                 foreach my $p (keys %pagesources) {
 373                         next unless pagespec_match($p, $pagespec);
 374                         my $mtime = $IkiWiki::pagectime{$p};
 375                         my $src   = $pagesources{$p};
 376                         my @date  = localtime($mtime);
 377                         my $mday  = $date[3];
 378                         my $month = $date[4] + 1;
 379                         my $year  = $date[5] + 1900;
 380                         my $mtag  = sprintf("%02d", $month);
 381
 382                         # Only one posting per day is being linked to.
 383                         $linkcache{"$year/$mtag/$mday"} = "$src";
 384                         $cache{$pagespec}{"$year"}++;
 385                         $cache{$pagespec}{"$year/$mtag"}++;
 386                         $cache{$pagespec}{"$year/$mtag/$mday"}++;
 387                 }
 388         }
 389
 390         if ($params{type} =~ /month/i) {
 391                 $calendar=format_month(%params);
 392         }
 393         elsif ($params{type} =~ /year/i) {
 394                 $calendar=format_year(%params);
 395         }
 396
 397         return "\n<div><div class=\"calendar\">$calendar</div></div>\n";
 398 } #}}
 399
 400 sub needsbuild (@) { #{{{
 401         my $needsbuild=shift;
 402         foreach my $page (keys %pagestate) {
 403                 if (exists $pagestate{$page}{calendar}{nextchange}) {
 404                         if ($pagestate{$page}{calendar}{nextchange} <= $time) {
 405                                 # force a rebuild so the calendar shows
 406                                 # the current day
 407                                 push @$needsbuild, $pagesources{$page};
 408                         }
 409                         if (exists $pagesources{$page} &&
 410                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
 411                                 # remove state, will be re-added if
 412                                 # the calendar is still there during the
 413                                 # rebuild
 414                                 delete $pagestate{$page}{calendar};
 415                         }
 416                 }
 417         }
 418 } # }}}
 419
 420 1