IkiWiki/Plugin/table.pm

   1 package IkiWiki::Plugin::table;
   2 # by Victor Moral <victor@taquiones.net>
   3
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "table", call => \&getsetup);
  11         hook(type => "preprocess", id => "table", call => \&preprocess, scan => 1);
  12 }
  13
  14 sub getsetup () {
  15         return
  16                 plugin => {
  17                         safe => 1,
  18                         rebuild => undef,
  19                         section => "widget",
  20                 },
  21 }
  22
  23 sub preprocess (@) {
  24         my %params =(
  25                 format  => 'auto',
  26                 header  => 'row',
  27                 @_
  28         );
  29
  30         if (exists $params{file}) {
  31                 if (! exists $pagesources{$params{file}}) {
  32                         error gettext("cannot find file");
  33                 }
  34                 $params{data} = readfile(srcfile($params{file}));
  35                 add_depends($params{page}, $params{file});
  36         }
  37
  38         if (! defined wantarray) {
  39                 # scan mode --  if the table uses an external file, need to
  40                 # scan that file too.
  41                 return unless exists $params{file};
  42
  43                 # Preprocess in scan-only mode.
  44                 IkiWiki::preprocess($params{page}, $params{page}, $params{data}, 1);
  45
  46                 IkiWiki::run_hooks(scan => sub {
  47                         shift->(
  48                                 page => $params{page},
  49                                 content => $params{data},
  50                         );
  51                 });
  52
  53                 return;
  54         }
  55
  56         if (lc $params{format} eq 'auto') {
  57                 # first try the more simple format
  58                 if (is_dsv_data($params{data})) {
  59                         $params{format} = 'dsv';
  60                 }
  61                 else {
  62                         $params{format} = 'csv';
  63                 }
  64         }
  65
  66         my @data;
  67         if (lc $params{format} eq 'csv') {
  68                 @data=split_csv($params{data},
  69                         defined $params{delimiter} ? $params{delimiter} : ",",);
  70                 # linkify after parsing since html link quoting can
  71                 # confuse CSV parsing
  72                 @data=map {
  73                         [ map {
  74                                 IkiWiki::linkify($params{page},
  75                                         $params{destpage}, $_);
  76                         } @$_ ]
  77                 } @data;
  78         }
  79         elsif (lc $params{format} eq 'dsv') {
  80                 # linkify before parsing since wikilinks can contain the
  81                 # delimiter
  82                 $params{data} = IkiWiki::linkify($params{page},
  83                         $params{destpage}, $params{data});
  84                 @data=split_dsv($params{data},
  85                         defined $params{delimiter} ? $params{delimiter} : "|",);
  86         }
  87         else {
  88                 error gettext("unknown data format");
  89         }
  90
  91         my $header;
  92         if (lc($params{header}) eq "row" || IkiWiki::yesno($params{header})) {
  93                 $header=shift @data;
  94         }
  95         if (! @data) {
  96                 error gettext("empty data");
  97         }
  98
  99         my @lines;
 100         push @lines, defined $params{class}
 101                         ? "<table class=\"".$params{class}.'">'
 102                         : '<table>';
 103         push @lines, "\t<thead>",
 104                 genrow(\%params, "th", @$header),
 105                 "\t</thead>" if defined $header;
 106         push @lines, "\t<tbody>" if defined $header;
 107         push @lines, genrow(\%params, "td", @$_) foreach @data;
 108         push @lines, "\t</tbody>" if defined $header;
 109         push @lines, '</table>';
 110         my $html = join("\n", @lines);
 111
 112         if (exists $params{file}) {
 113                 return $html."\n\n".
 114                         htmllink($params{page}, $params{destpage}, $params{file},
 115                                 linktext => gettext('Direct data download'));
 116         }
 117         else {
 118                 return $html;
 119         }
 120 }
 121
 122 sub is_dsv_data ($) {
 123         my $text = shift;
 124
 125         my ($line) = split(/\n/, $text);
 126         return $line =~ m{.+\|};
 127 }
 128
 129 sub split_csv ($$) {
 130         my @text_lines = split(/\n/, shift);
 131         my $delimiter = shift;
 132
 133         eval q{use Text::CSV};
 134         error($@) if $@;
 135         my $csv = Text::CSV->new({
 136                 sep_char        => $delimiter,
 137                 binary          => 1,
 138                 decode_utf8 => 1,
 139                 allow_loose_quotes => 1,
 140         }) || error("could not create a Text::CSV object");
 141
 142         my $l=0;
 143         my @data;
 144         foreach my $line (@text_lines) {
 145                 $l++;
 146                 if ($csv->parse($line)) {
 147                         push(@data, [ $csv->fields() ]);
 148                 }
 149                 else {
 150                         debug(sprintf(gettext('parse fail at line %d: %s'),
 151                                 $l, $csv->error_input()));
 152                 }
 153         }
 154
 155         return @data;
 156 }
 157
 158 sub split_dsv ($$) {
 159         my @text_lines = split(/\n/, shift);
 160         my $delimiter = shift;
 161         $delimiter="|" unless defined $delimiter;
 162
 163         my @data;
 164         foreach my $line (@text_lines) {
 165                 push @data, [ split(/\Q$delimiter\E/, $line, -1) ];
 166         }
 167
 168         return @data;
 169 }
 170
 171 sub genrow ($@) {
 172         my %params=%{shift()};
 173         my $elt = shift;
 174         my @data = @_;
 175
 176         my $page=$params{page};
 177         my $destpage=$params{destpage};
 178         my $type=pagetype($pagesources{$page});
 179
 180         my @ret;
 181         push @ret, "\t\t<tr>";
 182         for (my $x=0; $x < @data; $x++) {
 183                 my $cell=IkiWiki::htmlize($page, $destpage, $type,
 184                          IkiWiki::preprocess($page, $destpage, $data[$x]));
 185
 186                 # automatic colspan for empty cells
 187                 my $colspan=1;
 188                 while ($x+1 < @data && $data[$x+1] eq '') {
 189                         $x++;
 190                         $colspan++;
 191                 }
 192
 193                 # check if the first column should be a header
 194                 my $e=$elt;
 195                 if ($x == 0 && lc($params{header}) eq "column") {
 196                         $e="th";
 197                 }
 198
 199                 if ($colspan > 1) {
 200                         push @ret, "\t\t\t<$e colspan=\"$colspan\">$cell</$e>"
 201                 }
 202                 else {
 203                         push @ret, "\t\t\t<$e>$cell</$e>"
 204                 }
 205         }
 206         push @ret, "\t\t</tr>";
 207
 208         return @ret;
 209 }
 210
 211 1