IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %renderedfiles %oldrenderedfiles %pagesources %destsources
  14             %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  add_underlay
  21                  %config %links %renderedfiles %pagesources %destsources);
  22 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  23 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  24 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  25
  26 # Optimisation.
  27 use Memoize;
  28 memoize("abs2rel");
  29 memoize("pagespec_translate");
  30 memoize("file_pruned");
  31
  32 sub defaultconfig () { #{{{
  33         return
  34         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  35                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  36                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  37                 qr/(^|\/)_MTN\//,
  38                 qr/\.dpkg-tmp$/],
  39         wiki_link_regexp => qr{
  40                 \[\[                    # beginning of link
  41                 (?:
  42                         ([^\]\|\n\s]+)  # 1: link text
  43                         \|              # followed by '|'
  44                 )?                      # optional
  45
  46                 ([^\s\]#]+)             # 2: page to link to
  47                 (?:
  48                         \#              # '#', beginning of anchor
  49                         ([^\s\]]+)      # 3: anchor text
  50                 )?                      # optional
  51
  52                 \]\]                    # end of link
  53         }x,
  54         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  55         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  56         verbose => 0,
  57         syslog => 0,
  58         wikiname => "wiki",
  59         default_pageext => "mdwn",
  60         htmlext => "html",
  61         cgi => 0,
  62         post_commit => 0,
  63         rcs => '',
  64         notify => 0,
  65         url => '',
  66         cgiurl => '',
  67         historyurl => '',
  68         diffurl => '',
  69         rss => 0,
  70         atom => 0,
  71         discussion => 1,
  72         rebuild => 0,
  73         refresh => 0,
  74         getctime => 0,
  75         w3mmode => 0,
  76         wrapper => undef,
  77         wrappermode => undef,
  78         svnrepo => undef,
  79         svnpath => "trunk",
  80         gitorigin_branch => "origin",
  81         gitmaster_branch => "master",
  82         srcdir => undef,
  83         destdir => undef,
  84         pingurl => [],
  85         templatedir => "$installdir/share/ikiwiki/templates",
  86         underlaydir => "$installdir/share/ikiwiki/basewiki",
  87         underlaydirs => [],
  88         setup => undef,
  89         adminuser => undef,
  90         adminemail => undef,
  91         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  92                       lockedit conditional}],
  93         libdir => undef,
  94         timeformat => '%c',
  95         locale => undef,
  96         sslcookie => 0,
  97         httpauth => 0,
  98         userdir => "",
  99         usedirs => 1,
 100         numbacklinks => 10,
 101         account_creation_password => "",
 102 } #}}}
 103
 104 sub checkconfig () { #{{{
 105         # locale stuff; avoid LC_ALL since it overrides everything
 106         if (defined $ENV{LC_ALL}) {
 107                 $ENV{LANG} = $ENV{LC_ALL};
 108                 delete $ENV{LC_ALL};
 109         }
 110         if (defined $config{locale}) {
 111                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 112                         $ENV{LANG}=$config{locale};
 113                         $gettext_obj=undef;
 114                 }
 115         }
 116
 117         if ($config{w3mmode}) {
 118                 eval q{use Cwd q{abs_path}};
 119                 error($@) if $@;
 120                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 121                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 122                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 123                         unless $config{cgiurl} =~ m!file:///!;
 124                 $config{url}="file://".$config{destdir};
 125         }
 126
 127         if ($config{cgi} && ! length $config{url}) {
 128                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 129         }
 130
 131         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 132                 unless exists $config{wikistatedir};
 133
 134         if ($config{rcs}) {
 135                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 136                 if ($@) {
 137                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 138                 }
 139         }
 140         else {
 141                 require IkiWiki::Rcs::Stub;
 142         }
 143
 144         run_hooks(checkconfig => sub { shift->() });
 145
 146         return 1;
 147 } #}}}
 148
 149 sub loadplugins () { #{{{
 150         if (defined $config{libdir}) {
 151                 unshift @INC, possibly_foolish_untaint($config{libdir});
 152         }
 153
 154         loadplugin($_) foreach @{$config{plugin}};
 155
 156         run_hooks(getopt => sub { shift->() });
 157         if (grep /^-/, @ARGV) {
 158                 print STDERR "Unknown option: $_\n"
 159                         foreach grep /^-/, @ARGV;
 160                 usage();
 161         }
 162
 163         return 1;
 164 } #}}}
 165
 166 sub loadplugin ($) { #{{{
 167         my $plugin=shift;
 168
 169         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 170
 171         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 172                          "$installdir/lib/ikiwiki") {
 173                 if (defined $dir && -x "$dir/plugins/$plugin") {
 174                         require IkiWiki::Plugin::external;
 175                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 176                         return 1;
 177                 }
 178         }
 179
 180         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 181         eval qq{use $mod};
 182         if ($@) {
 183                 error("Failed to load plugin $mod: $@");
 184         }
 185         return 1;
 186 } #}}}
 187
 188 sub error ($;$) { #{{{
 189         my $message=shift;
 190         my $cleaner=shift;
 191         if ($config{cgi}) {
 192                 print "Content-type: text/html\n\n";
 193                 print misctemplate(gettext("Error"),
 194                         "<p>".gettext("Error").": $message</p>");
 195         }
 196         log_message('err' => $message) if $config{syslog};
 197         if (defined $cleaner) {
 198                 $cleaner->();
 199         }
 200         die $message."\n";
 201 } #}}}
 202
 203 sub debug ($) { #{{{
 204         return unless $config{verbose};
 205         return log_message(debug => @_);
 206 } #}}}
 207
 208 my $log_open=0;
 209 sub log_message ($$) { #{{{
 210         my $type=shift;
 211
 212         if ($config{syslog}) {
 213                 require Sys::Syslog;
 214                 if (! $log_open) {
 215                         Sys::Syslog::setlogsock('unix');
 216                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 217                         $log_open=1;
 218                 }
 219                 return eval {
 220                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 221                 };
 222         }
 223         elsif (! $config{cgi}) {
 224                 return print "@_\n";
 225         }
 226         else {
 227                 return print STDERR "@_\n";
 228         }
 229 } #}}}
 230
 231 sub possibly_foolish_untaint ($) { #{{{
 232         my $tainted=shift;
 233         my ($untainted)=$tainted=~/(.*)/s;
 234         return $untainted;
 235 } #}}}
 236
 237 sub basename ($) { #{{{
 238         my $file=shift;
 239
 240         $file=~s!.*/+!!;
 241         return $file;
 242 } #}}}
 243
 244 sub dirname ($) { #{{{
 245         my $file=shift;
 246
 247         $file=~s!/*[^/]+$!!;
 248         return $file;
 249 } #}}}
 250
 251 sub pagetype ($) { #{{{
 252         my $page=shift;
 253
 254         if ($page =~ /\.([^.]+)$/) {
 255                 return $1 if exists $hooks{htmlize}{$1};
 256         }
 257         return;
 258 } #}}}
 259
 260 sub pagename ($) { #{{{
 261         my $file=shift;
 262
 263         my $type=pagetype($file);
 264         my $page=$file;
 265         $page=~s/\Q.$type\E*$// if defined $type;
 266         return $page;
 267 } #}}}
 268
 269 sub targetpage ($$) { #{{{
 270         my $page=shift;
 271         my $ext=shift;
 272
 273         if (! $config{usedirs} || $page =~ /^index$/ ) {
 274                 return $page.".".$ext;
 275         } else {
 276                 return $page."/index.".$ext;
 277         }
 278 } #}}}
 279
 280 sub htmlpage ($) { #{{{
 281         my $page=shift;
 282
 283         return targetpage($page, $config{htmlext});
 284 } #}}}
 285
 286 sub srcfile ($) { #{{{
 287         my $file=shift;
 288
 289         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 290         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 291                 return "$dir/$file" if -e "$dir/$file";
 292         }
 293         error("internal error: $file cannot be found in $config{srcdir} or underlay");
 294         return;
 295 } #}}}
 296
 297 sub add_underlay ($) { #{{{
 298         my $dir=shift;
 299
 300         if ($dir=~/^\//) {
 301                 unshift @{$config{underlaydirs}}, $dir;
 302         }
 303         else {
 304                 unshift @{$config{underlaydirs}}, "$config{underlaydir}/../$dir";
 305         }
 306
 307         return 1;
 308 } #}}}
 309
 310 sub readfile ($;$$) { #{{{
 311         my $file=shift;
 312         my $binary=shift;
 313         my $wantfd=shift;
 314
 315         if (-l $file) {
 316                 error("cannot read a symlink ($file)");
 317         }
 318
 319         local $/=undef;
 320         open (my $in, "<", $file) || error("failed to read $file: $!");
 321         binmode($in) if ($binary);
 322         return \*$in if $wantfd;
 323         my $ret=<$in>;
 324         close $in || error("failed to read $file: $!");
 325         return $ret;
 326 } #}}}
 327
 328 sub writefile ($$$;$$) { #{{{
 329         my $file=shift; # can include subdirs
 330         my $destdir=shift; # directory to put file in
 331         my $content=shift;
 332         my $binary=shift;
 333         my $writer=shift;
 334
 335         my $test=$file;
 336         while (length $test) {
 337                 if (-l "$destdir/$test") {
 338                         error("cannot write to a symlink ($test)");
 339                 }
 340                 $test=dirname($test);
 341         }
 342         my $newfile="$destdir/$file.ikiwiki-new";
 343         if (-l $newfile) {
 344                 error("cannot write to a symlink ($newfile)");
 345         }
 346
 347         my $dir=dirname($newfile);
 348         if (! -d $dir) {
 349                 my $d="";
 350                 foreach my $s (split(m!/+!, $dir)) {
 351                         $d.="$s/";
 352                         if (! -d $d) {
 353                                 mkdir($d) || error("failed to create directory $d: $!");
 354                         }
 355                 }
 356         }
 357
 358         my $cleanup = sub { unlink($newfile) };
 359         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 360         binmode($out) if ($binary);
 361         if ($writer) {
 362                 $writer->(\*$out, $cleanup);
 363         }
 364         else {
 365                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 366         }
 367         close $out || error("failed saving $newfile: $!", $cleanup);
 368         rename($newfile, "$destdir/$file") ||
 369                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 370
 371         return 1;
 372 } #}}}
 373
 374 my %cleared;
 375 sub will_render ($$;$) { #{{{
 376         my $page=shift;
 377         my $dest=shift;
 378         my $clear=shift;
 379
 380         # Important security check.
 381         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 382             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 383                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 384         }
 385
 386         if (! $clear || $cleared{$page}) {
 387                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 388         }
 389         else {
 390                 foreach my $old (@{$renderedfiles{$page}}) {
 391                         delete $destsources{$old};
 392                 }
 393                 $renderedfiles{$page}=[$dest];
 394                 $cleared{$page}=1;
 395         }
 396         $destsources{$dest}=$page;
 397
 398         return 1;
 399 } #}}}
 400
 401 sub bestlink ($$) { #{{{
 402         my $page=shift;
 403         my $link=shift;
 404
 405         my $cwd=$page;
 406         if ($link=~s/^\/+//) {
 407                 # absolute links
 408                 $cwd="";
 409         }
 410
 411         do {
 412                 my $l=$cwd;
 413                 $l.="/" if length $l;
 414                 $l.=$link;
 415
 416                 if (exists $links{$l}) {
 417                         return $l;
 418                 }
 419                 elsif (exists $pagecase{lc $l}) {
 420                         return $pagecase{lc $l};
 421                 }
 422         } while $cwd=~s!/?[^/]+$!!;
 423
 424         if (length $config{userdir}) {
 425                 my $l = "$config{userdir}/".lc($link);
 426                 if (exists $links{$l}) {
 427                         return $l;
 428                 }
 429                 elsif (exists $pagecase{lc $l}) {
 430                         return $pagecase{lc $l};
 431                 }
 432         }
 433
 434         #print STDERR "warning: page $page, broken link: $link\n";
 435         return "";
 436 } #}}}
 437
 438 sub isinlinableimage ($) { #{{{
 439         my $file=shift;
 440
 441         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 442 } #}}}
 443
 444 sub pagetitle ($;$) { #{{{
 445         my $page=shift;
 446         my $unescaped=shift;
 447
 448         if ($unescaped) {
 449                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 450         }
 451         else {
 452                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 453         }
 454
 455         return $page;
 456 } #}}}
 457
 458 sub titlepage ($) { #{{{
 459         my $title=shift;
 460         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 461         return $title;
 462 } #}}}
 463
 464 sub linkpage ($) { #{{{
 465         my $link=shift;
 466         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 467         return $link;
 468 } #}}}
 469
 470 sub cgiurl (@) { #{{{
 471         my %params=@_;
 472
 473         return $config{cgiurl}."?".
 474                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 475 } #}}}
 476
 477 sub baseurl (;$) { #{{{
 478         my $page=shift;
 479
 480         return "$config{url}/" if ! defined $page;
 481
 482         $page=htmlpage($page);
 483         $page=~s/[^\/]+$//;
 484         $page=~s/[^\/]+\//..\//g;
 485         return $page;
 486 } #}}}
 487
 488 sub abs2rel ($$) { #{{{
 489         # Work around very innefficient behavior in File::Spec if abs2rel
 490         # is passed two relative paths. It's much faster if paths are
 491         # absolute! (Debian bug #376658; fixed in debian unstable now)
 492         my $path="/".shift;
 493         my $base="/".shift;
 494
 495         require File::Spec;
 496         my $ret=File::Spec->abs2rel($path, $base);
 497         $ret=~s/^// if defined $ret;
 498         return $ret;
 499 } #}}}
 500
 501 sub displaytime ($) { #{{{
 502         my $time=shift;
 503
 504         # strftime doesn't know about encodings, so make sure
 505         # its output is properly treated as utf8
 506         return decode_utf8(POSIX::strftime(
 507                         $config{timeformat}, localtime($time)));
 508 } #}}}
 509
 510 sub beautify_url ($) { #{{{
 511         my $url=shift;
 512
 513         $url =~ s!/index.$config{htmlext}$!/!;
 514         $url =~ s!^$!./!; # Browsers don't like empty links...
 515
 516         return $url;
 517 } #}}}
 518
 519 sub urlto ($$) { #{{{
 520         my $to=shift;
 521         my $from=shift;
 522
 523         if (! length $to) {
 524                 return beautify_url(baseurl($from));
 525         }
 526
 527         if (! $destsources{$to}) {
 528                 $to=htmlpage($to);
 529         }
 530
 531         my $link = abs2rel($to, dirname(htmlpage($from)));
 532
 533         return beautify_url($link);
 534 } #}}}
 535
 536 sub htmllink ($$$;@) { #{{{
 537         my $lpage=shift; # the page doing the linking
 538         my $page=shift; # the page that will contain the link (different for inline)
 539         my $link=shift;
 540         my %opts=@_;
 541
 542         my $bestlink;
 543         if (! $opts{forcesubpage}) {
 544                 $bestlink=bestlink($lpage, $link);
 545         }
 546         else {
 547                 $bestlink="$lpage/".lc($link);
 548         }
 549
 550         my $linktext;
 551         if (defined $opts{linktext}) {
 552                 $linktext=$opts{linktext};
 553         }
 554         else {
 555                 $linktext=pagetitle(basename($link));
 556         }
 557
 558         return "<span class=\"selflink\">$linktext</span>"
 559                 if length $bestlink && $page eq $bestlink;
 560
 561         if (! $destsources{$bestlink}) {
 562                 $bestlink=htmlpage($bestlink);
 563
 564                 if (! $destsources{$bestlink}) {
 565                         return $linktext unless length $config{cgiurl};
 566                         return "<span><a href=\"".
 567                                 cgiurl(
 568                                         do => "create",
 569                                         page => pagetitle(lc($link), 1),
 570                                         from => $lpage
 571                                 ).
 572                                 "\">?</a>$linktext</span>"
 573                 }
 574         }
 575
 576         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 577         $bestlink=beautify_url($bestlink);
 578
 579         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 580                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 581         }
 582
 583         if (defined $opts{anchor}) {
 584                 $bestlink.="#".$opts{anchor};
 585         }
 586
 587         my @attrs;
 588         if (defined $opts{rel}) {
 589                 push @attrs, ' rel="'.$opts{rel}.'"';
 590         }
 591         if (defined $opts{class}) {
 592                 push @attrs, ' class="'.$opts{class}.'"';
 593         }
 594
 595         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 596 } #}}}
 597
 598 sub htmlize ($$$) { #{{{
 599         my $page=shift;
 600         my $type=shift;
 601         my $content=shift;
 602
 603         if (exists $hooks{htmlize}{$type}) {
 604                 $content=$hooks{htmlize}{$type}{call}->(
 605                         page => $page,
 606                         content => $content,
 607                 );
 608         }
 609         else {
 610                 error("htmlization of $type not supported");
 611         }
 612
 613         run_hooks(sanitize => sub {
 614                 $content=shift->(
 615                         page => $page,
 616                         content => $content,
 617                 );
 618         });
 619
 620         return $content;
 621 } #}}}
 622
 623 sub linkify ($$$) { #{{{
 624         my $lpage=shift; # the page containing the links
 625         my $page=shift; # the page the link will end up on (different for inline)
 626         my $content=shift;
 627
 628         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 629                 defined $2
 630                         ? ( $1
 631                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 632                                 : htmllink($lpage, $page, linkpage($3),
 633                                         anchor => $4, linktext => pagetitle($2)))
 634                         : ( $1
 635                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 636                                 : htmllink($lpage, $page, linkpage($3),
 637                                         anchor => $4))
 638         }eg;
 639
 640         return $content;
 641 } #}}}
 642
 643 my %preprocessing;
 644 our $preprocess_preview=0;
 645 sub preprocess ($$$;$$) { #{{{
 646         my $page=shift; # the page the data comes from
 647         my $destpage=shift; # the page the data will appear in (different for inline)
 648         my $content=shift;
 649         my $scan=shift;
 650         my $preview=shift;
 651
 652         # Using local because it needs to be set within any nested calls
 653         # of this function.
 654         local $preprocess_preview=$preview if defined $preview;
 655
 656         my $handle=sub {
 657                 my $escape=shift;
 658                 my $command=shift;
 659                 my $params=shift;
 660                 if (length $escape) {
 661                         return "[[$command $params]]";
 662                 }
 663                 elsif (exists $hooks{preprocess}{$command}) {
 664                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 665                         # Note: preserve order of params, some plugins may
 666                         # consider it significant.
 667                         my @params;
 668                         while ($params =~ m{
 669                                 (?:(\w+)=)?             # 1: named parameter key?
 670                                 (?:
 671                                         """(.*?)"""     # 2: triple-quoted value
 672                                 |
 673                                         "([^"]+)"       # 3: single-quoted value
 674                                 |
 675                                         (\S+)           # 4: unquoted value
 676                                 )
 677                                 (?:\s+|$)               # delimiter to next param
 678                         }sgx) {
 679                                 my $key=$1;
 680                                 my $val;
 681                                 if (defined $2) {
 682                                         $val=$2;
 683                                         $val=~s/\r\n/\n/mg;
 684                                         $val=~s/^\n+//g;
 685                                         $val=~s/\n+$//g;
 686                                 }
 687                                 elsif (defined $3) {
 688                                         $val=$3;
 689                                 }
 690                                 elsif (defined $4) {
 691                                         $val=$4;
 692                                 }
 693
 694                                 if (defined $key) {
 695                                         push @params, $key, $val;
 696                                 }
 697                                 else {
 698                                         push @params, $val, '';
 699                                 }
 700                         }
 701                         if ($preprocessing{$page}++ > 3) {
 702                                 # Avoid loops of preprocessed pages preprocessing
 703                                 # other pages that preprocess them, etc.
 704                                 #translators: The first parameter is a
 705                                 #translators: preprocessor directive name,
 706                                 #translators: the second a page name, the
 707                                 #translators: third a number.
 708                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 709                                         $command, $page, $preprocessing{$page}).
 710                                 "]]";
 711                         }
 712                         my $ret=$hooks{preprocess}{$command}{call}->(
 713                                 @params,
 714                                 page => $page,
 715                                 destpage => $destpage,
 716                                 preview => $preprocess_preview,
 717                         );
 718                         $preprocessing{$page}--;
 719                         return $ret;
 720                 }
 721                 else {
 722                         return "[[$command $params]]";
 723                 }
 724         };
 725
 726         $content =~ s{
 727                 (\\?)           # 1: escape?
 728                 \[\[            # directive open
 729                 (\w+)           # 2: command
 730                 \s+
 731                 (               # 3: the parameters..
 732                         (?:
 733                                 (?:\w+=)?               # named parameter key?
 734                                 (?:
 735                                         """.*?"""       # triple-quoted value
 736                                         |
 737                                         "[^"]+"         # single-quoted value
 738                                         |
 739                                         [^\s\]]+        # unquoted value
 740                                 )
 741                                 \s*                     # whitespace or end
 742                                                         # of directive
 743                         )
 744                 *)              # 0 or more parameters
 745                 \]\]            # directive closed
 746         }{$handle->($1, $2, $3)}sexg;
 747         return $content;
 748 } #}}}
 749
 750 sub filter ($$$) { #{{{
 751         my $page=shift;
 752         my $destpage=shift;
 753         my $content=shift;
 754
 755         run_hooks(filter => sub {
 756                 $content=shift->(page => $page, destpage => $destpage,
 757                         content => $content);
 758         });
 759
 760         return $content;
 761 } #}}}
 762
 763 sub indexlink () { #{{{
 764         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 765 } #}}}
 766
 767 my $wikilock;
 768
 769 sub lockwiki (;$) { #{{{
 770         my $wait=@_ ? shift : 1;
 771         # Take an exclusive lock on the wiki to prevent multiple concurrent
 772         # run issues. The lock will be dropped on program exit.
 773         if (! -d $config{wikistatedir}) {
 774                 mkdir($config{wikistatedir});
 775         }
 776         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 777                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 778         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 779                 if ($wait) {
 780                         debug("wiki seems to be locked, waiting for lock");
 781                         my $wait=600; # arbitrary, but don't hang forever to
 782                                       # prevent process pileup
 783                         for (1..$wait) {
 784                                 return if flock($wikilock, 2 | 4);
 785                                 sleep 1;
 786                         }
 787                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 788                 }
 789                 else {
 790                         return 0;
 791                 }
 792         }
 793         return 1;
 794 } #}}}
 795
 796 sub unlockwiki () { #{{{
 797         return close($wikilock) if $wikilock;
 798         return;
 799 } #}}}
 800
 801 my $commitlock;
 802
 803 sub commit_hook_enabled () { #{{{
 804         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 805                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 806         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 807                 close($commitlock) || error("failed closing commitlock: $!");
 808                 return 0;
 809         }
 810         close($commitlock) || error("failed closing commitlock: $!");
 811         return 1;
 812 } #}}}
 813
 814 sub disable_commit_hook () { #{{{
 815         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 816                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 817         if (! flock($commitlock, 2)) { # LOCK_EX
 818                 error("failed to get commit lock");
 819         }
 820         return 1;
 821 } #}}}
 822
 823 sub enable_commit_hook () { #{{{
 824         return close($commitlock) if $commitlock;
 825         return;
 826 } #}}}
 827
 828 sub loadindex () { #{{{
 829         open (my $in, "<", "$config{wikistatedir}/index") || return;
 830         while (<$in>) {
 831                 $_=possibly_foolish_untaint($_);
 832                 chomp;
 833                 my %items;
 834                 $items{link}=[];
 835                 $items{dest}=[];
 836                 foreach my $i (split(/ /, $_)) {
 837                         my ($item, $val)=split(/=/, $i, 2);
 838                         push @{$items{$item}}, decode_entities($val);
 839                 }
 840
 841                 next unless exists $items{src}; # skip bad lines for now
 842
 843                 my $page=pagename($items{src}[0]);
 844                 if (! $config{rebuild}) {
 845                         $pagesources{$page}=$items{src}[0];
 846                         $pagemtime{$page}=$items{mtime}[0];
 847                         $oldlinks{$page}=[@{$items{link}}];
 848                         $links{$page}=[@{$items{link}}];
 849                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 850                         $destsources{$_}=$page foreach @{$items{dest}};
 851                         $renderedfiles{$page}=[@{$items{dest}}];
 852                         $pagecase{lc $page}=$page;
 853                 }
 854                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 855                 $pagectime{$page}=$items{ctime}[0];
 856         }
 857         return close($in);
 858 } #}}}
 859
 860 sub saveindex () { #{{{
 861         run_hooks(savestate => sub { shift->() });
 862
 863         if (! -d $config{wikistatedir}) {
 864                 mkdir($config{wikistatedir});
 865         }
 866         my $newfile="$config{wikistatedir}/index.new";
 867         my $cleanup = sub { unlink($newfile) };
 868         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 869         foreach my $page (keys %pagemtime) {
 870                 next unless $pagemtime{$page};
 871                 my $line="mtime=$pagemtime{$page} ".
 872                         "ctime=$pagectime{$page} ".
 873                         "src=$pagesources{$page}";
 874                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 875                 my %count;
 876                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 877                 if (exists $depends{$page}) {
 878                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 879                 }
 880                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 881         }
 882         close $out || error("failed saving to $newfile: $!", $cleanup);
 883         rename($newfile, "$config{wikistatedir}/index") ||
 884                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 885
 886         return 1;
 887 } #}}}
 888
 889 sub template_file ($) { #{{{
 890         my $template=shift;
 891
 892         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 893                 return "$dir/$template" if -e "$dir/$template";
 894         }
 895         return;
 896 } #}}}
 897
 898 sub template_params (@) { #{{{
 899         my $filename=template_file(shift);
 900
 901         if (! defined $filename) {
 902                 return if wantarray;
 903                 return "";
 904         }
 905
 906         my @ret=(
 907                 filter => sub {
 908                         my $text_ref = shift;
 909                         ${$text_ref} = decode_utf8(${$text_ref});
 910                 },
 911                 filename => $filename,
 912                 loop_context_vars => 1,
 913                 die_on_bad_params => 0,
 914                 @_
 915         );
 916         return wantarray ? @ret : {@ret};
 917 } #}}}
 918
 919 sub template ($;@) { #{{{
 920         require HTML::Template;
 921         return HTML::Template->new(template_params(@_));
 922 } #}}}
 923
 924 sub misctemplate ($$;@) { #{{{
 925         my $title=shift;
 926         my $pagebody=shift;
 927
 928         my $template=template("misc.tmpl");
 929         $template->param(
 930                 title => $title,
 931                 indexlink => indexlink(),
 932                 wikiname => $config{wikiname},
 933                 pagebody => $pagebody,
 934                 baseurl => baseurl(),
 935                 @_,
 936         );
 937         run_hooks(pagetemplate => sub {
 938                 shift->(page => "", destpage => "", template => $template);
 939         });
 940         return $template->output;
 941 }#}}}
 942
 943 sub hook (@) { # {{{
 944         my %param=@_;
 945
 946         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 947                 error 'hook requires type, call, and id parameters';
 948         }
 949
 950         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 951
 952         $hooks{$param{type}}{$param{id}}=\%param;
 953         return 1;
 954 } # }}}
 955
 956 sub run_hooks ($$) { # {{{
 957         # Calls the given sub for each hook of the given type,
 958         # passing it the hook function to call.
 959         my $type=shift;
 960         my $sub=shift;
 961
 962         if (exists $hooks{$type}) {
 963                 my @deferred;
 964                 foreach my $id (keys %{$hooks{$type}}) {
 965                         if ($hooks{$type}{$id}{last}) {
 966                                 push @deferred, $id;
 967                                 next;
 968                         }
 969                         $sub->($hooks{$type}{$id}{call});
 970                 }
 971                 foreach my $id (@deferred) {
 972                         $sub->($hooks{$type}{$id}{call});
 973                 }
 974         }
 975
 976         return 1;
 977 } #}}}
 978
 979 sub globlist_to_pagespec ($) { #{{{
 980         my @globlist=split(' ', shift);
 981
 982         my (@spec, @skip);
 983         foreach my $glob (@globlist) {
 984                 if ($glob=~/^!(.*)/) {
 985                         push @skip, $glob;
 986                 }
 987                 else {
 988                         push @spec, $glob;
 989                 }
 990         }
 991
 992         my $spec=join(' or ', @spec);
 993         if (@skip) {
 994                 my $skip=join(' and ', @skip);
 995                 if (length $spec) {
 996                         $spec="$skip and ($spec)";
 997                 }
 998                 else {
 999                         $spec=$skip;
1000                 }
1001         }
1002         return $spec;
1003 } #}}}
1004
1005 sub is_globlist ($) { #{{{
1006         my $s=shift;
1007         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1008 } #}}}
1009
1010 sub safequote ($) { #{{{
1011         my $s=shift;
1012         $s=~s/[{}]//g;
1013         return "q{$s}";
1014 } #}}}
1015
1016 sub add_depends ($$) { #{{{
1017         my $page=shift;
1018         my $pagespec=shift;
1019
1020         if (! exists $depends{$page}) {
1021                 $depends{$page}=$pagespec;
1022         }
1023         else {
1024                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1025         }
1026
1027         return 1;
1028 } # }}}
1029
1030 sub file_pruned ($$) { #{{{
1031         require File::Spec;
1032         my $file=File::Spec->canonpath(shift);
1033         my $base=File::Spec->canonpath(shift);
1034         $file =~ s#^\Q$base\E/*##;
1035
1036         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1037         return $file =~ m/$regexp/;
1038 } #}}}
1039
1040 sub gettext { #{{{
1041         # Only use gettext in the rare cases it's needed.
1042         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1043             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1044             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1045                 if (! $gettext_obj) {
1046                         $gettext_obj=eval q{
1047                                 use Locale::gettext q{textdomain};
1048                                 Locale::gettext->domain('ikiwiki')
1049                         };
1050                         if ($@) {
1051                                 print STDERR "$@";
1052                                 $gettext_obj=undef;
1053                                 return shift;
1054                         }
1055                 }
1056                 return $gettext_obj->get(shift);
1057         }
1058         else {
1059                 return shift;
1060         }
1061 } #}}}
1062
1063 sub pagespec_merge ($$) { #{{{
1064         my $a=shift;
1065         my $b=shift;
1066
1067         return $a if $a eq $b;
1068
1069         # Support for old-style GlobLists.
1070         if (is_globlist($a)) {
1071                 $a=globlist_to_pagespec($a);
1072         }
1073         if (is_globlist($b)) {
1074                 $b=globlist_to_pagespec($b);
1075         }
1076
1077         return "($a) or ($b)";
1078 } #}}}
1079
1080 sub pagespec_translate ($) { #{{{
1081         # This assumes that $page is in scope in the function
1082         # that evalulates the translated pagespec code.
1083         my $spec=shift;
1084
1085         # Support for old-style GlobLists.
1086         if (is_globlist($spec)) {
1087                 $spec=globlist_to_pagespec($spec);
1088         }
1089
1090         # Convert spec to perl code.
1091         my $code="";
1092         while ($spec=~m{
1093                 \s*             # ignore whitespace
1094                 (               # 1: match a single word
1095                         \!              # !
1096                 |
1097                         \(              # (
1098                 |
1099                         \)              # )
1100                 |
1101                         \w+\([^\)]*\)   # command(params)
1102                 |
1103                         [^\s()]+        # any other text
1104                 )
1105                 \s*             # ignore whitespace
1106         }igx) {
1107                 my $word=$1;
1108                 if (lc $word eq 'and') {
1109                         $code.=' &&';
1110                 }
1111                 elsif (lc $word eq 'or') {
1112                         $code.=' ||';
1113                 }
1114                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1115                         $code.=' '.$word;
1116                 }
1117                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1118                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1119                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1120                         }
1121                         else {
1122                                 $code.=' 0';
1123                         }
1124                 }
1125                 else {
1126                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1127                 }
1128         }
1129
1130         return $code;
1131 } #}}}
1132
1133 sub pagespec_match ($$;@) { #{{{
1134         my $page=shift;
1135         my $spec=shift;
1136         my @params=@_;
1137
1138         # Backwards compatability with old calling convention.
1139         if (@params == 1) {
1140                 unshift @params, 'location';
1141         }
1142
1143         my $ret=eval pagespec_translate($spec);
1144         return IkiWiki::FailReason->new('syntax error') if $@;
1145         return $ret;
1146 } #}}}
1147
1148 package IkiWiki::FailReason;
1149
1150 use overload ( #{{{
1151         '""'    => sub { ${$_[0]} },
1152         '0+'    => sub { 0 },
1153         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1154         fallback => 1,
1155 ); #}}}
1156
1157 sub new { #{{{
1158         return bless \$_[1], $_[0];
1159 } #}}}
1160
1161 package IkiWiki::SuccessReason;
1162
1163 use overload ( #{{{
1164         '""'    => sub { ${$_[0]} },
1165         '0+'    => sub { 1 },
1166         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1167         fallback => 1,
1168 ); #}}}
1169
1170 sub new { #{{{
1171         return bless \$_[1], $_[0];
1172 }; #}}}
1173
1174 package IkiWiki::PageSpec;
1175
1176 sub match_glob ($$;@) { #{{{
1177         my $page=shift;
1178         my $glob=shift;
1179         my %params=@_;
1180
1181         my $from=exists $params{location} ? $params{location} : '';
1182
1183         # relative matching
1184         if ($glob =~ m!^\./!) {
1185                 $from=~s#/?[^/]+$##;
1186                 $glob=~s#^\./##;
1187                 $glob="$from/$glob" if length $from;
1188         }
1189
1190         # turn glob into safe regexp
1191         $glob=quotemeta($glob);
1192         $glob=~s/\\\*/.*/g;
1193         $glob=~s/\\\?/./g;
1194
1195         if ($page=~/^$glob$/i) {
1196                 return IkiWiki::SuccessReason->new("$glob matches $page");
1197         }
1198         else {
1199                 return IkiWiki::FailReason->new("$glob does not match $page");
1200         }
1201 } #}}}
1202
1203 sub match_link ($$;@) { #{{{
1204         my $page=shift;
1205         my $link=lc(shift);
1206         my %params=@_;
1207
1208         my $from=exists $params{location} ? $params{location} : '';
1209
1210         # relative matching
1211         if ($link =~ m!^\.! && defined $from) {
1212                 $from=~s#/?[^/]+$##;
1213                 $link=~s#^\./##;
1214                 $link="$from/$link" if length $from;
1215         }
1216
1217         my $links = $IkiWiki::links{$page};
1218         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1219         my $bestlink = IkiWiki::bestlink($from, $link);
1220         foreach my $p (@{$links}) {
1221                 if (length $bestlink) {
1222                         return IkiWiki::SuccessReason->new("$page links to $link")
1223                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1224                 }
1225                 else {
1226                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1227                                 if match_glob($p, $link, %params);
1228                 }
1229         }
1230         return IkiWiki::FailReason->new("$page does not link to $link");
1231 } #}}}
1232
1233 sub match_backlink ($$;@) { #{{{
1234         return match_link($_[1], $_[0], @_);
1235 } #}}}
1236
1237 sub match_created_before ($$;@) { #{{{
1238         my $page=shift;
1239         my $testpage=shift;
1240
1241         if (exists $IkiWiki::pagectime{$testpage}) {
1242                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1243                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1244                 }
1245                 else {
1246                         return IkiWiki::FailReason->new("$page not created before $testpage");
1247                 }
1248         }
1249         else {
1250                 return IkiWiki::FailReason->new("$testpage has no ctime");
1251         }
1252 } #}}}
1253
1254 sub match_created_after ($$;@) { #{{{
1255         my $page=shift;
1256         my $testpage=shift;
1257
1258         if (exists $IkiWiki::pagectime{$testpage}) {
1259                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1260                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1261                 }
1262                 else {
1263                         return IkiWiki::FailReason->new("$page not created after $testpage");
1264                 }
1265         }
1266         else {
1267                 return IkiWiki::FailReason->new("$testpage has no ctime");
1268         }
1269 } #}}}
1270
1271 sub match_creation_day ($$;@) { #{{{
1272         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1273                 return IkiWiki::SuccessReason->new('creation_day matched');
1274         }
1275         else {
1276                 return IkiWiki::FailReason->new('creation_day did not match');
1277         }
1278 } #}}}
1279
1280 sub match_creation_month ($$;@) { #{{{
1281         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1282                 return IkiWiki::SuccessReason->new('creation_month matched');
1283         }
1284         else {
1285                 return IkiWiki::FailReason->new('creation_month did not match');
1286         }
1287 } #}}}
1288
1289 sub match_creation_year ($$;@) { #{{{
1290         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1291                 return IkiWiki::SuccessReason->new('creation_year matched');
1292         }
1293         else {
1294                 return IkiWiki::FailReason->new('creation_year did not match');
1295         }
1296 } #}}}
1297
1298 sub match_user ($$;@) { #{{{
1299         shift;
1300         my $user=shift;
1301         my %params=@_;
1302
1303         return IkiWiki::FailReason->new('cannot match user')
1304                 unless exists $params{user};
1305         if ($user eq $params{user}) {
1306                 return IkiWiki::SuccessReason->new("user is $user")
1307         }
1308         else {
1309                 return IkiWiki::FailReason->new("user is not $user");
1310         }
1311 } #}}}
1312
1313 1