IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX ();
  10 use Storable;
  11 use open qw{:utf8 :std};
  12
  13 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  14         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  15         %pagesources %delpagesources %destsources %depends %depends_simple
  16         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  17         %oldtypedlinks %autofiles};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error htmlpage template template_depends
  21         deptype add_depends pagespec_match pagespec_match_list bestlink
  22         htmllink readfile writefile pagetype srcfile pagename
  23         displaytime will_render gettext ngettext urlto targetpage
  24         add_underlay pagetitle titlepage linkpage newpagefile
  25         inject add_link add_autofile
  26         %config %links %pagestate %wikistate %renderedfiles
  27         %pagesources %destsources %typedlinks);
  28 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  29 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  30 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  31
  32 # Page dependency types.
  33 our $DEPEND_CONTENT=1;
  34 our $DEPEND_PRESENCE=2;
  35 our $DEPEND_LINKS=4;
  36
  37 # Optimisation.
  38 use Memoize;
  39 memoize("abs2rel");
  40 memoize("sortspec_translate");
  41 memoize("pagespec_translate");
  42 memoize("template_file");
  43
  44 sub getsetup () {
  45         wikiname => {
  46                 type => "string",
  47                 default => "wiki",
  48                 description => "name of the wiki",
  49                 safe => 1,
  50                 rebuild => 1,
  51         },
  52         adminemail => {
  53                 type => "string",
  54                 default => undef,
  55                 example => 'me@example.com',
  56                 description => "contact email for wiki",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         adminuser => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are wiki admins",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         banned_users => {
  68                 type => "string",
  69                 default => [],
  70                 description => "users who are banned from the wiki",
  71                 safe => 1,
  72                 rebuild => 0,
  73         },
  74         srcdir => {
  75                 type => "string",
  76                 default => undef,
  77                 example => "$ENV{HOME}/wiki",
  78                 description => "where the source of the wiki is located",
  79                 safe => 0, # path
  80                 rebuild => 1,
  81         },
  82         destdir => {
  83                 type => "string",
  84                 default => undef,
  85                 example => "/var/www/wiki",
  86                 description => "where to build the wiki",
  87                 safe => 0, # path
  88                 rebuild => 1,
  89         },
  90         url => {
  91                 type => "string",
  92                 default => '',
  93                 example => "http://example.com/wiki",
  94                 description => "base url to the wiki",
  95                 safe => 1,
  96                 rebuild => 1,
  97         },
  98         cgiurl => {
  99                 type => "string",
 100                 default => '',
 101                 example => "http://example.com/wiki/ikiwiki.cgi",
 102                 description => "url to the ikiwiki.cgi",
 103                 safe => 1,
 104                 rebuild => 1,
 105         },
 106         cgi_wrapper => {
 107                 type => "string",
 108                 default => '',
 109                 example => "/var/www/wiki/ikiwiki.cgi",
 110                 description => "filename of cgi wrapper to generate",
 111                 safe => 0, # file
 112                 rebuild => 0,
 113         },
 114         cgi_wrappermode => {
 115                 type => "string",
 116                 default => '06755',
 117                 description => "mode for cgi_wrapper (can safely be made suid)",
 118                 safe => 0,
 119                 rebuild => 0,
 120         },
 121         rcs => {
 122                 type => "string",
 123                 default => '',
 124                 description => "rcs backend to use",
 125                 safe => 0, # don't allow overriding
 126                 rebuild => 0,
 127         },
 128         default_plugins => {
 129                 type => "internal",
 130                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 131                                 openid signinedit lockedit conditional
 132                                 recentchanges parentlinks editpage}],
 133                 description => "plugins to enable by default",
 134                 safe => 0,
 135                 rebuild => 1,
 136         },
 137         add_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to add to the default configuration",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         disable_plugins => {
 145                 type => "string",
 146                 default => [],
 147                 description => "plugins to disable",
 148                 safe => 1,
 149                 rebuild => 1,
 150         },
 151         templatedir => {
 152                 type => "string",
 153                 default => "$installdir/share/ikiwiki/templates",
 154                 description => "additional directory to search for template files",
 155                 advanced => 1,
 156                 safe => 0, # path
 157                 rebuild => 1,
 158         },
 159         underlaydir => {
 160                 type => "string",
 161                 default => "$installdir/share/ikiwiki/basewiki",
 162                 description => "base wiki source location",
 163                 advanced => 1,
 164                 safe => 0, # path
 165                 rebuild => 0,
 166         },
 167         underlaydirbase => {
 168                 type => "internal",
 169                 default => "$installdir/share/ikiwiki",
 170                 description => "parent directory containing additional underlays",
 171                 safe => 0,
 172                 rebuild => 0,
 173         },
 174         wrappers => {
 175                 type => "internal",
 176                 default => [],
 177                 description => "wrappers to generate",
 178                 safe => 0,
 179                 rebuild => 0,
 180         },
 181         underlaydirs => {
 182                 type => "internal",
 183                 default => [],
 184                 description => "additional underlays to use",
 185                 safe => 0,
 186                 rebuild => 0,
 187         },
 188         verbose => {
 189                 type => "boolean",
 190                 example => 1,
 191                 description => "display verbose messages?",
 192                 safe => 1,
 193                 rebuild => 0,
 194         },
 195         syslog => {
 196                 type => "boolean",
 197                 example => 1,
 198                 description => "log to syslog?",
 199                 safe => 1,
 200                 rebuild => 0,
 201         },
 202         usedirs => {
 203                 type => "boolean",
 204                 default => 1,
 205                 description => "create output files named page/index.html?",
 206                 safe => 0, # changing requires manual transition
 207                 rebuild => 1,
 208         },
 209         prefix_directives => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "use '!'-prefixed preprocessor directives?",
 213                 safe => 0, # changing requires manual transition
 214                 rebuild => 1,
 215         },
 216         indexpages => {
 217                 type => "boolean",
 218                 default => 0,
 219                 description => "use page/index.mdwn source files",
 220                 safe => 1,
 221                 rebuild => 1,
 222         },
 223         discussion => {
 224                 type => "boolean",
 225                 default => 1,
 226                 description => "enable Discussion pages?",
 227                 safe => 1,
 228                 rebuild => 1,
 229         },
 230         discussionpage => {
 231                 type => "string",
 232                 default => gettext("Discussion"),
 233                 description => "name of Discussion pages",
 234                 safe => 1,
 235                 rebuild => 1,
 236         },
 237         html5 => {
 238                 type => "boolean",
 239                 default => 0,
 240                 description => "generate HTML5?",
 241                 advanced => 0,
 242                 safe => 1,
 243                 rebuild => 1,
 244         },
 245         sslcookie => {
 246                 type => "boolean",
 247                 default => 0,
 248                 description => "only send cookies over SSL connections?",
 249                 advanced => 1,
 250                 safe => 1,
 251                 rebuild => 0,
 252         },
 253         default_pageext => {
 254                 type => "string",
 255                 default => "mdwn",
 256                 description => "extension to use for new pages",
 257                 safe => 0, # not sanitized
 258                 rebuild => 0,
 259         },
 260         htmlext => {
 261                 type => "string",
 262                 default => "html",
 263                 description => "extension to use for html files",
 264                 safe => 0, # not sanitized
 265                 rebuild => 1,
 266         },
 267         timeformat => {
 268                 type => "string",
 269                 default => '%c',
 270                 description => "strftime format string to display date",
 271                 advanced => 1,
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         locale => {
 276                 type => "string",
 277                 default => undef,
 278                 example => "en_US.UTF-8",
 279                 description => "UTF-8 locale to use",
 280                 advanced => 1,
 281                 safe => 0,
 282                 rebuild => 1,
 283         },
 284         userdir => {
 285                 type => "string",
 286                 default => "",
 287                 example => "users",
 288                 description => "put user pages below specified page",
 289                 safe => 1,
 290                 rebuild => 1,
 291         },
 292         numbacklinks => {
 293                 type => "integer",
 294                 default => 10,
 295                 description => "how many backlinks to show before hiding excess (0 to show all)",
 296                 safe => 1,
 297                 rebuild => 1,
 298         },
 299         hardlink => {
 300                 type => "boolean",
 301                 default => 0,
 302                 description => "attempt to hardlink source files? (optimisation for large files)",
 303                 advanced => 1,
 304                 safe => 0, # paranoia
 305                 rebuild => 0,
 306         },
 307         umask => {
 308                 type => "string",
 309                 example => "public",
 310                 description => "force ikiwiki to use a particular umask (keywords public, group or private, or a number)",
 311                 advanced => 1,
 312                 safe => 0, # paranoia
 313                 rebuild => 0,
 314         },
 315         wrappergroup => {
 316                 type => "string",
 317                 example => "ikiwiki",
 318                 description => "group for wrappers to run in",
 319                 advanced => 1,
 320                 safe => 0, # paranoia
 321                 rebuild => 0,
 322         },
 323         libdir => {
 324                 type => "string",
 325                 default => "",
 326                 example => "$ENV{HOME}/.ikiwiki/",
 327                 description => "extra library and plugin directory",
 328                 advanced => 1,
 329                 safe => 0, # directory
 330                 rebuild => 0,
 331         },
 332         ENV => {
 333                 type => "string",
 334                 default => {},
 335                 description => "environment variables",
 336                 safe => 0, # paranoia
 337                 rebuild => 0,
 338         },
 339         timezone => {
 340                 type => "string",
 341                 default => "",
 342                 example => "US/Eastern",
 343                 description => "time zone name",
 344                 safe => 1,
 345                 rebuild => 1,
 346         },
 347         include => {
 348                 type => "string",
 349                 default => undef,
 350                 example => '^\.htaccess$',
 351                 description => "regexp of normally excluded files to include",
 352                 advanced => 1,
 353                 safe => 0, # regexp
 354                 rebuild => 1,
 355         },
 356         exclude => {
 357                 type => "string",
 358                 default => undef,
 359                 example => '^(*\.private|Makefile)$',
 360                 description => "regexp of files that should be skipped",
 361                 advanced => 1,
 362                 safe => 0, # regexp
 363                 rebuild => 1,
 364         },
 365         wiki_file_prune_regexps => {
 366                 type => "internal",
 367                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 368                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 369                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 370                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 371                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 372                 description => "regexps of source files to ignore",
 373                 safe => 0,
 374                 rebuild => 1,
 375         },
 376         wiki_file_chars => {
 377                 type => "string",
 378                 description => "specifies the characters that are allowed in source filenames",
 379                 default => "-[:alnum:]+/.:_",
 380                 safe => 0,
 381                 rebuild => 1,
 382         },
 383         wiki_file_regexp => {
 384                 type => "internal",
 385                 description => "regexp of legal source files",
 386                 safe => 0,
 387                 rebuild => 1,
 388         },
 389         web_commit_regexp => {
 390                 type => "internal",
 391                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 392                 description => "regexp to parse web commits from logs",
 393                 safe => 0,
 394                 rebuild => 0,
 395         },
 396         cgi => {
 397                 type => "internal",
 398                 default => 0,
 399                 description => "run as a cgi",
 400                 safe => 0,
 401                 rebuild => 0,
 402         },
 403         cgi_disable_uploads => {
 404                 type => "internal",
 405                 default => 1,
 406                 description => "whether CGI should accept file uploads",
 407                 safe => 0,
 408                 rebuild => 0,
 409         },
 410         post_commit => {
 411                 type => "internal",
 412                 default => 0,
 413                 description => "run as a post-commit hook",
 414                 safe => 0,
 415                 rebuild => 0,
 416         },
 417         rebuild => {
 418                 type => "internal",
 419                 default => 0,
 420                 description => "running in rebuild mode",
 421                 safe => 0,
 422                 rebuild => 0,
 423         },
 424         setup => {
 425                 type => "internal",
 426                 default => undef,
 427                 description => "running in setup mode",
 428                 safe => 0,
 429                 rebuild => 0,
 430         },
 431         clean => {
 432                 type => "internal",
 433                 default => 0,
 434                 description => "running in clean mode",
 435                 safe => 0,
 436                 rebuild => 0,
 437         },
 438         refresh => {
 439                 type => "internal",
 440                 default => 0,
 441                 description => "running in refresh mode",
 442                 safe => 0,
 443                 rebuild => 0,
 444         },
 445         test_receive => {
 446                 type => "internal",
 447                 default => 0,
 448                 description => "running in receive test mode",
 449                 safe => 0,
 450                 rebuild => 0,
 451         },
 452         wrapper_background_command => {
 453                 type => "internal",
 454                 default => '',
 455                 description => "background shell command to run",
 456                 safe => 0,
 457                 rebuild => 0,
 458         },
 459         gettime => {
 460                 type => "internal",
 461                 description => "running in gettime mode",
 462                 safe => 0,
 463                 rebuild => 0,
 464         },
 465         w3mmode => {
 466                 type => "internal",
 467                 default => 0,
 468                 description => "running in w3mmode",
 469                 safe => 0,
 470                 rebuild => 0,
 471         },
 472         wikistatedir => {
 473                 type => "internal",
 474                 default => undef,
 475                 description => "path to the .ikiwiki directory holding ikiwiki state",
 476                 safe => 0,
 477                 rebuild => 0,
 478         },
 479         setupfile => {
 480                 type => "internal",
 481                 default => undef,
 482                 description => "path to setup file",
 483                 safe => 0,
 484                 rebuild => 0,
 485         },
 486         setuptype => {
 487                 type => "internal",
 488                 default => "Yaml",
 489                 description => "perl class to use to dump setup file",
 490                 safe => 0,
 491                 rebuild => 0,
 492         },
 493         allow_symlinks_before_srcdir => {
 494                 type => "boolean",
 495                 default => 0,
 496                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 497                 safe => 0,
 498                 rebuild => 0,
 499         },
 500 }
 501
 502 sub defaultconfig () {
 503         my %s=getsetup();
 504         my @ret;
 505         foreach my $key (keys %s) {
 506                 push @ret, $key, $s{$key}->{default};
 507         }
 508         return @ret;
 509 }
 510
 511 # URL to top of wiki as a path starting with /, valid from any wiki page or
 512 # the CGI; if that's not possible, an absolute URL. Either way, it ends with /
 513 my $local_url;
 514 # URL to CGI script, similar to $local_url
 515 my $local_cgiurl;
 516
 517 sub checkconfig () {
 518         # locale stuff; avoid LC_ALL since it overrides everything
 519         if (defined $ENV{LC_ALL}) {
 520                 $ENV{LANG} = $ENV{LC_ALL};
 521                 delete $ENV{LC_ALL};
 522         }
 523         if (defined $config{locale}) {
 524                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 525                         $ENV{LANG}=$config{locale};
 526                         define_gettext();
 527                 }
 528         }
 529
 530         if (! defined $config{wiki_file_regexp}) {
 531                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 532         }
 533
 534         if (ref $config{ENV} eq 'HASH') {
 535                 foreach my $val (keys %{$config{ENV}}) {
 536                         $ENV{$val}=$config{ENV}{$val};
 537                 }
 538         }
 539         if (defined $config{timezone} && length $config{timezone}) {
 540                 $ENV{TZ}=$config{timezone};
 541         }
 542         else {
 543                 $config{timezone}=$ENV{TZ};
 544         }
 545
 546         if ($config{w3mmode}) {
 547                 eval q{use Cwd q{abs_path}};
 548                 error($@) if $@;
 549                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 550                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 551                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 552                         unless $config{cgiurl} =~ m!file:///!;
 553                 $config{url}="file://".$config{destdir};
 554         }
 555
 556         if ($config{cgi} && ! length $config{url}) {
 557                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 558         }
 559
 560         if (defined $config{url} && length $config{url}) {
 561                 eval q{use URI};
 562                 my $baseurl = URI->new($config{url});
 563
 564                 $local_url = $baseurl->path . "/";
 565                 $local_cgiurl = undef;
 566
 567                 if (length $config{cgiurl}) {
 568                         my $cgiurl = URI->new($config{cgiurl});
 569
 570                         $local_cgiurl = $cgiurl->path;
 571
 572                         if ($cgiurl->scheme ne $baseurl->scheme or
 573                                 $cgiurl->authority ne $baseurl->authority) {
 574                                 # too far apart, fall back to absolute URLs
 575                                 $local_url = "$config{url}/";
 576                                 $local_cgiurl = $config{cgiurl};
 577                         }
 578                 }
 579
 580                 $local_url =~ s{//$}{/};
 581         }
 582         else {
 583                 $local_cgiurl = $config{cgiurl};
 584         }
 585
 586         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 587                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 588
 589         if (defined $config{umask}) {
 590                 my $u = possibly_foolish_untaint($config{umask});
 591
 592                 if ($u =~ m/^\d+$/) {
 593                         umask($u);
 594                 }
 595                 elsif ($u eq 'private') {
 596                         umask(077);
 597                 }
 598                 elsif ($u eq 'group') {
 599                         umask(027);
 600                 }
 601                 elsif ($u eq 'public') {
 602                         umask(022);
 603                 }
 604                 else {
 605                         error(sprintf(gettext("unsupported umask setting %s"), $u));
 606                 }
 607         }
 608
 609         run_hooks(checkconfig => sub { shift->() });
 610
 611         return 1;
 612 }
 613
 614 sub listplugins () {
 615         my %ret;
 616
 617         foreach my $dir (@INC, $config{libdir}) {
 618                 next unless defined $dir && length $dir;
 619                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 620                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 621                         $ret{$plugin}=1;
 622                 }
 623         }
 624         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 625                 next unless defined $dir && length $dir;
 626                 foreach my $file (glob("$dir/plugins/*")) {
 627                         $ret{basename($file)}=1 if -x $file;
 628                 }
 629         }
 630
 631         return keys %ret;
 632 }
 633
 634 sub loadplugins () {
 635         if (defined $config{libdir} && length $config{libdir}) {
 636                 unshift @INC, possibly_foolish_untaint($config{libdir});
 637         }
 638
 639         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 640                 loadplugin($plugin);
 641         }
 642
 643         if ($config{rcs}) {
 644                 if (exists $hooks{rcs}) {
 645                         error(gettext("cannot use multiple rcs plugins"));
 646                 }
 647                 loadplugin($config{rcs});
 648         }
 649         if (! exists $hooks{rcs}) {
 650                 loadplugin("norcs");
 651         }
 652
 653         run_hooks(getopt => sub { shift->() });
 654         if (grep /^-/, @ARGV) {
 655                 print STDERR "Unknown option (or missing parameter): $_\n"
 656                         foreach grep /^-/, @ARGV;
 657                 usage();
 658         }
 659
 660         return 1;
 661 }
 662
 663 sub loadplugin ($;$) {
 664         my $plugin=shift;
 665         my $force=shift;
 666
 667         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 668
 669         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 670                          "$installdir/lib/ikiwiki") {
 671                 if (defined $dir && -x "$dir/plugins/$plugin") {
 672                         eval { require IkiWiki::Plugin::external };
 673                         if ($@) {
 674                                 my $reason=$@;
 675                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 676                         }
 677                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 678                         $loaded_plugins{$plugin}=1;
 679                         return 1;
 680                 }
 681         }
 682
 683         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 684         eval qq{use $mod};
 685         if ($@) {
 686                 error("Failed to load plugin $mod: $@");
 687         }
 688         $loaded_plugins{$plugin}=1;
 689         return 1;
 690 }
 691
 692 sub error ($;$) {
 693         my $message=shift;
 694         my $cleaner=shift;
 695         log_message('err' => $message) if $config{syslog};
 696         if (defined $cleaner) {
 697                 $cleaner->();
 698         }
 699         die $message."\n";
 700 }
 701
 702 sub debug ($) {
 703         return unless $config{verbose};
 704         return log_message(debug => @_);
 705 }
 706
 707 my $log_open=0;
 708 sub log_message ($$) {
 709         my $type=shift;
 710
 711         if ($config{syslog}) {
 712                 require Sys::Syslog;
 713                 if (! $log_open) {
 714                         Sys::Syslog::setlogsock('unix');
 715                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 716                         $log_open=1;
 717                 }
 718                 return eval {
 719                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 720                 };
 721         }
 722         elsif (! $config{cgi}) {
 723                 return print "@_\n";
 724         }
 725         else {
 726                 return print STDERR "@_\n";
 727         }
 728 }
 729
 730 sub possibly_foolish_untaint ($) {
 731         my $tainted=shift;
 732         my ($untainted)=$tainted=~/(.*)/s;
 733         return $untainted;
 734 }
 735
 736 sub basename ($) {
 737         my $file=shift;
 738
 739         $file=~s!.*/+!!;
 740         return $file;
 741 }
 742
 743 sub dirname ($) {
 744         my $file=shift;
 745
 746         $file=~s!/*[^/]+$!!;
 747         return $file;
 748 }
 749
 750 sub isinternal ($) {
 751         my $page=shift;
 752         return exists $pagesources{$page} &&
 753                 $pagesources{$page} =~ /\._([^.]+)$/;
 754 }
 755
 756 sub pagetype ($) {
 757         my $file=shift;
 758
 759         if ($file =~ /\.([^.]+)$/) {
 760                 return $1 if exists $hooks{htmlize}{$1};
 761         }
 762         my $base=basename($file);
 763         if (exists $hooks{htmlize}{$base} &&
 764             $hooks{htmlize}{$base}{noextension}) {
 765                 return $base;
 766         }
 767         return;
 768 }
 769
 770 my %pagename_cache;
 771
 772 sub pagename ($) {
 773         my $file=shift;
 774
 775         if (exists $pagename_cache{$file}) {
 776                 return $pagename_cache{$file};
 777         }
 778
 779         my $type=pagetype($file);
 780         my $page=$file;
 781         $page=~s/\Q.$type\E*$//
 782                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 783                         && !$hooks{htmlize}{$type}{noextension};
 784         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 785                 $page=$1;
 786         }
 787
 788         $pagename_cache{$file} = $page;
 789         return $page;
 790 }
 791
 792 sub newpagefile ($$) {
 793         my $page=shift;
 794         my $type=shift;
 795
 796         if (! $config{indexpages} || $page eq 'index') {
 797                 return $page.".".$type;
 798         }
 799         else {
 800                 return $page."/index.".$type;
 801         }
 802 }
 803
 804 sub targetpage ($$;$) {
 805         my $page=shift;
 806         my $ext=shift;
 807         my $filename=shift;
 808
 809         if (defined $filename) {
 810                 return $page."/".$filename.".".$ext;
 811         }
 812         elsif (! $config{usedirs} || $page eq 'index') {
 813                 return $page.".".$ext;
 814         }
 815         else {
 816                 return $page."/index.".$ext;
 817         }
 818 }
 819
 820 sub htmlpage ($) {
 821         my $page=shift;
 822
 823         return targetpage($page, $config{htmlext});
 824 }
 825
 826 sub srcfile_stat {
 827         my $file=shift;
 828         my $nothrow=shift;
 829
 830         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 831         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 832                 return "$dir/$file", stat(_) if -e "$dir/$file";
 833         }
 834         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 835         return;
 836 }
 837
 838 sub srcfile ($;$) {
 839         return (srcfile_stat(@_))[0];
 840 }
 841
 842 sub add_literal_underlay ($) {
 843         my $dir=shift;
 844
 845         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 846                 unshift @{$config{underlaydirs}}, $dir;
 847         }
 848 }
 849
 850 sub add_underlay ($) {
 851         my $dir = shift;
 852
 853         if ($dir !~ /^\//) {
 854                 $dir="$config{underlaydirbase}/$dir";
 855         }
 856
 857         add_literal_underlay($dir);
 858         # why does it return 1? we just don't know
 859         return 1;
 860 }
 861
 862 sub readfile ($;$$) {
 863         my $file=shift;
 864         my $binary=shift;
 865         my $wantfd=shift;
 866
 867         if (-l $file) {
 868                 error("cannot read a symlink ($file)");
 869         }
 870
 871         local $/=undef;
 872         open (my $in, "<", $file) || error("failed to read $file: $!");
 873         binmode($in) if ($binary);
 874         return \*$in if $wantfd;
 875         my $ret=<$in>;
 876         # check for invalid utf-8, and toss it back to avoid crashes
 877         if (! utf8::valid($ret)) {
 878                 $ret=encode_utf8($ret);
 879         }
 880         close $in || error("failed to read $file: $!");
 881         return $ret;
 882 }
 883
 884 sub prep_writefile ($$) {
 885         my $file=shift;
 886         my $destdir=shift;
 887
 888         my $test=$file;
 889         while (length $test) {
 890                 if (-l "$destdir/$test") {
 891                         error("cannot write to a symlink ($test)");
 892                 }
 893                 if (-f _ && $test ne $file) {
 894                         # Remove conflicting file.
 895                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 896                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 897                                         if ($f eq $test) {
 898                                                 unlink("$destdir/$test");
 899                                                 last;
 900                                         }
 901                                 }
 902                         }
 903                 }
 904                 $test=dirname($test);
 905         }
 906
 907         my $dir=dirname("$destdir/$file");
 908         if (! -d $dir) {
 909                 my $d="";
 910                 foreach my $s (split(m!/+!, $dir)) {
 911                         $d.="$s/";
 912                         if (! -d $d) {
 913                                 mkdir($d) || error("failed to create directory $d: $!");
 914                         }
 915                 }
 916         }
 917
 918         return 1;
 919 }
 920
 921 sub writefile ($$$;$$) {
 922         my $file=shift; # can include subdirs
 923         my $destdir=shift; # directory to put file in
 924         my $content=shift;
 925         my $binary=shift;
 926         my $writer=shift;
 927
 928         prep_writefile($file, $destdir);
 929
 930         my $newfile="$destdir/$file.ikiwiki-new";
 931         if (-l $newfile) {
 932                 error("cannot write to a symlink ($newfile)");
 933         }
 934
 935         my $cleanup = sub { unlink($newfile) };
 936         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 937         binmode($out) if ($binary);
 938         if ($writer) {
 939                 $writer->(\*$out, $cleanup);
 940         }
 941         else {
 942                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 943         }
 944         close $out || error("failed saving $newfile: $!", $cleanup);
 945         rename($newfile, "$destdir/$file") ||
 946                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 947
 948         return 1;
 949 }
 950
 951 my %cleared;
 952 sub will_render ($$;$) {
 953         my $page=shift;
 954         my $dest=shift;
 955         my $clear=shift;
 956
 957         # Important security check for independently created files.
 958         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 959             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 960                 my $from_other_page=0;
 961                 # Expensive, but rarely runs.
 962                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 963                         if (grep {
 964                                 $_ eq $dest ||
 965                                 dirname($_) eq $dest
 966                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 967                                 $from_other_page=1;
 968                                 last;
 969                         }
 970                 }
 971
 972                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
 973                         unless $from_other_page;
 974         }
 975
 976         # If $dest exists as a directory, remove conflicting files in it
 977         # rendered from other pages.
 978         if (-d _) {
 979                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 980                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 981                                 if (dirname($f) eq $dest) {
 982                                         unlink("$config{destdir}/$f");
 983                                         rmdir(dirname("$config{destdir}/$f"));
 984                                 }
 985                         }
 986                 }
 987         }
 988
 989         if (! $clear || $cleared{$page}) {
 990                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 991         }
 992         else {
 993                 foreach my $old (@{$renderedfiles{$page}}) {
 994                         delete $destsources{$old};
 995                 }
 996                 $renderedfiles{$page}=[$dest];
 997                 $cleared{$page}=1;
 998         }
 999         $destsources{$dest}=$page;
1000
1001         return 1;
1002 }
1003
1004 sub bestlink ($$) {
1005         my $page=shift;
1006         my $link=shift;
1007
1008         my $cwd=$page;
1009         if ($link=~s/^\/+//) {
1010                 # absolute links
1011                 $cwd="";
1012         }
1013         $link=~s/\/$//;
1014
1015         do {
1016                 my $l=$cwd;
1017                 $l.="/" if length $l;
1018                 $l.=$link;
1019
1020                 if (exists $pagesources{$l}) {
1021                         return $l;
1022                 }
1023                 elsif (exists $pagecase{lc $l}) {
1024                         return $pagecase{lc $l};
1025                 }
1026         } while $cwd=~s{/?[^/]+$}{};
1027
1028         if (length $config{userdir}) {
1029                 my $l = "$config{userdir}/".lc($link);
1030                 if (exists $pagesources{$l}) {
1031                         return $l;
1032                 }
1033                 elsif (exists $pagecase{lc $l}) {
1034                         return $pagecase{lc $l};
1035                 }
1036         }
1037
1038         #print STDERR "warning: page $page, broken link: $link\n";
1039         return "";
1040 }
1041
1042 sub isinlinableimage ($) {
1043         my $file=shift;
1044
1045         return $file =~ /\.(png|gif|jpg|jpeg|svg)$/i;
1046 }
1047
1048 sub pagetitle ($;$) {
1049         my $page=shift;
1050         my $unescaped=shift;
1051
1052         if ($unescaped) {
1053                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
1054         }
1055         else {
1056                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
1057         }
1058
1059         return $page;
1060 }
1061
1062 sub titlepage ($) {
1063         my $title=shift;
1064         # support use w/o %config set
1065         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1066         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1067         return $title;
1068 }
1069
1070 sub linkpage ($) {
1071         my $link=shift;
1072         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1073         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1074         return $link;
1075 }
1076
1077 sub cgiurl (@) {
1078         my %params=@_;
1079
1080         my $cgiurl=$local_cgiurl;
1081
1082         if (exists $params{cgiurl}) {
1083                 $cgiurl=$params{cgiurl};
1084                 delete $params{cgiurl};
1085         }
1086
1087         unless (%params) {
1088                 return $cgiurl;
1089         }
1090
1091         return $cgiurl."?".
1092                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
1093 }
1094
1095 sub baseurl (;$) {
1096         my $page=shift;
1097
1098         return $local_url if ! defined $page;
1099
1100         $page=htmlpage($page);
1101         $page=~s/[^\/]+$//;
1102         $page=~s/[^\/]+\//..\//g;
1103         return $page;
1104 }
1105
1106 sub urlabs ($$) {
1107         my $url=shift;
1108         my $urlbase=shift;
1109
1110         return $url unless defined $urlbase && length $urlbase;
1111
1112         eval q{use URI};
1113         URI->new_abs($url, $urlbase)->as_string;
1114 }
1115
1116 sub abs2rel ($$) {
1117         # Work around very innefficient behavior in File::Spec if abs2rel
1118         # is passed two relative paths. It's much faster if paths are
1119         # absolute! (Debian bug #376658; fixed in debian unstable now)
1120         my $path="/".shift;
1121         my $base="/".shift;
1122
1123         require File::Spec;
1124         my $ret=File::Spec->abs2rel($path, $base);
1125         $ret=~s/^// if defined $ret;
1126         return $ret;
1127 }
1128
1129 sub displaytime ($;$$) {
1130         # Plugins can override this function to mark up the time to
1131         # display.
1132         my $time=formattime($_[0], $_[1]);
1133         if ($config{html5}) {
1134                 return '<time datetime="'.date_3339($_[0]).'"'.
1135                         ($_[2] ? ' pubdate="pubdate"' : '').
1136                         '>'.$time.'</time>';
1137         }
1138         else {
1139                 return '<span class="date">'.$time.'</span>';
1140         }
1141 }
1142
1143 sub formattime ($;$) {
1144         # Plugins can override this function to format the time.
1145         my $time=shift;
1146         my $format=shift;
1147         if (! defined $format) {
1148                 $format=$config{timeformat};
1149         }
1150
1151         # strftime doesn't know about encodings, so make sure
1152         # its output is properly treated as utf8
1153         return decode_utf8(POSIX::strftime($format, localtime($time)));
1154 }
1155
1156 sub date_3339 ($) {
1157         my $time=shift;
1158
1159         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1160         POSIX::setlocale(&POSIX::LC_TIME, "C");
1161         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1162         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1163         return $ret;
1164 }
1165
1166 sub beautify_urlpath ($) {
1167         my $url=shift;
1168
1169         # Ensure url is not an empty link, and if necessary,
1170         # add ./ to avoid colon confusion.
1171         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1172                 $url="./$url";
1173         }
1174
1175         if ($config{usedirs}) {
1176                 $url =~ s!/index.$config{htmlext}$!/!;
1177         }
1178
1179         return $url;
1180 }
1181
1182 sub urlto ($;$$) {
1183         my $to=shift;
1184         my $from=shift;
1185         my $absolute=shift;
1186
1187         if (! length $to) {
1188                 $to = 'index';
1189         }
1190
1191         if (! $destsources{$to}) {
1192                 $to=htmlpage($to);
1193         }
1194
1195         if ($absolute) {
1196                 return $config{url}.beautify_urlpath("/".$to);
1197         }
1198
1199         if (! defined $from) {
1200                 my $u = $local_url || '';
1201                 $u =~ s{/$}{};
1202                 return $u.beautify_urlpath("/".$to);
1203         }
1204
1205         my $link = abs2rel($to, dirname(htmlpage($from)));
1206
1207         return beautify_urlpath($link);
1208 }
1209
1210 sub isselflink ($$) {
1211         # Plugins can override this function to support special types
1212         # of selflinks.
1213         my $page=shift;
1214         my $link=shift;
1215
1216         return $page eq $link;
1217 }
1218
1219 sub htmllink ($$$;@) {
1220         my $lpage=shift; # the page doing the linking
1221         my $page=shift; # the page that will contain the link (different for inline)
1222         my $link=shift;
1223         my %opts=@_;
1224
1225         $link=~s/\/$//;
1226
1227         my $bestlink;
1228         if (! $opts{forcesubpage}) {
1229                 $bestlink=bestlink($lpage, $link);
1230         }
1231         else {
1232                 $bestlink="$lpage/".lc($link);
1233         }
1234
1235         my $linktext;
1236         if (defined $opts{linktext}) {
1237                 $linktext=$opts{linktext};
1238         }
1239         else {
1240                 $linktext=pagetitle(basename($link));
1241         }
1242
1243         return "<span class=\"selflink\">$linktext</span>"
1244                 if length $bestlink && isselflink($page, $bestlink) &&
1245                    ! defined $opts{anchor};
1246
1247         if (! $destsources{$bestlink}) {
1248                 $bestlink=htmlpage($bestlink);
1249
1250                 if (! $destsources{$bestlink}) {
1251                         my $cgilink = "";
1252                         if (length $config{cgiurl}) {
1253                                 $cgilink = "<a href=\"".
1254                                         cgiurl(
1255                                                 do => "create",
1256                                                 page => $link,
1257                                                 from => $lpage
1258                                         )."\" rel=\"nofollow\">?</a>";
1259                         }
1260                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1261                 }
1262         }
1263
1264         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1265         $bestlink=beautify_urlpath($bestlink);
1266
1267         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1268                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1269         }
1270
1271         if (defined $opts{anchor}) {
1272                 $bestlink.="#".$opts{anchor};
1273         }
1274
1275         my @attrs;
1276         foreach my $attr (qw{rel class title}) {
1277                 if (defined $opts{$attr}) {
1278                         push @attrs, " $attr=\"$opts{$attr}\"";
1279                 }
1280         }
1281
1282         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1283 }
1284
1285 sub userpage ($) {
1286         my $user=shift;
1287         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1288 }
1289
1290 sub openiduser ($) {
1291         my $user=shift;
1292
1293         if (defined $user && $user =~ m!^https?://! &&
1294             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1295                 my $display;
1296
1297                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1298                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1299                 }
1300                 else {
1301                         # backcompat with old version
1302                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1303                         $display=$oid->display;
1304                 }
1305
1306                 # Convert "user.somehost.com" to "user [somehost.com]"
1307                 # (also "user.somehost.co.uk")
1308                 if ($display !~ /\[/) {
1309                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1310                 }
1311                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1312                 # (also "https://somehost.com/user/")
1313                 if ($display !~ /\[/) {
1314                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1315                 }
1316                 $display=~s!^https?://!!; # make sure this is removed
1317                 eval q{use CGI 'escapeHTML'};
1318                 error($@) if $@;
1319                 return escapeHTML($display);
1320         }
1321         return;
1322 }
1323
1324 sub htmlize ($$$$) {
1325         my $page=shift;
1326         my $destpage=shift;
1327         my $type=shift;
1328         my $content=shift;
1329
1330         my $oneline = $content !~ /\n/;
1331
1332         if (exists $hooks{htmlize}{$type}) {
1333                 $content=$hooks{htmlize}{$type}{call}->(
1334                         page => $page,
1335                         content => $content,
1336                 );
1337         }
1338         else {
1339                 error("htmlization of $type not supported");
1340         }
1341
1342         run_hooks(sanitize => sub {
1343                 $content=shift->(
1344                         page => $page,
1345                         destpage => $destpage,
1346                         content => $content,
1347                 );
1348         });
1349
1350         if ($oneline) {
1351                 # hack to get rid of enclosing junk added by markdown
1352                 # and other htmlizers/sanitizers
1353                 $content=~s/^<p>//i;
1354                 $content=~s/<\/p>\n*$//i;
1355         }
1356
1357         return $content;
1358 }
1359
1360 sub linkify ($$$) {
1361         my $page=shift;
1362         my $destpage=shift;
1363         my $content=shift;
1364
1365         run_hooks(linkify => sub {
1366                 $content=shift->(
1367                         page => $page,
1368                         destpage => $destpage,
1369                         content => $content,
1370                 );
1371         });
1372
1373         return $content;
1374 }
1375
1376 our %preprocessing;
1377 our $preprocess_preview=0;
1378 sub preprocess ($$$;$$) {
1379         my $page=shift; # the page the data comes from
1380         my $destpage=shift; # the page the data will appear in (different for inline)
1381         my $content=shift;
1382         my $scan=shift;
1383         my $preview=shift;
1384
1385         # Using local because it needs to be set within any nested calls
1386         # of this function.
1387         local $preprocess_preview=$preview if defined $preview;
1388
1389         my $handle=sub {
1390                 my $escape=shift;
1391                 my $prefix=shift;
1392                 my $command=shift;
1393                 my $params=shift;
1394                 $params="" if ! defined $params;
1395
1396                 if (length $escape) {
1397                         return "[[$prefix$command $params]]";
1398                 }
1399                 elsif (exists $hooks{preprocess}{$command}) {
1400                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1401                         # Note: preserve order of params, some plugins may
1402                         # consider it significant.
1403                         my @params;
1404                         while ($params =~ m{
1405                                 (?:([-\w]+)=)?          # 1: named parameter key?
1406                                 (?:
1407                                         """(.*?)"""     # 2: triple-quoted value
1408                                 |
1409                                         "([^"]*?)"      # 3: single-quoted value
1410                                 |
1411                                         '''(.*?)'''     # 4: triple-single-quote
1412                                 |
1413                                         <<([a-zA-Z]+)\n # 5: heredoc start
1414                                         (.*?)\n\5       # 6: heredoc value
1415                                 |
1416                                         (\S+)           # 7: unquoted value
1417                                 )
1418                                 (?:\s+|$)               # delimiter to next param
1419                         }msgx) {
1420                                 my $key=$1;
1421                                 my $val;
1422                                 if (defined $2) {
1423                                         $val=$2;
1424                                         $val=~s/\r\n/\n/mg;
1425                                         $val=~s/^\n+//g;
1426                                         $val=~s/\n+$//g;
1427                                 }
1428                                 elsif (defined $3) {
1429                                         $val=$3;
1430                                 }
1431                                 elsif (defined $4) {
1432                                         $val=$4;
1433                                 }
1434                                 elsif (defined $7) {
1435                                         $val=$7;
1436                                 }
1437                                 elsif (defined $6) {
1438                                         $val=$6;
1439                                 }
1440
1441                                 if (defined $key) {
1442                                         push @params, $key, $val;
1443                                 }
1444                                 else {
1445                                         push @params, $val, '';
1446                                 }
1447                         }
1448                         if ($preprocessing{$page}++ > 3) {
1449                                 # Avoid loops of preprocessed pages preprocessing
1450                                 # other pages that preprocess them, etc.
1451                                 return "[[!$command <span class=\"error\">".
1452                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1453                                                 $page, $preprocessing{$page}).
1454                                         "</span>]]";
1455                         }
1456                         my $ret;
1457                         if (! $scan) {
1458                                 $ret=eval {
1459                                         $hooks{preprocess}{$command}{call}->(
1460                                                 @params,
1461                                                 page => $page,
1462                                                 destpage => $destpage,
1463                                                 preview => $preprocess_preview,
1464                                         );
1465                                 };
1466                                 if ($@) {
1467                                         my $error=$@;
1468                                         chomp $error;
1469                                         $ret="[[!$command <span class=\"error\">".
1470                                                 gettext("Error").": $error"."</span>]]";
1471                                 }
1472                         }
1473                         else {
1474                                 # use void context during scan pass
1475                                 eval {
1476                                         $hooks{preprocess}{$command}{call}->(
1477                                                 @params,
1478                                                 page => $page,
1479                                                 destpage => $destpage,
1480                                                 preview => $preprocess_preview,
1481                                         );
1482                                 };
1483                                 $ret="";
1484                         }
1485                         $preprocessing{$page}--;
1486                         return $ret;
1487                 }
1488                 else {
1489                         return "[[$prefix$command $params]]";
1490                 }
1491         };
1492
1493         my $regex;
1494         if ($config{prefix_directives}) {
1495                 $regex = qr{
1496                         (\\?)           # 1: escape?
1497                         \[\[(!)         # directive open; 2: prefix
1498                         ([-\w]+)        # 3: command
1499                         (               # 4: the parameters..
1500                                 \s+     # Must have space if parameters present
1501                                 (?:
1502                                         (?:[-\w]+=)?            # named parameter key?
1503                                         (?:
1504                                                 """.*?"""       # triple-quoted value
1505                                                 |
1506                                                 "[^"]*?"        # single-quoted value
1507                                                 |
1508                                                 '''.*?'''       # triple-single-quote
1509                                                 |
1510                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1511                                                 (?:.*?)\n\5     # heredoc value
1512                                                 |
1513                                                 [^"\s\]]+       # unquoted value
1514                                         )
1515                                         \s*                     # whitespace or end
1516                                                                 # of directive
1517                                 )
1518                         *)?             # 0 or more parameters
1519                         \]\]            # directive closed
1520                 }sx;
1521         }
1522         else {
1523                 $regex = qr{
1524                         (\\?)           # 1: escape?
1525                         \[\[(!?)        # directive open; 2: optional prefix
1526                         ([-\w]+)        # 3: command
1527                         \s+
1528                         (               # 4: the parameters..
1529                                 (?:
1530                                         (?:[-\w]+=)?            # named parameter key?
1531                                         (?:
1532                                                 """.*?"""       # triple-quoted value
1533                                                 |
1534                                                 "[^"]*?"        # single-quoted value
1535                                                 |
1536                                                 '''.*?'''       # triple-single-quote
1537                                                 |
1538                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1539                                                 (?:.*?)\n\5     # heredoc value
1540                                                 |
1541                                                 [^"\s\]]+       # unquoted value
1542                                         )
1543                                         \s*                     # whitespace or end
1544                                                                 # of directive
1545                                 )
1546                         *)              # 0 or more parameters
1547                         \]\]            # directive closed
1548                 }sx;
1549         }
1550
1551         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1552         return $content;
1553 }
1554
1555 sub filter ($$$) {
1556         my $page=shift;
1557         my $destpage=shift;
1558         my $content=shift;
1559
1560         run_hooks(filter => sub {
1561                 $content=shift->(page => $page, destpage => $destpage,
1562                         content => $content);
1563         });
1564
1565         return $content;
1566 }
1567
1568 sub check_canedit ($$$;$) {
1569         my $page=shift;
1570         my $q=shift;
1571         my $session=shift;
1572         my $nonfatal=shift;
1573
1574         my $canedit;
1575         run_hooks(canedit => sub {
1576                 return if defined $canedit;
1577                 my $ret=shift->($page, $q, $session);
1578                 if (defined $ret) {
1579                         if ($ret eq "") {
1580                                 $canedit=1;
1581                         }
1582                         elsif (ref $ret eq 'CODE') {
1583                                 $ret->() unless $nonfatal;
1584                                 $canedit=0;
1585                         }
1586                         elsif (defined $ret) {
1587                                 error($ret) unless $nonfatal;
1588                                 $canedit=0;
1589                         }
1590                 }
1591         });
1592         return defined $canedit ? $canedit : 1;
1593 }
1594
1595 sub check_content (@) {
1596         my %params=@_;
1597
1598         return 1 if ! exists $hooks{checkcontent}; # optimisation
1599
1600         if (exists $pagesources{$params{page}}) {
1601                 my @diff;
1602                 my %old=map { $_ => 1 }
1603                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1604                 foreach my $line (split("\n", $params{content})) {
1605                         push @diff, $line if ! exists $old{$line};
1606                 }
1607                 $params{diff}=join("\n", @diff);
1608         }
1609
1610         my $ok;
1611         run_hooks(checkcontent => sub {
1612                 return if defined $ok;
1613                 my $ret=shift->(%params);
1614                 if (defined $ret) {
1615                         if ($ret eq "") {
1616                                 $ok=1;
1617                         }
1618                         elsif (ref $ret eq 'CODE') {
1619                                 $ret->() unless $params{nonfatal};
1620                                 $ok=0;
1621                         }
1622                         elsif (defined $ret) {
1623                                 error($ret) unless $params{nonfatal};
1624                                 $ok=0;
1625                         }
1626                 }
1627
1628         });
1629         return defined $ok ? $ok : 1;
1630 }
1631
1632 sub check_canchange (@) {
1633         my %params = @_;
1634         my $cgi = $params{cgi};
1635         my $session = $params{session};
1636         my @changes = @{$params{changes}};
1637
1638         my %newfiles;
1639         foreach my $change (@changes) {
1640                 # This untaint is safe because we check file_pruned and
1641                 # wiki_file_regexp.
1642                 my ($file)=$change->{file}=~/$config{wiki_file_regexp}/;
1643                 $file=possibly_foolish_untaint($file);
1644                 if (! defined $file || ! length $file ||
1645                     file_pruned($file)) {
1646                         error(gettext("bad file name %s"), $file);
1647                 }
1648
1649                 my $type=pagetype($file);
1650                 my $page=pagename($file) if defined $type;
1651
1652                 if ($change->{action} eq 'add') {
1653                         $newfiles{$file}=1;
1654                 }
1655
1656                 if ($change->{action} eq 'change' ||
1657                     $change->{action} eq 'add') {
1658                         if (defined $page) {
1659                                 check_canedit($page, $cgi, $session);
1660                                 next;
1661                         }
1662                         else {
1663                                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
1664                                         IkiWiki::Plugin::attachment::check_canattach($session, $file, $change->{path});
1665                                         check_canedit($file, $cgi, $session);
1666                                         next;
1667                                 }
1668                         }
1669                 }
1670                 elsif ($change->{action} eq 'remove') {
1671                         # check_canremove tests to see if the file is present
1672                         # on disk. This will fail when a single commit adds a
1673                         # file and then removes it again. Avoid the problem
1674                         # by not testing the removal in such pairs of changes.
1675                         # (The add is still tested, just to make sure that
1676                         # no data is added to the repo that a web edit
1677                         # could not add.)
1678                         next if $newfiles{$file};
1679
1680                         if (IkiWiki::Plugin::remove->can("check_canremove")) {
1681                                 IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
1682                                 check_canedit(defined $page ? $page : $file, $cgi, $session);
1683                                 next;
1684                         }
1685                 }
1686                 else {
1687                         error "unknown action ".$change->{action};
1688                 }
1689
1690                 error sprintf(gettext("you are not allowed to change %s"), $file);
1691         }
1692 }
1693
1694
1695 my $wikilock;
1696
1697 sub lockwiki () {
1698         # Take an exclusive lock on the wiki to prevent multiple concurrent
1699         # run issues. The lock will be dropped on program exit.
1700         if (! -d $config{wikistatedir}) {
1701                 mkdir($config{wikistatedir});
1702         }
1703         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1704                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1705         if (! flock($wikilock, 2)) { # LOCK_EX
1706                 error("failed to get lock");
1707         }
1708         return 1;
1709 }
1710
1711 sub unlockwiki () {
1712         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1713         return close($wikilock) if $wikilock;
1714         return;
1715 }
1716
1717 my $commitlock;
1718
1719 sub commit_hook_enabled () {
1720         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1721                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1722         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1723                 close($commitlock) || error("failed closing commitlock: $!");
1724                 return 0;
1725         }
1726         close($commitlock) || error("failed closing commitlock: $!");
1727         return 1;
1728 }
1729
1730 sub disable_commit_hook () {
1731         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1732                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1733         if (! flock($commitlock, 2)) { # LOCK_EX
1734                 error("failed to get commit lock");
1735         }
1736         return 1;
1737 }
1738
1739 sub enable_commit_hook () {
1740         return close($commitlock) if $commitlock;
1741         return;
1742 }
1743
1744 sub loadindex () {
1745         %oldrenderedfiles=%pagectime=();
1746         if (! $config{rebuild}) {
1747                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1748                 %destsources=%renderedfiles=%pagecase=%pagestate=
1749                 %depends_simple=%typedlinks=%oldtypedlinks=();
1750         }
1751         my $in;
1752         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1753                 if (-e "$config{wikistatedir}/index") {
1754                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1755                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1756                 }
1757                 else {
1758                         $config{gettime}=1; # first build
1759                         return;
1760                 }
1761         }
1762
1763         my $index=Storable::fd_retrieve($in);
1764         if (! defined $index) {
1765                 return 0;
1766         }
1767
1768         my $pages;
1769         if (exists $index->{version} && ! ref $index->{version}) {
1770                 $pages=$index->{page};
1771                 %wikistate=%{$index->{state}};
1772                 # Handle plugins that got disabled by loading a new setup.
1773                 if (exists $config{setupfile}) {
1774                         require IkiWiki::Setup;
1775                         IkiWiki::Setup::disabled_plugins(
1776                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1777                 }
1778         }
1779         else {
1780                 $pages=$index;
1781                 %wikistate=();
1782         }
1783
1784         foreach my $src (keys %$pages) {
1785                 my $d=$pages->{$src};
1786                 my $page=pagename($src);
1787                 $pagectime{$page}=$d->{ctime};
1788                 $pagesources{$page}=$src;
1789                 if (! $config{rebuild}) {
1790                         $pagemtime{$page}=$d->{mtime};
1791                         $renderedfiles{$page}=$d->{dest};
1792                         if (exists $d->{links} && ref $d->{links}) {
1793                                 $links{$page}=$d->{links};
1794                                 $oldlinks{$page}=[@{$d->{links}}];
1795                         }
1796                         if (ref $d->{depends_simple} eq 'ARRAY') {
1797                                 # old format
1798                                 $depends_simple{$page}={
1799                                         map { $_ => 1 } @{$d->{depends_simple}}
1800                                 };
1801                         }
1802                         elsif (exists $d->{depends_simple}) {
1803                                 $depends_simple{$page}=$d->{depends_simple};
1804                         }
1805                         if (exists $d->{dependslist}) {
1806                                 # old format
1807                                 $depends{$page}={
1808                                         map { $_ => $DEPEND_CONTENT }
1809                                                 @{$d->{dependslist}}
1810                                 };
1811                         }
1812                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1813                                 # old format
1814                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1815                         }
1816                         elsif (exists $d->{depends}) {
1817                                 $depends{$page}=$d->{depends};
1818                         }
1819                         if (exists $d->{state}) {
1820                                 $pagestate{$page}=$d->{state};
1821                         }
1822                         if (exists $d->{typedlinks}) {
1823                                 $typedlinks{$page}=$d->{typedlinks};
1824
1825                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
1826                                         next unless %$links;
1827                                         $oldtypedlinks{$page}{$type} = {%$links};
1828                                 }
1829                         }
1830                 }
1831                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1832         }
1833         foreach my $page (keys %pagesources) {
1834                 $pagecase{lc $page}=$page;
1835         }
1836         foreach my $page (keys %renderedfiles) {
1837                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1838         }
1839         return close($in);
1840 }
1841
1842 sub saveindex () {
1843         run_hooks(savestate => sub { shift->() });
1844
1845         my @plugins=keys %loaded_plugins;
1846
1847         if (! -d $config{wikistatedir}) {
1848                 mkdir($config{wikistatedir});
1849         }
1850         my $newfile="$config{wikistatedir}/indexdb.new";
1851         my $cleanup = sub { unlink($newfile) };
1852         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1853
1854         my %index;
1855         foreach my $page (keys %pagemtime) {
1856                 next unless $pagemtime{$page};
1857                 my $src=$pagesources{$page};
1858
1859                 $index{page}{$src}={
1860                         ctime => $pagectime{$page},
1861                         mtime => $pagemtime{$page},
1862                         dest => $renderedfiles{$page},
1863                         links => $links{$page},
1864                 };
1865
1866                 if (exists $depends{$page}) {
1867                         $index{page}{$src}{depends} = $depends{$page};
1868                 }
1869
1870                 if (exists $depends_simple{$page}) {
1871                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1872                 }
1873
1874                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
1875                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
1876                 }
1877
1878                 if (exists $pagestate{$page}) {
1879                         foreach my $id (@plugins) {
1880                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1881                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1882                                 }
1883                         }
1884                 }
1885         }
1886
1887         $index{state}={};
1888         foreach my $id (@plugins) {
1889                 $index{state}{$id}={}; # used to detect disabled plugins
1890                 foreach my $key (keys %{$wikistate{$id}}) {
1891                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1892                 }
1893         }
1894
1895         $index{version}="3";
1896         my $ret=Storable::nstore_fd(\%index, $out);
1897         return if ! defined $ret || ! $ret;
1898         close $out || error("failed saving to $newfile: $!", $cleanup);
1899         rename($newfile, "$config{wikistatedir}/indexdb") ||
1900                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1901
1902         return 1;
1903 }
1904
1905 sub template_file ($) {
1906         my $name=shift;
1907
1908         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
1909         my $template;
1910         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
1911                 $template=srcfile($pagesources{$tpage}, 1);
1912                 $name.=".tmpl";
1913         }
1914         else {
1915                 $template=srcfile($tpage, 1);
1916         }
1917
1918         if (defined $template) {
1919                 return $template, $tpage, 1 if wantarray;
1920                 return $template;
1921         }
1922         else {
1923                 $name=~s:/::; # avoid path traversal
1924                 foreach my $dir ($config{templatedir},
1925                                  "$installdir/share/ikiwiki/templates") {
1926                         if (-e "$dir/$name") {
1927                                 $template="$dir/$name";
1928                                 last;
1929                         }
1930                 }
1931                 if (defined $template) {
1932                         return $template, $tpage if wantarray;
1933                         return $template;
1934                 }
1935         }
1936
1937         return;
1938 }
1939
1940 sub template_depends ($$;@) {
1941         my $name=shift;
1942         my $page=shift;
1943
1944         my ($filename, $tpage, $untrusted)=template_file($name);
1945         if (! defined $filename) {
1946                 error(sprintf(gettext("template %s not found"), $name))
1947         }
1948
1949         if (defined $page && defined $tpage) {
1950                 add_depends($page, $tpage);
1951         }
1952
1953         my @opts=(
1954                 filter => sub {
1955                         my $text_ref = shift;
1956                         ${$text_ref} = decode_utf8(${$text_ref});
1957                 },
1958                 loop_context_vars => 1,
1959                 die_on_bad_params => 0,
1960                 parent_global_vars => 1,
1961                 filename => $filename,
1962                 @_,
1963                 ($untrusted ? (no_includes => 1) : ()),
1964         );
1965         return @opts if wantarray;
1966
1967         require HTML::Template;
1968         return HTML::Template->new(@opts);
1969 }
1970
1971 sub template ($;@) {
1972         template_depends(shift, undef, @_);
1973 }
1974
1975 sub templateactions ($$) {
1976         my $template=shift;
1977         my $page=shift;
1978
1979         my $have_actions=0;
1980         my @actions;
1981         run_hooks(pageactions => sub {
1982                 push @actions, map { { action => $_ } }
1983                         grep { defined } shift->(page => $page);
1984         });
1985         $template->param(actions => \@actions);
1986
1987         if ($config{cgiurl} && exists $hooks{auth}) {
1988                 $template->param(prefsurl => cgiurl(do => "prefs"));
1989                 $have_actions=1;
1990         }
1991
1992         if ($have_actions || @actions) {
1993                 $template->param(have_actions => 1);
1994         }
1995 }
1996
1997 sub hook (@) {
1998         my %param=@_;
1999
2000         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
2001                 error 'hook requires type, call, and id parameters';
2002         }
2003
2004         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
2005
2006         $hooks{$param{type}}{$param{id}}=\%param;
2007         return 1;
2008 }
2009
2010 sub run_hooks ($$) {
2011         # Calls the given sub for each hook of the given type,
2012         # passing it the hook function to call.
2013         my $type=shift;
2014         my $sub=shift;
2015
2016         if (exists $hooks{$type}) {
2017                 my (@first, @middle, @last);
2018                 foreach my $id (keys %{$hooks{$type}}) {
2019                         if ($hooks{$type}{$id}{first}) {
2020                                 push @first, $id;
2021                         }
2022                         elsif ($hooks{$type}{$id}{last}) {
2023                                 push @last, $id;
2024                         }
2025                         else {
2026                                 push @middle, $id;
2027                         }
2028                 }
2029                 foreach my $id (@first, @middle, @last) {
2030                         $sub->($hooks{$type}{$id}{call});
2031                 }
2032         }
2033
2034         return 1;
2035 }
2036
2037 sub rcs_update () {
2038         $hooks{rcs}{rcs_update}{call}->(@_);
2039 }
2040
2041 sub rcs_prepedit ($) {
2042         $hooks{rcs}{rcs_prepedit}{call}->(@_);
2043 }
2044
2045 sub rcs_commit (@) {
2046         $hooks{rcs}{rcs_commit}{call}->(@_);
2047 }
2048
2049 sub rcs_commit_staged (@) {
2050         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
2051 }
2052
2053 sub rcs_add ($) {
2054         $hooks{rcs}{rcs_add}{call}->(@_);
2055 }
2056
2057 sub rcs_remove ($) {
2058         $hooks{rcs}{rcs_remove}{call}->(@_);
2059 }
2060
2061 sub rcs_rename ($$) {
2062         $hooks{rcs}{rcs_rename}{call}->(@_);
2063 }
2064
2065 sub rcs_recentchanges ($) {
2066         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
2067 }
2068
2069 sub rcs_diff ($;$) {
2070         $hooks{rcs}{rcs_diff}{call}->(@_);
2071 }
2072
2073 sub rcs_getctime ($) {
2074         $hooks{rcs}{rcs_getctime}{call}->(@_);
2075 }
2076
2077 sub rcs_getmtime ($) {
2078         $hooks{rcs}{rcs_getmtime}{call}->(@_);
2079 }
2080
2081 sub rcs_receive () {
2082         $hooks{rcs}{rcs_receive}{call}->();
2083 }
2084
2085 sub add_depends ($$;$) {
2086         my $page=shift;
2087         my $pagespec=shift;
2088         my $deptype=shift || $DEPEND_CONTENT;
2089
2090         # Is the pagespec a simple page name?
2091         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
2092             $pagespec !~ /[\s*?()!]/) {
2093                 $depends_simple{$page}{lc $pagespec} |= $deptype;
2094                 return 1;
2095         }
2096
2097         # Add explicit dependencies for influences.
2098         my $sub=pagespec_translate($pagespec);
2099         return unless defined $sub;
2100         foreach my $p (keys %pagesources) {
2101                 my $r=$sub->($p, location => $page);
2102                 my $i=$r->influences;
2103                 my $static=$r->influences_static;
2104                 foreach my $k (keys %$i) {
2105                         next unless $r || $static || $k eq $page;
2106                         $depends_simple{$page}{lc $k} |= $i->{$k};
2107                 }
2108                 last if $static;
2109         }
2110
2111         $depends{$page}{$pagespec} |= $deptype;
2112         return 1;
2113 }
2114
2115 sub deptype (@) {
2116         my $deptype=0;
2117         foreach my $type (@_) {
2118                 if ($type eq 'presence') {
2119                         $deptype |= $DEPEND_PRESENCE;
2120                 }
2121                 elsif ($type eq 'links') {
2122                         $deptype |= $DEPEND_LINKS;
2123                 }
2124                 elsif ($type eq 'content') {
2125                         $deptype |= $DEPEND_CONTENT;
2126                 }
2127         }
2128         return $deptype;
2129 }
2130
2131 my $file_prune_regexp;
2132 sub file_pruned ($) {
2133         my $file=shift;
2134
2135         if (defined $config{include} && length $config{include}) {
2136                 return 0 if $file =~ m/$config{include}/;
2137         }
2138
2139         if (! defined $file_prune_regexp) {
2140                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
2141                 $file_prune_regexp=qr/$file_prune_regexp/;
2142         }
2143         return $file =~ m/$file_prune_regexp/;
2144 }
2145
2146 sub define_gettext () {
2147         # If translation is needed, redefine the gettext function to do it.
2148         # Otherwise, it becomes a quick no-op.
2149         my $gettext_obj;
2150         my $getobj;
2151         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2152             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2153             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2154                 $getobj=sub {
2155                         $gettext_obj=eval q{
2156                                 use Locale::gettext q{textdomain};
2157                                 Locale::gettext->domain('ikiwiki')
2158                         };
2159                 };
2160         }
2161
2162         no warnings 'redefine';
2163         *gettext=sub {
2164                 $getobj->() if $getobj;
2165                 if ($gettext_obj) {
2166                         $gettext_obj->get(shift);
2167                 }
2168                 else {
2169                         return shift;
2170                 }
2171         };
2172         *ngettext=sub {
2173                 $getobj->() if $getobj;
2174                 if ($gettext_obj) {
2175                         $gettext_obj->nget(@_);
2176                 }
2177                 else {
2178                         return ($_[2] == 1 ? $_[0] : $_[1])
2179                 }
2180         };
2181 }
2182
2183 sub gettext {
2184         define_gettext();
2185         gettext(@_);
2186 }
2187
2188 sub ngettext {
2189         define_gettext();
2190         ngettext(@_);
2191 }
2192
2193 sub yesno ($) {
2194         my $val=shift;
2195
2196         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2197 }
2198
2199 sub inject {
2200         # Injects a new function into the symbol table to replace an
2201         # exported function.
2202         my %params=@_;
2203
2204         # This is deep ugly perl foo, beware.
2205         no strict;
2206         no warnings;
2207         if (! defined $params{parent}) {
2208                 $params{parent}='::';
2209                 $params{old}=\&{$params{name}};
2210                 $params{name}=~s/.*:://;
2211         }
2212         my $parent=$params{parent};
2213         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2214                 $ns = $params{parent} . $ns;
2215                 inject(%params, parent => $ns) unless $ns eq '::main::';
2216                 *{$ns . $params{name}} = $params{call}
2217                         if exists ${$ns}{$params{name}} &&
2218                            \&{${$ns}{$params{name}}} == $params{old};
2219         }
2220         use strict;
2221         use warnings;
2222 }
2223
2224 sub add_link ($$;$) {
2225         my $page=shift;
2226         my $link=shift;
2227         my $type=shift;
2228
2229         push @{$links{$page}}, $link
2230                 unless grep { $_ eq $link } @{$links{$page}};
2231
2232         if (defined $type) {
2233                 $typedlinks{$page}{$type}{$link} = 1;
2234         }
2235 }
2236
2237 sub add_autofile ($$$) {
2238         my $file=shift;
2239         my $plugin=shift;
2240         my $generator=shift;
2241
2242         $autofiles{$file}{plugin}=$plugin;
2243         $autofiles{$file}{generator}=$generator;
2244 }
2245
2246 sub sortspec_translate ($$) {
2247         my $spec = shift;
2248         my $reverse = shift;
2249
2250         my $code = "";
2251         my @data;
2252         while ($spec =~ m{
2253                 \s*
2254                 (-?)            # group 1: perhaps negated
2255                 \s*
2256                 (               # group 2: a word
2257                         \w+\([^\)]*\)   # command(params)
2258                         |
2259                         [^\s]+          # or anything else
2260                 )
2261                 \s*
2262         }gx) {
2263                 my $negated = $1;
2264                 my $word = $2;
2265                 my $params = undef;
2266
2267                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2268                         # command with parameters
2269                         $params = $2;
2270                         $word = $1;
2271                 }
2272                 elsif ($word !~ m/^\w+$/) {
2273                         error(sprintf(gettext("invalid sort type %s"), $word));
2274                 }
2275
2276                 if (length $code) {
2277                         $code .= " || ";
2278                 }
2279
2280                 if ($negated) {
2281                         $code .= "-";
2282                 }
2283
2284                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2285                         if (defined $params) {
2286                                 push @data, $params;
2287                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2288                         }
2289                         else {
2290                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2291                         }
2292                 }
2293                 else {
2294                         error(sprintf(gettext("unknown sort type %s"), $word));
2295                 }
2296         }
2297
2298         if (! length $code) {
2299                 # undefined sorting method... sort arbitrarily
2300                 return sub { 0 };
2301         }
2302
2303         if ($reverse) {
2304                 $code="-($code)";
2305         }
2306
2307         no warnings;
2308         return eval 'sub { '.$code.' }';
2309 }
2310
2311 sub pagespec_translate ($) {
2312         my $spec=shift;
2313
2314         # Convert spec to perl code.
2315         my $code="";
2316         my @data;
2317         while ($spec=~m{
2318                 \s*             # ignore whitespace
2319                 (               # 1: match a single word
2320                         \!              # !
2321                 |
2322                         \(              # (
2323                 |
2324                         \)              # )
2325                 |
2326                         \w+\([^\)]*\)   # command(params)
2327                 |
2328                         [^\s()]+        # any other text
2329                 )
2330                 \s*             # ignore whitespace
2331         }gx) {
2332                 my $word=$1;
2333                 if (lc $word eq 'and') {
2334                         $code.=' &';
2335                 }
2336                 elsif (lc $word eq 'or') {
2337                         $code.=' |';
2338                 }
2339                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2340                         $code.=' '.$word;
2341                 }
2342                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2343                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2344                                 push @data, $2;
2345                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2346                         }
2347                         else {
2348                                 push @data, qq{unknown function in pagespec "$word"};
2349                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2350                         }
2351                 }
2352                 else {
2353                         push @data, $word;
2354                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2355                 }
2356         }
2357
2358         if (! length $code) {
2359                 $code="IkiWiki::FailReason->new('empty pagespec')";
2360         }
2361
2362         no warnings;
2363         return eval 'sub { my $page=shift; '.$code.' }';
2364 }
2365
2366 sub pagespec_match ($$;@) {
2367         my $page=shift;
2368         my $spec=shift;
2369         my @params=@_;
2370
2371         # Backwards compatability with old calling convention.
2372         if (@params == 1) {
2373                 unshift @params, 'location';
2374         }
2375
2376         my $sub=pagespec_translate($spec);
2377         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2378                 if ! defined $sub;
2379         return $sub->($page, @params);
2380 }
2381
2382 sub pagespec_match_list ($$;@) {
2383         my $page=shift;
2384         my $pagespec=shift;
2385         my %params=@_;
2386
2387         # Backwards compatability with old calling convention.
2388         if (ref $page) {
2389                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2390                 $params{list}=$page;
2391                 $page=$params{location}; # ugh!
2392         }
2393
2394         my $sub=pagespec_translate($pagespec);
2395         error "syntax error in pagespec \"$pagespec\""
2396                 if ! defined $sub;
2397         my $sort=sortspec_translate($params{sort}, $params{reverse})
2398                 if defined $params{sort};
2399
2400         my @candidates;
2401         if (exists $params{list}) {
2402                 @candidates=exists $params{filter}
2403                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2404                         : @{$params{list}};
2405         }
2406         else {
2407                 @candidates=exists $params{filter}
2408                         ? grep { ! $params{filter}->($_) } keys %pagesources
2409                         : keys %pagesources;
2410         }
2411
2412         # clear params, remainder is passed to pagespec
2413         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2414         my $num=$params{num};
2415         delete @params{qw{num deptype reverse sort filter list}};
2416
2417         # when only the top matches will be returned, it's efficient to
2418         # sort before matching to pagespec,
2419         if (defined $num && defined $sort) {
2420                 @candidates=IkiWiki::SortSpec::sort_pages(
2421                         $sort, @candidates);
2422         }
2423
2424         my @matches;
2425         my $firstfail;
2426         my $count=0;
2427         my $accum=IkiWiki::SuccessReason->new();
2428         foreach my $p (@candidates) {
2429                 my $r=$sub->($p, %params, location => $page);
2430                 error(sprintf(gettext("cannot match pages: %s"), $r))
2431                         if $r->isa("IkiWiki::ErrorReason");
2432                 unless ($r || $r->influences_static) {
2433                         $r->remove_influence($p);
2434                 }
2435                 $accum |= $r;
2436                 if ($r) {
2437                         push @matches, $p;
2438                         last if defined $num && ++$count == $num;
2439                 }
2440         }
2441
2442         # Add simple dependencies for accumulated influences.
2443         my $i=$accum->influences;
2444         foreach my $k (keys %$i) {
2445                 $depends_simple{$page}{lc $k} |= $i->{$k};
2446         }
2447
2448         # when all matches will be returned, it's efficient to
2449         # sort after matching
2450         if (! defined $num && defined $sort) {
2451                 return IkiWiki::SortSpec::sort_pages(
2452                         $sort, @matches);
2453         }
2454         else {
2455                 return @matches;
2456         }
2457 }
2458
2459 sub pagespec_valid ($) {
2460         my $spec=shift;
2461
2462         return defined pagespec_translate($spec);
2463 }
2464
2465 sub glob2re ($) {
2466         my $re=quotemeta(shift);
2467         $re=~s/\\\*/.*/g;
2468         $re=~s/\\\?/./g;
2469         return qr/^$re$/i;
2470 }
2471
2472 package IkiWiki::FailReason;
2473
2474 use overload (
2475         '""'    => sub { $_[0][0] },
2476         '0+'    => sub { 0 },
2477         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2478         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2479         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2480         fallback => 1,
2481 );
2482
2483 our @ISA = 'IkiWiki::SuccessReason';
2484
2485 package IkiWiki::SuccessReason;
2486
2487 use overload (
2488         '""'    => sub { $_[0][0] },
2489         '0+'    => sub { 1 },
2490         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2491         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2492         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2493         fallback => 1,
2494 );
2495
2496 sub new {
2497         my $class = shift;
2498         my $value = shift;
2499         return bless [$value, {@_}], $class;
2500 }
2501
2502 sub influences {
2503         my $this=shift;
2504         $this->[1]={@_} if @_;
2505         my %i=%{$this->[1]};
2506         delete $i{""};
2507         return \%i;
2508 }
2509
2510 sub influences_static {
2511         return ! $_[0][1]->{""};
2512 }
2513
2514 sub merge_influences {
2515         my $this=shift;
2516         my $other=shift;
2517         my $anded=shift;
2518
2519         if (! $anded || (($this || %{$this->[1]}) &&
2520                          ($other || %{$other->[1]}))) {
2521                 foreach my $influence (keys %{$other->[1]}) {
2522                         $this->[1]{$influence} |= $other->[1]{$influence};
2523                 }
2524         }
2525         else {
2526                 # influence blocker
2527                 $this->[1]={};
2528         }
2529 }
2530
2531 sub remove_influence {
2532         my $this=shift;
2533         my $torm=shift;
2534
2535         delete $this->[1]{$torm};
2536 }
2537
2538 package IkiWiki::ErrorReason;
2539
2540 our @ISA = 'IkiWiki::FailReason';
2541
2542 package IkiWiki::PageSpec;
2543
2544 sub derel ($$) {
2545         my $path=shift;
2546         my $from=shift;
2547
2548         if ($path =~ m!^\.(/|$)!) {
2549                 if ($1) {
2550                         $from=~s#/?[^/]+$## if defined $from;
2551                         $path=~s#^\./##;
2552                         $path="$from/$path" if defined $from && length $from;
2553                 }
2554                 else {
2555                         $path = $from;
2556                         $path = "" unless defined $path;
2557                 }
2558         }
2559
2560         return $path;
2561 }
2562
2563 my %glob_cache;
2564
2565 sub match_glob ($$;@) {
2566         my $page=shift;
2567         my $glob=shift;
2568         my %params=@_;
2569
2570         $glob=derel($glob, $params{location});
2571
2572         # Instead of converting the glob to a regex every time,
2573         # cache the compiled regex to save time.
2574         my $re=$glob_cache{$glob};
2575         unless (defined $re) {
2576                 $glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
2577         }
2578         if ($page =~ $re) {
2579                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2580                         return IkiWiki::SuccessReason->new("$glob matches $page");
2581                 }
2582                 else {
2583                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2584                 }
2585         }
2586         else {
2587                 return IkiWiki::FailReason->new("$glob does not match $page");
2588         }
2589 }
2590
2591 sub match_internal ($$;@) {
2592         return match_glob(shift, shift, @_, internal => 1)
2593 }
2594
2595 sub match_page ($$;@) {
2596         my $page=shift;
2597         my $match=match_glob($page, shift, @_);
2598         if ($match) {
2599                 my $source=exists $IkiWiki::pagesources{$page} ?
2600                         $IkiWiki::pagesources{$page} :
2601                         $IkiWiki::delpagesources{$page};
2602                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2603                 if (! defined $type) {
2604                         return IkiWiki::FailReason->new("$page is not a page");
2605                 }
2606         }
2607         return $match;
2608 }
2609
2610 sub match_link ($$;@) {
2611         my $page=shift;
2612         my $link=lc(shift);
2613         my %params=@_;
2614
2615         $link=derel($link, $params{location});
2616         my $from=exists $params{location} ? $params{location} : '';
2617         my $linktype=$params{linktype};
2618         my $qualifier='';
2619         if (defined $linktype) {
2620                 $qualifier=" with type $linktype";
2621         }
2622
2623         my $links = $IkiWiki::links{$page};
2624         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2625                 unless $links && @{$links};
2626         my $bestlink = IkiWiki::bestlink($from, $link);
2627         foreach my $p (@{$links}) {
2628                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2629
2630                 if (length $bestlink) {
2631                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2632                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2633                         }
2634                 }
2635                 else {
2636                         if (match_glob($p, $link, %params)) {
2637                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2638                         }
2639                         my ($p_rel)=$p=~/^\/?(.*)/;
2640                         $link=~s/^\///;
2641                         if (match_glob($p_rel, $link, %params)) {
2642                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2643                         }
2644                 }
2645         }
2646         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2647 }
2648
2649 sub match_backlink ($$;@) {
2650         my $ret=match_link($_[1], $_[0], @_);
2651         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2652         return $ret;
2653 }
2654
2655 sub match_created_before ($$;@) {
2656         my $page=shift;
2657         my $testpage=shift;
2658         my %params=@_;
2659
2660         $testpage=derel($testpage, $params{location});
2661
2662         if (exists $IkiWiki::pagectime{$testpage}) {
2663                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2664                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2665                 }
2666                 else {
2667                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2668                 }
2669         }
2670         else {
2671                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2672         }
2673 }
2674
2675 sub match_created_after ($$;@) {
2676         my $page=shift;
2677         my $testpage=shift;
2678         my %params=@_;
2679
2680         $testpage=derel($testpage, $params{location});
2681
2682         if (exists $IkiWiki::pagectime{$testpage}) {
2683                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2684                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2685                 }
2686                 else {
2687                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2688                 }
2689         }
2690         else {
2691                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2692         }
2693 }
2694
2695 sub match_creation_day ($$;@) {
2696         my $page=shift;
2697         my $d=shift;
2698         if ($d !~ /^\d+$/) {
2699                 return IkiWiki::ErrorReason->new("invalid day $d");
2700         }
2701         if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
2702                 return IkiWiki::SuccessReason->new('creation_day matched');
2703         }
2704         else {
2705                 return IkiWiki::FailReason->new('creation_day did not match');
2706         }
2707 }
2708
2709 sub match_creation_month ($$;@) {
2710         my $page=shift;
2711         my $m=shift;
2712         if ($m !~ /^\d+$/) {
2713                 return IkiWiki::ErrorReason->new("invalid month $m");
2714         }
2715         if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
2716                 return IkiWiki::SuccessReason->new('creation_month matched');
2717         }
2718         else {
2719                 return IkiWiki::FailReason->new('creation_month did not match');
2720         }
2721 }
2722
2723 sub match_creation_year ($$;@) {
2724         my $page=shift;
2725         my $y=shift;
2726         if ($y !~ /^\d+$/) {
2727                 return IkiWiki::ErrorReason->new("invalid year $y");
2728         }
2729         if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
2730                 return IkiWiki::SuccessReason->new('creation_year matched');
2731         }
2732         else {
2733                 return IkiWiki::FailReason->new('creation_year did not match');
2734         }
2735 }
2736
2737 sub match_user ($$;@) {
2738         shift;
2739         my $user=shift;
2740         my %params=@_;
2741
2742         my $regexp=IkiWiki::glob2re($user);
2743
2744         if (! exists $params{user}) {
2745                 return IkiWiki::ErrorReason->new("no user specified");
2746         }
2747
2748         if (defined $params{user} && $params{user}=~$regexp) {
2749                 return IkiWiki::SuccessReason->new("user is $user");
2750         }
2751         elsif (! defined $params{user}) {
2752                 return IkiWiki::FailReason->new("not logged in");
2753         }
2754         else {
2755                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2756         }
2757 }
2758
2759 sub match_admin ($$;@) {
2760         shift;
2761         shift;
2762         my %params=@_;
2763
2764         if (! exists $params{user}) {
2765                 return IkiWiki::ErrorReason->new("no user specified");
2766         }
2767
2768         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2769                 return IkiWiki::SuccessReason->new("user is an admin");
2770         }
2771         elsif (! defined $params{user}) {
2772                 return IkiWiki::FailReason->new("not logged in");
2773         }
2774         else {
2775                 return IkiWiki::FailReason->new("user is not an admin");
2776         }
2777 }
2778
2779 sub match_ip ($$;@) {
2780         shift;
2781         my $ip=shift;
2782         my %params=@_;
2783
2784         if (! exists $params{ip}) {
2785                 return IkiWiki::ErrorReason->new("no IP specified");
2786         }
2787
2788         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2789                 return IkiWiki::SuccessReason->new("IP is $ip");
2790         }
2791         else {
2792                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2793         }
2794 }
2795
2796 package IkiWiki::SortSpec;
2797
2798 # This is in the SortSpec namespace so that the $a and $b that sort() uses
2799 # are easily available in this namespace, for cmp functions to use them.
2800 sub sort_pages {
2801         my $f=shift;
2802         sort $f @_
2803 }
2804
2805 sub cmp_title {
2806         IkiWiki::pagetitle(IkiWiki::basename($a))
2807         cmp
2808         IkiWiki::pagetitle(IkiWiki::basename($b))
2809 }
2810
2811 sub cmp_path { IkiWiki::pagetitle($a) cmp IkiWiki::pagetitle($b) }
2812 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
2813 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
2814
2815 1