IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use HTML::Entities;
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX;
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15             %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16             %pagesources %destsources %depends %hooks %forcerebuild
  17             $gettext_obj %loaded_plugins};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  21                  bestlink htmllink readfile writefile pagetype srcfile pagename
  22                  displaytime will_render gettext urlto targetpage
  23                  add_underlay pagetitle titlepage linkpage newpagefile
  24                  inject
  25                  %config %links %pagestate %wikistate %renderedfiles
  26                  %pagesources %destsources);
  27 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29 our $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  30
  31 # Optimisation.
  32 use Memoize;
  33 memoize("abs2rel");
  34 memoize("pagespec_translate");
  35 memoize("file_pruned");
  36
  37 sub getsetup () {
  38         wikiname => {
  39                 type => "string",
  40                 default => "wiki",
  41                 description => "name of the wiki",
  42                 safe => 1,
  43                 rebuild => 1,
  44         },
  45         adminemail => {
  46                 type => "string",
  47                 default => undef,
  48                 example => 'me@example.com',
  49                 description => "contact email for wiki",
  50                 safe => 1,
  51                 rebuild => 0,
  52         },
  53         adminuser => {
  54                 type => "string",
  55                 default => [],
  56                 description => "users who are wiki admins",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         banned_users => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are banned from the wiki",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         srcdir => {
  68                 type => "string",
  69                 default => undef,
  70                 example => "$ENV{HOME}/wiki",
  71                 description => "where the source of the wiki is located",
  72                 safe => 0, # path
  73                 rebuild => 1,
  74         },
  75         destdir => {
  76                 type => "string",
  77                 default => undef,
  78                 example => "/var/www/wiki",
  79                 description => "where to build the wiki",
  80                 safe => 0, # path
  81                 rebuild => 1,
  82         },
  83         url => {
  84                 type => "string",
  85                 default => '',
  86                 example => "http://example.com/wiki",
  87                 description => "base url to the wiki",
  88                 safe => 1,
  89                 rebuild => 1,
  90         },
  91         cgiurl => {
  92                 type => "string",
  93                 default => '',
  94                 example => "http://example.com/wiki/ikiwiki.cgi",
  95                 description => "url to the ikiwiki.cgi",
  96                 safe => 1,
  97                 rebuild => 1,
  98         },
  99         cgi_wrapper => {
 100                 type => "string",
 101                 default => '',
 102                 example => "/var/www/wiki/ikiwiki.cgi",
 103                 description => "filename of cgi wrapper to generate",
 104                 safe => 0, # file
 105                 rebuild => 0,
 106         },
 107         cgi_wrappermode => {
 108                 type => "string",
 109                 default => '06755',
 110                 description => "mode for cgi_wrapper (can safely be made suid)",
 111                 safe => 0,
 112                 rebuild => 0,
 113         },
 114         rcs => {
 115                 type => "string",
 116                 default => '',
 117                 description => "rcs backend to use",
 118                 safe => 0, # don't allow overriding
 119                 rebuild => 0,
 120         },
 121         default_plugins => {
 122                 type => "internal",
 123                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 124                                 openid signinedit lockedit conditional
 125                                 recentchanges parentlinks editpage}],
 126                 description => "plugins to enable by default",
 127                 safe => 0,
 128                 rebuild => 1,
 129         },
 130         add_plugins => {
 131                 type => "string",
 132                 default => [],
 133                 description => "plugins to add to the default configuration",
 134                 safe => 1,
 135                 rebuild => 1,
 136         },
 137         disable_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to disable",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         templatedir => {
 145                 type => "string",
 146                 default => "$installdir/share/ikiwiki/templates",
 147                 description => "location of template files",
 148                 advanced => 1,
 149                 safe => 0, # path
 150                 rebuild => 1,
 151         },
 152         underlaydir => {
 153                 type => "string",
 154                 default => "$installdir/share/ikiwiki/basewiki",
 155                 description => "base wiki source location",
 156                 advanced => 1,
 157                 safe => 0, # path
 158                 rebuild => 0,
 159         },
 160         wrappers => {
 161                 type => "internal",
 162                 default => [],
 163                 description => "wrappers to generate",
 164                 safe => 0,
 165                 rebuild => 0,
 166         },
 167         underlaydirs => {
 168                 type => "internal",
 169                 default => [],
 170                 description => "additional underlays to use",
 171                 safe => 0,
 172                 rebuild => 0,
 173         },
 174         verbose => {
 175                 type => "boolean",
 176                 example => 1,
 177                 description => "display verbose messages?",
 178                 safe => 1,
 179                 rebuild => 0,
 180         },
 181         syslog => {
 182                 type => "boolean",
 183                 example => 1,
 184                 description => "log to syslog?",
 185                 safe => 1,
 186                 rebuild => 0,
 187         },
 188         usedirs => {
 189                 type => "boolean",
 190                 default => 1,
 191                 description => "create output files named page/index.html?",
 192                 safe => 0, # changing requires manual transition
 193                 rebuild => 1,
 194         },
 195         prefix_directives => {
 196                 type => "boolean",
 197                 default => 1,
 198                 description => "use '!'-prefixed preprocessor directives?",
 199                 safe => 0, # changing requires manual transition
 200                 rebuild => 1,
 201         },
 202         indexpages => {
 203                 type => "boolean",
 204                 default => 0,
 205                 description => "use page/index.mdwn source files",
 206                 safe => 1,
 207                 rebuild => 1,
 208         },
 209         discussion => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "enable Discussion pages?",
 213                 safe => 1,
 214                 rebuild => 1,
 215         },
 216         sslcookie => {
 217                 type => "boolean",
 218                 default => 0,
 219                 description => "only send cookies over SSL connections?",
 220                 advanced => 1,
 221                 safe => 1,
 222                 rebuild => 0,
 223         },
 224         default_pageext => {
 225                 type => "string",
 226                 default => "mdwn",
 227                 description => "extension to use for new pages",
 228                 safe => 0, # not sanitized
 229                 rebuild => 0,
 230         },
 231         htmlext => {
 232                 type => "string",
 233                 default => "html",
 234                 description => "extension to use for html files",
 235                 safe => 0, # not sanitized
 236                 rebuild => 1,
 237         },
 238         timeformat => {
 239                 type => "string",
 240                 default => '%c',
 241                 description => "strftime format string to display date",
 242                 advanced => 1,
 243                 safe => 1,
 244                 rebuild => 1,
 245         },
 246         locale => {
 247                 type => "string",
 248                 default => undef,
 249                 example => "en_US.UTF-8",
 250                 description => "UTF-8 locale to use",
 251                 advanced => 1,
 252                 safe => 0,
 253                 rebuild => 1,
 254         },
 255         userdir => {
 256                 type => "string",
 257                 default => "",
 258                 example => "users",
 259                 description => "put user pages below specified page",
 260                 safe => 1,
 261                 rebuild => 1,
 262         },
 263         numbacklinks => {
 264                 type => "integer",
 265                 default => 10,
 266                 description => "how many backlinks to show before hiding excess (0 to show all)",
 267                 safe => 1,
 268                 rebuild => 1,
 269         },
 270         hardlink => {
 271                 type => "boolean",
 272                 default => 0,
 273                 description => "attempt to hardlink source files? (optimisation for large files)",
 274                 advanced => 1,
 275                 safe => 0, # paranoia
 276                 rebuild => 0,
 277         },
 278         umask => {
 279                 type => "integer",
 280                 example => "022",
 281                 description => "force ikiwiki to use a particular umask",
 282                 advanced => 1,
 283                 safe => 0, # paranoia
 284                 rebuild => 0,
 285         },
 286         wrappergroup => {
 287                 type => "string",
 288                 example => "ikiwiki",
 289                 description => "group for wrappers to run in",
 290                 advanced => 1,
 291                 safe => 0, # paranoia
 292                 rebuild => 0,
 293         },
 294         libdir => {
 295                 type => "string",
 296                 default => "",
 297                 example => "$ENV{HOME}/.ikiwiki/",
 298                 description => "extra library and plugin directory",
 299                 advanced => 1,
 300                 safe => 0, # directory
 301                 rebuild => 0,
 302         },
 303         ENV => {
 304                 type => "string",
 305                 default => {},
 306                 description => "environment variables",
 307                 safe => 0, # paranoia
 308                 rebuild => 0,
 309         },
 310         exclude => {
 311                 type => "string",
 312                 default => undef,
 313                 example => '\.wav$',
 314                 description => "regexp of source files to ignore",
 315                 advanced => 1,
 316                 safe => 0, # regexp
 317                 rebuild => 1,
 318         },
 319         wiki_file_prune_regexps => {
 320                 type => "internal",
 321                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
 322                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 323                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 324                         qr/(^|\/)_MTN\//,
 325                         qr/\.dpkg-tmp$/],
 326                 description => "regexps of source files to ignore",
 327                 safe => 0,
 328                 rebuild => 1,
 329         },
 330         wiki_file_chars => {
 331                 type => "string",
 332                 description => "specifies the characters that are allowed in source filenames",
 333                 default => "-[:alnum:]+/.:_",
 334                 safe => 0,
 335                 rebuild => 1,
 336         },
 337         wiki_file_regexp => {
 338                 type => "internal",
 339                 description => "regexp of legal source files",
 340                 safe => 0,
 341                 rebuild => 1,
 342         },
 343         web_commit_regexp => {
 344                 type => "internal",
 345                 default => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
 346                 description => "regexp to parse web commits from logs",
 347                 safe => 0,
 348                 rebuild => 0,
 349         },
 350         cgi => {
 351                 type => "internal",
 352                 default => 0,
 353                 description => "run as a cgi",
 354                 safe => 0,
 355                 rebuild => 0,
 356         },
 357         cgi_disable_uploads => {
 358                 type => "internal",
 359                 default => 1,
 360                 description => "whether CGI should accept file uploads",
 361                 safe => 0,
 362                 rebuild => 0,
 363         },
 364         post_commit => {
 365                 type => "internal",
 366                 default => 0,
 367                 description => "run as a post-commit hook",
 368                 safe => 0,
 369                 rebuild => 0,
 370         },
 371         rebuild => {
 372                 type => "internal",
 373                 default => 0,
 374                 description => "running in rebuild mode",
 375                 safe => 0,
 376                 rebuild => 0,
 377         },
 378         setup => {
 379                 type => "internal",
 380                 default => undef,
 381                 description => "running in setup mode",
 382                 safe => 0,
 383                 rebuild => 0,
 384         },
 385         refresh => {
 386                 type => "internal",
 387                 default => 0,
 388                 description => "running in refresh mode",
 389                 safe => 0,
 390                 rebuild => 0,
 391         },
 392         test_receive => {
 393                 type => "internal",
 394                 default => 0,
 395                 description => "running in receive test mode",
 396                 safe => 0,
 397                 rebuild => 0,
 398         },
 399         getctime => {
 400                 type => "internal",
 401                 default => 0,
 402                 description => "running in getctime mode",
 403                 safe => 0,
 404                 rebuild => 0,
 405         },
 406         w3mmode => {
 407                 type => "internal",
 408                 default => 0,
 409                 description => "running in w3mmode",
 410                 safe => 0,
 411                 rebuild => 0,
 412         },
 413         wikistatedir => {
 414                 type => "internal",
 415                 default => undef,
 416                 description => "path to the .ikiwiki directory holding ikiwiki state",
 417                 safe => 0,
 418                 rebuild => 0,
 419         },
 420         setupfile => {
 421                 type => "internal",
 422                 default => undef,
 423                 description => "path to setup file",
 424                 safe => 0,
 425                 rebuild => 0,
 426         },
 427         allow_symlinks_before_srcdir => {
 428                 type => "boolean",
 429                 default => 0,
 430                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 431                 safe => 0,
 432                 rebuild => 0,
 433         },
 434 }
 435
 436 sub defaultconfig () {
 437         my %s=getsetup();
 438         my @ret;
 439         foreach my $key (keys %s) {
 440                 push @ret, $key, $s{$key}->{default};
 441         }
 442         use Data::Dumper;
 443         return @ret;
 444 }
 445
 446 sub checkconfig () {
 447         # locale stuff; avoid LC_ALL since it overrides everything
 448         if (defined $ENV{LC_ALL}) {
 449                 $ENV{LANG} = $ENV{LC_ALL};
 450                 delete $ENV{LC_ALL};
 451         }
 452         if (defined $config{locale}) {
 453                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 454                         $ENV{LANG}=$config{locale};
 455                         $gettext_obj=undef;
 456                 }
 457         }
 458
 459         if (! defined $config{wiki_file_regexp}) {
 460                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 461         }
 462
 463         if (ref $config{ENV} eq 'HASH') {
 464                 foreach my $val (keys %{$config{ENV}}) {
 465                         $ENV{$val}=$config{ENV}{$val};
 466                 }
 467         }
 468
 469         if ($config{w3mmode}) {
 470                 eval q{use Cwd q{abs_path}};
 471                 error($@) if $@;
 472                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 473                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 474                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 475                         unless $config{cgiurl} =~ m!file:///!;
 476                 $config{url}="file://".$config{destdir};
 477         }
 478
 479         if ($config{cgi} && ! length $config{url}) {
 480                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 481         }
 482
 483         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 484                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 485
 486         if (defined $config{umask}) {
 487                 umask(possibly_foolish_untaint($config{umask}));
 488         }
 489
 490         run_hooks(checkconfig => sub { shift->() });
 491
 492         return 1;
 493 }
 494
 495 sub listplugins () {
 496         my %ret;
 497
 498         foreach my $dir (@INC, $config{libdir}) {
 499                 next unless defined $dir && length $dir;
 500                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 501                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 502                         $ret{$plugin}=1;
 503                 }
 504         }
 505         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 506                 next unless defined $dir && length $dir;
 507                 foreach my $file (glob("$dir/plugins/*")) {
 508                         $ret{basename($file)}=1 if -x $file;
 509                 }
 510         }
 511
 512         return keys %ret;
 513 }
 514
 515 sub loadplugins () {
 516         if (defined $config{libdir} && length $config{libdir}) {
 517                 unshift @INC, possibly_foolish_untaint($config{libdir});
 518         }
 519
 520         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 521                 loadplugin($plugin);
 522         }
 523
 524         if ($config{rcs}) {
 525                 if (exists $IkiWiki::hooks{rcs}) {
 526                         error(gettext("cannot use multiple rcs plugins"));
 527                 }
 528                 loadplugin($config{rcs});
 529         }
 530         if (! exists $IkiWiki::hooks{rcs}) {
 531                 loadplugin("norcs");
 532         }
 533
 534         run_hooks(getopt => sub { shift->() });
 535         if (grep /^-/, @ARGV) {
 536                 print STDERR "Unknown option: $_\n"
 537                         foreach grep /^-/, @ARGV;
 538                 usage();
 539         }
 540
 541         return 1;
 542 }
 543
 544 sub loadplugin ($) {
 545         my $plugin=shift;
 546
 547         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 548
 549         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 550                          "$installdir/lib/ikiwiki") {
 551                 if (defined $dir && -x "$dir/plugins/$plugin") {
 552                         eval { require IkiWiki::Plugin::external };
 553                         if ($@) {
 554                                 my $reason=$@;
 555                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 556                         }
 557                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 558                         $loaded_plugins{$plugin}=1;
 559                         return 1;
 560                 }
 561         }
 562
 563         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 564         eval qq{use $mod};
 565         if ($@) {
 566                 error("Failed to load plugin $mod: $@");
 567         }
 568         $loaded_plugins{$plugin}=1;
 569         return 1;
 570 }
 571
 572 sub error ($;$) {
 573         my $message=shift;
 574         my $cleaner=shift;
 575         log_message('err' => $message) if $config{syslog};
 576         if (defined $cleaner) {
 577                 $cleaner->();
 578         }
 579         die $message."\n";
 580 }
 581
 582 sub debug ($) {
 583         return unless $config{verbose};
 584         return log_message(debug => @_);
 585 }
 586
 587 my $log_open=0;
 588 sub log_message ($$) {
 589         my $type=shift;
 590
 591         if ($config{syslog}) {
 592                 require Sys::Syslog;
 593                 if (! $log_open) {
 594                         Sys::Syslog::setlogsock('unix');
 595                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 596                         $log_open=1;
 597                 }
 598                 return eval {
 599                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 600                 };
 601         }
 602         elsif (! $config{cgi}) {
 603                 return print "@_\n";
 604         }
 605         else {
 606                 return print STDERR "@_\n";
 607         }
 608 }
 609
 610 sub possibly_foolish_untaint ($) {
 611         my $tainted=shift;
 612         my ($untainted)=$tainted=~/(.*)/s;
 613         return $untainted;
 614 }
 615
 616 sub basename ($) {
 617         my $file=shift;
 618
 619         $file=~s!.*/+!!;
 620         return $file;
 621 }
 622
 623 sub dirname ($) {
 624         my $file=shift;
 625
 626         $file=~s!/*[^/]+$!!;
 627         return $file;
 628 }
 629
 630 sub pagetype ($) {
 631         my $page=shift;
 632
 633         if ($page =~ /\.([^.]+)$/) {
 634                 return $1 if exists $hooks{htmlize}{$1};
 635         }
 636         return;
 637 }
 638
 639 sub isinternal ($) {
 640         my $page=shift;
 641         return exists $pagesources{$page} &&
 642                 $pagesources{$page} =~ /\._([^.]+)$/;
 643 }
 644
 645 sub pagename ($) {
 646         my $file=shift;
 647
 648         my $type=pagetype($file);
 649         my $page=$file;
 650         $page=~s/\Q.$type\E*$// if defined $type && !$hooks{htmlize}{$type}{keepextension};
 651         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 652                 $page=$1;
 653         }
 654         return $page;
 655 }
 656
 657 sub newpagefile ($$) {
 658         my $page=shift;
 659         my $type=shift;
 660
 661         if (! $config{indexpages} || $page eq 'index') {
 662                 return $page.".".$type;
 663         }
 664         else {
 665                 return $page."/index.".$type;
 666         }
 667 }
 668
 669 sub targetpage ($$;$) {
 670         my $page=shift;
 671         my $ext=shift;
 672         my $filename=shift;
 673
 674         if (defined $filename) {
 675                 return $page."/".$filename.".".$ext;
 676         }
 677         elsif (! $config{usedirs} || $page eq 'index') {
 678                 return $page.".".$ext;
 679         }
 680         else {
 681                 return $page."/index.".$ext;
 682         }
 683 }
 684
 685 sub htmlpage ($) {
 686         my $page=shift;
 687
 688         return targetpage($page, $config{htmlext});
 689 }
 690
 691 sub srcfile_stat {
 692         my $file=shift;
 693         my $nothrow=shift;
 694
 695         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 696         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 697                 return "$dir/$file", stat(_) if -e "$dir/$file";
 698         }
 699         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 700         return;
 701 }
 702
 703 sub srcfile ($;$) {
 704         return (srcfile_stat(@_))[0];
 705 }
 706
 707 sub add_underlay ($) {
 708         my $dir=shift;
 709
 710         if ($dir !~ /^\//) {
 711                 $dir="$config{underlaydir}/../$dir";
 712         }
 713
 714         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 715                 unshift @{$config{underlaydirs}}, $dir;
 716         }
 717
 718         return 1;
 719 }
 720
 721 sub readfile ($;$$) {
 722         my $file=shift;
 723         my $binary=shift;
 724         my $wantfd=shift;
 725
 726         if (-l $file) {
 727                 error("cannot read a symlink ($file)");
 728         }
 729
 730         local $/=undef;
 731         open (my $in, "<", $file) || error("failed to read $file: $!");
 732         binmode($in) if ($binary);
 733         return \*$in if $wantfd;
 734         my $ret=<$in>;
 735         # check for invalid utf-8, and toss it back to avoid crashes
 736         if (! utf8::valid($ret)) {
 737                 $ret=encode_utf8($ret);
 738         }
 739         close $in || error("failed to read $file: $!");
 740         return $ret;
 741 }
 742
 743 sub prep_writefile ($$) {
 744         my $file=shift;
 745         my $destdir=shift;
 746
 747         my $test=$file;
 748         while (length $test) {
 749                 if (-l "$destdir/$test") {
 750                         error("cannot write to a symlink ($test)");
 751                 }
 752                 $test=dirname($test);
 753         }
 754
 755         my $dir=dirname("$destdir/$file");
 756         if (! -d $dir) {
 757                 my $d="";
 758                 foreach my $s (split(m!/+!, $dir)) {
 759                         $d.="$s/";
 760                         if (! -d $d) {
 761                                 mkdir($d) || error("failed to create directory $d: $!");
 762                         }
 763                 }
 764         }
 765
 766         return 1;
 767 }
 768
 769 sub writefile ($$$;$$) {
 770         my $file=shift; # can include subdirs
 771         my $destdir=shift; # directory to put file in
 772         my $content=shift;
 773         my $binary=shift;
 774         my $writer=shift;
 775
 776         prep_writefile($file, $destdir);
 777
 778         my $newfile="$destdir/$file.ikiwiki-new";
 779         if (-l $newfile) {
 780                 error("cannot write to a symlink ($newfile)");
 781         }
 782
 783         my $cleanup = sub { unlink($newfile) };
 784         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 785         binmode($out) if ($binary);
 786         if ($writer) {
 787                 $writer->(\*$out, $cleanup);
 788         }
 789         else {
 790                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 791         }
 792         close $out || error("failed saving $newfile: $!", $cleanup);
 793         rename($newfile, "$destdir/$file") ||
 794                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 795
 796         return 1;
 797 }
 798
 799 my %cleared;
 800 sub will_render ($$;$) {
 801         my $page=shift;
 802         my $dest=shift;
 803         my $clear=shift;
 804
 805         # Important security check.
 806         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 807             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 808                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 809         }
 810
 811         if (! $clear || $cleared{$page}) {
 812                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 813         }
 814         else {
 815                 foreach my $old (@{$renderedfiles{$page}}) {
 816                         delete $destsources{$old};
 817                 }
 818                 $renderedfiles{$page}=[$dest];
 819                 $cleared{$page}=1;
 820         }
 821         $destsources{$dest}=$page;
 822
 823         return 1;
 824 }
 825
 826 sub bestlink ($$) {
 827         my $page=shift;
 828         my $link=shift;
 829
 830         my $cwd=$page;
 831         if ($link=~s/^\/+//) {
 832                 # absolute links
 833                 $cwd="";
 834         }
 835         $link=~s/\/$//;
 836
 837         do {
 838                 my $l=$cwd;
 839                 $l.="/" if length $l;
 840                 $l.=$link;
 841
 842                 if (exists $links{$l}) {
 843                         return $l;
 844                 }
 845                 elsif (exists $pagecase{lc $l}) {
 846                         return $pagecase{lc $l};
 847                 }
 848         } while $cwd=~s{/?[^/]+$}{};
 849
 850         if (length $config{userdir}) {
 851                 my $l = "$config{userdir}/".lc($link);
 852                 if (exists $links{$l}) {
 853                         return $l;
 854                 }
 855                 elsif (exists $pagecase{lc $l}) {
 856                         return $pagecase{lc $l};
 857                 }
 858         }
 859
 860         #print STDERR "warning: page $page, broken link: $link\n";
 861         return "";
 862 }
 863
 864 sub isinlinableimage ($) {
 865         my $file=shift;
 866
 867         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 868 }
 869
 870 sub pagetitle ($;$) {
 871         my $page=shift;
 872         my $unescaped=shift;
 873
 874         if ($unescaped) {
 875                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 876         }
 877         else {
 878                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 879         }
 880
 881         return $page;
 882 }
 883
 884 sub titlepage ($) {
 885         my $title=shift;
 886         # support use w/o %config set
 887         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 888         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 889         return $title;
 890 }
 891
 892 sub linkpage ($) {
 893         my $link=shift;
 894         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 895         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 896         return $link;
 897 }
 898
 899 sub cgiurl (@) {
 900         my %params=@_;
 901
 902         return $config{cgiurl}."?".
 903                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 904 }
 905
 906 sub baseurl (;$) {
 907         my $page=shift;
 908
 909         return "$config{url}/" if ! defined $page;
 910
 911         $page=htmlpage($page);
 912         $page=~s/[^\/]+$//;
 913         $page=~s/[^\/]+\//..\//g;
 914         return $page;
 915 }
 916
 917 sub abs2rel ($$) {
 918         # Work around very innefficient behavior in File::Spec if abs2rel
 919         # is passed two relative paths. It's much faster if paths are
 920         # absolute! (Debian bug #376658; fixed in debian unstable now)
 921         my $path="/".shift;
 922         my $base="/".shift;
 923
 924         require File::Spec;
 925         my $ret=File::Spec->abs2rel($path, $base);
 926         $ret=~s/^// if defined $ret;
 927         return $ret;
 928 }
 929
 930 sub displaytime ($;$) {
 931         # Plugins can override this function to mark up the time to
 932         # display.
 933         return '<span class="date">'.formattime(@_).'</span>';
 934 }
 935
 936 sub formattime ($;$) {
 937         # Plugins can override this function to format the time.
 938         my $time=shift;
 939         my $format=shift;
 940         if (! defined $format) {
 941                 $format=$config{timeformat};
 942         }
 943
 944         # strftime doesn't know about encodings, so make sure
 945         # its output is properly treated as utf8
 946         return decode_utf8(POSIX::strftime($format, localtime($time)));
 947 }
 948
 949 sub beautify_urlpath ($) {
 950         my $url=shift;
 951
 952         # Ensure url is not an empty link, and if necessary,
 953         # add ./ to avoid colon confusion.
 954         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
 955                 $url="./$url";
 956         }
 957
 958         if ($config{usedirs}) {
 959                 $url =~ s!/index.$config{htmlext}$!/!;
 960         }
 961
 962         return $url;
 963 }
 964
 965 sub urlto ($$;$) {
 966         my $to=shift;
 967         my $from=shift;
 968         my $absolute=shift;
 969
 970         if (! length $to) {
 971                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
 972         }
 973
 974         if (! $destsources{$to}) {
 975                 $to=htmlpage($to);
 976         }
 977
 978         if ($absolute) {
 979                 return $config{url}.beautify_urlpath("/".$to);
 980         }
 981
 982         my $link = abs2rel($to, dirname(htmlpage($from)));
 983
 984         return beautify_urlpath($link);
 985 }
 986
 987 sub htmllink ($$$;@) {
 988         my $lpage=shift; # the page doing the linking
 989         my $page=shift; # the page that will contain the link (different for inline)
 990         my $link=shift;
 991         my %opts=@_;
 992
 993         $link=~s/\/$//;
 994
 995         my $bestlink;
 996         if (! $opts{forcesubpage}) {
 997                 $bestlink=bestlink($lpage, $link);
 998         }
 999         else {
1000                 $bestlink="$lpage/".lc($link);
1001         }
1002
1003         my $linktext;
1004         if (defined $opts{linktext}) {
1005                 $linktext=$opts{linktext};
1006         }
1007         else {
1008                 $linktext=pagetitle(basename($link));
1009         }
1010
1011         return "<span class=\"selflink\">$linktext</span>"
1012                 if length $bestlink && $page eq $bestlink &&
1013                    ! defined $opts{anchor};
1014
1015         if (! $destsources{$bestlink}) {
1016                 $bestlink=htmlpage($bestlink);
1017
1018                 if (! $destsources{$bestlink}) {
1019                         return $linktext unless length $config{cgiurl};
1020                         return "<span class=\"createlink\"><a href=\"".
1021                                 cgiurl(
1022                                         do => "create",
1023                                         page => lc($link),
1024                                         from => $lpage
1025                                 ).
1026                                 "\" rel=\"nofollow\">?</a>$linktext</span>"
1027                 }
1028         }
1029
1030         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1031         $bestlink=beautify_urlpath($bestlink);
1032
1033         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1034                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1035         }
1036
1037         if (defined $opts{anchor}) {
1038                 $bestlink.="#".$opts{anchor};
1039         }
1040
1041         my @attrs;
1042         if (defined $opts{rel}) {
1043                 push @attrs, ' rel="'.$opts{rel}.'"';
1044         }
1045         if (defined $opts{class}) {
1046                 push @attrs, ' class="'.$opts{class}.'"';
1047         }
1048
1049         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1050 }
1051
1052 sub userlink ($) {
1053         my $user=shift;
1054
1055         my $oiduser=eval { openiduser($user) };
1056         if (defined $oiduser) {
1057                 return "<a href=\"$user\">$oiduser</a>";
1058         }
1059         else {
1060                 eval q{use CGI 'escapeHTML'};
1061                 error($@) if $@;
1062
1063                 return htmllink("", "", escapeHTML(
1064                         length $config{userdir} ? $config{userdir}."/".$user : $user
1065                 ), noimageinline => 1);
1066         }
1067 }
1068
1069 sub htmlize ($$$$) {
1070         my $page=shift;
1071         my $destpage=shift;
1072         my $type=shift;
1073         my $content=shift;
1074
1075         my $oneline = $content !~ /\n/;
1076
1077         if (exists $hooks{htmlize}{$type}) {
1078                 $content=$hooks{htmlize}{$type}{call}->(
1079                         page => $page,
1080                         content => $content,
1081                 );
1082         }
1083         else {
1084                 error("htmlization of $type not supported");
1085         }
1086
1087         run_hooks(sanitize => sub {
1088                 $content=shift->(
1089                         page => $page,
1090                         destpage => $destpage,
1091                         content => $content,
1092                 );
1093         });
1094
1095         if ($oneline) {
1096                 # hack to get rid of enclosing junk added by markdown
1097                 # and other htmlizers
1098                 $content=~s/^<p>//i;
1099                 $content=~s/<\/p>$//i;
1100                 chomp $content;
1101         }
1102
1103         return $content;
1104 }
1105
1106 sub linkify ($$$) {
1107         my $page=shift;
1108         my $destpage=shift;
1109         my $content=shift;
1110
1111         run_hooks(linkify => sub {
1112                 $content=shift->(
1113                         page => $page,
1114                         destpage => $destpage,
1115                         content => $content,
1116                 );
1117         });
1118
1119         return $content;
1120 }
1121
1122 our %preprocessing;
1123 our $preprocess_preview=0;
1124 sub preprocess ($$$;$$) {
1125         my $page=shift; # the page the data comes from
1126         my $destpage=shift; # the page the data will appear in (different for inline)
1127         my $content=shift;
1128         my $scan=shift;
1129         my $preview=shift;
1130
1131         # Using local because it needs to be set within any nested calls
1132         # of this function.
1133         local $preprocess_preview=$preview if defined $preview;
1134
1135         my $handle=sub {
1136                 my $escape=shift;
1137                 my $prefix=shift;
1138                 my $command=shift;
1139                 my $params=shift;
1140                 $params="" if ! defined $params;
1141
1142                 if (length $escape) {
1143                         return "[[$prefix$command $params]]";
1144                 }
1145                 elsif (exists $hooks{preprocess}{$command}) {
1146                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1147                         # Note: preserve order of params, some plugins may
1148                         # consider it significant.
1149                         my @params;
1150                         while ($params =~ m{
1151                                 (?:([-\w]+)=)?          # 1: named parameter key?
1152                                 (?:
1153                                         """(.*?)"""     # 2: triple-quoted value
1154                                 |
1155                                         "([^"]+)"       # 3: single-quoted value
1156                                 |
1157                                         (\S+)           # 4: unquoted value
1158                                 )
1159                                 (?:\s+|$)               # delimiter to next param
1160                         }sgx) {
1161                                 my $key=$1;
1162                                 my $val;
1163                                 if (defined $2) {
1164                                         $val=$2;
1165                                         $val=~s/\r\n/\n/mg;
1166                                         $val=~s/^\n+//g;
1167                                         $val=~s/\n+$//g;
1168                                 }
1169                                 elsif (defined $3) {
1170                                         $val=$3;
1171                                 }
1172                                 elsif (defined $4) {
1173                                         $val=$4;
1174                                 }
1175
1176                                 if (defined $key) {
1177                                         push @params, $key, $val;
1178                                 }
1179                                 else {
1180                                         push @params, $val, '';
1181                                 }
1182                         }
1183                         if ($preprocessing{$page}++ > 3) {
1184                                 # Avoid loops of preprocessed pages preprocessing
1185                                 # other pages that preprocess them, etc.
1186                                 return "[[!$command <span class=\"error\">".
1187                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1188                                                 $page, $preprocessing{$page}).
1189                                         "</span>]]";
1190                         }
1191                         my $ret;
1192                         if (! $scan) {
1193                                 $ret=eval {
1194                                         $hooks{preprocess}{$command}{call}->(
1195                                                 @params,
1196                                                 page => $page,
1197                                                 destpage => $destpage,
1198                                                 preview => $preprocess_preview,
1199                                         );
1200                                 };
1201                                 if ($@) {
1202                                         chomp $@;
1203                                         $ret="[[!$command <span class=\"error\">".
1204                                                 gettext("Error").": $@"."</span>]]";
1205                                 }
1206                         }
1207                         else {
1208                                 # use void context during scan pass
1209                                 eval {
1210                                         $hooks{preprocess}{$command}{call}->(
1211                                                 @params,
1212                                                 page => $page,
1213                                                 destpage => $destpage,
1214                                                 preview => $preprocess_preview,
1215                                         );
1216                                 };
1217                                 $ret="";
1218                         }
1219                         $preprocessing{$page}--;
1220                         return $ret;
1221                 }
1222                 else {
1223                         return "[[$prefix$command $params]]";
1224                 }
1225         };
1226
1227         my $regex;
1228         if ($config{prefix_directives}) {
1229                 $regex = qr{
1230                         (\\?)           # 1: escape?
1231                         \[\[(!)         # directive open; 2: prefix
1232                         ([-\w]+)        # 3: command
1233                         (               # 4: the parameters..
1234                                 \s+     # Must have space if parameters present
1235                                 (?:
1236                                         (?:[-\w]+=)?            # named parameter key?
1237                                         (?:
1238                                                 """.*?"""       # triple-quoted value
1239                                                 |
1240                                                 "[^"]+"         # single-quoted value
1241                                                 |
1242                                                 [^\s\]]+        # unquoted value
1243                                         )
1244                                         \s*                     # whitespace or end
1245                                                                 # of directive
1246                                 )
1247                         *)?             # 0 or more parameters
1248                         \]\]            # directive closed
1249                 }sx;
1250         }
1251         else {
1252                 $regex = qr{
1253                         (\\?)           # 1: escape?
1254                         \[\[(!?)        # directive open; 2: optional prefix
1255                         ([-\w]+)        # 3: command
1256                         \s+
1257                         (               # 4: the parameters..
1258                                 (?:
1259                                         (?:[-\w]+=)?            # named parameter key?
1260                                         (?:
1261                                                 """.*?"""       # triple-quoted value
1262                                                 |
1263                                                 "[^"]+"         # single-quoted value
1264                                                 |
1265                                                 [^\s\]]+        # unquoted value
1266                                         )
1267                                         \s*                     # whitespace or end
1268                                                                 # of directive
1269                                 )
1270                         *)              # 0 or more parameters
1271                         \]\]            # directive closed
1272                 }sx;
1273         }
1274
1275         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1276         return $content;
1277 }
1278
1279 sub filter ($$$) {
1280         my $page=shift;
1281         my $destpage=shift;
1282         my $content=shift;
1283
1284         run_hooks(filter => sub {
1285                 $content=shift->(page => $page, destpage => $destpage,
1286                         content => $content);
1287         });
1288
1289         return $content;
1290 }
1291
1292 sub indexlink () {
1293         return "<a href=\"$config{url}\">$config{wikiname}</a>";
1294 }
1295
1296 sub check_canedit ($$$;$) {
1297         my $page=shift;
1298         my $q=shift;
1299         my $session=shift;
1300         my $nonfatal=shift;
1301
1302         my $canedit;
1303         run_hooks(canedit => sub {
1304                 return if defined $canedit;
1305                 my $ret=shift->($page, $q, $session);
1306                 if (defined $ret) {
1307                         if ($ret eq "") {
1308                                 $canedit=1;
1309                         }
1310                         elsif (ref $ret eq 'CODE') {
1311                                 $ret->() unless $nonfatal;
1312                                 $canedit=0;
1313                         }
1314                         elsif (defined $ret) {
1315                                 error($ret) unless $nonfatal;
1316                                 $canedit=0;
1317                         }
1318                 }
1319         });
1320         return defined $canedit ? $canedit : 1;
1321 }
1322
1323 sub check_content (@) {
1324         my %params=@_;
1325
1326         return 1 if ! exists $hooks{checkcontent}; # optimisation
1327
1328         if (exists $pagesources{$params{page}}) {
1329                 my @diff;
1330                 my %old=map { $_ => 1 }
1331                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1332                 foreach my $line (split("\n", $params{content})) {
1333                         push @diff, $line if ! exists $old{$_};
1334                 }
1335                 $params{content}=join("\n", @diff);
1336         }
1337
1338         my $ok;
1339         run_hooks(checkcontent => sub {
1340                 return if defined $ok;
1341                 my $ret=shift->(%params);
1342                 if (defined $ret) {
1343                         if ($ret eq "") {
1344                                 $ok=1;
1345                         }
1346                         elsif (ref $ret eq 'CODE') {
1347                                 $ret->() unless $params{nonfatal};
1348                                 $ok=0;
1349                         }
1350                         elsif (defined $ret) {
1351                                 error($ret) unless $params{nonfatal};
1352                                 $ok=0;
1353                         }
1354                 }
1355
1356         });
1357         return defined $ok ? $ok : 1;
1358 }
1359
1360 my $wikilock;
1361
1362 sub lockwiki () {
1363         # Take an exclusive lock on the wiki to prevent multiple concurrent
1364         # run issues. The lock will be dropped on program exit.
1365         if (! -d $config{wikistatedir}) {
1366                 mkdir($config{wikistatedir});
1367         }
1368         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1369                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1370         if (! flock($wikilock, 2)) { # LOCK_EX
1371                 error("failed to get lock");
1372         }
1373         return 1;
1374 }
1375
1376 sub unlockwiki () {
1377         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1378         return close($wikilock) if $wikilock;
1379         return;
1380 }
1381
1382 my $commitlock;
1383
1384 sub commit_hook_enabled () {
1385         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1386                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1387         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1388                 close($commitlock) || error("failed closing commitlock: $!");
1389                 return 0;
1390         }
1391         close($commitlock) || error("failed closing commitlock: $!");
1392         return 1;
1393 }
1394
1395 sub disable_commit_hook () {
1396         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1397                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1398         if (! flock($commitlock, 2)) { # LOCK_EX
1399                 error("failed to get commit lock");
1400         }
1401         return 1;
1402 }
1403
1404 sub enable_commit_hook () {
1405         return close($commitlock) if $commitlock;
1406         return;
1407 }
1408
1409 sub loadindex () {
1410         %oldrenderedfiles=%pagectime=();
1411         if (! $config{rebuild}) {
1412                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1413                 %destsources=%renderedfiles=%pagecase=%pagestate=();
1414         }
1415         my $in;
1416         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1417                 if (-e "$config{wikistatedir}/index") {
1418                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1419                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1420                 }
1421                 else {
1422                         return;
1423                 }
1424         }
1425
1426         my $index=Storable::fd_retrieve($in);
1427         if (! defined $index) {
1428                 return 0;
1429         }
1430
1431         my $pages;
1432         if (exists $index->{version} && ! ref $index->{version}) {
1433                 $pages=$index->{page};
1434                 %wikistate=%{$index->{state}};
1435         }
1436         else {
1437                 $pages=$index;
1438                 %wikistate=();
1439         }
1440
1441         foreach my $src (keys %$pages) {
1442                 my $d=$pages->{$src};
1443                 my $page=pagename($src);
1444                 $pagectime{$page}=$d->{ctime};
1445                 if (! $config{rebuild}) {
1446                         $pagesources{$page}=$src;
1447                         $pagemtime{$page}=$d->{mtime};
1448                         $renderedfiles{$page}=$d->{dest};
1449                         if (exists $d->{links} && ref $d->{links}) {
1450                                 $links{$page}=$d->{links};
1451                                 $oldlinks{$page}=[@{$d->{links}}];
1452                         }
1453                         if (exists $d->{depends}) {
1454                                 $depends{$page}=$d->{depends};
1455                         }
1456                         if (exists $d->{state}) {
1457                                 $pagestate{$page}=$d->{state};
1458                         }
1459                 }
1460                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1461         }
1462         foreach my $page (keys %pagesources) {
1463                 $pagecase{lc $page}=$page;
1464         }
1465         foreach my $page (keys %renderedfiles) {
1466                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1467         }
1468         return close($in);
1469 }
1470
1471 sub saveindex () {
1472         run_hooks(savestate => sub { shift->() });
1473
1474         my %hookids;
1475         foreach my $type (keys %hooks) {
1476                 $hookids{$_}=1 foreach keys %{$hooks{$type}};
1477         }
1478         my @hookids=keys %hookids;
1479
1480         if (! -d $config{wikistatedir}) {
1481                 mkdir($config{wikistatedir});
1482         }
1483         my $newfile="$config{wikistatedir}/indexdb.new";
1484         my $cleanup = sub { unlink($newfile) };
1485         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1486
1487         my %index;
1488         foreach my $page (keys %pagemtime) {
1489                 next unless $pagemtime{$page};
1490                 my $src=$pagesources{$page};
1491
1492                 $index{page}{$src}={
1493                         ctime => $pagectime{$page},
1494                         mtime => $pagemtime{$page},
1495                         dest => $renderedfiles{$page},
1496                         links => $links{$page},
1497                 };
1498
1499                 if (exists $depends{$page}) {
1500                         $index{page}{$src}{depends} = $depends{$page};
1501                 }
1502
1503                 if (exists $pagestate{$page}) {
1504                         foreach my $id (@hookids) {
1505                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1506                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1507                                 }
1508                         }
1509                 }
1510         }
1511
1512         $index{state}={};
1513         foreach my $id (@hookids) {
1514                 foreach my $key (keys %{$wikistate{$id}}) {
1515                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1516                 }
1517         }
1518
1519         $index{version}="3";
1520         my $ret=Storable::nstore_fd(\%index, $out);
1521         return if ! defined $ret || ! $ret;
1522         close $out || error("failed saving to $newfile: $!", $cleanup);
1523         rename($newfile, "$config{wikistatedir}/indexdb") ||
1524                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1525
1526         return 1;
1527 }
1528
1529 sub template_file ($) {
1530         my $template=shift;
1531
1532         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
1533                 return "$dir/$template" if -e "$dir/$template";
1534         }
1535         return;
1536 }
1537
1538 sub template_params (@) {
1539         my $filename=template_file(shift);
1540
1541         if (! defined $filename) {
1542                 return if wantarray;
1543                 return "";
1544         }
1545
1546         my @ret=(
1547                 filter => sub {
1548                         my $text_ref = shift;
1549                         ${$text_ref} = decode_utf8(${$text_ref});
1550                 },
1551                 filename => $filename,
1552                 loop_context_vars => 1,
1553                 die_on_bad_params => 0,
1554                 @_
1555         );
1556         return wantarray ? @ret : {@ret};
1557 }
1558
1559 sub template ($;@) {
1560         require HTML::Template;
1561         return HTML::Template->new(template_params(@_));
1562 }
1563
1564 sub misctemplate ($$;@) {
1565         my $title=shift;
1566         my $pagebody=shift;
1567
1568         my $template=template("misc.tmpl");
1569         $template->param(
1570                 title => $title,
1571                 indexlink => indexlink(),
1572                 wikiname => $config{wikiname},
1573                 pagebody => $pagebody,
1574                 baseurl => baseurl(),
1575                 @_,
1576         );
1577         run_hooks(pagetemplate => sub {
1578                 shift->(page => "", destpage => "", template => $template);
1579         });
1580         return $template->output;
1581 }
1582
1583 sub hook (@) {
1584         my %param=@_;
1585
1586         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1587                 error 'hook requires type, call, and id parameters';
1588         }
1589
1590         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1591
1592         $hooks{$param{type}}{$param{id}}=\%param;
1593         return 1;
1594 }
1595
1596 sub run_hooks ($$) {
1597         # Calls the given sub for each hook of the given type,
1598         # passing it the hook function to call.
1599         my $type=shift;
1600         my $sub=shift;
1601
1602         if (exists $hooks{$type}) {
1603                 my (@first, @middle, @last);
1604                 foreach my $id (keys %{$hooks{$type}}) {
1605                         if ($hooks{$type}{$id}{first}) {
1606                                 push @first, $id;
1607                         }
1608                         elsif ($hooks{$type}{$id}{last}) {
1609                                 push @last, $id;
1610                         }
1611                         else {
1612                                 push @middle, $id;
1613                         }
1614                 }
1615                 foreach my $id (@first, @middle, @last) {
1616                         $sub->($hooks{$type}{$id}{call});
1617                 }
1618         }
1619
1620         return 1;
1621 }
1622
1623 sub rcs_update () {
1624         $hooks{rcs}{rcs_update}{call}->(@_);
1625 }
1626
1627 sub rcs_prepedit ($) {
1628         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1629 }
1630
1631 sub rcs_commit ($$$;$$) {
1632         $hooks{rcs}{rcs_commit}{call}->(@_);
1633 }
1634
1635 sub rcs_commit_staged ($$$) {
1636         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1637 }
1638
1639 sub rcs_add ($) {
1640         $hooks{rcs}{rcs_add}{call}->(@_);
1641 }
1642
1643 sub rcs_remove ($) {
1644         $hooks{rcs}{rcs_remove}{call}->(@_);
1645 }
1646
1647 sub rcs_rename ($$) {
1648         $hooks{rcs}{rcs_rename}{call}->(@_);
1649 }
1650
1651 sub rcs_recentchanges ($) {
1652         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1653 }
1654
1655 sub rcs_diff ($) {
1656         $hooks{rcs}{rcs_diff}{call}->(@_);
1657 }
1658
1659 sub rcs_getctime ($) {
1660         $hooks{rcs}{rcs_getctime}{call}->(@_);
1661 }
1662
1663 sub rcs_receive () {
1664         $hooks{rcs}{rcs_receive}{call}->();
1665 }
1666
1667 sub safequote ($) {
1668         my $s=shift;
1669         $s=~s/[{}]//g;
1670         return "q{$s}";
1671 }
1672
1673 sub add_depends ($$) {
1674         my $page=shift;
1675         my $pagespec=shift;
1676
1677         return unless pagespec_valid($pagespec);
1678
1679         if (! exists $depends{$page}) {
1680                 $depends{$page}=$pagespec;
1681         }
1682         else {
1683                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1684         }
1685
1686         return 1;
1687 }
1688
1689 sub file_pruned ($$) {
1690         require File::Spec;
1691         my $file=File::Spec->canonpath(shift);
1692         my $base=File::Spec->canonpath(shift);
1693         $file =~ s#^\Q$base\E/+##;
1694
1695         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1696         return $file =~ m/$regexp/ && $file ne $base;
1697 }
1698
1699 sub gettext {
1700         # Only use gettext in the rare cases it's needed.
1701         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1702             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1703             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1704                 if (! $gettext_obj) {
1705                         $gettext_obj=eval q{
1706                                 use Locale::gettext q{textdomain};
1707                                 Locale::gettext->domain('ikiwiki')
1708                         };
1709                         if ($@) {
1710                                 print STDERR "$@";
1711                                 $gettext_obj=undef;
1712                                 return shift;
1713                         }
1714                 }
1715                 return $gettext_obj->get(shift);
1716         }
1717         else {
1718                 return shift;
1719         }
1720 }
1721
1722 sub yesno ($) {
1723         my $val=shift;
1724
1725         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
1726 }
1727
1728 sub inject {
1729         # Injects a new function into the symbol table to replace an
1730         # exported function.
1731         my %params=@_;
1732
1733         # This is deep ugly perl foo, beware.
1734         no strict;
1735         no warnings;
1736         if (! defined $params{parent}) {
1737                 $params{parent}='::';
1738                 $params{old}=\&{$params{name}};
1739                 $params{name}=~s/.*:://;
1740         }
1741         my $parent=$params{parent};
1742         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
1743                 $ns = $params{parent} . $ns;
1744                 inject(%params, parent => $ns) unless $ns eq '::main::';
1745                 *{$ns . $params{name}} = $params{call}
1746                         if exists ${$ns}{$params{name}} &&
1747                            \&{${$ns}{$params{name}}} == $params{old};
1748         }
1749         use strict;
1750         use warnings;
1751 }
1752
1753 sub pagespec_merge ($$) {
1754         my $a=shift;
1755         my $b=shift;
1756
1757         return $a if $a eq $b;
1758         return "($a) or ($b)";
1759 }
1760
1761 sub pagespec_translate ($) {
1762         my $spec=shift;
1763
1764         # Convert spec to perl code.
1765         my $code="";
1766         while ($spec=~m{
1767                 \s*             # ignore whitespace
1768                 (               # 1: match a single word
1769                         \!              # !
1770                 |
1771                         \(              # (
1772                 |
1773                         \)              # )
1774                 |
1775                         \w+\([^\)]*\)   # command(params)
1776                 |
1777                         [^\s()]+        # any other text
1778                 )
1779                 \s*             # ignore whitespace
1780         }igx) {
1781                 my $word=$1;
1782                 if (lc $word eq 'and') {
1783                         $code.=' &&';
1784                 }
1785                 elsif (lc $word eq 'or') {
1786                         $code.=' ||';
1787                 }
1788                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1789                         $code.=' '.$word;
1790                 }
1791                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1792                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1793                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@_)";
1794                         }
1795                         else {
1796                                 $code.="IkiWiki::FailReason->new(".safequote(qq{unknown function in pagespec "$word"}).")";
1797                         }
1798                 }
1799                 else {
1800                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@_)";
1801                 }
1802         }
1803
1804         if (! length $code) {
1805                 $code="IkiWiki::FailReason->new('empty pagespec')";
1806         }
1807
1808         no warnings;
1809         return eval 'sub { my $page=shift; '.$code.' }';
1810 }
1811
1812 sub pagespec_match ($$;@) {
1813         my $page=shift;
1814         my $spec=shift;
1815         my @params=@_;
1816
1817         # Backwards compatability with old calling convention.
1818         if (@params == 1) {
1819                 unshift @params, 'location';
1820         }
1821
1822         my $sub=pagespec_translate($spec);
1823         return IkiWiki::FailReason->new("syntax error in pagespec \"$spec\"")
1824                 if $@ || ! defined $sub;
1825         return $sub->($page, @params);
1826 }
1827
1828 sub pagespec_valid ($) {
1829         my $spec=shift;
1830
1831         my $sub=pagespec_translate($spec);
1832         return ! $@;
1833 }
1834
1835 sub glob2re ($) {
1836         my $re=quotemeta(shift);
1837         $re=~s/\\\*/.*/g;
1838         $re=~s/\\\?/./g;
1839         return $re;
1840 }
1841
1842 package IkiWiki::FailReason;
1843
1844 use overload (
1845         '""'    => sub { ${$_[0]} },
1846         '0+'    => sub { 0 },
1847         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1848         fallback => 1,
1849 );
1850
1851 sub new {
1852         my $class = shift;
1853         my $value = shift;
1854         return bless \$value, $class;
1855 }
1856
1857 package IkiWiki::SuccessReason;
1858
1859 use overload (
1860         '""'    => sub { ${$_[0]} },
1861         '0+'    => sub { 1 },
1862         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1863         fallback => 1,
1864 );
1865
1866 sub new {
1867         my $class = shift;
1868         my $value = shift;
1869         return bless \$value, $class;
1870 };
1871
1872 package IkiWiki::PageSpec;
1873
1874 sub derel ($$) {
1875         my $path=shift;
1876         my $from=shift;
1877
1878         if ($path =~ m!^\./!) {
1879                 $from=~s#/?[^/]+$## if defined $from;
1880                 $path=~s#^\./##;
1881                 $path="$from/$path" if length $from;
1882         }
1883
1884         return $path;
1885 }
1886
1887 sub match_glob ($$;@) {
1888         my $page=shift;
1889         my $glob=shift;
1890         my %params=@_;
1891
1892         $glob=derel($glob, $params{location});
1893
1894         my $regexp=IkiWiki::glob2re($glob);
1895         if ($page=~/^$regexp$/i) {
1896                 if (! IkiWiki::isinternal($page) || $params{internal}) {
1897                         return IkiWiki::SuccessReason->new("$glob matches $page");
1898                 }
1899                 else {
1900                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
1901                 }
1902         }
1903         else {
1904                 return IkiWiki::FailReason->new("$glob does not match $page");
1905         }
1906 }
1907
1908 sub match_internal ($$;@) {
1909         return match_glob($_[0], $_[1], @_, internal => 1)
1910 }
1911
1912 sub match_link ($$;@) {
1913         my $page=shift;
1914         my $link=lc(shift);
1915         my %params=@_;
1916
1917         $link=derel($link, $params{location});
1918         my $from=exists $params{location} ? $params{location} : '';
1919
1920         my $links = $IkiWiki::links{$page};
1921         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1922         my $bestlink = IkiWiki::bestlink($from, $link);
1923         foreach my $p (@{$links}) {
1924                 if (length $bestlink) {
1925                         return IkiWiki::SuccessReason->new("$page links to $link")
1926                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1927                 }
1928                 else {
1929                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1930                                 if match_glob($p, $link, %params);
1931                         $p=~s/^\///;
1932                         $link=~s/^\///;
1933                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1934                                 if match_glob($p, $link, %params);
1935                 }
1936         }
1937         return IkiWiki::FailReason->new("$page does not link to $link");
1938 }
1939
1940 sub match_backlink ($$;@) {
1941         return match_link($_[1], $_[0], @_);
1942 }
1943
1944 sub match_created_before ($$;@) {
1945         my $page=shift;
1946         my $testpage=shift;
1947         my %params=@_;
1948
1949         $testpage=derel($testpage, $params{location});
1950
1951         if (exists $IkiWiki::pagectime{$testpage}) {
1952                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1953                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1954                 }
1955                 else {
1956                         return IkiWiki::FailReason->new("$page not created before $testpage");
1957                 }
1958         }
1959         else {
1960                 return IkiWiki::FailReason->new("$testpage has no ctime");
1961         }
1962 }
1963
1964 sub match_created_after ($$;@) {
1965         my $page=shift;
1966         my $testpage=shift;
1967         my %params=@_;
1968
1969         $testpage=derel($testpage, $params{location});
1970
1971         if (exists $IkiWiki::pagectime{$testpage}) {
1972                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1973                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1974                 }
1975                 else {
1976                         return IkiWiki::FailReason->new("$page not created after $testpage");
1977                 }
1978         }
1979         else {
1980                 return IkiWiki::FailReason->new("$testpage has no ctime");
1981         }
1982 }
1983
1984 sub match_creation_day ($$;@) {
1985         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1986                 return IkiWiki::SuccessReason->new('creation_day matched');
1987         }
1988         else {
1989                 return IkiWiki::FailReason->new('creation_day did not match');
1990         }
1991 }
1992
1993 sub match_creation_month ($$;@) {
1994         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1995                 return IkiWiki::SuccessReason->new('creation_month matched');
1996         }
1997         else {
1998                 return IkiWiki::FailReason->new('creation_month did not match');
1999         }
2000 }
2001
2002 sub match_creation_year ($$;@) {
2003         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
2004                 return IkiWiki::SuccessReason->new('creation_year matched');
2005         }
2006         else {
2007                 return IkiWiki::FailReason->new('creation_year did not match');
2008         }
2009 }
2010
2011 sub match_user ($$;@) {
2012         shift;
2013         my $user=shift;
2014         my %params=@_;
2015
2016         if (! exists $params{user}) {
2017                 return IkiWiki::FailReason->new("no user specified");
2018         }
2019
2020         if (defined $params{user} && lc $params{user} eq lc $user) {
2021                 return IkiWiki::SuccessReason->new("user is $user");
2022         }
2023         elsif (! defined $params{user}) {
2024                 return IkiWiki::FailReason->new("not logged in");
2025         }
2026         else {
2027                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2028         }
2029 }
2030
2031 sub match_admin ($$;@) {
2032         shift;
2033         shift;
2034         my %params=@_;
2035
2036         if (! exists $params{user}) {
2037                 return IkiWiki::FailReason->new("no user specified");
2038         }
2039
2040         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2041                 return IkiWiki::SuccessReason->new("user is an admin");
2042         }
2043         elsif (! defined $params{user}) {
2044                 return IkiWiki::FailReason->new("not logged in");
2045         }
2046         else {
2047                 return IkiWiki::FailReason->new("user is not an admin");
2048         }
2049 }
2050
2051 sub match_ip ($$;@) {
2052         shift;
2053         my $ip=shift;
2054         my %params=@_;
2055
2056         if (! exists $params{ip}) {
2057                 return IkiWiki::FailReason->new("no IP specified");
2058         }
2059
2060         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2061                 return IkiWiki::SuccessReason->new("IP is $ip");
2062         }
2063         else {
2064                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2065         }
2066 }
2067
2068 1