IkiWiki/Plugin/linkmap.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::linkmap;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7 use IPC::Open2;
   8
   9 sub import { #{{{
  10         hook(type => "preprocess", id => "linkmap", call => \&preprocess);
  11         hook(type => "format", id => "linkmap", call => \&format);
  12 } # }}}
  13
  14 my $mapnum=0;
  15 my %maps;
  16
  17 sub preprocess (@) { #{{{
  18         my %params=@_;
  19
  20         $params{pages}="*" unless defined $params{pages};
  21
  22         # Needs to update whenever a page is added or removed, so
  23         # register a dependency.
  24         add_depends($params{page}, $params{pages});
  25
  26         # Can't just return the linkmap here, since the htmlscrubber
  27         # scrubs out all <object> tags (with good reason!)
  28         # Instead, insert a placeholder tag, which will be expanded during
  29         # formatting.
  30         $mapnum++;
  31         $maps{$mapnum}=\%params;
  32         return "<div class=\"linkmap$mapnum\"></div>";
  33 } # }}}
  34
  35 sub format (@) { #{{{
  36         my %params=@_;
  37
  38         $params{content}=~s/<div class=\"linkmap(\d+)"><\/div>/genmap($1)/eg;
  39
  40         return $params{content};
  41 } # }}}
  42
  43 sub genmap ($) { #{{{
  44         my $mapnum=shift;
  45         return "" unless exists $maps{$mapnum};
  46         my %params=%{$maps{$mapnum}};
  47
  48         # Get all the items to map.
  49         my %mapitems = ();
  50         foreach my $item (keys %links) {
  51                 if (pagespec_match($item, $params{pages}, location => $params{page})) {
  52                         $mapitems{$item}=urlto($item, $params{destpage});
  53                 }
  54         }
  55
  56         my $dest=$params{page}."/linkmap.png";
  57
  58         # Use ikiwiki's function to create the file, this makes sure needed
  59         # subdirs are there and does some sanity checking.
  60         will_render($params{page}, $dest);
  61         writefile($dest, $config{destdir}, "");
  62
  63         # Run dot to create the graphic and get the map data.
  64         my $pid;
  65         my $sigpipe=0;
  66         $SIG{PIPE}=sub { $sigpipe=1 };
  67         $pid=open2(*IN, *OUT, "dot -Tpng -o '$config{destdir}/$dest' -Tcmapx");
  68
  69         # open2 doesn't respect "use open ':utf8'"
  70         binmode (IN, ':utf8');
  71         binmode (OUT, ':utf8');
  72
  73         print OUT "digraph linkmap$mapnum {\n";
  74         print OUT "concentrate=true;\n";
  75         print OUT "charset=\"utf-8\";\n";
  76         print OUT "ratio=compress;\nsize=\"".($params{width}+0).", ".($params{height}+0)."\";\n"
  77                 if defined $params{width} and defined $params{height};
  78         foreach my $item (keys %mapitems) {
  79                 print OUT "\"$item\" [shape=box,href=\"$mapitems{$item}\"];\n";
  80                 foreach my $link (map { bestlink($item, $_) } @{$links{$item}}) {
  81                         print OUT "\"$item\" -> \"$link\";\n"
  82                                 if $mapitems{$link};
  83                 }
  84         }
  85         print OUT "}\n";
  86         close OUT;
  87
  88         local $/=undef;
  89         my $ret="<object data=\"".urlto($dest, $params{destpage}).
  90                "\" type=\"image/png\" usemap=\"#linkmap$mapnum\">\n".
  91                 <IN>.
  92                 "</object>";
  93         close IN;
  94
  95         waitpid $pid, 0;
  96         $SIG{PIPE}="DEFAULT";
  97         error gettext("failed to run dot") if $sigpipe;
  98
  99         return $ret;
 100 } #}}}
 101
 102 1