t/img.t

   1 #!/usr/bin/perl
   2 #
   3 # unit test that creates test images (png, svg, multi-page pdf), runs ikiwiki
   4 # on them, checks the resulting images for plausibility based on their image
   5 # sizes, and checks if they vanish when not required in the build process any
   6 # more
   7 #
   8 # if you have trouble here, be aware that there are three debian packages that
   9 # can provide Image::Magick: perlmagick, libimage-magick-perl and
  10 # graphicsmagick-libmagick-dev-compat
  11 #
  12 package IkiWiki;
  13
  14 use warnings;
  15 use strict;
  16 use Test::More;
  17 plan(skip_all => "Image::Magick not available")
  18         unless eval q{use Image::Magick; 1};
  19
  20 use IkiWiki;
  21
  22 my $installed = $ENV{INSTALLED_TESTS};
  23
  24 my @command;
  25 if ($installed) {
  26         @command = qw(ikiwiki);
  27 }
  28 else {
  29         ok(! system("make -s ikiwiki.out"));
  30         @command = qw(perl -I. ./ikiwiki.out
  31                 --underlaydir=underlays/basewiki
  32                 --set underlaydirbase=underlays
  33                 --templatedir=templates);
  34 }
  35
  36 push @command, qw(--set usedirs=0 --plugin img t/tmp/in t/tmp/out --verbose);
  37
  38 my $magick = new Image::Magick;
  39 my $SVGS_WORK = defined $magick->QueryFormat("svg");
  40
  41 $magick->Read("t/img/twopages.pdf");
  42 my $PDFS_WORK = defined $magick->Get("width");
  43
  44 ok(! system("rm -rf t/tmp; mkdir -p t/tmp/in"));
  45
  46 ok(! system("cp t/img/redsquare.png t/tmp/in/redsquare.png"));
  47 # colons in filenames are a corner case for img
  48 ok(! system("cp t/img/redsquare.png t/tmp/in/hello:world.png"));
  49 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c.png"));
  50 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d.png"));
  51 ok(! system("cp t/img/redsquare.png t/tmp/in/a:b:c:d:e:f:g:h:i:j.png"));
  52
  53 if ($SVGS_WORK) {
  54         writefile("bluesquare.svg", "t/tmp/in",
  55                 '<svg width="30" height="30"><rect x="0" y="0" width="30" height="30" fill="blue"/></svg>');
  56 }
  57
  58 # using different image sizes for different pages, so the pagenumber selection can be tested easily
  59 ok(! system("cp t/img/twopages.pdf t/tmp/in/twopages.pdf"));
  60
  61 my $maybe_svg_img = "";
  62 if ($SVGS_WORK) {
  63         $maybe_svg_img = "[[!img bluesquare.svg size=10x]]";
  64 }
  65
  66 my $maybe_pdf_img = "";
  67 if ($PDFS_WORK) {
  68         $maybe_pdf_img = <<EOF;
  69 [[!img twopages.pdf size=12x]]
  70 [[!img twopages.pdf size=16x pagenumber=1]]
  71 EOF
  72 }
  73
  74 writefile("imgconversions.mdwn", "t/tmp/in", <<EOF
  75 [[!img redsquare.png]]
  76 [[!img redsquare.png size=10x]]
  77 [[!img redsquare.png size=30x50]] expecting 30x30
  78 [[!img hello:world.png size=x8]] expecting 8x8
  79 [[!img a:b:c.png size=x4]]
  80 [[!img a:b:c:d:e:f:g:h:i:j.png size=x6]]
  81 $maybe_svg_img
  82 $maybe_pdf_img
  83 EOF
  84 );
  85 ok(utime(333333333, 333333333, "t/tmp/in/imgconversions.mdwn"));
  86
  87 ok(! system(@command));
  88
  89 sub size($) {
  90         my $filename = shift;
  91         my $im = Image::Magick->new();
  92         my $r = $im->Read(":$filename");
  93         return "no image" if $r;
  94         my $w = $im->Get("width");
  95         my $h = $im->Get("height");
  96         return "${w}x${h}";
  97 }
  98
  99 my $outpath = "t/tmp/out/imgconversions";
 100 my $outhtml = readfile("$outpath.html");
 101
 102 is(size("$outpath/10x-redsquare.png"), "10x10");
 103 ok(! -e "$outpath/30x-redsquare.png");
 104 ok($outhtml =~ /width="30" height="30".*expecting 30x30/);
 105
 106 SKIP: {
 107         skip "SVG support not installed (try libmagickcore-extra)", 1
 108                 unless $SVGS_WORK;
 109         # if this fails, you need libmagickcore-6.q16-2-extra installed
 110         is(size("$outpath/10x-bluesquare.png"), "10x10");
 111 }
 112
 113 SKIP: {
 114         skip "PDF support not installed (try ghostscript)", 2
 115                 unless $PDFS_WORK;
 116         is(size("$outpath/12x-twopages.png"), "12x12");
 117         is(size("$outpath/16x-p1-twopages.png"), "16x2");
 118 }
 119
 120 ok($outhtml =~ /width="8" height="8".*expecting 8x8/);
 121 is(size("$outpath/x8-hello:world.png"), "8x8");
 122 is(size("$outpath/x4-a:b:c.png"), "4x4");
 123 is(size("$outpath/x6-a:b:c:d:e:f:g:h:i:j.png"), "6x6");
 124
 125 # now let's remove them again
 126
 127 if (1) { # for easier testing
 128         writefile("imgconversions.mdwn", "t/tmp/in", "nothing to see here");
 129
 130         ok(! system(@command, "--refresh"));
 131
 132         ok(! -e "$outpath/10x-redsquare.png");
 133         ok(! -e "$outpath/10x-bluesquare.png");
 134         ok(! -e "$outpath/12x-twopages.png");
 135         ok(! -e "$outpath/16x-p1-twopages.png");
 136         ok(! -e "$outpath/x8-hello:world.png");
 137         ok(! -e "$outpath/x4-a:b:c.png");
 138         ok(! -e "$outpath/x6-a:b:c:d:e:f:g:h:i:j.png");
 139
 140         # cleanup
 141         ok(! system("rm -rf t/tmp"));
 142 }
 143 done_testing;
 144
 145 1;