IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild $gettext_obj};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render gettext
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version, next is ikiwiki version
  20 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  21 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  22
  23 # Optimisation.
  24 use Memoize;
  25 memoize("abs2rel");
  26 memoize("pagespec_translate");
  27 memoize("file_pruned");
  28
  29 sub defaultconfig () { #{{{
  30         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  31                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => '',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         rss => 0,
  48         atom => 0,
  49         discussion => 1,
  50         rebuild => 0,
  51         refresh => 0,
  52         getctime => 0,
  53         w3mmode => 0,
  54         wrapper => undef,
  55         wrappermode => undef,
  56         svnrepo => undef,
  57         svnpath => "trunk",
  58         gitorigin_branch => "origin",
  59         gitmaster_branch => "master",
  60         srcdir => undef,
  61         destdir => undef,
  62         pingurl => [],
  63         templatedir => "$installdir/share/ikiwiki/templates",
  64         underlaydir => "$installdir/share/ikiwiki/basewiki",
  65         setup => undef,
  66         adminuser => undef,
  67         adminemail => undef,
  68         plugin => [qw{mdwn inline htmlscrubber passwordauth signinedit
  69                       lockedit conditional}],
  70         timeformat => '%c',
  71         locale => undef,
  72         sslcookie => 0,
  73         httpauth => 0,
  74         userdir => "",
  75 } #}}}
  76
  77 sub checkconfig () { #{{{
  78         # locale stuff; avoid LC_ALL since it overrides everything
  79         if (defined $ENV{LC_ALL}) {
  80                 $ENV{LANG} = $ENV{LC_ALL};
  81                 delete $ENV{LC_ALL};
  82         }
  83         if (defined $config{locale}) {
  84                 eval q{use POSIX};
  85                 error($@) if $@;
  86                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
  87                         $ENV{LANG}=$config{locale};
  88                         $gettext_obj=undef;
  89                 }
  90         }
  91
  92         if ($config{w3mmode}) {
  93                 eval q{use Cwd q{abs_path}};
  94                 error($@) if $@;
  95                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  96                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  97                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  98                         unless $config{cgiurl} =~ m!file:///!;
  99                 $config{url}="file://".$config{destdir};
 100         }
 101
 102         if ($config{cgi} && ! length $config{url}) {
 103                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 104         }
 105
 106         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 107                 unless exists $config{wikistatedir};
 108
 109         if ($config{rcs}) {
 110                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 111                 if ($@) {
 112                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 113                 }
 114         }
 115         else {
 116                 require IkiWiki::Rcs::Stub;
 117         }
 118
 119         run_hooks(checkconfig => sub { shift->() });
 120 } #}}}
 121
 122 sub loadplugins () { #{{{
 123         loadplugin($_) foreach @{$config{plugin}};
 124
 125         run_hooks(getopt => sub { shift->() });
 126         if (grep /^-/, @ARGV) {
 127                 print STDERR "Unknown option: $_\n"
 128                         foreach grep /^-/, @ARGV;
 129                 usage();
 130         }
 131 } #}}}
 132
 133 sub loadplugin ($) { #{{{
 134         my $plugin=shift;
 135
 136         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 137
 138         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 139         eval qq{use $mod};
 140         if ($@) {
 141                 error("Failed to load plugin $mod: $@");
 142         }
 143 } #}}}
 144
 145 sub error ($;$) { #{{{
 146         my $message=shift;
 147         my $cleaner=shift;
 148         if ($config{cgi}) {
 149                 print "Content-type: text/html\n\n";
 150                 print misctemplate(gettext("Error"),
 151                         "<p>".gettext("Error").": $message</p>");
 152         }
 153         log_message(debug => $message) if $config{syslog};
 154         if (defined $cleaner) {
 155                 $cleaner->();
 156         }
 157         die $message."\n";
 158 } #}}}
 159
 160 sub debug ($) { #{{{
 161         return unless $config{verbose};
 162         log_message(debug => @_);
 163 } #}}}
 164
 165 my $log_open=0;
 166 sub log_message ($$) { #{{{
 167         my $type=shift;
 168
 169         if ($config{syslog}) {
 170                 require Sys::Syslog;
 171                 unless ($log_open) {
 172                         Sys::Syslog::setlogsock('unix');
 173                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 174                         $log_open=1;
 175                 }
 176                 eval {
 177                         Sys::Syslog::syslog($type, "%s", join(" ", @_));
 178                 }
 179         }
 180         elsif (! $config{cgi}) {
 181                 print "@_\n";
 182         }
 183         else {
 184                 print STDERR "@_\n";
 185         }
 186 } #}}}
 187
 188 sub possibly_foolish_untaint ($) { #{{{
 189         my $tainted=shift;
 190         my ($untainted)=$tainted=~/(.*)/;
 191         return $untainted;
 192 } #}}}
 193
 194 sub basename ($) { #{{{
 195         my $file=shift;
 196
 197         $file=~s!.*/+!!;
 198         return $file;
 199 } #}}}
 200
 201 sub dirname ($) { #{{{
 202         my $file=shift;
 203
 204         $file=~s!/*[^/]+$!!;
 205         return $file;
 206 } #}}}
 207
 208 sub pagetype ($) { #{{{
 209         my $page=shift;
 210
 211         if ($page =~ /\.([^.]+)$/) {
 212                 return $1 if exists $hooks{htmlize}{$1};
 213         }
 214         return undef;
 215 } #}}}
 216
 217 sub pagename ($) { #{{{
 218         my $file=shift;
 219
 220         my $type=pagetype($file);
 221         my $page=$file;
 222         $page=~s/\Q.$type\E*$// if defined $type;
 223         return $page;
 224 } #}}}
 225
 226 sub htmlpage ($) { #{{{
 227         my $page=shift;
 228
 229         return $page.".html";
 230 } #}}}
 231
 232 sub srcfile ($) { #{{{
 233         my $file=shift;
 234
 235         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 236         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 237         error("internal error: $file cannot be found");
 238 } #}}}
 239
 240 sub readfile ($;$$) { #{{{
 241         my $file=shift;
 242         my $binary=shift;
 243         my $wantfd=shift;
 244
 245         if (-l $file) {
 246                 error("cannot read a symlink ($file)");
 247         }
 248
 249         local $/=undef;
 250         open (IN, $file) || error("failed to read $file: $!");
 251         binmode(IN) if ($binary);
 252         return \*IN if $wantfd;
 253         my $ret=<IN>;
 254         close IN || error("failed to read $file: $!");
 255         return $ret;
 256 } #}}}
 257
 258 sub writefile ($$$;$$) { #{{{
 259         my $file=shift; # can include subdirs
 260         my $destdir=shift; # directory to put file in
 261         my $content=shift;
 262         my $binary=shift;
 263         my $writer=shift;
 264
 265         my $test=$file;
 266         while (length $test) {
 267                 if (-l "$destdir/$test") {
 268                         error("cannot write to a symlink ($test)");
 269                 }
 270                 $test=dirname($test);
 271         }
 272         my $newfile="$destdir/$file.ikiwiki-new";
 273         if (-l $newfile) {
 274                 error("cannot write to a symlink ($newfile)");
 275         }
 276
 277         my $dir=dirname($newfile);
 278         if (! -d $dir) {
 279                 my $d="";
 280                 foreach my $s (split(m!/+!, $dir)) {
 281                         $d.="$s/";
 282                         if (! -d $d) {
 283                                 mkdir($d) || error("failed to create directory $d: $!");
 284                         }
 285                 }
 286         }
 287
 288         my $cleanup = sub { unlink($newfile) };
 289         open (OUT, ">$newfile") || error("failed to write $newfile: $!", $cleanup);
 290         binmode(OUT) if ($binary);
 291         if ($writer) {
 292                 $writer->(\*OUT, $cleanup);
 293         }
 294         else {
 295                 print OUT $content || error("failed writing to $newfile: $!", $cleanup);
 296         }
 297         close OUT || error("failed saving $newfile: $!", $cleanup);
 298         rename($newfile, "$destdir/$file") ||
 299                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 300 } #}}}
 301
 302 my %cleared;
 303 sub will_render ($$;$) { #{{{
 304         my $page=shift;
 305         my $dest=shift;
 306         my $clear=shift;
 307
 308         # Important security check.
 309         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 310             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 311                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 312         }
 313
 314         if (! $clear || $cleared{$page}) {
 315                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 316         }
 317         else {
 318                 $renderedfiles{$page}=[$dest];
 319                 $cleared{$page}=1;
 320         }
 321 } #}}}
 322
 323 sub bestlink ($$) { #{{{
 324         my $page=shift;
 325         my $link=shift;
 326
 327         my $cwd=$page;
 328         if ($link=~s/^\/+//) {
 329                 # absolute links
 330                 $cwd="";
 331         }
 332
 333         do {
 334                 my $l=$cwd;
 335                 $l.="/" if length $l;
 336                 $l.=$link;
 337
 338                 if (exists $links{$l}) {
 339                         return $l;
 340                 }
 341                 elsif (exists $pagecase{lc $l}) {
 342                         return $pagecase{lc $l};
 343                 }
 344         } while $cwd=~s!/?[^/]+$!!;
 345
 346         if (length $config{userdir} && exists $links{"$config{userdir}/".lc($link)}) {
 347                 return "$config{userdir}/".lc($link);
 348         }
 349
 350         #print STDERR "warning: page $page, broken link: $link\n";
 351         return "";
 352 } #}}}
 353
 354 sub isinlinableimage ($) { #{{{
 355         my $file=shift;
 356
 357         $file=~/\.(png|gif|jpg|jpeg)$/i;
 358 } #}}}
 359
 360 sub pagetitle ($;$) { #{{{
 361         my $page=shift;
 362         my $unescaped=shift;
 363
 364         if ($unescaped) {
 365                 $page=~s/__(\d+)__/chr($1)/eg;
 366         }
 367         else {
 368                 $page=~s/__(\d+)__/&#$1;/g;
 369         }
 370         $page=~y/_/ /;
 371
 372         return $page;
 373 } #}}}
 374
 375 sub titlepage ($) { #{{{
 376         my $title=shift;
 377         $title=~y/ /_/;
 378         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 379         return $title;
 380 } #}}}
 381
 382 sub cgiurl (@) { #{{{
 383         my %params=@_;
 384
 385         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 386 } #}}}
 387
 388 sub baseurl (;$) { #{{{
 389         my $page=shift;
 390
 391         return "$config{url}/" if ! defined $page;
 392
 393         $page=~s/[^\/]+$//;
 394         $page=~s/[^\/]+\//..\//g;
 395         return $page;
 396 } #}}}
 397
 398 sub abs2rel ($$) { #{{{
 399         # Work around very innefficient behavior in File::Spec if abs2rel
 400         # is passed two relative paths. It's much faster if paths are
 401         # absolute! (Debian bug #376658; fixed in debian unstable now)
 402         my $path="/".shift;
 403         my $base="/".shift;
 404
 405         require File::Spec;
 406         my $ret=File::Spec->abs2rel($path, $base);
 407         $ret=~s/^// if defined $ret;
 408         return $ret;
 409 } #}}}
 410
 411 sub displaytime ($) { #{{{
 412         my $time=shift;
 413
 414         eval q{use POSIX};
 415         error($@) if $@;
 416         # strftime doesn't know about encodings, so make sure
 417         # its output is properly treated as utf8
 418         return decode_utf8(POSIX::strftime(
 419                         $config{timeformat}, localtime($time)));
 420 } #}}}
 421
 422 sub htmllink ($$$;$$$) { #{{{
 423         my $lpage=shift; # the page doing the linking
 424         my $page=shift; # the page that will contain the link (different for inline)
 425         my $link=shift;
 426         my $noimageinline=shift; # don't turn links into inline html images
 427         my $forcesubpage=shift; # force a link to a subpage
 428         my $linktext=shift; # set to force the link text to something
 429
 430         my $bestlink;
 431         if (! $forcesubpage) {
 432                 $bestlink=bestlink($lpage, $link);
 433         }
 434         else {
 435                 $bestlink="$lpage/".lc($link);
 436         }
 437
 438         $linktext=pagetitle(basename($link)) unless defined $linktext;
 439
 440         return "<span class=\"selflink\">$linktext</span>"
 441                 if length $bestlink && $page eq $bestlink;
 442
 443         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 444                 $bestlink=htmlpage($bestlink);
 445         }
 446         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 447                 return $linktext unless length $config{cgiurl};
 448                 return "<span><a href=\"".
 449                         cgiurl(do => "create", page => lc($link), from => $page).
 450                         "\">?</a>$linktext</span>"
 451         }
 452
 453         $bestlink=abs2rel($bestlink, dirname($page));
 454
 455         if (! $noimageinline && isinlinableimage($bestlink)) {
 456                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 457         }
 458         return "<a href=\"$bestlink\">$linktext</a>";
 459 } #}}}
 460
 461 sub htmlize ($$$) { #{{{
 462         my $page=shift;
 463         my $type=shift;
 464         my $content=shift;
 465
 466         if (exists $hooks{htmlize}{$type}) {
 467                 $content=$hooks{htmlize}{$type}{call}->(
 468                         page => $page,
 469                         content => $content,
 470                 );
 471         }
 472         else {
 473                 error("htmlization of $type not supported");
 474         }
 475
 476         run_hooks(sanitize => sub {
 477                 $content=shift->(
 478                         page => $page,
 479                         content => $content,
 480                 );
 481         });
 482
 483         return $content;
 484 } #}}}
 485
 486 sub linkify ($$$) { #{{{
 487         my $lpage=shift; # the page containing the links
 488         my $page=shift; # the page the link will end up on (different for inline)
 489         my $content=shift;
 490
 491         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 492                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 493                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 494         }eg;
 495
 496         return $content;
 497 } #}}}
 498
 499 my %preprocessing;
 500 sub preprocess ($$$;$) { #{{{
 501         my $page=shift; # the page the data comes from
 502         my $destpage=shift; # the page the data will appear in (different for inline)
 503         my $content=shift;
 504         my $scan=shift;
 505
 506         my $handle=sub {
 507                 my $escape=shift;
 508                 my $command=shift;
 509                 my $params=shift;
 510                 if (length $escape) {
 511                         return "[[$command $params]]";
 512                 }
 513                 elsif (exists $hooks{preprocess}{$command}) {
 514                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 515                         # Note: preserve order of params, some plugins may
 516                         # consider it significant.
 517                         my @params;
 518                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 519                                 my $key=$1;
 520                                 my $val;
 521                                 if (defined $2) {
 522                                         $val=$2;
 523                                         $val=~s/\r\n/\n/mg;
 524                                         $val=~s/^\n+//g;
 525                                         $val=~s/\n+$//g;
 526                                 }
 527                                 elsif (defined $3) {
 528                                         $val=$3;
 529                                 }
 530                                 elsif (defined $4) {
 531                                         $val=$4;
 532                                 }
 533
 534                                 if (defined $key) {
 535                                         push @params, $key, $val;
 536                                 }
 537                                 else {
 538                                         push @params, $val, '';
 539                                 }
 540                         }
 541                         if ($preprocessing{$page}++ > 3) {
 542                                 # Avoid loops of preprocessed pages preprocessing
 543                                 # other pages that preprocess them, etc.
 544                                 #translators: The first parameter is a
 545                                 #translators: preprocessor directive name,
 546                                 #translators: the second a page name, the
 547                                 #translators: third a number.
 548                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 549                                         $command, $page, $preprocessing{$page}).
 550                                 "]]";
 551                         }
 552                         my $ret=$hooks{preprocess}{$command}{call}->(
 553                                 @params,
 554                                 page => $page,
 555                                 destpage => $destpage,
 556                         );
 557                         $preprocessing{$page}--;
 558                         return $ret;
 559                 }
 560                 else {
 561                         return "[[$command $params]]";
 562                 }
 563         };
 564
 565         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 566         return $content;
 567 } #}}}
 568
 569 sub filter ($$) { #{{{
 570         my $page=shift;
 571         my $content=shift;
 572
 573         run_hooks(filter => sub {
 574                 $content=shift->(page => $page, content => $content);
 575         });
 576
 577         return $content;
 578 } #}}}
 579
 580 sub indexlink () { #{{{
 581         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 582 } #}}}
 583
 584 sub lockwiki () { #{{{
 585         # Take an exclusive lock on the wiki to prevent multiple concurrent
 586         # run issues. The lock will be dropped on program exit.
 587         if (! -d $config{wikistatedir}) {
 588                 mkdir($config{wikistatedir});
 589         }
 590         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 591                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 592         if (! flock(WIKILOCK, 2 | 4)) {
 593                 debug("wiki seems to be locked, waiting for lock");
 594                 my $wait=600; # arbitrary, but don't hang forever to
 595                               # prevent process pileup
 596                 for (1..$wait) {
 597                         return if flock(WIKILOCK, 2 | 4);
 598                         sleep 1;
 599                 }
 600                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 601         }
 602 } #}}}
 603
 604 sub unlockwiki () { #{{{
 605         close WIKILOCK;
 606 } #}}}
 607
 608 sub loadindex () { #{{{
 609         open (IN, "$config{wikistatedir}/index") || return;
 610         while (<IN>) {
 611                 $_=possibly_foolish_untaint($_);
 612                 chomp;
 613                 my %items;
 614                 $items{link}=[];
 615                 $items{dest}=[];
 616                 foreach my $i (split(/ /, $_)) {
 617                         my ($item, $val)=split(/=/, $i, 2);
 618                         push @{$items{$item}}, decode_entities($val);
 619                 }
 620
 621                 next unless exists $items{src}; # skip bad lines for now
 622
 623                 my $page=pagename($items{src}[0]);
 624                 if (! $config{rebuild}) {
 625                         $pagesources{$page}=$items{src}[0];
 626                         $oldpagemtime{$page}=$items{mtime}[0];
 627                         $oldlinks{$page}=[@{$items{link}}];
 628                         $links{$page}=[@{$items{link}}];
 629                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 630                         $renderedfiles{$page}=[@{$items{dest}}];
 631                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 632                         $pagecase{lc $page}=$page;
 633                 }
 634                 $pagectime{$page}=$items{ctime}[0];
 635         }
 636         close IN;
 637 } #}}}
 638
 639 sub saveindex () { #{{{
 640         run_hooks(savestate => sub { shift->() });
 641
 642         if (! -d $config{wikistatedir}) {
 643                 mkdir($config{wikistatedir});
 644         }
 645         my $newfile="$config{wikistatedir}/index.new";
 646         my $cleanup = sub { unlink($newfile) };
 647         open (OUT, ">$newfile") || error("cannot write to $newfile: $!", $cleanup);
 648         foreach my $page (keys %oldpagemtime) {
 649                 next unless $oldpagemtime{$page};
 650                 my $line="mtime=$oldpagemtime{$page} ".
 651                         "ctime=$pagectime{$page} ".
 652                         "src=$pagesources{$page}";
 653                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 654                 my %count;
 655                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 656                 if (exists $depends{$page}) {
 657                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 658                 }
 659                 print OUT $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 660         }
 661         close OUT || error("failed saving to $newfile: $!", $cleanup);
 662         rename($newfile, "$config{wikistatedir}/index") ||
 663                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 664 } #}}}
 665
 666 sub template_file ($) { #{{{
 667         my $template=shift;
 668
 669         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 670                 return "$dir/$template" if -e "$dir/$template";
 671         }
 672         return undef;
 673 } #}}}
 674
 675 sub template_params (@) { #{{{
 676         my $filename=template_file(shift);
 677
 678         if (! defined $filename) {
 679                 return if wantarray;
 680                 return "";
 681         }
 682
 683         require HTML::Template;
 684         my @ret=(
 685                 filter => sub {
 686                         my $text_ref = shift;
 687                         $$text_ref=&Encode::decode_utf8($$text_ref);
 688                 },
 689                 filename => $filename,
 690                 loop_context_vars => 1,
 691                 die_on_bad_params => 0,
 692                 @_
 693         );
 694         return wantarray ? @ret : {@ret};
 695 } #}}}
 696
 697 sub template ($;@) { #{{{
 698         HTML::Template->new(template_params(@_));
 699 } #}}}
 700
 701 sub misctemplate ($$;@) { #{{{
 702         my $title=shift;
 703         my $pagebody=shift;
 704
 705         my $template=template("misc.tmpl");
 706         $template->param(
 707                 title => $title,
 708                 indexlink => indexlink(),
 709                 wikiname => $config{wikiname},
 710                 pagebody => $pagebody,
 711                 baseurl => baseurl(),
 712                 @_,
 713         );
 714         run_hooks(pagetemplate => sub {
 715                 shift->(page => "", destpage => "", template => $template);
 716         });
 717         return $template->output;
 718 }#}}}
 719
 720 sub hook (@) { # {{{
 721         my %param=@_;
 722
 723         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 724                 error "hook requires type, call, and id parameters";
 725         }
 726
 727         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 728
 729         $hooks{$param{type}}{$param{id}}=\%param;
 730 } # }}}
 731
 732 sub run_hooks ($$) { # {{{
 733         # Calls the given sub for each hook of the given type,
 734         # passing it the hook function to call.
 735         my $type=shift;
 736         my $sub=shift;
 737
 738         if (exists $hooks{$type}) {
 739                 my @deferred;
 740                 foreach my $id (keys %{$hooks{$type}}) {
 741                         if ($hooks{$type}{$id}{last}) {
 742                                 push @deferred, $id;
 743                                 next;
 744                         }
 745                         $sub->($hooks{$type}{$id}{call});
 746                 }
 747                 foreach my $id (@deferred) {
 748                         $sub->($hooks{$type}{$id}{call});
 749                 }
 750         }
 751 } #}}}
 752
 753 sub globlist_to_pagespec ($) { #{{{
 754         my @globlist=split(' ', shift);
 755
 756         my (@spec, @skip);
 757         foreach my $glob (@globlist) {
 758                 if ($glob=~/^!(.*)/) {
 759                         push @skip, $glob;
 760                 }
 761                 else {
 762                         push @spec, $glob;
 763                 }
 764         }
 765
 766         my $spec=join(" or ", @spec);
 767         if (@skip) {
 768                 my $skip=join(" and ", @skip);
 769                 if (length $spec) {
 770                         $spec="$skip and ($spec)";
 771                 }
 772                 else {
 773                         $spec=$skip;
 774                 }
 775         }
 776         return $spec;
 777 } #}}}
 778
 779 sub is_globlist ($) { #{{{
 780         my $s=shift;
 781         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 782 } #}}}
 783
 784 sub safequote ($) { #{{{
 785         my $s=shift;
 786         $s=~s/[{}]//g;
 787         return "q{$s}";
 788 } #}}}
 789
 790 sub add_depends ($$) { #{{{
 791         my $page=shift;
 792         my $pagespec=shift;
 793
 794         if (! exists $depends{$page}) {
 795                 $depends{$page}=$pagespec;
 796         }
 797         else {
 798                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 799         }
 800 } # }}}
 801
 802 sub file_pruned ($$) { #{{{
 803         require File::Spec;
 804         my $file=File::Spec->canonpath(shift);
 805         my $base=File::Spec->canonpath(shift);
 806         $file=~s#^\Q$base\E/*##;
 807
 808         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 809         $file =~ m/$regexp/;
 810 } #}}}
 811
 812 sub gettext { #{{{
 813         # Only use gettext in the rare cases it's needed.
 814         if (exists $ENV{LANG} || exists $ENV{LC_ALL} || exists $ENV{LC_MESSAGES}) {
 815                 if (! $gettext_obj) {
 816                         $gettext_obj=eval q{
 817                                 use Locale::gettext q{textdomain};
 818                                 Locale::gettext->domain('ikiwiki')
 819                         };
 820                         if ($@) {
 821                                 print STDERR "$@";
 822                                 $gettext_obj=undef;
 823                                 return shift;
 824                         }
 825                 }
 826                 return $gettext_obj->get(shift);
 827         }
 828         else {
 829                 return shift;
 830         }
 831 } #}}}
 832
 833 sub pagespec_merge ($$) { #{{{
 834         my $a=shift;
 835         my $b=shift;
 836
 837         return $a if $a eq $b;
 838
 839         # Support for old-style GlobLists.
 840         if (is_globlist($a)) {
 841                 $a=globlist_to_pagespec($a);
 842         }
 843         if (is_globlist($b)) {
 844                 $b=globlist_to_pagespec($b);
 845         }
 846
 847         return "($a) or ($b)";
 848 } #}}}
 849
 850 sub pagespec_translate ($) { #{{{
 851         # This assumes that $page is in scope in the function
 852         # that evalulates the translated pagespec code.
 853         my $spec=shift;
 854
 855         # Support for old-style GlobLists.
 856         if (is_globlist($spec)) {
 857                 $spec=globlist_to_pagespec($spec);
 858         }
 859
 860         # Convert spec to perl code.
 861         my $code="";
 862         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 863                 my $word=$1;
 864                 if (lc $word eq "and") {
 865                         $code.=" &&";
 866                 }
 867                 elsif (lc $word eq "or") {
 868                         $code.=" ||";
 869                 }
 870                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 871                         $code.=" ".$word;
 872                 }
 873                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
 874                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
 875                                 $code.=" IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).")";
 876                         }
 877                         else {
 878                                 $code.=" 0";
 879                         }
 880                 }
 881                 else {
 882                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \$from)";
 883                 }
 884         }
 885
 886         return $code;
 887 } #}}}
 888
 889 sub pagespec_match ($$;$) { #{{{
 890         my $page=shift;
 891         my $spec=shift;
 892         my $from=shift;
 893
 894         return eval pagespec_translate($spec);
 895 } #}}}
 896
 897 package IkiWiki::PageSpec;
 898
 899 sub match_glob ($$$) { #{{{
 900         my $page=shift;
 901         my $glob=shift;
 902         my $from=shift;
 903         if (! defined $from){
 904                 $from = "";
 905         }
 906
 907         # relative matching
 908         if ($glob =~ m!^\./!) {
 909                 $from=~s!/?[^/]+$!!;
 910                 $glob=~s!^\./!!;
 911                 $glob="$from/$glob" if length $from;
 912         }
 913
 914         # turn glob into safe regexp
 915         $glob=quotemeta($glob);
 916         $glob=~s/\\\*/.*/g;
 917         $glob=~s/\\\?/./g;
 918
 919         return $page=~/^$glob$/i;
 920 } #}}}
 921
 922 sub match_link ($$) { #{{{
 923         my $page=shift;
 924         my $link=lc(shift);
 925
 926         my $links = $IkiWiki::links{$page} or return undef;
 927         foreach my $p (@$links) {
 928                 return 1 if lc $p eq $link;
 929         }
 930         return 0;
 931 } #}}}
 932
 933 sub match_backlink ($$) { #{{{
 934         match_link(pop, pop);
 935 } #}}}
 936
 937 sub match_created_before ($$) { #{{{
 938         my $page=shift;
 939         my $testpage=shift;
 940
 941         if (exists $IkiWiki::pagectime{$testpage}) {
 942                 return $IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage};
 943         }
 944         else {
 945                 return 0;
 946         }
 947 } #}}}
 948
 949 sub match_created_after ($$) { #{{{
 950         my $page=shift;
 951         my $testpage=shift;
 952
 953         if (exists $IkiWiki::pagectime{$testpage}) {
 954                 return $IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage};
 955         }
 956         else {
 957                 return 0;
 958         }
 959 } #}}}
 960
 961 sub match_creation_day ($$) { #{{{
 962         return ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift);
 963 } #}}}
 964
 965 sub match_creation_month ($$) { #{{{
 966         return ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift);
 967 } #}}}
 968
 969 sub match_creation_year ($$) { #{{{
 970         return ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift);
 971 } #}}}
 972
 973 1