IkiWiki/Plugin/search.pm

   1 #!/usr/bin/perl
   2 # xapian-omega search engine plugin
   3 package IkiWiki::Plugin::search;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 sub import {
  10         hook(type => "getsetup", id => "search", call => \&getsetup);
  11         hook(type => "checkconfig", id => "search", call => \&checkconfig);
  12         hook(type => "pagetemplate", id => "search", call => \&pagetemplate);
  13         hook(type => "postscan", id => "search", call => \&index);
  14         hook(type => "delete", id => "search", call => \&delete);
  15         hook(type => "cgi", id => "search", call => \&cgi);
  16 }
  17
  18 sub getsetup () {
  19         return
  20                 plugin => {
  21                         safe => 1,
  22                         rebuild => 1,
  23                         section => "web",
  24                 },
  25                 omega_cgi => {
  26                         type => "string",
  27                         example => "/usr/lib/cgi-bin/omega/omega",
  28                         description => "path to the omega cgi program",
  29                         safe => 0, # external program
  30                         rebuild => 0,
  31                 },
  32 }
  33
  34 sub checkconfig () {
  35         foreach my $required (qw(url cgiurl)) {
  36                 if (! length $config{$required}) {
  37                         error(sprintf(gettext("Must specify %s when using the %s plugin"), $required, 'search'));
  38                 }
  39         }
  40
  41         if (! defined $config{omega_cgi}) {
  42                 $config{omega_cgi}="/usr/lib/cgi-bin/omega/omega";
  43         }
  44 }
  45
  46 my $form;
  47 sub pagetemplate (@) {
  48         my %params=@_;
  49         my $page=$params{page};
  50         my $template=$params{template};
  51
  52         # Add search box to page header.
  53         if ($template->query(name => "searchform")) {
  54                 if (! defined $form) {
  55                         my $searchform = template("searchform.tmpl", blind_cache => 1);
  56                         $searchform->param(searchaction => $config{cgiurl});
  57                         $form=$searchform->output;
  58                 }
  59
  60                 $template->param(searchform => $form);
  61         }
  62 }
  63
  64 my $scrubber;
  65 my $stemmer;
  66 sub index (@) {
  67         my %params=@_;
  68
  69         setupfiles();
  70
  71         # A unique pageterm is used to identify the document for a page.
  72         my $pageterm=pageterm($params{page});
  73         return $params{content} unless defined $pageterm;
  74
  75         my $db=xapiandb();
  76         my $doc=Search::Xapian::Document->new();
  77         my $caption=pagetitle($params{page});
  78         my $title;
  79         if (exists $pagestate{$params{page}}{meta} &&
  80                 exists $pagestate{$params{page}}{meta}{title}) {
  81                 $title=$pagestate{$params{page}}{meta}{title};
  82         }
  83         else {
  84                 $title=$caption;
  85         }
  86
  87         # Remove html from text to be indexed.
  88         if (! defined $scrubber) {
  89                 eval q{use HTML::Scrubber};
  90                 if (! $@) {
  91                         $scrubber=HTML::Scrubber->new(allow => []);
  92                 }
  93         }
  94         my $toindex = defined $scrubber ? $scrubber->scrub($params{content}) : $params{content};
  95
  96         # Take 512 characters for a sample, then extend it out
  97         # if it stopped in the middle of a word.
  98         my $size=512;
  99         my ($sample)=substr($toindex, 0, $size);
 100         if (length($sample) == $size) {
 101                 my $max=length($toindex);
 102                 my $next;
 103                 while ($size < $max &&
 104                        ($next=substr($toindex, $size++, 1)) !~ /\s/) {
 105                         $sample.=$next;
 106                 }
 107         }
 108         $sample=~s/\n/ /g;
 109
 110         # data used by omega
 111         # Decode html entities in it, since omega re-encodes them.
 112         eval q{use HTML::Entities};
 113         $doc->set_data(
 114                 "url=".urlto($params{page}, "")."\n".
 115                 "sample=".decode_entities($sample)."\n".
 116                 "caption=".decode_entities($caption)."\n".
 117                 "modtime=$IkiWiki::pagemtime{$params{page}}\n".
 118                 "size=".length($params{content})."\n"
 119         );
 120
 121         # Index document and add terms for other metadata.
 122         my $tg = Search::Xapian::TermGenerator->new();
 123         if (! $stemmer) {
 124                 my $langcode=$ENV{LANG} || "en";
 125                 $langcode=~s/_.*//;
 126
 127                 # This whitelist is here to work around a xapian bug (#486138)
 128                 my @whitelist=qw{da de en es fi fr hu it no pt ru ro sv tr};
 129
 130                 if (grep { $_ eq $langcode } @whitelist) {
 131                         $stemmer=Search::Xapian::Stem->new($langcode);
 132                 }
 133                 else {
 134                         $stemmer=Search::Xapian::Stem->new("english");
 135                 }
 136         }
 137         $tg->set_stemmer($stemmer);
 138         $tg->set_document($doc);
 139         $tg->index_text($params{page}, 2);
 140         $tg->index_text($caption, 2);
 141         $tg->index_text($title, 2) if $title ne $caption;
 142         $tg->index_text($toindex);
 143         $tg->index_text(lc($title), 1, "S"); # for title:foo
 144         foreach my $link (@{$links{$params{page}}}) {
 145                 $tg->index_text(lc($link), 1, "XLINK"); # for link:bar
 146         }
 147
 148         $doc->add_term($pageterm);
 149         $db->replace_document_by_term($pageterm, $doc);
 150 }
 151
 152 sub delete (@) {
 153         my $db=xapiandb();
 154         foreach my $page (@_) {
 155                 my $pageterm=pageterm(pagename($page));
 156                 $db->delete_document_by_term($pageterm) if defined $pageterm;
 157         }
 158 }
 159
 160 sub cgi ($) {
 161         my $cgi=shift;
 162
 163         if (defined $cgi->param('P')) {
 164                 # only works for GET requests
 165                 chdir("$config{wikistatedir}/xapian") || error("chdir: $!");
 166                 $ENV{OMEGA_CONFIG_FILE}="./omega.conf";
 167                 $ENV{CGIURL}=$config{cgiurl},
 168                 IkiWiki::loadindex();
 169                 $ENV{HELPLINK}=htmllink("", "", "ikiwiki/searching",
 170                         noimageinline => 1, linktext => "Help");
 171                 exec($config{omega_cgi}) || error("$config{omega_cgi} failed: $!");
 172         }
 173 }
 174
 175 sub pageterm ($) {
 176         my $page=shift;
 177
 178         # 240 is the number used by omindex to decide when to hash an
 179         # overlong term. This does not use a compatible hash method though.
 180         if (length $page > 240) {
 181                 eval q{use Digest::SHA1};
 182                 if ($@) {
 183                         debug("search: ".sprintf(gettext("need Digest::SHA1 to index %s"), $page)) if $@;
 184                         return undef;
 185                 }
 186
 187                 # Note no colon, therefore it's guaranteed to not overlap
 188                 # with a page with the same name as the hash..
 189                 return "U".lc(Digest::SHA1::sha1_hex($page));
 190         }
 191         else {
 192                 return "U:".$page;
 193         }
 194 }
 195
 196 my $db;
 197 sub xapiandb () {
 198         if (! defined $db) {
 199                 eval q{
 200                         use Search::Xapian;
 201                         use Search::Xapian::WritableDatabase;
 202                 };
 203                 error($@) if $@;
 204                 $db=Search::Xapian::WritableDatabase->new($config{wikistatedir}."/xapian/default",
 205                         Search::Xapian::DB_CREATE_OR_OPEN());
 206         }
 207         return $db;
 208 }
 209
 210 {
 211 my $setup=0;
 212 sub setupfiles () {
 213         if (! $setup and (! -e $config{wikistatedir}."/xapian" || $config{rebuild})) {
 214                 writefile("omega.conf", $config{wikistatedir}."/xapian",
 215                         "database_dir .\n".
 216                         "template_dir ./templates\n");
 217                 writefile("query", $config{wikistatedir}."/xapian/templates",
 218                         IkiWiki::misctemplate(gettext("search"),
 219                                 readfile(IkiWiki::template_file("searchquery.tmpl"))));
 220                 $setup=1;
 221         }
 222 }
 223 }
 224
 225 1