IkiWiki/Plugin/pagestats.pm

   1 #!/usr/bin/perl
   2 #
   3 # Produce page statistics in various forms.
   4 #
   5 # Currently supported:
   6 #   cloud: produces statistics in the form of a del.icio.us-style tag cloud
   7 #          (default)
   8 #   table: produces a table with the number of backlinks for each page
   9 #
  10 # by Enrico Zini
  11 package IkiWiki::Plugin::pagestats;
  12
  13 use warnings;
  14 use strict;
  15 use IkiWiki 3.00;
  16
  17 # Names of the HTML classes to use for the tag cloud
  18 our @classes = ('smallestPC', 'smallPC', 'normalPC', 'bigPC', 'biggestPC' );
  19
  20 sub import {
  21         hook(type => "getsetup", id => "pagestats", call => \&getsetup);
  22         hook(type => "preprocess", id => "pagestats", call => \&preprocess);
  23 }
  24
  25 sub getsetup () {
  26         return
  27                 plugin => {
  28                         safe => 1,
  29                         rebuild => undef,
  30                 },
  31 }
  32
  33 sub preprocess (@) {
  34         my %params=@_;
  35         $params{pages}="*" unless defined $params{pages};
  36         my $style = ($params{style} or 'cloud');
  37
  38         my %counts;
  39         my $max = 0;
  40         foreach my $page (pagespec_match_list($params{page}, $params{pages},
  41                                   # update when a displayed page is added/removed
  42                                   deptype => deptype("presence"))) {
  43                 use IkiWiki::Render;
  44
  45                 my @backlinks = IkiWiki::backlink_pages($page);
  46
  47                 if (exists $params{among}) {
  48                         # only consider backlinks from the amoung pages
  49                         @backlinks = pagespec_match_list(
  50                                 $params{page}, $params{among},
  51                                 # update whenever links on those pages change
  52                                 deptype => deptype("links"),
  53                                 list => \@backlinks
  54                         );
  55                 }
  56                 else {
  57                         # update when any page with links changes,
  58                         # in case the links point to our displayed pages
  59                         add_depends($params{page}, "*", deptype("links"));
  60                 }
  61
  62                 $counts{$page} = scalar(@backlinks);
  63                 $max = $counts{$page} if $counts{$page} > $max;
  64         }
  65
  66         if ($style eq 'table') {
  67                 return "<table class='pageStats'>\n".
  68                         join("\n", map {
  69                                 "<tr><td>".
  70                                 htmllink($params{page}, $params{destpage}, $_, noimageinline => 1).
  71                                 "</td><td>".$counts{$_}."</td></tr>"
  72                         }
  73                         sort { $counts{$b} <=> $counts{$a} } keys %counts).
  74                         "\n</table>\n" ;
  75         }
  76         else {
  77                 # In case of misspelling, default to a page cloud
  78
  79                 my $res = "<div class='pagecloud'>\n";
  80                 foreach my $page (sort keys %counts) {
  81                         next unless $counts{$page} > 0;
  82
  83                         my $class = $classes[$counts{$page} * scalar(@classes) / ($max + 1)];
  84                         $res .= "<span class=\"$class\">".
  85                                 htmllink($params{page}, $params{destpage}, $page).
  86                                 "</span>\n";
  87                 }
  88                 $res .= "</div>\n";
  89
  90                 return $res;
  91         }
  92 }
  93
  94 1