IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use open qw{:utf8 :std};
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  29         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  30         hook(type => "rcs", id => "rcs_preprevert", call => \&rcs_preprevert);
  31         hook(type => "rcs", id => "rcs_revert", call => \&rcs_revert);
  32         hook(type => "rcs", id => "rcs_find_changes", call => \&rcs_find_changes);
  33         hook(type => "rcs", id => "rcs_get_current_rev", call => \&rcs_get_current_rev);
  34 }
  35
  36 sub checkconfig () {
  37         if (! defined $config{gitorigin_branch}) {
  38                 $config{gitorigin_branch}="origin";
  39         }
  40         if (! defined $config{gitmaster_branch}) {
  41                 $config{gitmaster_branch}="master";
  42         }
  43         if (defined $config{git_wrapper} &&
  44             length $config{git_wrapper}) {
  45                 push @{$config{wrappers}}, {
  46                         wrapper => $config{git_wrapper},
  47                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  48                         wrapper_background_command => $config{git_wrapper_background_command},
  49                 };
  50         }
  51
  52         if (defined $config{git_test_receive_wrapper} &&
  53             length $config{git_test_receive_wrapper} &&
  54             defined $config{untrusted_committers} &&
  55             @{$config{untrusted_committers}}) {
  56                 push @{$config{wrappers}}, {
  57                         test_receive => 1,
  58                         wrapper => $config{git_test_receive_wrapper},
  59                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  60                 };
  61         }
  62
  63         # Avoid notes, parser does not handle and they only slow things down.
  64         $ENV{GIT_NOTES_REF}="";
  65
  66         # Run receive test only if being called by the wrapper, and not
  67         # when generating same.
  68         if ($config{test_receive} && ! exists $config{wrapper}) {
  69                 require IkiWiki::Receive;
  70                 IkiWiki::Receive::test();
  71         }
  72 }
  73
  74 sub getsetup () {
  75         return
  76                 plugin => {
  77                         safe => 0, # rcs plugin
  78                         rebuild => undef,
  79                         section => "rcs",
  80                 },
  81                 git_wrapper => {
  82                         type => "string",
  83                         example => "/git/wiki.git/hooks/post-update",
  84                         description => "git hook to generate",
  85                         safe => 0, # file
  86                         rebuild => 0,
  87                 },
  88                 git_wrapper_background_command => {
  89                         type => "string",
  90                         example => "git push github",
  91                         description => "shell command for git_wrapper to run, in the background",
  92                         safe => 0, # command
  93                         rebuild => 0,
  94                 },
  95                 git_wrappermode => {
  96                         type => "string",
  97                         example => '06755',
  98                         description => "mode for git_wrapper (can safely be made suid)",
  99                         safe => 0,
 100                         rebuild => 0,
 101                 },
 102                 git_test_receive_wrapper => {
 103                         type => "string",
 104                         example => "/git/wiki.git/hooks/pre-receive",
 105                         description => "git pre-receive hook to generate",
 106                         safe => 0, # file
 107                         rebuild => 0,
 108                 },
 109                 untrusted_committers => {
 110                         type => "string",
 111                         example => [],
 112                         description => "unix users whose commits should be checked by the pre-receive hook",
 113                         safe => 0,
 114                         rebuild => 0,
 115                 },
 116                 historyurl => {
 117                         type => "string",
 118                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]];hb=HEAD",
 119                         description => "gitweb url to show file history ([[file]] substituted)",
 120                         safe => 1,
 121                         rebuild => 1,
 122                 },
 123                 diffurl => {
 124                         type => "string",
 125                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 126                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 127                         safe => 1,
 128                         rebuild => 1,
 129                 },
 130                 gitorigin_branch => {
 131                         type => "string",
 132                         example => "origin",
 133                         description => "where to pull and push changes (set to empty string to disable)",
 134                         safe => 0, # paranoia
 135                         rebuild => 0,
 136                 },
 137                 gitmaster_branch => {
 138                         type => "string",
 139                         example => "master",
 140                         description => "branch that the wiki is stored in",
 141                         safe => 0, # paranoia
 142                         rebuild => 0,
 143                 },
 144 }
 145
 146 sub genwrapper {
 147         if ($config{test_receive}) {
 148                 require IkiWiki::Receive;
 149                 return IkiWiki::Receive::genwrapper();
 150         }
 151         else {
 152                 return "";
 153         }
 154 }
 155
 156 my $git_dir=undef;
 157 my $prefix=undef;
 158
 159 sub in_git_dir ($$) {
 160         $git_dir=shift;
 161         my @ret=shift->();
 162         $git_dir=undef;
 163         $prefix=undef;
 164         return @ret;
 165 }
 166
 167 sub safe_git (&@) {
 168         # Start a child process safely without resorting to /bin/sh.
 169         # Returns command output (in list content) or success state
 170         # (in scalar context), or runs the specified data handler.
 171
 172         my ($error_handler, $data_handler, @cmdline) = @_;
 173
 174         my $pid = open my $OUT, "-|";
 175
 176         error("Cannot fork: $!") if !defined $pid;
 177
 178         if (!$pid) {
 179                 # In child.
 180                 # Git commands want to be in wc.
 181                 if (! defined $git_dir) {
 182                         chdir $config{srcdir}
 183                             or error("cannot chdir to $config{srcdir}: $!");
 184                 }
 185                 else {
 186                         chdir $git_dir
 187                             or error("cannot chdir to $git_dir: $!");
 188                 }
 189                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 190         }
 191         # In parent.
 192
 193         # git output is probably utf-8 encoded, but may contain
 194         # other encodings or invalidly encoded stuff. So do not rely
 195         # on the normal utf-8 IO layer, decode it by hand.
 196         binmode($OUT);
 197
 198         my @lines;
 199         while (<$OUT>) {
 200                 $_=decode_utf8($_, 0);
 201
 202                 chomp;
 203
 204                 if (! defined $data_handler) {
 205                         push @lines, $_;
 206                 }
 207                 else {
 208                         last unless $data_handler->($_);
 209                 }
 210         }
 211
 212         close $OUT;
 213
 214         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 215
 216         return wantarray ? @lines : ($? == 0);
 217 }
 218 # Convenient wrappers.
 219 sub run_or_die ($@) { safe_git(\&error, undef, @_) }
 220 sub run_or_cry ($@) { safe_git(sub { warn @_ }, undef, @_) }
 221 sub run_or_non ($@) { safe_git(undef, undef, @_) }
 222
 223
 224 sub merge_past ($$$) {
 225         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 226         # Git merge commands work with the committed changes, except in the
 227         # implicit case of '-m' of git checkout(1).  So we should invent a
 228         # kludge here.  In principle, we need to create a throw-away branch
 229         # in preparing for the merge itself.  Since branches are cheap (and
 230         # branching is fast), this shouldn't cost high.
 231         #
 232         # The main problem is the presence of _uncommitted_ local changes.  One
 233         # possible approach to get rid of this situation could be that we first
 234         # make a temporary commit in the master branch and later restore the
 235         # initial state (this is possible since Git has the ability to undo a
 236         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 237         # as follows:
 238         #
 239         #       - create a diff of HEAD:current-sha1
 240         #       - dummy commit
 241         #       - create a dummy branch and switch to it
 242         #       - rewind to past (reset --hard to the current-sha1)
 243         #       - apply the diff and commit
 244         #       - switch to master and do the merge with the dummy branch
 245         #       - make a soft reset (undo the last commit of master)
 246         #
 247         # The above method has some drawbacks: (1) it needs a redundant commit
 248         # just to get rid of local changes, (2) somewhat slow because of the
 249         # required system forks.  Until someone points a more straight method
 250         # (which I would be grateful) I have implemented an alternative method.
 251         # In this approach, we hide all the modified files from Git by renaming
 252         # them (using the 'rename' builtin) and later restore those files in
 253         # the throw-away branch (that is, we put the files themselves instead
 254         # of applying a patch).
 255
 256         my ($sha1, $file, $message) = @_;
 257
 258         my @undo;      # undo stack for cleanup in case of an error
 259         my $conflict;  # file content with conflict markers
 260
 261         eval {
 262                 # Hide local changes from Git by renaming the modified file.
 263                 # Relative paths must be converted to absolute for renaming.
 264                 my ($target, $hidden) = (
 265                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 266                 );
 267                 rename($target, $hidden)
 268                     or error("rename '$target' to '$hidden' failed: $!");
 269                 # Ensure to restore the renamed file on error.
 270                 push @undo, sub {
 271                         return if ! -e "$hidden"; # already renamed
 272                         rename($hidden, $target)
 273                             or warn "rename '$hidden' to '$target' failed: $!";
 274                 };
 275
 276                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 277
 278                 # Create a throw-away branch and rewind backward.
 279                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 280                 run_or_die('git', 'branch', $branch, $sha1);
 281
 282                 # Switch to throw-away branch for the merge operation.
 283                 push @undo, sub {
 284                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 285                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 286                         }
 287                 };
 288                 run_or_die('git', 'checkout', $branch);
 289
 290                 # Put the modified file in _this_ branch.
 291                 rename($hidden, $target)
 292                     or error("rename '$hidden' to '$target' failed: $!");
 293
 294                 # _Silently_ commit all modifications in the current branch.
 295                 run_or_non('git', 'commit', '-m', $message, '-a');
 296                 # ... and re-switch to master.
 297                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 298
 299                 # Attempt to merge without complaining.
 300                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 301                         $conflict = readfile($target);
 302                         run_or_die('git', 'reset', '--hard');
 303                 }
 304         };
 305         my $failure = $@;
 306
 307         # Process undo stack (in reverse order).  By policy cleanup
 308         # actions should normally print a warning on failure.
 309         while (my $handle = pop @undo) {
 310                 $handle->();
 311         }
 312
 313         error("Git merge failed!\n$failure\n") if $failure;
 314
 315         return $conflict;
 316 }
 317
 318 sub decode_git_file ($) {
 319         my $file=shift;
 320
 321         # git does not output utf-8 filenames, but instead
 322         # double-quotes them with the utf-8 characters
 323         # escaped as \nnn\nnn.
 324         if ($file =~ m/^"(.*)"$/) {
 325                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 326         }
 327
 328         # strip prefix if in a subdir
 329         if (! defined $prefix) {
 330                 ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 331                 if (! defined $prefix) {
 332                         $prefix="";
 333                 }
 334         }
 335         $file =~ s/^\Q$prefix\E//;
 336
 337         return decode("utf8", $file);
 338 }
 339
 340 sub parse_diff_tree ($) {
 341         # Parse the raw diff tree chunk and return the info hash.
 342         # See git-diff-tree(1) for the syntax.
 343         my $dt_ref = shift;
 344
 345         # End of stream?
 346         return if ! @{ $dt_ref } ||
 347                   !defined $dt_ref->[0] || !length $dt_ref->[0];
 348
 349         my %ci;
 350         # Header line.
 351         while (my $line = shift @{ $dt_ref }) {
 352                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 353
 354                 my $sha1 = $2;
 355                 $ci{'sha1'} = $sha1;
 356                 last;
 357         }
 358
 359         # Identification lines for the commit.
 360         while (my $line = shift @{ $dt_ref }) {
 361                 # Regexps are semi-stolen from gitweb.cgi.
 362                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 363                         $ci{'tree'} = $1;
 364                 }
 365                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 366                         # XXX: collecting in reverse order
 367                         push @{ $ci{'parents'} }, $1;
 368                 }
 369                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 370                         my ($who, $name, $epoch, $tz) =
 371                            ($1,   $2,    $3,     $4 );
 372
 373                         $ci{  $who          } = $name;
 374                         $ci{ "${who}_epoch" } = $epoch;
 375                         $ci{ "${who}_tz"    } = $tz;
 376
 377                         if ($name =~ m/^([^<]+)\s+<([^@>]+)/) {
 378                                 $ci{"${who}_name"} = $1;
 379                                 $ci{"${who}_username"} = $2;
 380                         }
 381                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 382                                 $ci{"${who}_username"} = $1;
 383                         }
 384                         else {
 385                                 $ci{"${who}_username"} = $name;
 386                         }
 387                 }
 388                 elsif ($line =~ m/^$/) {
 389                         # Trailing empty line signals next section.
 390                         last;
 391                 }
 392         }
 393
 394         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 395
 396         if (defined $ci{'parents'}) {
 397                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 398         }
 399         else {
 400                 $ci{'parent'} = 0 x 40;
 401         }
 402
 403         # Commit message (optional).
 404         while ($dt_ref->[0] =~ /^    /) {
 405                 my $line = shift @{ $dt_ref };
 406                 $line =~ s/^    //;
 407                 push @{ $ci{'comment'} }, $line;
 408         }
 409         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 410
 411         # Modified files.
 412         while (my $line = shift @{ $dt_ref }) {
 413                 if ($line =~ m{^
 414                         (:+)       # number of parents
 415                         ([^\t]+)\t # modes, sha1, status
 416                         (.*)       # file names
 417                 $}xo) {
 418                         my $num_parents = length $1;
 419                         my @tmp = split(" ", $2);
 420                         my ($file, $file_to) = split("\t", $3);
 421                         my @mode_from = splice(@tmp, 0, $num_parents);
 422                         my $mode_to = shift(@tmp);
 423                         my @sha1_from = splice(@tmp, 0, $num_parents);
 424                         my $sha1_to = shift(@tmp);
 425                         my $status = shift(@tmp);
 426
 427                         if (length $file) {
 428                                 push @{ $ci{'details'} }, {
 429                                         'file'      => decode_git_file($file),
 430                                         'sha1_from' => $sha1_from[0],
 431                                         'sha1_to'   => $sha1_to,
 432                                         'mode_from' => $mode_from[0],
 433                                         'mode_to'   => $mode_to,
 434                                         'status'    => $status,
 435                                 };
 436                         }
 437                         next;
 438                 };
 439                 last;
 440         }
 441
 442         return \%ci;
 443 }
 444
 445 sub git_commit_info ($;$) {
 446         # Return an array of commit info hashes of num commits
 447         # starting from the given sha1sum.
 448         my ($sha1, $num) = @_;
 449
 450         my @opts;
 451         push @opts, "--max-count=$num" if defined $num;
 452
 453         my @raw_lines = run_or_die('git', 'log', @opts,
 454                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 455                 '-r', $sha1, '--', '.');
 456
 457         my @ci;
 458         while (my $parsed = parse_diff_tree(\@raw_lines)) {
 459                 push @ci, $parsed;
 460         }
 461
 462         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 463
 464         return wantarray ? @ci : $ci[0];
 465 }
 466
 467 sub rcs_find_changes ($) {
 468         my $oldrev=shift;
 469
 470         my @raw_lines = run_or_die('git', 'log',
 471                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 472                 '--no-renames', , '--reverse',
 473                 '-r', "$oldrev..HEAD", '--', '.');
 474
 475         # Due to --reverse, we see changes in chronological order.
 476         my %changed;
 477         my %deleted;
 478         my $nullsha = 0 x 40;
 479         my $newrev=$oldrev;
 480         while (my $ci = parse_diff_tree(\@raw_lines)) {
 481                 $newrev=$ci->{sha1};
 482                 foreach my $i (@{$ci->{details}}) {
 483                         my $file=$i->{file};
 484                         if ($i->{sha1_to} eq $nullsha) {
 485                                 delete $changed{$file};
 486                                 $deleted{$file}=1;
 487                         }
 488                         else {
 489                                 delete $deleted{$file};
 490                                 $changed{$file}=1;
 491                         }
 492                 }
 493         }
 494
 495         return (\%changed, \%deleted, $newrev);
 496 }
 497
 498 sub git_sha1_file ($) {
 499         my $file=shift;
 500         git_sha1("--", $file);
 501 }
 502
 503 sub git_sha1 (@) {
 504         # Ignore error since a non-existing file might be given.
 505         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 506                 '--', @_);
 507         if (defined $sha1) {
 508                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 509         }
 510         return defined $sha1 ? $sha1 : '';
 511 }
 512
 513 sub rcs_get_current_rev () {
 514         git_sha1();
 515 }
 516
 517 sub rcs_update () {
 518         # Update working directory.
 519
 520         if (length $config{gitorigin_branch}) {
 521                 run_or_cry('git', 'pull', '--prune', $config{gitorigin_branch});
 522         }
 523 }
 524
 525 sub rcs_prepedit ($) {
 526         # Return the commit sha1sum of the file when editing begins.
 527         # This will be later used in rcs_commit if a merge is required.
 528         my ($file) = @_;
 529
 530         return git_sha1_file($file);
 531 }
 532
 533 sub rcs_commit (@) {
 534         # Try to commit the page; returns undef on _success_ and
 535         # a version of the page with the rcs's conflict markers on
 536         # failure.
 537         my %params=@_;
 538
 539         # Check to see if the page has been changed by someone else since
 540         # rcs_prepedit was called.
 541         my $cur    = git_sha1_file($params{file});
 542         my ($prev) = $params{token} =~ /^($sha1_pattern)$/; # untaint
 543
 544         if (defined $cur && defined $prev && $cur ne $prev) {
 545                 my $conflict = merge_past($prev, $params{file}, $dummy_commit_msg);
 546                 return $conflict if defined $conflict;
 547         }
 548
 549         return rcs_commit_helper(@_);
 550 }
 551
 552 sub rcs_commit_staged (@) {
 553         # Commits all staged changes. Changes can be staged using rcs_add,
 554         # rcs_remove, and rcs_rename.
 555         return rcs_commit_helper(@_);
 556 }
 557
 558 sub rcs_commit_helper (@) {
 559         my %params=@_;
 560
 561         my %env=%ENV;
 562
 563         if (defined $params{session}) {
 564                 # Set the commit author and email based on web session info.
 565                 my $u;
 566                 if (defined $params{session}->param("name")) {
 567                         $u=$params{session}->param("name");
 568                 }
 569                 elsif (defined $params{session}->remote_addr()) {
 570                         $u=$params{session}->remote_addr();
 571                 }
 572                 if (defined $u) {
 573                         $u=encode_utf8($u);
 574                         $ENV{GIT_AUTHOR_NAME}=$u;
 575                 }
 576                 if (defined $params{session}->param("nickname")) {
 577                         $u=encode_utf8($params{session}->param("nickname"));
 578                         $u=~s/\s+/_/g;
 579                         $u=~s/[^-_0-9[:alnum:]]+//g;
 580                 }
 581                 if (defined $u) {
 582                         $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 583                 }
 584         }
 585
 586         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 587         my @opts;
 588         if ($params{message} !~ /\S/) {
 589                 # Force git to allow empty commit messages.
 590                 # (If this version of git supports it.)
 591                 my ($version)=`git --version` =~ /git version (.*)/;
 592                 if ($version ge "1.7.8") {
 593                         push @opts, "--allow-empty-message", "--no-edit";
 594                 }
 595                 if ($version ge "1.7.2") {
 596                         push @opts, "--allow-empty-message";
 597                 }
 598                 elsif ($version ge "1.5.4") {
 599                         push @opts, '--cleanup=verbatim';
 600                 }
 601                 else {
 602                         $params{message}.=".";
 603                 }
 604         }
 605         if (exists $params{file}) {
 606                 push @opts, '--', $params{file};
 607         }
 608         # git commit returns non-zero if nothing really changed.
 609         # So we should ignore its exit status (hence run_or_non).
 610         if (run_or_non('git', 'commit', '-m', $params{message}, '-q', @opts)) {
 611                 if (length $config{gitorigin_branch}) {
 612                         run_or_cry('git', 'push', $config{gitorigin_branch});
 613                 }
 614         }
 615
 616         %ENV=%env;
 617         return undef; # success
 618 }
 619
 620 sub rcs_add ($) {
 621         # Add file to archive.
 622
 623         my ($file) = @_;
 624
 625         run_or_cry('git', 'add', $file);
 626 }
 627
 628 sub rcs_remove ($) {
 629         # Remove file from archive.
 630
 631         my ($file) = @_;
 632
 633         run_or_cry('git', 'rm', '-f', $file);
 634 }
 635
 636 sub rcs_rename ($$) {
 637         my ($src, $dest) = @_;
 638
 639         run_or_cry('git', 'mv', '-f', $src, $dest);
 640 }
 641
 642 sub rcs_recentchanges ($) {
 643         # List of recent changes.
 644
 645         my ($num) = @_;
 646
 647         eval q{use Date::Parse};
 648         error($@) if $@;
 649
 650         my @rets;
 651         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 652                 # Skip redundant commits.
 653                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 654
 655                 my ($sha1, $when) = (
 656                         $ci->{'sha1'},
 657                         $ci->{'author_epoch'}
 658                 );
 659
 660                 my @pages;
 661                 foreach my $detail (@{ $ci->{'details'} }) {
 662                         my $file = $detail->{'file'};
 663                         my $efile = uri_escape_utf8($file);
 664
 665                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 666                         $diffurl =~ s/\[\[file\]\]/$efile/go;
 667                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 668                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 669                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 670                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 671
 672                         push @pages, {
 673                                 page => pagename($file),
 674                                 diffurl => $diffurl,
 675                         };
 676                 }
 677
 678                 my @messages;
 679                 my $pastblank=0;
 680                 foreach my $line (@{$ci->{'comment'}}) {
 681                         $pastblank=1 if $line eq '';
 682                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 683                         push @messages, { line => $line };
 684                 }
 685
 686                 my $user=$ci->{'author_username'};
 687                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 688                 my $nickname;
 689
 690                 # Set nickname only if a non-url author_username is available,
 691                 # and author_name is an url.
 692                 if ($user !~ /:\/\// && defined $ci->{'author_name'} &&
 693                     $ci->{'author_name'} =~ /:\/\//) {
 694                         $nickname=$user;
 695                         $user=$ci->{'author_name'};
 696                 }
 697
 698                 # compatability code for old web commit messages
 699                 if (! $web_commit &&
 700                       defined $messages[0] &&
 701                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 702                         $user = defined $2 ? "$2" : "$3";
 703                         $messages[0]->{line} = $4;
 704                         $web_commit=1;
 705                 }
 706
 707                 push @rets, {
 708                         rev        => $sha1,
 709                         user       => $user,
 710                         nickname   => $nickname,
 711                         committype => $web_commit ? "web" : "git",
 712                         when       => $when,
 713                         message    => [@messages],
 714                         pages      => [@pages],
 715                 } if @pages;
 716
 717                 last if @rets >= $num;
 718         }
 719
 720         return @rets;
 721 }
 722
 723 sub rcs_diff ($;$) {
 724         my $rev=shift;
 725         my $maxlines=shift;
 726         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 727         my @lines;
 728         my $addlines=sub {
 729                 my $line=shift;
 730                 return if defined $maxlines && @lines == $maxlines;
 731                 push @lines, $line."\n"
 732                         if (@lines || $line=~/^diff --git/);
 733                 return 1;
 734         };
 735         safe_git(undef, $addlines, "git", "show", $sha1);
 736         if (wantarray) {
 737                 return @lines;
 738         }
 739         else {
 740                 return join("", @lines);
 741         }
 742 }
 743
 744 {
 745 my %time_cache;
 746
 747 sub findtimes ($$) {
 748         my $file=shift;
 749         my $id=shift; # 0 = mtime ; 1 = ctime
 750
 751         if (! keys %time_cache) {
 752                 my $date;
 753                 foreach my $line (run_or_die('git', 'log',
 754                                 '--pretty=format:%at',
 755                                 '--name-only', '--relative')) {
 756                         if (! defined $date && $line =~ /^(\d+)$/) {
 757                                 $date=$line;
 758                         }
 759                         elsif (! length $line) {
 760                                 $date=undef;
 761                         }
 762                         else {
 763                                 my $f=decode_git_file($line);
 764
 765                                 if (! $time_cache{$f}) {
 766                                         $time_cache{$f}[0]=$date; # mtime
 767                                 }
 768                                 $time_cache{$f}[1]=$date; # ctime
 769                         }
 770                 }
 771         }
 772
 773         return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
 774 }
 775
 776 }
 777
 778 sub rcs_getctime ($) {
 779         my $file=shift;
 780
 781         return findtimes($file, 1);
 782 }
 783
 784 sub rcs_getmtime ($) {
 785         my $file=shift;
 786
 787         return findtimes($file, 0);
 788 }
 789
 790 {
 791 my $ret;
 792 sub git_find_root {
 793         # The wiki may not be the only thing in the git repo.
 794         # Determine if it is in a subdirectory by examining the srcdir,
 795         # and its parents, looking for the .git directory.
 796
 797         return @$ret if defined $ret;
 798
 799         my $subdir="";
 800         my $dir=$config{srcdir};
 801         while (! -d "$dir/.git") {
 802                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 803                 $dir=IkiWiki::dirname($dir);
 804                 if (! length $dir) {
 805                         error("cannot determine root of git repo");
 806                 }
 807         }
 808
 809         $ret=[$subdir, $dir];
 810         return @$ret;
 811 }
 812
 813 }
 814
 815 sub git_parse_changes {
 816         my $reverted = shift;
 817         my @changes = @_;
 818
 819         my ($subdir, $rootdir) = git_find_root();
 820         my @rets;
 821         foreach my $ci (@changes) {
 822                 foreach my $detail (@{ $ci->{'details'} }) {
 823                         my $file = $detail->{'file'};
 824
 825                         # check that all changed files are in the subdir
 826                         if (length $subdir &&
 827                             ! ($file =~ s/^\Q$subdir\E//)) {
 828                                 error sprintf(gettext("you are not allowed to change %s"), $file);
 829                         }
 830
 831                         my ($action, $mode, $path);
 832                         if ($detail->{'status'} =~ /^[M]+\d*$/) {
 833                                 $action="change";
 834                                 $mode=$detail->{'mode_to'};
 835                         }
 836                         elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 837                                 $action= $reverted ? "remove" : "add";
 838                                 $mode=$detail->{'mode_to'};
 839                         }
 840                         elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 841                                 $action= $reverted ? "add" : "remove";
 842                                 $mode=$detail->{'mode_from'};
 843                         }
 844                         else {
 845                                 error "unknown status ".$detail->{'status'};
 846                         }
 847
 848                         # test that the file mode is ok
 849                         if ($mode !~ /^100[64][64][64]$/) {
 850                                 error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 851                         }
 852                         if ($action eq "change") {
 853                                 if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 854                                         error gettext("you are not allowed to change file modes");
 855                                 }
 856                         }
 857
 858                         # extract attachment to temp file
 859                         if (($action eq 'add' || $action eq 'change') &&
 860                             ! pagetype($file)) {
 861                                 eval q{use File::Temp};
 862                                 die $@ if $@;
 863                                 my $fh;
 864                                 ($fh, $path)=File::Temp::tempfile(undef, UNLINK => 1);
 865                                 my $cmd = "cd $git_dir && ".
 866                                           "git show $detail->{sha1_to} > '$path'";
 867                                 if (system($cmd) != 0) {
 868                                         error("failed writing temp file '$path'.");
 869                                 }
 870                         }
 871
 872                         push @rets, {
 873                                 file => $file,
 874                                 action => $action,
 875                                 path => $path,
 876                         };
 877                 }
 878         }
 879
 880         return @rets;
 881 }
 882
 883 sub rcs_receive () {
 884         my @rets;
 885         while (<>) {
 886                 chomp;
 887                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 888
 889                 # only allow changes to gitmaster_branch
 890                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 891                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 892                 }
 893
 894                 # Avoid chdir when running git here, because the changes
 895                 # are in the master git repo, not the srcdir repo.
 896                 # (Also, if a subdir is involved, we don't want to chdir to
 897                 # it and only see changes in it.)
 898                 # The pre-receive hook already puts us in the right place.
 899                 in_git_dir(".", sub {
 900                         push @rets, git_parse_changes(0, git_commit_info($oldrev."..".$newrev));
 901                 });
 902         }
 903
 904         return reverse @rets;
 905 }
 906
 907 sub rcs_preprevert ($) {
 908         my $rev=shift;
 909         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 910
 911         # Examine changes from root of git repo, not from any subdir,
 912         # in order to see all changes.
 913         my ($subdir, $rootdir) = git_find_root();
 914         in_git_dir($rootdir, sub {
 915                 my @commits=git_commit_info($sha1, 1);
 916
 917                 if (! @commits) {
 918                         error "unknown commit"; # just in case
 919                 }
 920
 921                 # git revert will fail on merge commits. Add a nice message.
 922                 if (exists $commits[0]->{parents} &&
 923                     @{$commits[0]->{parents}} > 1) {
 924                         error gettext("you are not allowed to revert a merge");
 925                 }
 926
 927                 git_parse_changes(1, @commits);
 928         });
 929 }
 930
 931 sub rcs_revert ($) {
 932         # Try to revert the given rev; returns undef on _success_.
 933         my $rev = shift;
 934         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 935
 936         if (run_or_non('git', 'revert', '--no-commit', $sha1)) {
 937                 return undef;
 938         }
 939         else {
 940                 run_or_die('git', 'reset', '--hard');
 941                 return sprintf(gettext("Failed to revert commit %s"), $sha1);
 942         }
 943 }
 944
 945 1