IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23 }
  24
  25 sub check_canremove ($$$) {
  26         my $page=shift;
  27         my $q=shift;
  28         my $session=shift;
  29
  30         # Must be a known source file.
  31         if (! exists $pagesources{$page}) {
  32                 error(sprintf(gettext("%s does not exist"),
  33                         htmllink("", "", $page, noimageinline => 1)));
  34         }
  35
  36         # Must exist on disk, and be a regular file.
  37         my $file=$pagesources{$page};
  38         if (! -e "$config{srcdir}/$file") {
  39                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  40         }
  41         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  42                 error(sprintf(gettext("%s is not a file"), $file));
  43         }
  44
  45         # If a user can't upload an attachment, don't let them delete it.
  46         # This is sorta overkill, but better safe than sorry.
  47         if (! defined pagetype($pagesources{$page})) {
  48                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  49                         IkiWiki::Plugin::attachment::check_canattach($session, $page, "$config{srcdir}/$file");
  50                 }
  51                 else {
  52                         error("removal of attachments is not allowed");
  53                 }
  54         }
  55
  56         my $canremove;
  57         IkiWiki::run_hooks(canremove => sub {
  58                 return if defined $canremove;
  59                 my $ret=shift->(page => $page, cgi => $q, session => $session);
  60                 if (defined $ret) {
  61                         if ($ret eq "") {
  62                                 $canremove=1;
  63                         }
  64                         elsif (ref $ret eq 'CODE') {
  65                                 $ret->();
  66                                 $canremove=0;
  67                         }
  68                         elsif (defined $ret) {
  69                                 error($ret);
  70                                 $canremove=0;
  71                         }
  72                 }
  73         });
  74         return defined $canremove ? $canremove : 1;
  75 }
  76
  77 sub formbuilder_setup (@) {
  78         my %params=@_;
  79         my $form=$params{form};
  80         my $q=$params{cgi};
  81
  82         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  83             $form->field("do") eq "create")) {
  84                 # Removal button for the page, and also for attachments.
  85                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  86                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  87         }
  88 }
  89
  90 sub confirmation_form ($$) {
  91         my $q=shift;
  92         my $session=shift;
  93
  94         eval q{use CGI::FormBuilder};
  95         error($@) if $@;
  96         my $f = CGI::FormBuilder->new(
  97                 name => "remove",
  98                 header => 0,
  99                 charset => "utf-8",
 100                 method => 'POST',
 101                 javascript => 0,
 102                 params => $q,
 103                 action => IkiWiki::cgiurl(),
 104                 stylesheet => 1,
 105                 fields => [qw{do page}],
 106         );
 107
 108         $f->field(name => "sid", type => "hidden", value => $session->id,
 109                 force => 1);
 110         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
 111
 112         return $f, ["Remove", "Cancel"];
 113 }
 114
 115 sub removal_confirm ($$@) {
 116         my $q=shift;
 117         my $session=shift;
 118         my $attachment=shift;
 119         my @pages=@_;
 120
 121         # Special case for unsaved attachments.
 122         foreach my $page (@pages) {
 123                 if ($attachment && IkiWiki::Plugin::attachment->can("is_held_attachment")) {
 124                         my $f=IkiWiki::Plugin::attachment::is_held_attachment($page);
 125                         if (defined $f) {
 126                                 require IkiWiki::Render;
 127                                 IkiWiki::prune($f);
 128                         }
 129                 }
 130         }
 131         @pages=grep { exists $pagesources{$_} } @pages;
 132         return unless @pages;
 133
 134         foreach my $page (@pages) {
 135                 IkiWiki::check_canedit($page, $q, $session);
 136                 check_canremove($page, $q, $session);
 137         }
 138
 139         # Save current form state to allow returning to it later
 140         # without losing any edits.
 141         # (But don't save what button was submitted, to avoid
 142         # looping back to here.)
 143         # Note: "_submit" is CGI::FormBuilder internals.
 144         $q->param(-name => "_submit", -value => "");
 145         $session->param(postremove => scalar $q->Vars);
 146         IkiWiki::cgi_savesession($session);
 147
 148         my ($f, $buttons)=confirmation_form($q, $session);
 149         $f->title(sprintf(gettext("confirm removal of %s"),
 150                 join(", ", map { pagetitle($_) } @pages)));
 151         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 152         if (defined $attachment) {
 153                 $f->field(name => "attachment", type => "hidden",
 154                         value => $attachment, force => 1);
 155         }
 156
 157         IkiWiki::showform($f, $buttons, $session, $q);
 158         exit 0;
 159 }
 160
 161 sub postremove ($) {
 162         my $session=shift;
 163
 164         # Load saved form state and return to edit form.
 165         my $postremove=CGI->new($session->param("postremove"));
 166         $session->clear("postremove");
 167         IkiWiki::cgi_savesession($session);
 168         IkiWiki::cgi($postremove, $session);
 169 }
 170
 171 sub formbuilder (@) {
 172         my %params=@_;
 173         my $form=$params{form};
 174
 175         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 176             $form->field("do") eq "create")) {
 177                 my $q=$params{cgi};
 178                 my $session=$params{session};
 179
 180                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 181                         removal_confirm($q, $session, 0, $form->field("page"));
 182                 }
 183                 elsif ($form->submitted eq "Remove Attachments") {
 184                         my @selected=map { Encode::decode_utf8($_) } $q->param("attachment_select");
 185                         if (! @selected) {
 186                                 error(gettext("Please select the attachments to remove."));
 187                         }
 188                         removal_confirm($q, $session, 1, @selected);
 189                 }
 190         }
 191 }
 192
 193 sub sessioncgi ($$) {
 194         my $q=shift;
 195
 196         if ($q->param("do") eq 'remove') {
 197                 my $session=shift;
 198                 my ($form, $buttons)=confirmation_form($q, $session);
 199                 IkiWiki::decode_form_utf8($form);
 200
 201                 if ($form->submitted eq 'Cancel') {
 202                         postremove($session);
 203                 }
 204                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 205                         IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 206
 207                         my @pages=$form->field("page");
 208
 209                         # Validate removal by checking that the page exists,
 210                         # and that the user is allowed to edit(/remove) it.
 211                         my @files;
 212                         foreach my $page (@pages) {
 213                                 IkiWiki::check_canedit($page, $q, $session);
 214                                 check_canremove($page, $q, $session);
 215
 216                                 # This untaint is safe because of the
 217                                 # checks performed above, which verify the
 218                                 # page is a normal file, etc.
 219                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 220                         }
 221
 222                         # Do removal, and update the wiki.
 223                         require IkiWiki::Render;
 224                         if ($config{rcs}) {
 225                                 IkiWiki::disable_commit_hook();
 226                                 foreach my $file (@files) {
 227                                         IkiWiki::rcs_remove($file);
 228                                 }
 229                                 IkiWiki::rcs_commit_staged(
 230                                         message => gettext("removed"),
 231                                         session => $session,
 232                                 );
 233                                 IkiWiki::enable_commit_hook();
 234                                 IkiWiki::rcs_update();
 235                         }
 236                         else {
 237                                 foreach my $file (@files) {
 238                                         IkiWiki::prune("$config{srcdir}/$file");
 239                                 }
 240                         }
 241                         IkiWiki::refresh();
 242                         IkiWiki::saveindex();
 243
 244                         if ($q->param("attachment")) {
 245                                 # Attachments were deleted, so redirect
 246                                 # back to the edit form.
 247                                 postremove($session);
 248                         }
 249                         else {
 250                                 # The page is gone, so redirect to parent
 251                                 # of the page.
 252                                 my $parent=IkiWiki::dirname($pages[0]);
 253                                 if (! exists $pagesources{$parent}) {
 254                                         $parent="index";
 255                                 }
 256                                 IkiWiki::redirect($q, urlto($parent));
 257                         }
 258                 }
 259                 else {
 260                         removal_confirm($q, $session, 0, $form->field("page"));
 261                 }
 262
 263                 exit 0;
 264         }
 265 }
 266
 267 1