IkiWiki/Rcs/bzr.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9 use open qw{:utf8 :std};
  10
  11 sub bzr_log ($) { #{{{
  12         my $out = shift;
  13         my @infos = ();
  14         my $key = undef;
  15
  16         while (<$out>) {
  17                 my $line = $_;
  18                 my ($value);
  19                 if ($line =~ /^message:/) {
  20                         $key = "message";
  21                         $infos[$#infos]{$key} = "";
  22                 }
  23                 elsif ($line =~ /^(modified|added|renamed|renamed and modified|removed):/) {
  24                         $key = "files";
  25                         unless (defined($infos[$#infos]{$key})) { $infos[$#infos]{$key} = ""; }
  26                 }
  27                 elsif (defined($key) and $line =~ /^  (.*)/) {
  28                         $infos[$#infos]{$key} .= $1;
  29                 }
  30                 elsif ($line eq "------------------------------------------------------------\n") {
  31                         $key = undef;
  32                         push (@infos, {});
  33                 }
  34                 else {
  35                         chomp $line;
  36                                 ($key, $value) = split /: +/, $line, 2;
  37                         $infos[$#infos]{$key} = $value;
  38                 }
  39         }
  40         close $out;
  41
  42         return @infos;
  43 } #}}}
  44
  45 sub rcs_update () { #{{{
  46         my @cmdline = ("bzr", "update", "--quiet", $config{srcdir});
  47         if (system(@cmdline) != 0) {
  48                 warn "'@cmdline' failed: $!";
  49         }
  50 } #}}}
  51
  52 sub rcs_prepedit ($) { #{{{
  53         return "";
  54 } #}}}
  55
  56 sub rcs_commit ($$$;$$) { #{{{
  57         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
  58
  59         if (defined $user) {
  60                 $user = possibly_foolish_untaint($user);
  61         }
  62         elsif (defined $ipaddr) {
  63                 $user = "Anonymous from ".possibly_foolish_untaint($ipaddr);
  64         }
  65         else {
  66                 $user = "Anonymous";
  67         }
  68
  69         $message = possibly_foolish_untaint($message);
  70         if (! length $message) {
  71                 $message = "no message given";
  72         }
  73
  74         my @cmdline = ("bzr", "commit", "--quiet", "-m", $message, "--author", $user,
  75                        $config{srcdir}."/".$file);
  76         if (system(@cmdline) != 0) {
  77                 warn "'@cmdline' failed: $!";
  78         }
  79
  80         return undef; # success
  81 } #}}}
  82
  83 sub rcs_add ($) { # {{{
  84         my ($file) = @_;
  85
  86         my @cmdline = ("bzr", "add", "--quiet", "$config{srcdir}/$file");
  87         if (system(@cmdline) != 0) {
  88                 warn "'@cmdline' failed: $!";
  89         }
  90 } #}}}
  91
  92 sub rcs_remove ($) { # {{{
  93         my ($file) = @_;
  94
  95         error("rcs_remove not implemented for bzr"); # TODO
  96 } #}}}
  97
  98 sub rcs_recentchanges ($) { #{{{
  99         my ($num) = @_;
 100
 101         my @cmdline = ("bzr", "log", "-v", "--show-ids", "--limit", $num,
 102                            $config{srcdir});
 103         open (my $out, "@cmdline |");
 104
 105         eval q{use Date::Parse};
 106         error($@) if $@;
 107
 108         my @ret;
 109         foreach my $info (bzr_log($out)) {
 110                 my @pages = ();
 111                 my @message = ();
 112
 113                 foreach my $msgline (split(/\n/, $info->{message})) {
 114                         push @message, { line => $msgline };
 115                 }
 116
 117                 foreach my $file (split(/\n/, $info->{files})) {
 118                         my ($filename, $fileid) = split(/[ \t]+/, $file);
 119                         my $diffurl = $config{'diffurl'};
 120                         $diffurl =~ s/\[\[file\]\]/$filename/go;
 121                         $diffurl =~ s/\[\[file-id\]\]/$fileid/go;
 122                         $diffurl =~ s/\[\[r2\]\]/$info->{revno}/go;
 123
 124                         push @pages, {
 125                                 page => pagename($filename),
 126                                 diffurl => $diffurl,
 127                         };
 128                 }
 129
 130                 my $user = $info->{"committer"};
 131                 if (defined($info->{"author"})) { $user = $info->{"author"}; }
 132                 $user =~ s/\s*<.*>\s*$//;
 133                 $user =~ s/^\s*//;
 134
 135                 push @ret, {
 136                         rev        => $info->{"revno"},
 137                         user       => $user,
 138                         committype => "bzr",
 139                         when       => time - str2time($info->{"timestamp"}),
 140                         message    => [@message],
 141                         pages      => [@pages],
 142                 };
 143         }
 144
 145         return @ret;
 146 } #}}}
 147
 148 sub rcs_getctime ($) { #{{{
 149         my ($file) = @_;
 150
 151         # XXX filename passes through the shell here, should try to avoid
 152         # that just in case
 153         my @cmdline = ("bzr", "log", "--limit", '1', "$config{srcdir}/$file");
 154         open (my $out, "@cmdline |");
 155
 156         my @log = bzr_log($out);
 157
 158         if (length @log < 1) {
 159                 return 0;
 160         }
 161
 162         eval q{use Date::Parse};
 163         error($@) if $@;
 164
 165         my $ctime = str2time($log[0]->{"timestamp"});
 166         return $ctime;
 167 } #}}}
 168
 169 1