IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my %backlinks;
  11 my $backlinks_calculated=0;
  12
  13 sub calculate_backlinks () { #{{{
  14         return if $backlinks_calculated;
  15         %backlinks=();
  16         foreach my $page (keys %links) {
  17                 foreach my $link (@{$links{$page}}) {
  18                         my $bestlink=bestlink($page, $link);
  19                         if (length $bestlink && $bestlink ne $page) {
  20                                 $backlinks{$bestlink}{$page}=1;
  21                         }
  22                 }
  23         }
  24         $backlinks_calculated=1;
  25 } #}}}
  26
  27 sub backlinks ($) { #{{{
  28         my $page=shift;
  29
  30         calculate_backlinks();
  31
  32         my @links;
  33         return unless $backlinks{$page};
  34         foreach my $p (keys %{$backlinks{$page}}) {
  35                 my $href=abs2rel(htmlpage($p), dirname($page));
  36
  37                 # Trim common dir prefixes from both pages.
  38                 my $p_trimmed=$p;
  39                 my $page_trimmed=$page;
  40                 my $dir;
  41                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  42                         defined $dir &&
  43                         $p_trimmed=~s/^\Q$dir\E// &&
  44                         $page_trimmed=~s/^\Q$dir\E//;
  45
  46                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  47         }
  48
  49         return sort { $a->{page} cmp $b->{page} } @links;
  50 } #}}}
  51
  52 sub parentlinks ($) { #{{{
  53         my $page=shift;
  54
  55         my @ret;
  56         my $pagelink="";
  57         my $path="";
  58         my $skip=1;
  59         return if $page eq 'index'; # toplevel
  60         foreach my $dir (reverse split("/", $page)) {
  61                 if (! $skip) {
  62                         $path.="../";
  63                         unshift @ret, { url => $path.htmlpage($dir), page => pagetitle($dir) };
  64                 }
  65                 else {
  66                         $skip=0;
  67                 }
  68         }
  69         unshift @ret, { url => length $path ? $path : ".", page => $config{wikiname} };
  70         return @ret;
  71 } #}}}
  72
  73 sub genpage ($$$) { #{{{
  74         my $page=shift;
  75         my $content=shift;
  76         my $mtime=shift;
  77
  78         my $template=template("page.tmpl", blind_cache => 1);
  79         my $actions=0;
  80
  81         if (length $config{cgiurl}) {
  82                 $template->param(editurl => cgiurl(do => "edit", page => $page));
  83                 $template->param(prefsurl => cgiurl(do => "prefs"));
  84                 if ($config{rcs}) {
  85                         $template->param(recentchangesurl => cgiurl(do => "recentchanges"));
  86                 }
  87                 $actions++;
  88         }
  89
  90         if (length $config{historyurl}) {
  91                 my $u=$config{historyurl};
  92                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  93                 $template->param(historyurl => $u);
  94                 $actions++;
  95         }
  96         if ($config{discussion}) {
  97                 my $discussionlink=gettext("discussion");
  98                 if ($page !~ /.*\/\Q$discussionlink\E$/ &&
  99                    (length $config{cgiurl} ||
 100                     exists $links{$page."/".$discussionlink})) {
 101                         $template->param(discussionlink => htmllink($page, $page, gettext("Discussion"), 1, 1));
 102                         $actions++;
 103                 }
 104         }
 105
 106         if ($actions) {
 107                 $template->param(have_actions => 1);
 108         }
 109
 110         $template->param(
 111                 title => $page eq 'index'
 112                         ? $config{wikiname}
 113                         : pagetitle(basename($page)),
 114                 wikiname => $config{wikiname},
 115                 parentlinks => [parentlinks($page)],
 116                 content => $content,
 117                 backlinks => [backlinks($page)],
 118                 mtime => displaytime($mtime),
 119                 baseurl => baseurl($page),
 120         );
 121
 122         run_hooks(pagetemplate => sub {
 123                 shift->(page => $page, destpage => $page, template => $template);
 124         });
 125
 126         $content=$template->output;
 127
 128         run_hooks(format => sub {
 129                 $content=shift->(
 130                         page => $page,
 131                         content => $content,
 132                 );
 133         });
 134
 135         return $content;
 136 } #}}}
 137
 138 sub mtime ($) { #{{{
 139         my $file=shift;
 140
 141         return (stat($file))[9];
 142 } #}}}
 143
 144 sub scan ($) { #{{{
 145         my $file=shift;
 146
 147         my $type=pagetype($file);
 148         if (defined $type) {
 149                 my $srcfile=srcfile($file);
 150                 my $content=readfile($srcfile);
 151                 my $page=pagename($file);
 152                 will_render($page, htmlpage($page), 1);
 153
 154                 # Always needs to be done, since filters might add links
 155                 # to the content.
 156                 $content=filter($page, $content);
 157
 158                 my @links;
 159                 while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 160                         push @links, titlepage($2);
 161                 }
 162                 if ($config{discussion}) {
 163                         # Discussion links are a special case since they're
 164                         # not in the text of the page, but on its template.
 165                         push @links, $page."/".gettext("discussion");
 166                 }
 167                 $links{$page}=\@links;
 168
 169                 # Preprocess in scan-only mode.
 170                 preprocess($page, $page, $content, 1);
 171         }
 172         else {
 173                 will_render($file, $file, 1);
 174         }
 175 } #}}}
 176
 177 sub render ($) { #{{{
 178         my $file=shift;
 179
 180         my $type=pagetype($file);
 181         my $srcfile=srcfile($file);
 182         if (defined $type) {
 183                 my $content=readfile($srcfile);
 184                 my $page=pagename($file);
 185                 delete $depends{$page};
 186                 will_render($page, htmlpage($page), 1);
 187
 188                 $content=filter($page, $content);
 189                 $content=preprocess($page, $page, $content);
 190                 $content=linkify($page, $page, $content);
 191                 $content=htmlize($page, $type, $content);
 192
 193                 writefile(htmlpage($page), $config{destdir},
 194                         genpage($page, $content, mtime($srcfile)));
 195                 $oldpagemtime{$page}=time;
 196         }
 197         else {
 198                 my $content=readfile($srcfile, 1);
 199                 delete $depends{$file};
 200                 will_render($file, $file, 1);
 201                 writefile($file, $config{destdir}, $content, 1);
 202                 $oldpagemtime{$file}=time;
 203         }
 204 } #}}}
 205
 206 sub prune ($) { #{{{
 207         my $file=shift;
 208
 209         unlink($file);
 210         my $dir=dirname($file);
 211         while (rmdir($dir)) {
 212                 $dir=dirname($dir);
 213         }
 214 } #}}}
 215
 216 sub refresh () { #{{{
 217         # find existing pages
 218         my %exists;
 219         my @files;
 220         eval q{use File::Find};
 221         error($@) if $@;
 222         find({
 223                 no_chdir => 1,
 224                 wanted => sub {
 225                         $_=decode_utf8($_);
 226                         if (file_pruned($_, $config{srcdir})) {
 227                                 $File::Find::prune=1;
 228                         }
 229                         elsif (! -d $_ && ! -l $_) {
 230                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 231                                 if (! defined $f) {
 232                                         warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
 233                                 }
 234                                 else {
 235                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 236                                         push @files, $f;
 237                                         $exists{pagename($f)}=1;
 238                                 }
 239                         }
 240                 },
 241         }, $config{srcdir});
 242         find({
 243                 no_chdir => 1,
 244                 wanted => sub {
 245                         $_=decode_utf8($_);
 246                         if (file_pruned($_, $config{underlaydir})) {
 247                                 $File::Find::prune=1;
 248                         }
 249                         elsif (! -d $_ && ! -l $_) {
 250                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 251                                 if (! defined $f) {
 252                                         warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
 253                                 }
 254                                 else {
 255                                         # Don't add pages that are in the
 256                                         # srcdir.
 257                                         $f=~s/^\Q$config{underlaydir}\E\/?//;
 258                                         if (! -e "$config{srcdir}/$f" &&
 259                                             ! -l "$config{srcdir}/$f") {
 260                                                 my $page=pagename($f);
 261                                                 if (! $exists{$page}) {
 262                                                         push @files, $f;
 263                                                         $exists{$page}=1;
 264                                                 }
 265                                         }
 266                                 }
 267                         }
 268                 },
 269         }, $config{underlaydir});
 270
 271         my %rendered;
 272
 273         # check for added or removed pages
 274         my @add;
 275         foreach my $file (@files) {
 276                 my $page=pagename($file);
 277                 $pagesources{$page}=$file;
 278                 if (! $oldpagemtime{$page}) {
 279                         push @add, $file;
 280                         $pagecase{lc $page}=$page;
 281                         if ($config{getctime} && -e "$config{srcdir}/$file") {
 282                                 $pagectime{$page}=rcs_getctime("$config{srcdir}/$file");
 283                         }
 284                         elsif (! exists $pagectime{$page}) {
 285                                 $pagectime{$page}=mtime(srcfile($file));
 286                         }
 287                 }
 288         }
 289         my @del;
 290         foreach my $page (keys %oldpagemtime) {
 291                 if (! $exists{$page}) {
 292                         debug(sprintf(gettext("removing old page %s"), $page));
 293                         push @del, $pagesources{$page};
 294                         $links{$page}=[];
 295                         $renderedfiles{$page}=[];
 296                         $oldpagemtime{$page}=0;
 297                         prune($config{destdir}."/".$_)
 298                                 foreach @{$oldrenderedfiles{$page}};
 299                         delete $pagesources{$page};
 300                 }
 301         }
 302
 303         # scan changed and new files
 304         my @changed;
 305         foreach my $file (@files) {
 306                 my $page=pagename($file);
 307
 308                 if (! exists $oldpagemtime{$page} ||
 309                     mtime(srcfile($file)) > $oldpagemtime{$page} ||
 310                     $forcerebuild{$page}) {
 311                         debug(sprintf(gettext("scanning %s"), $file));
 312                         push @changed, $file;
 313                         scan($file);
 314                 }
 315         }
 316         calculate_backlinks();
 317
 318         # render changed and new pages
 319         foreach my $file (@changed) {
 320                 debug(sprintf(gettext("rendering %s"), $file));
 321                 render($file);
 322                 $rendered{$file}=1;
 323         }
 324
 325         # rebuild pages that link to added or removed pages
 326         if (@add || @del) {
 327                 foreach my $f (@add, @del) {
 328                         my $p=pagename($f);
 329                         foreach my $page (keys %{$backlinks{$p}}) {
 330                                 my $file=$pagesources{$page};
 331                                 next if $rendered{$file};
 332                                 debug(sprintf(gettext("rendering %s, which links to %s"), $file, $p));
 333                                 render($file);
 334                                 $rendered{$file}=1;
 335                         }
 336                 }
 337         }
 338
 339         if (%rendered || @del) {
 340                 # rebuild dependant pages
 341                 foreach my $f (@files) {
 342                         next if $rendered{$f};
 343                         my $p=pagename($f);
 344                         if (exists $depends{$p}) {
 345                                 foreach my $file (keys %rendered, @del) {
 346                                         next if $f eq $file;
 347                                         my $page=pagename($file);
 348                                         if (pagespec_match($page, $depends{$p})) {
 349                                                 debug(sprintf(gettext("rendering %s, which depends on %s"), $f, $page));
 350                                                 render($f);
 351                                                 $rendered{$f}=1;
 352                                                 last;
 353                                         }
 354                                 }
 355                         }
 356                 }
 357
 358                 # handle backlinks; if a page has added/removed links,
 359                 # update the pages it links to
 360                 my %linkchanged;
 361                 foreach my $file (keys %rendered, @del) {
 362                         my $page=pagename($file);
 363
 364                         if (exists $links{$page}) {
 365                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 366                                         if (length $link &&
 367                                             (! exists $oldlinks{$page} ||
 368                                              ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
 369                                                 $linkchanged{$link}=1;
 370                                         }
 371                                 }
 372                         }
 373                         if (exists $oldlinks{$page}) {
 374                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 375                                         if (length $link &&
 376                                             (! exists $links{$page} ||
 377                                              ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
 378                                                 $linkchanged{$link}=1;
 379                                         }
 380                                 }
 381                         }
 382                 }
 383                 foreach my $link (keys %linkchanged) {
 384                         my $linkfile=$pagesources{$link};
 385                         if (defined $linkfile) {
 386                                 next if $rendered{$linkfile};
 387                                 debug(sprintf(gettext("rendering %s, to update its backlinks"), $linkfile));
 388                                 render($linkfile);
 389                                 $rendered{$linkfile}=1;
 390                         }
 391                 }
 392         }
 393
 394         # remove no longer rendered files
 395         foreach my $src (keys %rendered) {
 396                 my $page=pagename($src);
 397                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 398                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 399                                 debug(sprintf(gettext("removing %s, no longer rendered by %s"), $file, $page));
 400                                 prune($config{destdir}."/".$file);
 401                         }
 402                 }
 403         }
 404
 405         if (@del) {
 406                 run_hooks(delete => sub { shift->(@del) });
 407         }
 408         if (%rendered) {
 409                 run_hooks(change => sub { shift->(keys %rendered) });
 410         }
 411 } #}}}
 412
 413 sub commandline_render () { #{{{
 414         loadplugins();
 415         checkconfig();
 416         lockwiki();
 417         loadindex();
 418         unlockwiki();
 419
 420         my $srcfile=possibly_foolish_untaint($config{render});
 421         my $file=$srcfile;
 422         $file=~s/\Q$config{srcdir}\E\/?//;
 423
 424         my $type=pagetype($file);
 425         die sprintf(gettext("ikiwiki: cannot render %s"), $srcfile)."\n" unless defined $type;
 426         my $content=readfile($srcfile);
 427         my $page=pagename($file);
 428         $pagesources{$page}=$file;
 429         $content=filter($page, $content);
 430         $content=preprocess($page, $page, $content);
 431         $content=linkify($page, $page, $content);
 432         $content=htmlize($page, $type, $content);
 433
 434         print genpage($page, $content, mtime($srcfile));
 435         exit 0;
 436 } #}}}
 437
 438 1