IkiWiki/Plugin/editpage.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::editpage;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use open qw{:utf8 :std};
   8
   9 sub import {
  10         hook(type => "getsetup", id => "editpage", call => \&getsetup);
  11         hook(type => "refresh", id => "editpage", call => \&refresh);
  12         hook(type => "sessioncgi", id => "editpage", call => \&IkiWiki::cgi_editpage);
  13 }
  14
  15 sub getsetup () {
  16         return
  17                 plugin => {
  18                         safe => 1,
  19                         rebuild => 1,
  20                         section => "core",
  21                 },
  22 }
  23
  24 sub refresh () {
  25         if (exists $wikistate{editpage} && exists $wikistate{editpage}{previews}) {
  26                 # Expire old preview files after one hour.
  27                 my $expire=time - (60 * 60);
  28
  29                 my @previews;
  30                 foreach my $file (@{$wikistate{editpage}{previews}}) {
  31                         my $mtime=(stat("$config{destdir}/$file"))[9];
  32                         if (defined $mtime && $mtime <= $expire) {
  33                                 # Avoid deleting a preview that was later saved.
  34                                 my $delete=1;
  35                                 foreach my $page (keys %renderedfiles) {
  36                                         if (grep { $_ eq $file } @{$renderedfiles{$page}}) {
  37                                                 $delete=0;
  38                                         }
  39                                 }
  40                                 if ($delete) {
  41                                         debug(sprintf(gettext("removing old preview %s"), $file));
  42                                         IkiWiki::prune("$config{destdir}/$file");
  43                                 }
  44                         }
  45                         elsif (defined $mtime) {
  46                                 push @previews, $file;
  47                         }
  48                 }
  49                 $wikistate{editpage}{previews}=\@previews;
  50         }
  51 }
  52
  53 # Back to ikiwiki namespace for the rest, this code is very much
  54 # internal to ikiwiki even though it's separated into a plugin,
  55 # and other plugins use the function below.
  56 package IkiWiki;
  57
  58 sub cgi_editpage ($$) {
  59         my $q=shift;
  60         my $session=shift;
  61
  62         my $do=$q->param('do');
  63         return unless $do eq 'create' || $do eq 'edit';
  64
  65         decode_cgi_utf8($q);
  66
  67         my @fields=qw(do rcsinfo subpage from page type editcontent editmessage);
  68         my @buttons=("Save Page", "Preview", "Cancel");
  69         eval q{use CGI::FormBuilder};
  70         error($@) if $@;
  71         my $form = CGI::FormBuilder->new(
  72                 fields => \@fields,
  73                 charset => "utf-8",
  74                 method => 'POST',
  75                 required => [qw{editcontent}],
  76                 javascript => 0,
  77                 params => $q,
  78                 action => IkiWiki::cgiurl(),
  79                 header => 0,
  80                 table => 0,
  81                 template => { template("editpage.tmpl") },
  82         );
  83
  84         decode_form_utf8($form);
  85         run_hooks(formbuilder_setup => sub {
  86                 shift->(form => $form, cgi => $q, session => $session,
  87                         buttons => \@buttons);
  88         });
  89         decode_form_utf8($form);
  90
  91         # This untaint is safe because we check file_pruned and
  92         # wiki_file_regexp.
  93         my ($page)=$form->field('page')=~/$config{wiki_file_regexp}/;
  94         $page=possibly_foolish_untaint($page);
  95         my $absolute=($page =~ s#^/+##); # absolute name used to force location
  96         if (! defined $page || ! length $page ||
  97             file_pruned($page)) {
  98                 error(gettext("bad page name"));
  99         }
 100
 101         my $baseurl = urlto($page, undef);
 102
 103         my $from;
 104         if (defined $form->field('from')) {
 105                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 106         }
 107
 108         my $file;
 109         my $type;
 110         if (exists $pagesources{$page} && $form->field("do") ne "create") {
 111                 $file=$pagesources{$page};
 112                 $type=pagetype($file);
 113                 if (! defined $type || $type=~/^_/) {
 114                         error(sprintf(gettext("%s is not an editable page"), $page));
 115                 }
 116                 if (! $form->submitted) {
 117                         $form->field(name => "rcsinfo",
 118                                 value => rcs_prepedit($file), force => 1);
 119                 }
 120                 $form->field(name => "editcontent", validate => '/.*/');
 121         }
 122         else {
 123                 $type=$form->param('type');
 124                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 125                         $type=possibly_foolish_untaint($type);
 126                 }
 127                 elsif (defined $from && exists $pagesources{$from}) {
 128                         # favor the type of linking page
 129                         $type=pagetype($pagesources{$from});
 130                 }
 131                 $type=$config{default_pageext} unless defined $type;
 132                 $file=newpagefile($page, $type);
 133                 if (! $form->submitted) {
 134                         $form->field(name => "rcsinfo", value => "", force => 1);
 135                 }
 136                 $form->field(name => "editcontent", validate => '/.+/');
 137         }
 138
 139         $form->field(name => "do", type => 'hidden');
 140         $form->field(name => "sid", type => "hidden", value => $session->id,
 141                 force => 1);
 142         $form->field(name => "from", type => 'hidden');
 143         $form->field(name => "rcsinfo", type => 'hidden');
 144         $form->field(name => "subpage", type => 'hidden');
 145         $form->field(name => "page", value => $page, force => 1);
 146         $form->field(name => "type", value => $type, force => 1);
 147         $form->field(name => "editmessage", type => "text", size => 80);
 148         $form->field(name => "editcontent", type => "textarea", rows => 20,
 149                 cols => 80);
 150         $form->tmpl_param("can_commit", $config{rcs});
 151         $form->tmpl_param("helponformattinglink",
 152                 htmllink($page, $page, "ikiwiki/formatting",
 153                         noimageinline => 1,
 154                         linktext => "FormattingHelp"));
 155
 156         my $previewing=0;
 157         if ($form->submitted eq "Cancel") {
 158                 if ($form->field("do") eq "create" && defined $from) {
 159                         redirect($q, urlto($from, undef));
 160                 }
 161                 elsif ($form->field("do") eq "create") {
 162                         redirect($q, baseurl(undef));
 163                 }
 164                 else {
 165                         redirect($q, urlto($page, undef));
 166                 }
 167                 exit;
 168         }
 169         elsif ($form->submitted eq "Preview") {
 170                 $previewing=1;
 171
 172                 my $new=not exists $pagesources{$page};
 173                 # temporarily record its type
 174                 $pagesources{$page}=$page.".".$type if $new;
 175                 my %wasrendered=map { $_ => 1 } @{$renderedfiles{$page}};
 176
 177                 my $content=$form->field('editcontent');
 178
 179                 run_hooks(editcontent => sub {
 180                         $content=shift->(
 181                                 content => $content,
 182                                 page => $page,
 183                                 cgi => $q,
 184                                 session => $session,
 185                         );
 186                 });
 187                 my $preview=htmlize($page, $page, $type,
 188                         linkify($page, $page,
 189                         preprocess($page, $page,
 190                         filter($page, $page, $content), 0, 1)));
 191                 run_hooks(format => sub {
 192                         $preview=shift->(
 193                                 page => $page,
 194                                 content => $preview,
 195                         );
 196                 });
 197                 $form->tmpl_param("page_preview", $preview);
 198
 199                 # Previewing may have created files on disk.
 200                 # Keep a list of these to be deleted later.
 201                 my %previews = map { $_ => 1 } @{$wikistate{editpage}{previews}};
 202                 foreach my $f (@{$renderedfiles{$page}}) {
 203                         $previews{$f}=1 unless $wasrendered{$f};
 204                 }
 205
 206                 # Throw out any other state changes made during previewing,
 207                 # and save the previews list.
 208                 loadindex();
 209                 @{$wikistate{editpage}{previews}} = keys %previews;
 210                 saveindex();
 211         }
 212         elsif ($form->submitted eq "Save Page") {
 213                 $form->tmpl_param("page_preview", "");
 214         }
 215
 216         if ($form->submitted ne "Save Page" || ! $form->validate) {
 217                 if ($form->field("do") eq "create") {
 218                         my @page_locs;
 219                         my $best_loc;
 220                         if (! defined $from || ! length $from ||
 221                             $from ne $form->field('from') ||
 222                             file_pruned($from) ||
 223                             $absolute ||
 224                             $form->submitted) {
 225                                 @page_locs=$best_loc=$page;
 226                         }
 227                         else {
 228                                 my $dir=$from."/";
 229                                 $dir=~s![^/]+/+$!!;
 230
 231                                 if ((defined $form->field('subpage') &&
 232                                      length $form->field('subpage')) ||
 233                                     $page eq lc($config{discussionpage})) {
 234                                         $best_loc="$from/$page";
 235                                 }
 236                                 else {
 237                                         $best_loc=$dir.$page;
 238                                 }
 239
 240                                 push @page_locs, $dir.$page;
 241                                 push @page_locs, "$from/$page";
 242                                 while (length $dir) {
 243                                         $dir=~s![^/]+/+$!!;
 244                                         push @page_locs, $dir.$page;
 245                                 }
 246
 247                                 my $userpage=IkiWiki::userpage($page);
 248                                 push @page_locs, $userpage
 249                                         if ! grep { $_ eq $userpage } @page_locs;
 250                         }
 251
 252                         @page_locs = grep {
 253                                 ! exists $pagecase{lc $_}
 254                         } @page_locs;
 255                         if (! @page_locs) {
 256                                 # hmm, someone else made the page in the
 257                                 # meantime?
 258                                 if ($previewing) {
 259                                         # let them go ahead with the edit
 260                                         # and resolve the conflict at save
 261                                         # time
 262                                         @page_locs=$page;
 263                                 }
 264                                 else {
 265                                         redirect($q, urlto($page, undef));
 266                                         exit;
 267                                 }
 268                         }
 269
 270                         my @editable_locs = grep {
 271                                 check_canedit($_, $q, $session, 1)
 272                         } @page_locs;
 273                         if (! @editable_locs) {
 274                                 # now let it throw an error, or prompt for
 275                                 # login
 276                                 map { check_canedit($_, $q, $session) }
 277                                         ($best_loc, @page_locs);
 278                         }
 279
 280                         my @page_types;
 281                         if (exists $hooks{htmlize}) {
 282                                 foreach my $key (grep { !/^_/ } keys %{$hooks{htmlize}}) {
 283                                         push @page_types, [$key, $hooks{htmlize}{$key}{longname} || $key];
 284                                 }
 285                         }
 286                         @page_types=sort @page_types;
 287
 288                         $form->tmpl_param("page_select", 1);
 289                         $form->field(name => "page", type => 'select',
 290                                 options => [ map { [ $_, pagetitle($_, 1) ] } @editable_locs ],
 291                                 value => $best_loc);
 292                         $form->field(name => "type", type => 'select',
 293                                 options => \@page_types);
 294                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 295
 296                 }
 297                 elsif ($form->field("do") eq "edit") {
 298                         check_canedit($page, $q, $session);
 299                         if (! defined $form->field('editcontent') ||
 300                             ! length $form->field('editcontent')) {
 301                                 my $content="";
 302                                 if (exists $pagesources{$page}) {
 303                                         $content=readfile(srcfile($pagesources{$page}));
 304                                         $content=~s/\n/\r\n/g;
 305                                 }
 306                                 $form->field(name => "editcontent", value => $content,
 307                                         force => 1);
 308                         }
 309                         $form->tmpl_param("page_select", 0);
 310                         $form->field(name => "page", type => 'hidden');
 311                         $form->field(name => "type", type => 'hidden');
 312                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 313                 }
 314
 315                 showform($form, \@buttons, $session, $q,
 316                         forcebaseurl => $baseurl, page => $page);
 317         }
 318         else {
 319                 # save page
 320                 check_canedit($page, $q, $session);
 321                 checksessionexpiry($q, $session, $q->param('sid'));
 322
 323                 my $exists=-e "$config{srcdir}/$file";
 324
 325                 if ($form->field("do") ne "create" && ! $exists &&
 326                     ! defined srcfile($file, 1)) {
 327                         $form->tmpl_param("message", template("editpagegone.tmpl")->output);
 328                         $form->field(name => "do", value => "create", force => 1);
 329                         $form->tmpl_param("page_select", 0);
 330                         $form->field(name => "page", type => 'hidden');
 331                         $form->field(name => "type", type => 'hidden');
 332                         $form->title(sprintf(gettext("editing %s"), $page));
 333                         showform($form, \@buttons, $session, $q,
 334                                 forcebaseurl => $baseurl, page => $page);
 335                         exit;
 336                 }
 337                 elsif ($form->field("do") eq "create" && $exists) {
 338                         $form->tmpl_param("message", template("editcreationconflict.tmpl")->output);
 339                         $form->field(name => "do", value => "edit", force => 1);
 340                         $form->tmpl_param("page_select", 0);
 341                         $form->field(name => "page", type => 'hidden');
 342                         $form->field(name => "type", type => 'hidden');
 343                         $form->title(sprintf(gettext("editing %s"), $page));
 344                         $form->field("editcontent",
 345                                 value => readfile("$config{srcdir}/$file").
 346                                          "\n\n\n".$form->field("editcontent"),
 347                                 force => 1);
 348                         showform($form, \@buttons, $session, $q,
 349                                 forcebaseurl => $baseurl, page => $page);
 350                         exit;
 351                 }
 352
 353                 my $message="";
 354                 if (defined $form->field('editmessage') &&
 355                     length $form->field('editmessage')) {
 356                         $message=$form->field('editmessage');
 357                 }
 358
 359                 my $content=$form->field('editcontent');
 360                 check_content(content => $content, page => $page,
 361                         cgi => $q, session => $session,
 362                         subject => $message);
 363                 run_hooks(editcontent => sub {
 364                         $content=shift->(
 365                                 content => $content,
 366                                 page => $page,
 367                                 cgi => $q,
 368                                 session => $session,
 369                         );
 370                 });
 371                 $content=~s/\r\n/\n/g;
 372                 $content=~s/\r/\n/g;
 373                 $content.="\n" if $content !~ /\n$/;
 374
 375                 $config{cgi}=0; # avoid cgi error message
 376                 eval { writefile($file, $config{srcdir}, $content) };
 377                 $config{cgi}=1;
 378                 if ($@) {
 379                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 380                                 force => 1);
 381                         my $mtemplate=template("editfailedsave.tmpl");
 382                         $mtemplate->param(error_message => $@);
 383                         $form->tmpl_param("message", $mtemplate->output);
 384                         $form->field("editcontent", value => $content, force => 1);
 385                         $form->tmpl_param("page_select", 0);
 386                         $form->field(name => "page", type => 'hidden');
 387                         $form->field(name => "type", type => 'hidden');
 388                         $form->title(sprintf(gettext("editing %s"), $page));
 389                         showform($form, \@buttons, $session, $q,
 390                                 forcebaseurl => $baseurl, page => $page);
 391                         exit;
 392                 }
 393
 394                 my $conflict;
 395                 if ($config{rcs}) {
 396                         if (! $exists) {
 397                                 rcs_add($file);
 398                         }
 399
 400                         # Prevent deadlock with post-commit hook by
 401                         # signaling to it that it should not try to
 402                         # do anything.
 403                         disable_commit_hook();
 404                         $conflict=rcs_commit(
 405                                 file => $file,
 406                                 message => $message,
 407                                 token => $form->field("rcsinfo"),
 408                                 session => $session,
 409                         );
 410                         enable_commit_hook();
 411                         rcs_update();
 412                 }
 413
 414                 # Refresh even if there was a conflict, since other changes
 415                 # may have been committed while the post-commit hook was
 416                 # disabled.
 417                 require IkiWiki::Render;
 418                 refresh();
 419                 saveindex();
 420
 421                 if (defined $conflict) {
 422                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 423                                 force => 1);
 424                         $form->tmpl_param("message", template("editconflict.tmpl")->output);
 425                         $form->field("editcontent", value => $conflict, force => 1);
 426                         $form->field("do", "edit", force => 1);
 427                         $form->tmpl_param("page_select", 0);
 428                         $form->field(name => "page", type => 'hidden');
 429                         $form->field(name => "type", type => 'hidden');
 430                         $form->title(sprintf(gettext("editing %s"), $page));
 431                         showform($form, \@buttons, $session, $q,
 432                                 forcebaseurl => $baseurl, page => $page);
 433                 }
 434                 else {
 435                         # The trailing question mark tries to avoid broken
 436                         # caches and get the most recent version of the page.
 437                         redirect($q, urlto($page, undef)."?updated");
 438                 }
 439         }
 440
 441         exit;
 442 }
 443
 444 1